helm/software/matita/nlibrary/sets/setoids.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "logic/connectives.ma".
  16 include "properties/relations.ma".
  17 include "hints_declaration.ma".
  18
  19 nrecord setoid : Type[1] ≝
  20  { carr:> Type[0];
  21    eq0: equivalence_relation carr
  22  }.
  23
  24 interpretation "setoid eq" 'eq t x y = (eq_rel ? (eq0 t) x y).
  25
  26 notation > "hvbox(a break =_0 b)" non associative with precedence 45
  27 for @{ eq_rel ? (eq0 ?) $a $b }.
  28
  29 interpretation "setoid symmetry" 'invert r = (sym ???? r).
  30 notation ".= r" with precedence 50 for @{'trans $r}.
  31 interpretation "trans" 'trans r = (trans ????? r).
  32
  33 nrecord unary_morphism (A,B: setoid) : Type[0] ≝
  34  { fun1:1> A → B;
  35    prop1: ∀a,a'. a = a' → fun1 a = fun1 a'
  36  }.
  37
  38 notation "† c" with precedence 90 for @{'prop1 $c }.
  39 notation "l ‡ r" with precedence 90 for @{'prop2 $l $r }.
  40 notation "#" with precedence 90 for @{'refl}.
  41 interpretation "prop1" 'prop1 c  = (prop1 ????? c).
  42 interpretation "refl" 'refl = (refl ???).
  43
  44 ndefinition unary_morph_setoid : setoid → setoid → setoid.
  45 #S1; #S2; @ (unary_morphism S1 S2); @;
  46 ##[ #f; #g; napply (∀x,x'. x=x' → f x = g x');
  47 ##| #f; #x; #x'; #Hx; napply (.= †Hx); napply #;
  48 ##| #f; #g; #H; #x; #x'; #Hx; napply ((H … Hx^-1)^-1);
  49 ##| #f; #g; #h; #H1; #H2; #x; #x'; #Hx; napply (trans … (H1 …) (H2 …)); //; ##]
  50 nqed.
  51
  52 alias symbol "hint_decl" (instance 1) = "hint_decl_Type1".
  53 unification hint 0 ≔ o1,o2 ;
  54      X ≟ unary_morph_setoid o1 o2
  55   (* ------------------------------ *) ⊢
  56      carr X ≡ unary_morphism o1 o2.
  57
  58 interpretation "prop2" 'prop2 l r = (prop1 ? (unary_morph_setoid ??) ? ?? l ?? r).
  59
  60 nlemma unary_morph_eq: ∀A,B.∀f,g: unary_morphism A B. (∀x. f x = g x) → f=g.
  61 #A B f g H x1 x2 E; napply (.= †E); napply H; nqed.
  62
  63 nlemma mk_binary_morphism:
  64  ∀A,B,C: setoid. ∀f: A → B → C. (∀a,a',b,b'. a=a' → b=b' → f a b = f a' b') →
  65   unary_morphism A (unary_morph_setoid B C).
  66  #A; #B; #C; #f; #H; @ [ #x; @ (f x) ] #a; #a'; #Ha [##2: napply unary_morph_eq; #y]
  67  /2/.
  68 nqed.
  69
  70 ndefinition composition ≝
  71  λo1,o2,o3:Type[0].λf:o2 → o3.λg: o1 → o2.λx.f (g x).
  72
  73 interpretation "function composition" 'compose f g = (composition ??? f g).
  74
  75 ndefinition comp_unary_morphisms:
  76  ∀o1,o2,o3:setoid.
  77   unary_morphism o2 o3 → unary_morphism o1 o2 →
  78    unary_morphism o1 o3.
  79 #o1; #o2; #o3; #f; #g; @ (f ∘ g);
  80  #a; #a'; #e; nnormalize; napply (.= †(†e)); napply #.
  81 nqed.
  82
  83 unification hint 0 ≔ o1,o2,o3:setoid,f:unary_morphism o2 o3,g:unary_morphism o1 o2;
  84    R ≟ mk_unary_morphism ?? (composition … f g)
  85         (prop1 ?? (comp_unary_morphisms o1 o2 o3 f g))
  86  (* -------------------------------------------------------------------- *) ⊢
  87                               fun1 ?? R ≡ (composition … f g).
  88
  89 ndefinition comp_binary_morphisms:
  90  ∀o1,o2,o3.
  91   unary_morphism (unary_morph_setoid o2 o3)
  92    (unary_morph_setoid (unary_morph_setoid o1 o2) (unary_morph_setoid o1 o3)).
  93 #o1; #o2; #o3; napply mk_binary_morphism
  94  [ #f; #g; napply (comp_unary_morphisms … f g) (*CSC: why not ∘?*)
  95  | #a; #a'; #b; #b'; #ea; #eb; #x; #x'; #Hx; nnormalize; /3/ ]
  96 nqed.