helm/software/matita/nlibrary/logic/cprop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "hints_declaration.ma".
  16 include "sets/setoids1.ma".
  17
  18 ndefinition CPROP: setoid1.
  19  napply mk_setoid1
  20   [ napply CProp[0]
  21   | napply (mk_equivalence_relation1 CProp[0])
  22      [ napply iff
  23      | #x; napply mk_iff; #H; nassumption
  24      | #x; #y; *; #H1; #H2; napply mk_iff; nassumption
  25      | #x; #y; #z; *; #H1; #H2; *; #H3; #H4; napply mk_iff; #w
  26         [ napply (H3 (H1 w)) | napply (H2 (H4 w))]##]##]
  27 nqed.
  28
  29 alias symbol "hint_decl" = "hint_decl_CProp2".
  30 unification hint 0 ≔ ⊢ CProp[0] ≡ carr1 CPROP.
  31
  32 (*ndefinition CProp0_of_CPROP: carr1 CPROP → CProp[0] ≝ λx.x.
  33 ncoercion CProp0_of_CPROP : ∀x: carr1 CPROP. CProp[0] ≝ CProp0_of_CPROP
  34  on _x: carr1 CPROP to CProp[0].*)
  35
  36 alias symbol "eq" = "setoid1 eq".
  37
  38 ndefinition fi': ∀A,B:CPROP. A = B → B → A.
  39  #A; #B; #H; napply (fi … H); nassumption.
  40 nqed.
  41
  42 notation ". r" with precedence 50 for @{'fi $r}.
  43 interpretation "fi" 'fi r = (fi' ?? r).
  44
  45 ndefinition and_morphism: unary_morphism1 CPROP (unary_morphism1_setoid1 CPROP CPROP).
  46  napply (mk_binary_morphism1 … And);
  47  #a; #a'; #b; #b'; #Ha; #Hb; @; *; #x; #y; @
  48   [ napply (. Ha^-1) | napply (. Hb^-1) | napply (. Ha) | napply (. Hb)] //.
  49 nqed.
  50
  51 unification hint 0 ≔ A,B ⊢
  52  mk_unary_morphism1 …
  53   (λX.mk_unary_morphism1 … (And X) (prop11 … (and_morphism X)))
  54   (prop11 … and_morphism)
  55    A B ≡ And A B.
  56
  57 (*
  58 naxiom daemon: False.
  59
  60 nlemma test: ∀A,A',B: CProp[0]. A=A' → (B ∨ A) = B → (B ∧ A) ∧ B.
  61  #A; #A'; #B; #H1; #H2; napply (. (#‡H1)‡H2^-1); nelim daemon.
  62 nqed.
  63
  64 CSC: ugly proof term
  65 ncheck test.
  66 *)
  67
  68 ndefinition or_morphism: unary_morphism1 CPROP (unary_morphism1_setoid1 CPROP CPROP).
  69  napply (mk_binary_morphism1 … Or);
  70  #a; #a'; #b; #b'; #Ha; #Hb; @; *; #x
  71   [ @1; napply (. Ha^-1) | @2; napply (. Hb^-1) | @1; napply (. Ha) | @2; napply (. Hb)] //.
  72 nqed.
  73
  74 unification hint 0 ≔ A,B ⊢
  75  mk_unary_morphism1 …
  76   (λX.mk_unary_morphism1 … (Or X) (prop11 … (or_morphism X)))
  77   (prop11 … or_morphism)
  78   A B ≡ Or A B.
  79
  80 ndefinition if_morphism: unary_morphism1 CPROP (unary_morphism1_setoid1 CPROP CPROP).
  81  napply (mk_binary_morphism1 … (λA,B:CProp[0]. A → B));
  82  #a; #a'; #b; #b'; #Ha; #Hb; @; #H; #x
  83   [ napply (. Hb^-1); napply H; napply (. Ha) | napply (. Hb); napply H; napply (. Ha^-1)]
  84  //.
  85 nqed.
  86
  87 unification hint 0 ≔ A,B ⊢
  88  mk_unary_morphism1 …
  89   (λX:CProp[0].mk_unary_morphism1 … (λY:CProp[0]. X → Y) (prop11 … (if_morphism X)))
  90   (prop11 … if_morphism)
  91   A B ≡ A → B.
  92
  93 (* not as morphism *)
  94 nlemma Not_morphism : CProp[0] ⇒_1 CProp[0].
  95 @(λx:CProp[0].¬ x); #a b; *; #; @; /3/; nqed.
  96
  97 unification hint 0 ≔ P : CProp[0];
  98    A ≟ CPROP,
  99    B ≟ CPROP,
 100    M ≟ mk_unary_morphism1 ?? (λP.¬ P) (prop11 ?? Not_morphism)
 101 (*------------------------*)⊢
 102   fun11 A B M P ≡ ¬ P.
 103
 104 (* Ex setoid support *)
 105
 106 (* The caml, as some patches for it
 107 ncoercion setoid1_of_setoid : ∀s:setoid. setoid1 ≝ setoid1_of_setoid on _s: setoid to setoid1.
 108 *)
 109
 110 (* simple case where the whole predicate can be rewritten *)
 111 nlemma Ex_morphism : ∀S:setoid.((setoid1_of_setoid S) ⇒_1 CProp[0]) ⇒_1 CProp[0].
 112 #S; @(λP: (setoid1_of_setoid S) ⇒_1 CProp[0].Ex S P);
 113 #P Q E; @; *; #x Px; @x; ncases (E x x #); /2/; nqed.
 114
 115 unification hint 0 ≔ S : setoid, P : (setoid1_of_setoid S) ⇒_1 CProp[0];
 116    A ≟ unary_morphism1_setoid1 (setoid1_of_setoid S) CPROP,
 117    B ≟ CPROP,
 118    M ≟ mk_unary_morphism1 ?? (λP: (setoid1_of_setoid S) ⇒_1 CProp[0].Ex S P)
 119         (prop11 ?? (Ex_morphism S))
 120 (*------------------------*)⊢
 121   fun11 A B M P ≡ Ex S (fun11 (setoid1_of_setoid S) CPROP P).
 122
 123 nlemma Ex_morphism_eta : ∀S:setoid.((setoid1_of_setoid S) ⇒_1 CProp[0]) ⇒_1 CProp[0].
 124 #S; @(λP: (setoid1_of_setoid S) ⇒_1 CProp[0].Ex S (λx.P x));
 125 #P Q E; @; *; #x Px; @x; ncases (E x x #); /2/; nqed.
 126
 127 unification hint 0 ≔ S : setoid, P : (setoid1_of_setoid S) ⇒_1 CProp[0];
 128    A ≟ unary_morphism1_setoid1 (setoid1_of_setoid S) CPROP,
 129    B ≟ CPROP,
 130    M ≟ mk_unary_morphism1 ?? (λP: (setoid1_of_setoid S) ⇒_1 CProp[0].Ex S (λx.P x))
 131         (prop11 ?? (Ex_morphism_eta S))
 132 (*------------------------*)⊢
 133   fun11 A B M P ≡ Ex S (λx.fun11 (setoid1_of_setoid S) CPROP P x).
 134
 135 nlemma Ex_setoid : ∀S:setoid.((setoid1_of_setoid S) ⇒_1 CPROP) → setoid.
 136 #T P; @ (Ex T (λx:T.P x)); @; ##[ #H1 H2; napply True |##*: //; ##] nqed.
 137
 138 unification hint 0 ≔ T,P ;
 139    S ≟ (Ex_setoid T P)
 140 (*---------------------------*) ⊢
 141    Ex T (λx:T.P x) ≡ carr S.
 142
 143 (* couts how many Ex we are traversing *)
 144 ninductive counter : Type[0] ≝
 145  | End : counter
 146  | Next : (Prop → Prop) → (* dummy arg please the notation mechanism *)
 147           counter → counter.
 148
 149 (* to rewrite terms (live in setoid) *)
 150 nlet rec mk_P (S, T : setoid) (n : counter) on n ≝
 151   match n with [ End ⇒ T → CProp[0] | Next _ m ⇒ S → (mk_P S T m) ].
 152
 153 nlet rec mk_F (S, T : setoid) (n : counter) on n ≝
 154   match n with [ End ⇒ T | Next _ m ⇒ S → (mk_F S T m) ].
 155
 156 nlet rec mk_E (S, T : setoid) (n : counter) on n : ∀f,g : mk_F S T n. CProp[0] ≝
 157   match n with
 158   [ End ⇒ λf,g:T. f = g
 159   | Next q m ⇒ λf,g: mk_F S T (Next q m). ∀x:S.mk_E S T m (f x) (g x) ].
 160
 161 nlet rec mk_H (S, T : setoid) (n : counter) on n :
 162 ∀P1,P2: mk_P S T n.∀f,g : mk_F S T n. CProp[1] ≝
 163   match n with
 164   [ End ⇒ λP1,P2:mk_P S T End.λf,g:T. f = g → P1 f =_1 P2 g
 165   | Next q m ⇒ λP1,P2: mk_P S T (Next q m).λf,g: mk_F S T (Next q m).
 166               ∀x:S.mk_H S T m (P1 x) (P2 x) (f x) (g x) ].
 167
 168 nlet rec mk_Ex (S, T : setoid) (n : counter) on n :
 169 ∀P: mk_P S T n.∀f : mk_F S T n. CProp[0] ≝
 170   match n with
 171   [ End ⇒ λP:mk_P S T End.λf:T. P f
 172   | Next q m ⇒ λP: mk_P S T (Next q m).λf: mk_F S T (Next q m).
 173               ∃x:S.mk_Ex S T m (P x) (f x) ].
 174
 175 nlemma Sig_generic : ∀S,T.∀n:counter.∀P,f,g.
 176   mk_E S T n f g → mk_H S T n P P f g → mk_Ex S T n P f =_1 mk_Ex S T n P g.
 177 #S T n; nelim n; nnormalize;
 178 ##[ #P f g E H; /2/;
 179 ##| #q m IH P f g E H; @; *; #x Px; @x; ncases (IH … (E x) (H x)); /3/; ##]
 180 nqed.
 181
 182 (* to rewrite propositions (live in setoid1) *)
 183 nlet rec mk_P1 (S : setoid) (T : setoid1) (n : counter) on n ≝
 184   match n with [ End ⇒ T → CProp[0] | Next _ m ⇒ S → (mk_P1 S T m) ].
 185
 186 nlet rec mk_F1 (S : setoid) (T : setoid1) (n : counter) on n ≝
 187   match n with [ End ⇒ T | Next _ m ⇒ S → (mk_F1 S T m) ].
 188
 189 nlet rec mk_E1 (S : setoid) (T : setoid1) (n : counter) on n : ∀f,g : mk_F1 S T n. CProp[1] ≝
 190   match n with
 191   [ End ⇒ λf,g:T. f =_1 g
 192   | Next q m ⇒ λf,g: mk_F1 S T (Next q m). ∀x:S.mk_E1 S T m (f x) (g x) ].
 193
 194 nlet rec mk_H1 (S : setoid) (T : setoid1) (n : counter) on n :
 195 ∀P1,P2: mk_P1 S T n.∀f,g : mk_F1 S T n. CProp[1] ≝
 196   match n with
 197   [ End ⇒ λP1,P2:mk_P1 S T End.λf,g:T. f = g → P1 f =_1 P2 g
 198   | Next q m ⇒ λP1,P2: mk_P1 S T (Next q m).λf,g: mk_F1 S T (Next q m).
 199               ∀x:S.mk_H1 S T m (P1 x) (P2 x) (f x) (g x) ].
 200
 201 nlet rec mk_Ex1 (S : setoid) (T : setoid1) (n : counter) on n :
 202 ∀P: mk_P1 S T n.∀f : mk_F1 S T n. CProp[0] ≝
 203   match n with
 204   [ End ⇒ λP:mk_P1 S T End.λf:T. P f
 205   | Next q m ⇒ λP: mk_P1 S T (Next q m).λf: mk_F1 S T (Next q m).
 206               ∃x:S.mk_Ex1 S T m (P x) (f x) ].
 207
 208 nlemma Sig_generic1 : ∀S,T.∀n:counter.∀P,f,g.
 209   mk_E1 S T n f g → mk_H1 S T n P P f g → mk_Ex1 S T n P f =_1 mk_Ex1 S T n P g.
 210 #S T n; nelim n; nnormalize;
 211 ##[ #P f g E H; /2/;
 212 ##| #q m IH P f g E H; @; *; #x Px; @x; ncases (IH … (E x) (H x)); /3/; ##]
 213 nqed.
 214
 215 (* notation "∑x1,...,xn. E / H ; P" were:
 216    - x1...xn are bound in E and P, H is bound in P
 217    - H is an identifier that will have the type of E in P
 218    - P is the proof that the two existentially quantified predicates are equal*)
 219 notation > "∑ list1 ident x sep , . term 56 E / ident nE ; term 19 H" with precedence 20
 220 for @{ 'Sig_gen
 221   ${ fold right @{ 'End }  rec acc @{ ('Next (λ${ident x}.${ident x}) $acc) } }
 222   ${ fold right @{ $E }              rec acc @{ λ${ident x}.$acc } }
 223   ${ fold right @{ λ${ident nE}.$H } rec acc @{ λ${ident x}.$acc } }
 224 }.
 225
 226 interpretation "next" 'Next x y = (Next x y).
 227 interpretation "end" 'End = End.
 228 interpretation "sig_gen" 'Sig_gen n E H = (Sig_generic  ?? n ??? E H).
 229 interpretation "sig_gen1" 'Sig_gen n E H = (Sig_generic1 ?? n ??? E H).
 230
 231 (*
 232 nlemma test0 : ∀S:setoid. ∀P: (setoid1_of_setoid S) ⇒_1 CPROP.∀f,g:S → S.
 233  (∀x:S.f x = g x) → (Ex S (λw.P (f w))) =_1 (Ex S (λw.P (g w))).
 234 #S P f g E; napply (∑w. E w / H ; ┼_1H); nqed.
 235
 236 nlemma test : ∀S:setoid. ∀P: (setoid1_of_setoid S) ⇒_1 CPROP.∀f,g:S → S.
 237  (∀x:S.f x = g x) → (Ex S (λw.P (f w)∧ True)) =_1 (Ex S (λw.P (g w)∧ True)).
 238 #S P f g E; napply (∑w. E w / H ; (┼_1H)╪_1#); nqed.
 239
 240 nlemma test_bound : ∀S:setoid. ∀e,f: (setoid1_of_setoid S) ⇒_1 CPROP. e = f →
 241    (Ex S (λw.e w ∧ True)) =_1 (Ex S (λw.f w ∧ True)).
 242 #S f g E; napply (.=_1 ∑x. E x x # / H ; (H ╪_1 #)); //; nqed.
 243
 244 nlemma test2 : ∀S:setoid. ∀ee: (setoid1_of_setoid S) ⇒_1 (setoid1_of_setoid S) ⇒_1 CPROP.
 245  ∀x,y:setoid1_of_setoid S.x =_1 y →
 246    (True ∧ (Ex S (λw.ee x w ∧ True))) =_1 (True ∧ (Ex S (λw.ee y w ∧ True))).
 247 #S m x y E; napply (.=_1 #╪_1(∑w. E / E ; ((E ╪_1 #) ╪_1 #))). //; nqed.
 248
 249 nlemma test3 : ∀S:setoid. ∀ee: (setoid1_of_setoid S) ⇒_1 (setoid1_of_setoid S) ⇒_1 CPROP.
 250  ∀x,y:setoid1_of_setoid S.x =_1 y →
 251    ((Ex S (λw.ee x w ∧ True) ∨ True)) =_1 ((Ex S (λw.ee y w ∧ True) ∨ True)).
 252 #S m x y E; napply (.=_1 (∑w. E / E ; ((E ╪_1 #) ╪_1 #)) ╪_1 #). //; nqed.
 253 *)
 254