helm/software/matita/nlibrary/sets/sets.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 (******************* SETS OVER TYPES *****************)
  16
  17 include "logic/connectives.ma".
  18
  19 nrecord powerclass (A: Type[0]) : Type[1] ≝ { mem: A → CProp[0] }.
  20
  21 interpretation "mem" 'mem a S = (mem ? S a).
  22 interpretation "powerclass" 'powerset A = (powerclass A).
  23 interpretation "subset construction" 'subset \eta.x = (mk_powerclass ? x).
  24
  25 ndefinition subseteq ≝ λA.λU,V.∀a:A. a ∈ U → a ∈ V.
  26 interpretation "subseteq" 'subseteq U V = (subseteq ? U V).
  27
  28 ndefinition overlaps ≝ λA.λU,V.∃x:A.x ∈ U ∧ x ∈ V.
  29 interpretation "overlaps" 'overlaps U V = (overlaps ? U V).
  30
  31 ndefinition intersect ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∧ x ∈ V }.
  32 interpretation "intersect" 'intersects U V = (intersect ? U V).
  33
  34 ndefinition union ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∨ x ∈ V }.
  35 interpretation "union" 'union U V = (union ? U V).
  36
  37 ndefinition big_union ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∃i. i ∈ T ∧ x ∈ f i }.
  38
  39 ndefinition big_intersection ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∀i. i ∈ T → x ∈ f i }.
  40
  41 ndefinition full_set: ∀A. Ω^A ≝ λA.{ x | True }.
  42
  43 nlemma subseteq_refl: ∀A.∀S: Ω^A. S ⊆ S.
  44  #A; #S; #x; #H; nassumption.
  45 nqed.
  46
  47 nlemma subseteq_trans: ∀A.∀S,T,U: Ω^A. S ⊆ T → T ⊆ U → S ⊆ U.
  48  #A; #S; #T; #U; #H1; #H2; #x; #P; napply H2; napply H1; nassumption.
  49 nqed.
  50
  51 include "properties/relations1.ma".
  52
  53 ndefinition seteq: ∀A. equivalence_relation1 (Ω^A).
  54  #A; @
  55   [ napply (λS,S'. S ⊆ S' ∧ S' ⊆ S)
  56   | #S; @; napply subseteq_refl
  57   | #S; #S'; *; #H1; #H2; @; nassumption
  58   | #S; #T; #U; *; #H1; #H2; *; #H3; #H4; @; napply subseteq_trans;
  59      ##[##2,5: nassumption |##1,4: ##skip |##*: nassumption]##]
  60 nqed.
  61
  62 include "sets/setoids1.ma".
  63
  64 (* this has to be declared here, so that it is combined with carr *)
  65 ncoercion full_set : ∀A:Type[0]. Ω^A ≝ full_set on A: Type[0] to (Ω^?).
  66
  67 ndefinition powerclass_setoid: Type[0] → setoid1.
  68  #A; @[ napply (Ω^A)| napply seteq ]
  69 nqed.
  70
  71 include "hints_declaration.ma".
  72
  73 alias symbol "hint_decl" = "hint_decl_Type2".
  74 unification hint 0 ≔ A ⊢ carr1 (powerclass_setoid A) ≡ Ω^A.
  75
  76 (************ SETS OVER SETOIDS ********************)
  77
  78 include "logic/cprop.ma".
  79
  80 nrecord qpowerclass (A: setoid) : Type[1] ≝
  81  { pc:> Ω^A; (* qui pc viene dichiarato con un target preciso...
  82                 forse lo si vorrebbe dichiarato con un target più lasco
  83                 ma la sintassi :> non lo supporta *)
  84    mem_ok': ∀x,x':A. x=x' → (x ∈ pc) = (x' ∈ pc)
  85  }.
  86
  87 ndefinition Full_set: ∀A. qpowerclass A.
  88  #A; @[ napply A | #x; #x'; #H; napply refl1]
  89 nqed.
  90 ncoercion Full_set: ∀A. qpowerclass A ≝ Full_set on A: setoid to qpowerclass ?.
  91
  92 ndefinition qseteq: ∀A. equivalence_relation1 (qpowerclass A).
  93  #A; @
  94   [ napply (λS,S'. S = S')
  95   | #S; napply (refl1 ? (seteq A))
  96   | #S; #S'; napply (sym1 ? (seteq A))
  97   | #S; #T; #U; napply (trans1 ? (seteq A))]
  98 nqed.
  99
 100 ndefinition qpowerclass_setoid: setoid → setoid1.
 101  #A; @
 102   [ napply (qpowerclass A)
 103   | napply (qseteq A) ]
 104 nqed.
 105
 106 unification hint 0 ≔ A ⊢
 107   carr1 (qpowerclass_setoid A) ≡ qpowerclass A.
 108
 109 nlemma mem_ok: ∀A. binary_morphism1 (setoid1_of_setoid A) (qpowerclass_setoid A) CPROP.
 110  #A; @
 111   [ napply (λx,S. x ∈ S)
 112   | #a; #a'; #b; #b'; #Ha; *; #Hb1; #Hb2; @; #H;
 113      ##[ napply Hb1; napply (. (mem_ok' …)); ##[##3: napply H| napply Ha^-1;##]
 114      ##| napply Hb2; napply (. (mem_ok' …)); ##[##3: napply H| napply Ha;##]
 115      ##]
 116   ##]
 117 nqed.
 118
 119 unification hint 0 ≔  A:setoid, x, S;
 120          SS ≟ (pc ? S)
 121   (*-------------------------------------*) ⊢
 122     fun21 ??? (mem_ok A) x S ≡ mem A SS x.
 123
 124 nlemma subseteq_ok: ∀A. binary_morphism1 (qpowerclass_setoid A) (qpowerclass_setoid A) CPROP.
 125  #A; @
 126   [ napply (λS,S'. S ⊆ S')
 127   | #a; #a'; #b; #b'; *; #Ha1; #Ha2; *; #Hb1; #Hb2; @; #H
 128      [ napply (subseteq_trans … a)
 129         [ nassumption | napply (subseteq_trans … b); nassumption ]
 130    ##| napply (subseteq_trans … a')
 131         [ nassumption | napply (subseteq_trans … b'); nassumption ] ##]
 132 nqed.
 133
 134 unification hint 0 ≔ A,a,a'
 135  (*-----------------------------------------------------------------*) ⊢
 136   eq_rel ? (eq A) a a' ≡ eq_rel1 ? (eq1 (setoid1_of_setoid A)) a a'.
 137
 138 nlemma intersect_ok: ∀A. binary_morphism1 (qpowerclass_setoid A) (qpowerclass_setoid A) (qpowerclass_setoid A).
 139  #A; @
 140   [ #S; #S'; @
 141      [ napply (S ∩ S')
 142      | #a; #a'; #Ha;
 143         nwhd in ⊢ (? ? ? % %); @; *; #H1; #H2; @
 144         [##1,2: napply (. Ha^-1‡#); nassumption;
 145       ##|##3,4: napply (. Ha‡#); nassumption]##]
 146  ##| #a; #a'; #b; #b'; #Ha; #Hb; nwhd; @; #x; nwhd in ⊢ (% → %); #H
 147       [ alias symbol "invert" = "setoid1 symmetry".
 148         napply (. ((#‡Ha^-1)‡(#‡Hb^-1))); nassumption
 149       | napply (. ((#‡Ha)‡(#‡Hb))); nassumption ]##]
 150 nqed.
 151
 152 (* unfold if intersect, exposing fun21 *)
 153 alias symbol "hint_decl" = "hint_decl_Type1".
 154 unification hint 0 ≔
 155   A : setoid, B,C : qpowerclass A ⊢
 156     pc A (intersect_ok A B C) ≡ intersect ? (pc ? B) (pc ? C).
 157
 158 nlemma test: ∀A:setoid. ∀U,V:qpowerclass A. ∀x,x':setoid1_of_setoid A. x=x' → x ∈ U ∩ V → x' ∈ U ∩ V.
 159  #A; #U; #V; #x; #x'; #H; #p; napply (. (H^-1‡#)); nassumption.
 160 nqed.
 161
 162 ndefinition image: ∀A,B. (carr A → carr B) → Ω^A → Ω^B ≝
 163  λA,B:setoid.λf:carr A → carr B.λSa:Ω^A.
 164   {y | ∃x. x ∈ Sa ∧ eq_rel (carr B) (eq B) (f x) y}.
 165
 166 ndefinition counter_image: ∀A,B. (carr A → carr B) → Ω^B → Ω^A ≝
 167  λA,B,f,Sb. {x | ∃y. y ∈ Sb ∧ f x = y}.
 168
 169 (******************* compatible equivalence relations **********************)
 170
 171 nrecord compatible_equivalence_relation (A: setoid) : Type[1] ≝
 172  { rel:> equivalence_relation A;
 173    compatibility: ∀x,x':A. x=x' → rel x x'
 174  }.
 175
 176 ndefinition quotient: ∀A. compatible_equivalence_relation A → setoid.
 177  #A; #R; @ A R;
 178 nqed.
 179
 180 (******************* first omomorphism theorem for sets **********************)
 181
 182 ndefinition eqrel_of_morphism:
 183  ∀A,B. unary_morphism A B → compatible_equivalence_relation A.
 184  #A; #B; #f; @
 185   [ @
 186      [ napply (λx,y. f x = f y)
 187      | #x; napply refl | #x; #y; napply sym | #x; #y; #z; napply trans]
 188 ##| #x; #x'; #H; nwhd; alias symbol "prop1" = "prop1".
 189 napply (.= (†H)); napply refl ]
 190 nqed.
 191
 192 ndefinition canonical_proj: ∀A,R. unary_morphism A (quotient A R).
 193  #A; #R; @
 194   [ napply (λx.x) | #a; #a'; #H; napply (compatibility … R … H) ]
 195 nqed.
 196
 197 ndefinition quotiented_mor:
 198  ∀A,B.∀f:unary_morphism A B.
 199   unary_morphism (quotient … (eqrel_of_morphism … f)) B.
 200  #A; #B; #f; @
 201   [ napply f | #a; #a'; #H; nassumption]
 202 nqed.
 203
 204 nlemma first_omomorphism_theorem_functions1:
 205  ∀A,B.∀f: unary_morphism A B.
 206   ∀x. f x = quotiented_mor … (canonical_proj … (eqrel_of_morphism … f) x).
 207  #A; #B; #f; #x; napply refl;
 208 nqed.
 209
 210 ndefinition surjective ≝
 211  λA,B.λS: qpowerclass A.λT: qpowerclass B.λf:unary_morphism A B.
 212   ∀y. y ∈ T → ∃x. x ∈ S ∧ f x = y.
 213
 214 ndefinition injective ≝
 215  λA,B.λS: qpowerclass A.λf:unary_morphism A B.
 216   ∀x,x'. x ∈ S → x' ∈ S → f x = f x' → x = x'.
 217
 218 nlemma first_omomorphism_theorem_functions2:
 219  ∀A,B.∀f: unary_morphism A B.
 220    surjective … (Full_set ?) (Full_set ?) (canonical_proj ? (eqrel_of_morphism … f)).
 221  #A; #B; #f; nwhd; #y; #Hy; @ y; @ I ; napply refl;
 222  (* bug, prova @ I refl *)
 223 nqed.
 224
 225 nlemma first_omomorphism_theorem_functions3:
 226  ∀A,B.∀f: unary_morphism A B.
 227    injective … (Full_set ?) (quotiented_mor … f).
 228  #A; #B; #f; nwhd; #x; #x'; #Hx; #Hx'; #K; nassumption.
 229 nqed.
 230
 231 nrecord isomorphism (A, B : setoid) (S: qpowerclass A) (T: qpowerclass B) : Type[0] ≝
 232  { iso_f:> unary_morphism A B;
 233    f_closed: ∀x. x ∈ S → iso_f x ∈ T;
 234    f_sur: surjective … S T iso_f;
 235    f_inj: injective … S iso_f
 236  }.
 237
 238 (*
 239 nrecord isomorphism (A, B : setoid) (S: qpowerclass A) (T: qpowerclass B) : CProp[0] ≝
 240  { iso_f:> unary_morphism A B;
 241    f_closed: ∀x. x ∈ pc A S → fun1 ?? iso_f x ∈ pc B T}.
 242
 243
 244 ncheck (λA:?.
 245    λB:?.
 246     λS:?.
 247      λT:?.
 248       λxxx:isomorphism A B S T.
 249        match xxx
 250        return λxxx:isomorphism A B S T.
 251                ∀x: carr A.
 252                 ∀x_72: mem (carr A) (pc A S) x.
 253                  mem (carr B) (pc B T) (fun1 A B ((λ_.?) A B S T xxx) x)
 254         with [ mk_isomorphism _ yyy ⇒ yyy ] ).
 255
 256    ;
 257  }.
 258 *)