helm/software/matita/nlibrary/sets/setoids1.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "properties/relations1.ma".
  16 include "sets/setoids.ma".
  17 include "hints_declaration.ma".
  18
  19 nrecord setoid1: Type[2] ≝ {
  20   carr1:> Type[1];
  21   eq1: equivalence_relation1 carr1
  22 }.
  23
  24 unification hint 0 ≔ R : setoid1;
  25    MR ≟ (carr1 R),
  26    lock ≟ mk_lock2 Type[1] MR setoid1 R
  27 (* ---------------------------------------- *) ⊢
  28    setoid1 ≡ force2 ? MR lock.
  29
  30 notation < "[\setoid1\ensp\of term 19 x]" non associative with precedence 90 for @{'mk_setoid1 $x}.
  31 interpretation "mk_setoid1" 'mk_setoid1 x = (mk_setoid1 x ?).
  32
  33 (* da capire se mettere come coercion *)
  34 ndefinition setoid1_of_setoid: setoid → setoid1.
  35  #s; @ (carr s); @ (eq0…) (refl…) (sym…) (trans…);
  36 nqed.
  37
  38
  39 alias symbol "hint_decl" (instance 1) = "hint_decl_Type2".
  40 unification hint 0 ≔ A,x,y
  41 (*-----------------------------------------------*) ⊢
  42    eq_rel ? (eq0 A) x y ≡ eq_rel1 ? (eq1 (setoid1_of_setoid A)) x y.
  43 (* XXX capire come mai questa hint non funziona se porto su (setoid1_of_setoid A) *)
  44
  45 interpretation "setoid1 eq" 'eq t x y = (eq_rel1 ? (eq1 t) x y).
  46 interpretation "setoid eq" 'eq t x y = (eq_rel ? (eq0 t) x y).
  47
  48 notation > "hvbox(a break =_12 b)" non associative with precedence 45
  49 for @{ eq_rel2 (carr2 (setoid2_of_setoid1 ?)) (eq2 (setoid2_of_setoid1 ?)) $a $b }.
  50 notation > "hvbox(a break =_0 b)" non associative with precedence 45
  51 for @{ eq_rel ? (eq0 ?) $a $b }.
  52 notation > "hvbox(a break =_1 b)" non associative with precedence 45
  53 for @{ eq_rel1 ? (eq1 ?) $a $b }.
  54
  55 interpretation "setoid1 symmetry" 'invert r = (sym1 ???? r).
  56 interpretation "setoid symmetry" 'invert r = (sym ???? r).
  57 notation ".=_1 r" with precedence 50 for @{'trans_x1 $r}.
  58 interpretation "trans1" 'trans r = (trans1 ????? r).
  59 interpretation "trans" 'trans r = (trans ????? r).
  60 interpretation "trans1_x1" 'trans_x1 r = (trans1 ????? r).
  61
  62 nrecord unary_morphism1 (A,B: setoid1) : Type[1] ≝ {
  63   fun11:1> A → B;
  64   prop11: ∀a,a'. eq1 ? a a' → eq1 ? (fun11 a) (fun11 a')
  65 }.
  66
  67 notation > "B ⇒_1 C" right associative with precedence 72 for @{'umorph1 $B $C}.
  68 notation "hvbox(B break ⇒\sub 1 C)" right associative with precedence 72 for @{'umorph1 $B $C}.
  69 interpretation "unary morphism 1" 'umorph1 A B = (unary_morphism1 A B).
  70
  71 notation "┼_1 c" with precedence 89 for @{'prop1_x1 $c }.
  72 interpretation "prop11" 'prop1 c = (prop11 ????? c).
  73 interpretation "prop11_x1" 'prop1_x1 c = (prop11 ????? c).
  74 interpretation "refl1" 'refl = (refl1 ???).
  75
  76 ndefinition unary_morphism1_setoid1: setoid1 → setoid1 → setoid1.
  77  #s; #s1; @ (s ⇒_1 s1); @
  78      [ #f; #g; napply (∀a,a':s. a=a' → f a = g a')
  79      | #x; #a; #a'; #Ha; napply (.= †Ha); napply refl1
  80      | #x; #y; #H; #a; #a'; #Ha; napply (.= †Ha); napply sym1; /2/
  81      | #x; #y; #z; #H1; #H2; #a; #a'; #Ha; napply (.= †Ha); napply trans1; ##[##2: napply H1 | ##skip | napply H2]//;##]
  82 nqed.
  83
  84 unification hint 0 ≔ S, T ;
  85    R ≟ (unary_morphism1_setoid1 S T)
  86 (* --------------------------------- *) ⊢
  87    carr1 R ≡ S ⇒_1 T.
  88
  89 notation "l ╪_1 r" with precedence 89 for @{'prop2_x1 $l $r }.
  90 interpretation "prop21" 'prop2 l r = (prop11 ? (unary_morphism1_setoid1 ??) ? ?? l ?? r).
  91 interpretation "prop21_x1" 'prop2_x1 l r = (prop11 ? (unary_morphism1_setoid1 ??) ? ?? l ?? r).
  92
  93 nlemma unary_morph1_eq1: ∀A,B.∀f,g: A ⇒_1 B. (∀x. f x = g x) → f = g.
  94 /3/. nqed.
  95
  96 nlemma mk_binary_morphism1:
  97  ∀A,B,C: setoid1. ∀f: A → B → C. (∀a,a',b,b'. a=a' → b=b' → f a b = f a' b') →
  98   A ⇒_1 (unary_morphism1_setoid1 B C).
  99  #A; #B; #C; #f; #H; @ [ #x; @ (f x) ] #a; #a'; #Ha [##2: napply unary_morph1_eq1; #y]
 100  /2/.
 101 nqed.
 102
 103 ndefinition composition1 ≝
 104  λo1,o2,o3:Type[1].λf:o2 → o3.λg: o1 → o2.λx.f (g x).
 105
 106 interpretation "function composition" 'compose f g = (composition ??? f g).
 107 interpretation "function composition1" 'compose f g = (composition1 ??? f g).
 108
 109 ndefinition comp1_unary_morphisms:
 110   ∀o1,o2,o3:setoid1.o2 ⇒_1 o3 → o1 ⇒_1 o2 → o1 ⇒_1 o3.
 111 #o1; #o2; #o3; #f; #g; @ (f ∘ g);
 112  #a; #a'; #e; nnormalize; napply (.= †(†e)); napply #.
 113 nqed.
 114
 115 unification hint 0 ≔ o1,o2,o3:setoid1,f:o2 ⇒_1 o3,g:o1 ⇒_1 o2;
 116    R ≟ (mk_unary_morphism1 ?? (composition1 ??? f g)
 117         (prop11 ?? (comp1_unary_morphisms o1 o2 o3 f g)))
 118  (* -------------------------------------------------------------------- *) ⊢
 119                               fun11 ?? R ≡ (composition1 ??? f g).
 120
 121 ndefinition comp1_binary_morphisms:
 122  ∀o1,o2,o3. (o2 ⇒_1 o3) ⇒_1 ((o1 ⇒_1 o2) ⇒_1 (o1 ⇒_1 o3)).
 123 #o1; #o2; #o3; napply mk_binary_morphism1
 124  [ #f; #g; napply (comp1_unary_morphisms … f g)
 125  | #a; #a'; #b; #b'; #ea; #eb; #x; #x'; #Hx; nnormalize; /3/ ]
 126 nqed.