helm/software/matita/nlibrary/sets/sets.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 (******************* SETS OVER TYPES *****************)
  16
  17 include "logic/connectives.ma".
  18
  19 nrecord powerclass (A: Type[0]) : Type[1] ≝ { mem: A → CProp[0] }.
  20
  21 interpretation "mem" 'mem a S = (mem ? S a).
  22 interpretation "powerclass" 'powerset A = (powerclass A).
  23 interpretation "subset construction" 'subset \eta.x = (mk_powerclass ? x).
  24
  25 ndefinition subseteq ≝ λA.λU,V.∀a:A. a ∈ U → a ∈ V.
  26 interpretation "subseteq" 'subseteq U V = (subseteq ? U V).
  27
  28 ndefinition overlaps ≝ λA.λU,V.∃x:A.x ∈ U ∧ x ∈ V.
  29 interpretation "overlaps" 'overlaps U V = (overlaps ? U V).
  30
  31 ndefinition intersect ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∧ x ∈ V }.
  32 interpretation "intersect" 'intersects U V = (intersect ? U V).
  33
  34 ndefinition union ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∨ x ∈ V }.
  35 interpretation "union" 'union U V = (union ? U V).
  36
  37 ndefinition big_union ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∃i. i ∈ T ∧ x ∈ f i }.
  38
  39 ndefinition big_intersection ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∀i. i ∈ T → x ∈ f i }.
  40
  41 ndefinition full_set: ∀A. Ω^A ≝ λA.{ x | True }.
  42
  43 nlemma subseteq_refl: ∀A.∀S: Ω^A. S ⊆ S.
  44 //.nqed.
  45
  46 nlemma subseteq_trans: ∀A.∀S,T,U: Ω^A. S ⊆ T → T ⊆ U → S ⊆ U.
  47 /3/.nqed.
  48
  49 include "properties/relations1.ma".
  50
  51 ndefinition seteq: ∀A. equivalence_relation1 (Ω^A).
  52 #A; @(λS,S'. S ⊆ S' ∧ S' ⊆ S); /2/; ##[ #A B; *; /3/]
  53 #S T U; *; #H1 H2; *; /4/;
  54 nqed.
  55
  56 include "sets/setoids1.ma".
  57
  58 (* this has to be declared here, so that it is combined with carr *)
  59 ncoercion full_set : ∀A:Type[0]. Ω^A ≝ full_set on A: Type[0] to (Ω^?).
  60
  61 ndefinition powerclass_setoid: Type[0] → setoid1.
  62  #A; @(Ω^A);//.
  63 nqed.
  64
  65 include "hints_declaration.ma".
  66
  67 alias symbol "hint_decl" = "hint_decl_Type2".
  68 unification hint 0 ≔ A;
  69   R ≟ (mk_setoid1 (Ω^A) (eq1 (powerclass_setoid A)))
  70 (*--------------------------------------------------*)⊢
  71      carr1 R ≡ Ω^A.
  72
  73 (************ SETS OVER SETOIDS ********************)
  74
  75 include "logic/cprop.ma".
  76
  77 nrecord ext_powerclass (A: setoid) : Type[1] ≝ {
  78    ext_carr:> Ω^A; (* qui pc viene dichiarato con un target preciso...
  79                       forse lo si vorrebbe dichiarato con un target più lasco
  80                       ma la sintassi :> non lo supporta *)
  81    ext_prop: ∀x,x':A. x=x' → (x ∈ ext_carr) = (x' ∈ ext_carr)
  82 }.
  83
  84 notation > "𝛀 ^ term 90 A" non associative with precedence 70
  85 for @{ 'ext_powerclass $A }.
  86
  87 notation < "Ω term 90 A \atop ≈" non associative with precedence 90
  88 for @{ 'ext_powerclass $A }.
  89
  90 interpretation "extensional powerclass" 'ext_powerclass a = (ext_powerclass a).
  91
  92 ndefinition Full_set: ∀A. 𝛀^A.
  93  #A; @[ napply A | #x; #x'; #H; napply refl1]
  94 nqed.
  95 ncoercion Full_set: ∀A. ext_powerclass A ≝ Full_set on A: setoid to ext_powerclass ?.
  96
  97 ndefinition ext_seteq: ∀A. equivalence_relation1 (𝛀^A).
  98  #A; @ [ napply (λS,S'. S = S') ] /2/.
  99 nqed.
 100
 101 ndefinition ext_powerclass_setoid: setoid → setoid1.
 102  #A; @ (ext_seteq A).
 103 nqed.
 104
 105 unification hint 0 ≔ A;
 106       R ≟ (mk_setoid1 (𝛀^A) (eq1 (ext_powerclass_setoid A)))
 107   (* ----------------------------------------------------- *) ⊢
 108                  carr1 R ≡ ext_powerclass A.
 109
 110 nlemma mem_ext_powerclass_setoid_is_morph:
 111  ∀A. (setoid1_of_setoid A) ⇒_1 (unary_morphism1_setoid1 (ext_powerclass_setoid A) CPROP).
 112  #A; napply (mk_binary_morphism1 … (λx:setoid1_of_setoid A.λS: 𝛀^A. x ∈ S));
 113  #a; #a'; #b; #b'; #Ha; *; #Hb1; #Hb2; @; #H
 114   [ napply (. (ext_prop … Ha^-1)) | napply (. (ext_prop … Ha)) ] /2/.
 115 nqed.
 116
 117 unification hint 0 ≔  AA, x, S;
 118      A ≟ carr AA,
 119      SS ≟ (ext_carr ? S),
 120      TT ≟ (mk_unary_morphism1 ??
 121              (λx:setoid1_of_setoid ?.
 122                mk_unary_morphism1 ??
 123                  (λS:ext_powerclass_setoid ?. x ∈ S)
 124                  (prop11 ?? (mem_ext_powerclass_setoid_is_morph AA x)))
 125              (prop11 ?? (mem_ext_powerclass_setoid_is_morph AA))),
 126      XX ≟ (ext_powerclass_setoid AA)
 127   (*-------------------------------------*) ⊢
 128       fun11 (setoid1_of_setoid AA)
 129        (unary_morphism1_setoid1 XX CPROP) TT x S
 130     ≡ mem A SS x.
 131
 132 nlemma set_ext : ∀S.∀A,B:Ω^S.A =_1 B → ∀x:S.(x ∈ A) =_1 (x ∈ B).
 133 #S A B; *; #H1 H2 x; @; ##[ napply H1 | napply H2] nqed.
 134
 135 nlemma ext_set : ∀S.∀A,B:Ω^S.(∀x:S. (x ∈ A) = (x ∈ B)) → A = B.
 136 #S A B H; @; #x; ncases (H x); #H1 H2; ##[ napply H1 | napply H2] nqed.
 137
 138 nlemma subseteq_is_morph: ∀A.
 139  (ext_powerclass_setoid A) ⇒_1
 140    (unary_morphism1_setoid1 (ext_powerclass_setoid A) CPROP).
 141  #A; napply (mk_binary_morphism1 … (λS,S':𝛀^A. S ⊆ S'));
 142  #a; #a'; #b; #b'; *; #H1; #H2; *; /5/ by mk_iff, sym1, subseteq_trans;
 143 nqed.
 144
 145 alias symbol "hint_decl" (instance 1) = "hint_decl_Type2".
 146 unification hint 0 ≔ A,x,y
 147 (*-----------------------------------------------*) ⊢
 148    eq_rel ? (eq0 A) x y ≡ eq_rel1 ? (eq1 (setoid1_of_setoid A)) x y.
 149
 150 (* XXX capire come mai questa hint non funziona se porto su (setoid1_of_setoid A) *)
 151
 152 nlemma intersect_is_ext: ∀A. 𝛀^A → 𝛀^A → 𝛀^A.
 153 #S A B; @ (A ∩ B); #x y Exy; @; *; #H1 H2; @;
 154 ##[##1,2: napply (. Exy^-1‡#); nassumption;
 155 ##|##3,4: napply (. Exy‡#); nassumption]
 156 nqed.
 157
 158 alias symbol "hint_decl" = "hint_decl_Type1".
 159 unification hint 0 ≔
 160   A : setoid, B,C : ext_powerclass A;
 161   R ≟ (mk_ext_powerclass ? (B ∩ C) (ext_prop ? (intersect_is_ext ? B C)))
 162   (* ------------------------------------------*)  ⊢
 163     ext_carr A R ≡ intersect ? (ext_carr ? B) (ext_carr ? C).
 164
 165 nlemma intersect_is_morph:
 166  ∀A. (powerclass_setoid A) ⇒_1 (unary_morphism1_setoid1 (powerclass_setoid A) (powerclass_setoid A)).
 167  #A; napply (mk_binary_morphism1 … (λS,S'. S ∩ S'));
 168  #a; #a'; #b; #b'; *; #Ha1; #Ha2; *; #Hb1; #Hb2; @; #x; nnormalize; *;/3/.
 169 nqed.
 170
 171 alias symbol "hint_decl" = "hint_decl_Type1".
 172 unification hint 0 ≔ A : Type[0], B,C : Ω^A;
 173   R ≟ mk_unary_morphism1 ??
 174        (λS. mk_unary_morphism1 ?? (λS'.S ∩ S') (prop11 ?? (intersect_is_morph A S)))
 175        (prop11 ?? (intersect_is_morph A))
 176 (*------------------------------------------------------------------------*) ⊢
 177     fun11 ?? (fun11 ?? R B) C  ≡ intersect A B C.
 178
 179 interpretation "prop21 ext" 'prop2 l r =
 180  (prop11 (ext_powerclass_setoid ?)
 181   (unary_morphism1_setoid1 (ext_powerclass_setoid ?) ?) ? ?? l ?? r).
 182
 183 nlemma intersect_is_ext_morph:
 184  ∀A.
 185  (ext_powerclass_setoid A) ⇒_1
 186   (unary_morphism1_setoid1 (ext_powerclass_setoid A) (ext_powerclass_setoid A)).
 187  #A; napply (mk_binary_morphism1 … (intersect_is_ext …));
 188  #a; #a'; #b; #b'; #Ha; #Hb; napply (prop11 … (intersect_is_morph A)); nassumption.
 189 nqed.
 190
 191 unification hint 1 ≔
 192       AA : setoid, B,C : 𝛀^AA;
 193       A ≟ carr AA,
 194       R ≟ (mk_unary_morphism1 ??
 195               (λS:𝛀^AA.
 196                mk_unary_morphism1 ??
 197                 (λS':𝛀^AA.
 198                   mk_ext_powerclass AA (S∩S') (ext_prop AA (intersect_is_ext ? S S')))
 199                 (prop11 ?? (intersect_is_ext_morph AA S)))
 200               (prop11 ?? (intersect_is_ext_morph AA))) ,
 201        BB ≟ (ext_carr ? B),
 202        CC ≟ (ext_carr ? C)
 203    (* ------------------------------------------------------*) ⊢
 204             ext_carr AA (R B C) ≡ intersect A BB CC.
 205
 206 nlemma union_is_morph :
 207  ∀A. (powerclass_setoid A) ⇒_1 (unary_morphism1_setoid1 (powerclass_setoid A) (powerclass_setoid A)).
 208 (*XXX ∀A.Ω^A ⇒_1 (Ω^A ⇒_1 Ω^A). avec non-unif-coerc*)
 209 #X; napply (mk_binary_morphism1 … (λA,B.A ∪ B));
 210 #A1 A2 B1 B2 EA EB; napply ext_set; #x;
 211 nchange in match (x ∈ (A1 ∪ B1)) with (?∨?);
 212 napply (.= (set_ext ??? EA x)‡#);
 213 napply (.= #‡(set_ext ??? EB x)); //;
 214 nqed.
 215
 216 nlemma union_is_ext: ∀A. 𝛀^A → 𝛀^A → 𝛀^A.
 217  #S A B; @ (A ∪ B); #x y Exy; @; *; #H1;
 218 ##[##1,3: @; ##|##*: @2 ]
 219 ##[##1,3: napply (. (Exy^-1)╪_1#)
 220 ##|##2,4: napply (. Exy╪_1#)]
 221 nassumption;
 222 nqed.
 223
 224 alias symbol "hint_decl" = "hint_decl_Type1".
 225 unification hint 0 ≔
 226    A : setoid, B,C :  𝛀^A;
 227    R ≟ (mk_ext_powerclass ? (B ∪ C) (ext_prop ? (union_is_ext ? B C)))
 228 (*-------------------------------------------------------------------------*)  ⊢
 229     ext_carr A R ≡ union ? (ext_carr ? B) (ext_carr ? C).
 230
 231 unification hint 0 ≔ S:Type[0], A,B:Ω^S;
 232   MM ≟ mk_unary_morphism1 ??
 233         (λA.mk_unary_morphism1 ?? (λB.A ∪ B) (prop11 ?? (union_is_morph S A)))
 234         (prop11 ?? (union_is_morph S))
 235 (*--------------------------------------------------------------------------*) ⊢
 236    fun11 ?? (fun11 ?? MM A) B ≡ A ∪ B.
 237
 238 nlemma union_is_ext_morph:∀A.
 239  (ext_powerclass_setoid A) ⇒_1
 240   (unary_morphism1_setoid1 (ext_powerclass_setoid A) (ext_powerclass_setoid A)).
 241 (*XXX ∀A:setoid.𝛀^A ⇒_1 (𝛀^A ⇒_1 𝛀^A). with coercion non uniformi *)
 242 #A; napply (mk_binary_morphism1 …  (union_is_ext …));
 243 #x1 x2 y1 y2 Ex Ey; napply (prop11 … (union_is_morph A)); nassumption.
 244 nqed.
 245
 246 unification hint 1 ≔
 247   AA : setoid, B,C : 𝛀^AA;
 248   A ≟ carr AA,
 249   R ≟ (mk_unary_morphism1 ??
 250           (λS:𝛀^AA.
 251            mk_unary_morphism1 ??
 252             (λS':𝛀^AA.
 253               mk_ext_powerclass AA (S ∪ S') (ext_prop AA (union_is_ext ? S S')))
 254             (prop11 ?? (union_is_ext_morph AA S)))
 255           (prop11 ?? (union_is_ext_morph AA))) ,
 256    BB ≟ (ext_carr ? B),
 257    CC ≟ (ext_carr ? C)
 258 (*------------------------------------------------------*) ⊢
 259    ext_carr AA (R B C) ≡ union A BB CC.
 260
 261 (*
 262 alias symbol "hint_decl" = "hint_decl_Type2".
 263 unification hint 0 ≔
 264   A : setoid, B,C : 𝛀^A ;
 265   CC ≟ (ext_carr ? C),
 266   BB ≟ (ext_carr ? B),
 267   C1 ≟ (carr1 (powerclass_setoid (carr A))),
 268   C2 ≟ (carr1 (ext_powerclass_setoid A))
 269   ⊢
 270      eq_rel1 C1 (eq1 (powerclass_setoid (carr A))) BB CC ≡
 271           eq_rel1 C2 (eq1 (ext_powerclass_setoid A)) B C.
 272
 273 unification hint 0 ≔
 274   A, B : CPROP ⊢ iff A B ≡ eq_rel1 ? (eq1 CPROP) A B.
 275
 276 nlemma test: ∀U.∀A,B:𝛀^U. A ∩ B = A →
 277  ∀x,y. x=y → x ∈ A → y ∈ A ∩ B.
 278  #U; #A; #B; #H; #x; #y; #K; #K2;
 279   alias symbol "prop2" = "prop21 mem".
 280   alias symbol "invert" = "setoid1 symmetry".
 281   napply (. K^-1‡H);
 282   nassumption;
 283 nqed.
 284
 285
 286 nlemma intersect_ok: ∀A. binary_morphism1 (ext_powerclass_setoid A) (ext_powerclass_setoid A) (ext_powerclass_setoid A).
 287  #A; @
 288   [ #S; #S'; @
 289      [ napply (S ∩ S')
 290      | #a; #a'; #Ha;
 291         nwhd in ⊢ (? ? ? % %); @; *; #H1; #H2; @
 292         [##1,2: napply (. Ha^-1‡#); nassumption;
 293       ##|##3,4: napply (. Ha‡#); nassumption]##]
 294  ##| #a; #a'; #b; #b'; #Ha; #Hb; nwhd; @; #x; nwhd in ⊢ (% → %); #H
 295       [ alias symbol "invert" = "setoid1 symmetry".
 296         alias symbol "refl" = "refl".
 297 alias symbol "prop2" = "prop21".
 298 napply (. ((#‡Ha^-1)‡(#‡Hb^-1))); nassumption
 299       | napply (. ((#‡Ha)‡(#‡Hb))); nassumption ]##]
 300 nqed.
 301
 302 (* unfold if intersect, exposing fun21 *)
 303 alias symbol "hint_decl" = "hint_decl_Type1".
 304 unification hint 0 ≔
 305   A : setoid, B,C : ext_powerclass A ⊢
 306     pc A (fun21 …
 307             (mk_binary_morphism1 …
 308               (λS,S':qpowerclass_setoid A.mk_qpowerclass ? (S ∩ S') (mem_ok' ? (intersect_ok ? S S')))
 309               (prop21 … (intersect_ok A)))
 310             B
 311             C)
 312     ≡ intersect ? (pc ? B) (pc ? C).
 313
 314 nlemma test: ∀A:setoid. ∀U,V:qpowerclass A. ∀x,x':setoid1_of_setoid A. x=x' → x ∈ U ∩ V → x' ∈ U ∩ V.
 315  #A; #U; #V; #x; #x'; #H; #p; napply (. (H^-1‡#)); nassumption.
 316 nqed.
 317 *)
 318
 319 ndefinition image: ∀A,B. (carr A → carr B) → Ω^A → Ω^B ≝
 320  λA,B:setoid.λf:carr A → carr B.λSa:Ω^A.
 321   {y | ∃x. x ∈ Sa ∧ eq_rel (carr B) (eq0 B) (f x) y}.
 322
 323 ndefinition counter_image: ∀A,B. (carr A → carr B) → Ω^B → Ω^A ≝
 324  λA,B,f,Sb. {x | ∃y. y ∈ Sb ∧ f x = y}.
 325
 326 (******************* compatible equivalence relations **********************)
 327
 328 nrecord compatible_equivalence_relation (A: setoid) : Type[1] ≝
 329  { rel:> equivalence_relation A;
 330    compatibility: ∀x,x':A. x=x' → rel x x'
 331  }.
 332
 333 ndefinition quotient: ∀A. compatible_equivalence_relation A → setoid.
 334  #A; #R; @ A R;
 335 nqed.
 336
 337 (******************* first omomorphism theorem for sets **********************)
 338
 339 ndefinition eqrel_of_morphism:
 340  ∀A,B. A ⇒_0 B → compatible_equivalence_relation A.
 341  #A; #B; #f; @
 342   [ @ [ napply (λx,y. f x = f y) ] /2/;
 343 ##| #x; #x'; #H; nwhd; alias symbol "prop1" = "prop1".
 344 napply (.= (†H)); // ]
 345 nqed.
 346
 347 ndefinition canonical_proj: ∀A,R. A ⇒_0 (quotient A R).
 348  #A; #R; @
 349   [ napply (λx.x) |  #a; #a'; #H; napply (compatibility … R … H) ]
 350 nqed.
 351
 352 ndefinition quotiented_mor:
 353  ∀A,B.∀f:A ⇒_0 B.(quotient … (eqrel_of_morphism … f)) ⇒_0 B.
 354  #A; #B; #f; @ [ napply f ] //.
 355 nqed.
 356
 357 nlemma first_omomorphism_theorem_functions1:
 358  ∀A,B.∀f: unary_morphism A B.
 359   ∀x. f x = quotiented_mor … (canonical_proj … (eqrel_of_morphism … f) x).
 360 //. nqed.
 361
 362 alias symbol "eq" = "setoid eq".
 363 ndefinition surjective ≝
 364  λA,B.λS: ext_powerclass A.λT: ext_powerclass B.λf:A ⇒_0 B.
 365   ∀y. y ∈ T → ∃x. x ∈ S ∧ f x = y.
 366
 367 ndefinition injective ≝
 368  λA,B.λS: ext_powerclass A.λf:A ⇒_0 B.
 369   ∀x,x'. x ∈ S → x' ∈ S → f x = f x' → x = x'.
 370
 371 nlemma first_omomorphism_theorem_functions2:
 372  ∀A,B.∀f:A ⇒_0 B.
 373    surjective … (Full_set ?) (Full_set ?) (canonical_proj ? (eqrel_of_morphism … f)).
 374 /3/. nqed.
 375
 376 nlemma first_omomorphism_theorem_functions3:
 377  ∀A,B.∀f:A ⇒_0 B.
 378    injective … (Full_set ?) (quotiented_mor … f).
 379  #A; #B; #f; nwhd; #x; #x'; #Hx; #Hx'; #K; nassumption.
 380 nqed.
 381
 382 nrecord isomorphism (A, B : setoid) (S: ext_powerclass A) (T: ext_powerclass B) : Type[0] ≝
 383  { iso_f:> A ⇒_0 B;
 384    f_closed: ∀x. x ∈ S → iso_f x ∈ T;
 385    f_sur: surjective … S T iso_f;
 386    f_inj: injective … S iso_f
 387  }.
 388
 389 nlemma subseteq_intersection_l: ∀A.∀U,V,W:Ω^A.U ⊆ W ∨ V ⊆ W → U ∩ V ⊆ W.
 390 #A; #U; #V; #W; *; #H; #x; *; /2/.
 391 nqed.
 392
 393 nlemma subseteq_union_l: ∀A.∀U,V,W:Ω^A.U ⊆ W → V ⊆ W → U ∪ V ⊆ W.
 394 #A; #U; #V; #W; #H; #H1; #x; *; /2/.
 395 nqed.
 396
 397 nlemma subseteq_intersection_r: ∀A.∀U,V,W:Ω^A.W ⊆ U → W ⊆ V → W ⊆ U ∩ V.
 398 /3/. nqed.
 399
 400 (*
 401 nrecord isomorphism (A, B : setoid) (S: qpowerclass A) (T: qpowerclass B) : CProp[0] ≝
 402  { iso_f:> unary_morphism A B;
 403    f_closed: ∀x. x ∈ pc A S → fun1 ?? iso_f x ∈ pc B T}.
 404
 405
 406 ncheck (λA:?.
 407    λB:?.
 408     λS:?.
 409      λT:?.
 410       λxxx:isomorphism A B S T.
 411        match xxx
 412        return λxxx:isomorphism A B S T.
 413                ∀x: carr A.
 414                 ∀x_72: mem (carr A) (pc A S) x.
 415                  mem (carr B) (pc B T) (fun1 A B ((λ_.?) A B S T xxx) x)
 416         with [ mk_isomorphism _ yyy ⇒ yyy ] ).
 417
 418    ;
 419  }.
 420 *)