helm/software/matita/nlibrary/sets/sets.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 (******************* SETS OVER TYPES *****************)
  16
  17 include "logic/connectives.ma".
  18
  19 nrecord powerclass (A: Type[0]) : Type[1] ≝ { mem: A → CProp[0] }.
  20
  21 interpretation "mem" 'mem a S = (mem ? S a).
  22 interpretation "powerclass" 'powerset A = (powerclass A).
  23 interpretation "subset construction" 'subset \eta.x = (mk_powerclass ? x).
  24
  25 ndefinition subseteq ≝ λA.λU,V.∀a:A. a ∈ U → a ∈ V.
  26 interpretation "subseteq" 'subseteq U V = (subseteq ? U V).
  27
  28 ndefinition overlaps ≝ λA.λU,V.∃x:A.x ∈ U ∧ x ∈ V.
  29 interpretation "overlaps" 'overlaps U V = (overlaps ? U V).
  30
  31 ndefinition intersect ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∧ x ∈ V }.
  32 interpretation "intersect" 'intersects U V = (intersect ? U V).
  33
  34 ndefinition union ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∨ x ∈ V }.
  35 interpretation "union" 'union U V = (union ? U V).
  36
  37 ndefinition big_union ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∃i. i ∈ T ∧ x ∈ f i }.
  38
  39 ndefinition big_intersection ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∀i. i ∈ T → x ∈ f i }.
  40
  41 ndefinition full_set: ∀A. Ω^A ≝ λA.{ x | True }.
  42
  43 nlemma subseteq_refl: ∀A.∀S: Ω^A. S ⊆ S.
  44  #A; #S; #x; #H; nassumption.
  45 nqed.
  46
  47 nlemma subseteq_trans: ∀A.∀S,T,U: Ω^A. S ⊆ T → T ⊆ U → S ⊆ U.
  48  #A; #S; #T; #U; #H1; #H2; #x; #P; napply H2; napply H1; nassumption.
  49 nqed.
  50
  51 include "properties/relations1.ma".
  52
  53 ndefinition seteq: ∀A. equivalence_relation1 (Ω^A).
  54  #A; @
  55   [ napply (λS,S'. S ⊆ S' ∧ S' ⊆ S)
  56   | #S; @; napply subseteq_refl
  57   | #S; #S'; *; #H1; #H2; @; nassumption
  58   | #S; #T; #U; *; #H1; #H2; *; #H3; #H4; @; napply subseteq_trans;
  59      ##[##2,5: nassumption |##1,4: ##skip |##*: nassumption]##]
  60 nqed.
  61
  62 include "sets/setoids1.ma".
  63
  64 (* this has to be declared here, so that it is combined with carr *)
  65 ncoercion full_set : ∀A:Type[0]. Ω^A ≝ full_set on A: Type[0] to (Ω^?).
  66
  67 ndefinition powerclass_setoid: Type[0] → setoid1.
  68  #A; @[ napply (Ω^A)| napply seteq ]
  69 nqed.
  70
  71 include "hints_declaration.ma".
  72
  73 alias symbol "hint_decl" = "hint_decl_Type2".
  74 unification hint 0 ≔ A ⊢ carr1 (mk_setoid1 (Ω^A) (eq1 (powerclass_setoid A))) ≡ Ω^A.
  75
  76 (************ SETS OVER SETOIDS ********************)
  77
  78 include "logic/cprop.ma".
  79
  80 nrecord ext_powerclass (A: setoid) : Type[1] ≝
  81  { ext_carr:> Ω^A; (* qui pc viene dichiarato con un target preciso...
  82                 forse lo si vorrebbe dichiarato con un target più lasco
  83                 ma la sintassi :> non lo supporta *)
  84    ext_prop: ∀x,x':A. x=x' → (x ∈ ext_carr) = (x' ∈ ext_carr)
  85  }.
  86
  87 notation > "𝛀 ^ term 90 A" non associative with precedence 70
  88 for @{ 'ext_powerclass $A }.
  89
  90 notation "Ω term 90 A \atop ≈" non associative with precedence 70
  91 for @{ 'ext_powerclass $A }.
  92
  93 interpretation "extensional powerclass" 'ext_powerclass a = (ext_powerclass a).
  94
  95 ndefinition Full_set: ∀A. 𝛀^A.
  96  #A; @[ napply A | #x; #x'; #H; napply refl1]
  97 nqed.
  98 ncoercion Full_set: ∀A. ext_powerclass A ≝ Full_set on A: setoid to ext_powerclass ?.
  99
 100 ndefinition ext_seteq: ∀A. equivalence_relation1 (𝛀^A).
 101  #A; @
 102   [ napply (λS,S'. S = S')
 103   | #S; napply (refl1 ? (seteq A))
 104   | #S; #S'; napply (sym1 ? (seteq A))
 105   | #S; #T; #U; napply (trans1 ? (seteq A))]
 106 nqed.
 107
 108 ndefinition ext_powerclass_setoid: setoid → setoid1.
 109  #A; @
 110   [ napply (ext_powerclass A)
 111   | napply (ext_seteq A) ]
 112 nqed.
 113
 114 unification hint 0 ≔ A;
 115       R ≟ (mk_setoid1 (𝛀^A) (eq1 (ext_powerclass_setoid A)))
 116   (* ----------------------------------------------------- *) ⊢
 117                  carr1 R ≡ ext_powerclass A.
 118
 119
 120 (*
 121 ncoercion ext_carr' : ∀A.∀x:ext_powerclass_setoid A. Ω^A ≝ ext_carr
 122 on _x : (carr1 (ext_powerclass_setoid ?)) to (Ω^?).
 123 *)
 124
 125 nlemma mem_ext_powerclass_setoid_is_morph:
 126  ∀A. binary_morphism1 (setoid1_of_setoid A) (ext_powerclass_setoid A) CPROP.
 127  #A; @
 128   [ napply (λx,S. x ∈ S)
 129   | #a; #a'; #b; #b'; #Ha; *; #Hb1; #Hb2; @; #H;
 130      ##[ napply Hb1; napply (. (ext_prop … Ha^-1)); nassumption;
 131      ##| napply Hb2; napply (. (ext_prop … Ha)); nassumption;
 132      ##]
 133   ##]
 134 nqed.
 135
 136 unification hint 0 ≔  A:setoid, x, S;
 137      SS ≟ (ext_carr ? S),
 138      TT ≟ (mk_binary_morphism1 ???
 139              (λx:setoid1_of_setoid ?.λS:ext_powerclass_setoid ?. x ∈ S)
 140              (prop21 ??? (mem_ext_powerclass_setoid_is_morph A))),
 141      M1 ≟ ?,
 142      M2 ≟ ?,
 143      M3 ≟ ?
 144   (*-------------------------------------*) ⊢
 145       fun21 M1 M2 M3 TT x S ≡ mem A SS x.
 146
 147 nlemma subseteq_is_morph: ∀A. binary_morphism1 (ext_powerclass_setoid A) (ext_powerclass_setoid A) CPROP.
 148  #A; @
 149   [ napply (λS,S'. S ⊆ S')
 150   | #a; #a'; #b; #b'; *; #Ha1; #Ha2; *; #Hb1; #Hb2; @; #H
 151      [ napply (subseteq_trans … a)
 152         [ nassumption | napply (subseteq_trans … b); nassumption ]
 153    ##| napply (subseteq_trans … a')
 154         [ nassumption | napply (subseteq_trans … b'); nassumption ] ##]
 155 nqed.
 156
 157 unification hint 0 ≔ A,a,a'
 158  (*-----------------------------------------------------------------*) ⊢
 159   eq_rel ? (eq A) a a' ≡ eq_rel1 ? (eq1 (setoid1_of_setoid A)) a a'.
 160
 161 nlemma intersect_is_ext: ∀A. 𝛀^A → 𝛀^A → 𝛀^A.
 162  #A; #S; #S'; @ (S ∩ S');
 163  #a; #a'; #Ha; @; *; #H1; #H2; @
 164   [##1,2: napply (. Ha^-1‡#); nassumption;
 165 ##|##3,4: napply (. Ha‡#); nassumption]
 166 nqed.
 167
 168 alias symbol "hint_decl" = "hint_decl_Type1".
 169 unification hint 0 ≔
 170   A : setoid, B,C : ext_powerclass A;
 171   R ≟ (mk_ext_powerclass ? (B ∩ C) (ext_prop ? (intersect_is_ext ? B C)))
 172
 173   (* ------------------------------------------*)  ⊢
 174     ext_carr A R ≡ intersect ? (ext_carr ? B) (ext_carr ? C).
 175
 176 nlemma intersect_is_morph:
 177  ∀A. binary_morphism1 (powerclass_setoid A) (powerclass_setoid A) (powerclass_setoid A).
 178  #A; @ (λS,S'. S ∩ S');
 179  #a; #a'; #b; #b'; *; #Ha1; #Ha2; *; #Hb1; #Hb2; @; #x; nnormalize; *; #Ka; #Kb; @
 180   [ napply Ha1; nassumption
 181   | napply Hb1; nassumption
 182   | napply Ha2; nassumption
 183   | napply Hb2; nassumption]
 184 nqed.
 185
 186 alias symbol "hint_decl" = "hint_decl_Type1".
 187 unification hint 0 ≔
 188   A : Type[0], B,C : Ω^A;
 189   R ≟ (mk_binary_morphism1 …
 190        (λS,S'.S ∩ S')
 191        (prop21 … (intersect_is_morph A)))
 192    ⊢
 193     fun21 (powerclass_setoid A) (powerclass_setoid A) (powerclass_setoid A) R B C
 194   ≡ intersect ? B C.
 195
 196 ndefinition prop21_mem :
 197   ∀A,C.∀f:binary_morphism1 (setoid1_of_setoid A) (ext_powerclass_setoid A) C.
 198    ∀a,a':setoid1_of_setoid A.
 199     ∀b,b':ext_powerclass_setoid A.a = a' → b = b' → f a b = f a' b'.
 200 #A; #C; #f; #a; #a'; #b; #b'; #H1; #H2; napply prop21; nassumption;
 201 nqed.
 202
 203 interpretation "prop21 mem" 'prop2 l r = (prop21_mem ??????? l r).
 204
 205 nlemma intersect_is_ext_morph:
 206  ∀A. binary_morphism1 (ext_powerclass_setoid A) (ext_powerclass_setoid A) (ext_powerclass_setoid A).
 207  #A; @ (intersect_is_ext …); nlapply (prop21 … (intersect_is_morph A));
 208 #H; #a; #a'; #b; #b'; #H1; #H2; napply H; nassumption;
 209 nqed.
 210
 211 unification hint 1 ≔
 212       A:setoid, B,C : 𝛀^A;
 213       R ≟ (mk_binary_morphism1 (ext_powerclass_setoid A) (ext_powerclass_setoid A) (ext_powerclass_setoid A)
 214               (λS,S':carr1 (ext_powerclass_setoid A).
 215                 mk_ext_powerclass A (S∩S') (ext_prop A (intersect_is_ext ? S S')))
 216               (prop21 … (intersect_is_ext_morph A))) ,
 217        BB ≟ (ext_carr ? B),
 218        CC ≟ (ext_carr ? C)
 219    (* ------------------------------------------------------*) ⊢
 220             ext_carr A
 221              (fun21
 222               (ext_powerclass_setoid A)
 223               (ext_powerclass_setoid A)
 224               (ext_powerclass_setoid A) R B C) ≡
 225             intersect (carr A) BB CC.
 226
 227 (*
 228
 229
 230 nlemma test: ∀U.∀A,B:qpowerclass U. A ∩ B = A →
 231  ∀x,y. x=y → x ∈ A → y ∈ A ∩ B.
 232  #U; #A; #B; #H; #x; #y; #K; #K2; napply (. #‡(?));
 233 ##[ nchange with (A ∩ B = ?);
 234     napply (prop21 ??? (mk_binary_morphism1 … (λS,S'.S ∩ S') (prop21 … (intersect_ok' U))) A A B B ##);
 235     #H; napply H;
 236   nassumption;
 237 nqed.
 238
 239 (*
 240 nlemma intersect_ok: ∀A. binary_morphism1 (qpowerclass_setoid A) (qpowerclass_setoid A) (qpowerclass_setoid A).
 241  #A; @
 242   [ #S; #S'; @
 243      [ napply (S ∩ S')
 244      | #a; #a'; #Ha;
 245         nwhd in ⊢ (? ? ? % %); @; *; #H1; #H2; @
 246         [##1,2: napply (. Ha^-1‡#); nassumption;
 247       ##|##3,4: napply (. Ha‡#); nassumption]##]
 248  ##| #a; #a'; #b; #b'; #Ha; #Hb; nwhd; @; #x; nwhd in ⊢ (% → %); #H
 249       [ alias symbol "invert" = "setoid1 symmetry".
 250         napply (. ((#‡Ha^-1)‡(#‡Hb^-1))); nassumption
 251       | napply (. ((#‡Ha)‡(#‡Hb))); nassumption ]##]
 252 nqed.
 253
 254 (* unfold if intersect, exposing fun21 *)
 255 alias symbol "hint_decl" = "hint_decl_Type1".
 256 unification hint 0 ≔
 257   A : setoid, B,C : qpowerclass A ⊢
 258     pc A (fun21 …
 259             (mk_binary_morphism1 …
 260               (λS,S':qpowerclass_setoid A.mk_qpowerclass ? (S ∩ S') (mem_ok' ? (intersect_ok ? S S')))
 261               (prop21 … (intersect_ok A)))
 262             B
 263             C)
 264     ≡ intersect ? (pc ? B) (pc ? C).
 265
 266 nlemma test: ∀A:setoid. ∀U,V:qpowerclass A. ∀x,x':setoid1_of_setoid A. x=x' → x ∈ U ∩ V → x' ∈ U ∩ V.
 267  #A; #U; #V; #x; #x'; #H; #p; napply (. (H^-1‡#)); nassumption.
 268 nqed.
 269 *)
 270 *)
 271
 272 ndefinition image: ∀A,B. (carr A → carr B) → Ω^A → Ω^B ≝
 273  λA,B:setoid.λf:carr A → carr B.λSa:Ω^A.
 274   {y | ∃x. x ∈ Sa ∧ eq_rel (carr B) (eq B) (f x) y}.
 275
 276 ndefinition counter_image: ∀A,B. (carr A → carr B) → Ω^B → Ω^A ≝
 277  λA,B,f,Sb. {x | ∃y. y ∈ Sb ∧ f x = y}.
 278
 279 (******************* compatible equivalence relations **********************)
 280
 281 nrecord compatible_equivalence_relation (A: setoid) : Type[1] ≝
 282  { rel:> equivalence_relation A;
 283    compatibility: ∀x,x':A. x=x' → rel x x'
 284  }.
 285
 286 ndefinition quotient: ∀A. compatible_equivalence_relation A → setoid.
 287  #A; #R; @ A R;
 288 nqed.
 289
 290 (******************* first omomorphism theorem for sets **********************)
 291
 292 ndefinition eqrel_of_morphism:
 293  ∀A,B. unary_morphism A B → compatible_equivalence_relation A.
 294  #A; #B; #f; @
 295   [ @
 296      [ napply (λx,y. f x = f y)
 297      | #x; napply refl | #x; #y; napply sym | #x; #y; #z; napply trans]
 298 ##| #x; #x'; #H; nwhd; alias symbol "prop1" = "prop1".
 299 napply (.= (†H)); napply refl ]
 300 nqed.
 301
 302 ndefinition canonical_proj: ∀A,R. unary_morphism A (quotient A R).
 303  #A; #R; @
 304   [ napply (λx.x) | #a; #a'; #H; napply (compatibility … R … H) ]
 305 nqed.
 306
 307 ndefinition quotiented_mor:
 308  ∀A,B.∀f:unary_morphism A B.
 309   unary_morphism (quotient … (eqrel_of_morphism … f)) B.
 310  #A; #B; #f; @
 311   [ napply f | #a; #a'; #H; nassumption]
 312 nqed.
 313
 314 nlemma first_omomorphism_theorem_functions1:
 315  ∀A,B.∀f: unary_morphism A B.
 316   ∀x. f x = quotiented_mor … (canonical_proj … (eqrel_of_morphism … f) x).
 317  #A; #B; #f; #x; napply refl;
 318 nqed.
 319
 320 ndefinition surjective ≝
 321  λA,B.λS: ext_powerclass A.λT: ext_powerclass B.λf:unary_morphism A B.
 322   ∀y. y ∈ T → ∃x. x ∈ S ∧ f x = y.
 323
 324 ndefinition injective ≝
 325  λA,B.λS: ext_powerclass A.λf:unary_morphism A B.
 326   ∀x,x'. x ∈ S → x' ∈ S → f x = f x' → x = x'.
 327
 328 nlemma first_omomorphism_theorem_functions2:
 329  ∀A,B.∀f: unary_morphism A B.
 330    surjective … (Full_set ?) (Full_set ?) (canonical_proj ? (eqrel_of_morphism … f)).
 331  #A; #B; #f; nwhd; #y; #Hy; @ y; @ I ; napply refl;
 332  (* bug, prova @ I refl *)
 333 nqed.
 334
 335 nlemma first_omomorphism_theorem_functions3:
 336  ∀A,B.∀f: unary_morphism A B.
 337    injective … (Full_set ?) (quotiented_mor … f).
 338  #A; #B; #f; nwhd; #x; #x'; #Hx; #Hx'; #K; nassumption.
 339 nqed.
 340
 341 nrecord isomorphism (A, B : setoid) (S: ext_powerclass A) (T: ext_powerclass B) : Type[0] ≝
 342  { iso_f:> unary_morphism A B;
 343    f_closed: ∀x. x ∈ S → iso_f x ∈ T;
 344    f_sur: surjective … S T iso_f;
 345    f_inj: injective … S iso_f
 346  }.
 347
 348 (*
 349 nrecord isomorphism (A, B : setoid) (S: qpowerclass A) (T: qpowerclass B) : CProp[0] ≝
 350  { iso_f:> unary_morphism A B;
 351    f_closed: ∀x. x ∈ pc A S → fun1 ?? iso_f x ∈ pc B T}.
 352
 353
 354 ncheck (λA:?.
 355    λB:?.
 356     λS:?.
 357      λT:?.
 358       λxxx:isomorphism A B S T.
 359        match xxx
 360        return λxxx:isomorphism A B S T.
 361                ∀x: carr A.
 362                 ∀x_72: mem (carr A) (pc A S) x.
 363                  mem (carr B) (pc B T) (fun1 A B ((λ_.?) A B S T xxx) x)
 364         with [ mk_isomorphism _ yyy ⇒ yyy ] ).
 365
 366    ;
 367  }.
 368 *)