helm/software/matita/nlibrary/sets/sets.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 (******************* SETS OVER TYPES *****************)
  16
  17 include "logic/connectives.ma".
  18
  19 nrecord powerclass (A: Type[0]) : Type[1] ≝ { mem: A → CProp[0] }.
  20
  21 interpretation "mem" 'mem a S = (mem ? S a).
  22 interpretation "powerclass" 'powerset A = (powerclass A).
  23 interpretation "subset construction" 'subset \eta.x = (mk_powerclass ? x).
  24
  25 ndefinition subseteq ≝ λA.λU,V.∀a:A. a ∈ U → a ∈ V.
  26 interpretation "subseteq" 'subseteq U V = (subseteq ? U V).
  27
  28 ndefinition overlaps ≝ λA.λU,V.∃x:A.x ∈ U ∧ x ∈ V.
  29 interpretation "overlaps" 'overlaps U V = (overlaps ? U V).
  30
  31 ndefinition intersect ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∧ x ∈ V }.
  32 interpretation "intersect" 'intersects U V = (intersect ? U V).
  33
  34 ndefinition union ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∨ x ∈ V }.
  35 interpretation "union" 'union U V = (union ? U V).
  36
  37 ndefinition big_union ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∃i. i ∈ T ∧ x ∈ f i }.
  38
  39 ndefinition big_intersection ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∀i. i ∈ T → x ∈ f i }.
  40
  41 ndefinition full_set: ∀A. Ω^A ≝ λA.{ x | True }.
  42
  43 nlemma subseteq_refl: ∀A.∀S: Ω^A. S ⊆ S.
  44  #A; #S; #x; #H; nassumption.
  45 nqed.
  46
  47 nlemma subseteq_trans: ∀A.∀S,T,U: Ω^A. S ⊆ T → T ⊆ U → S ⊆ U.
  48  #A; #S; #T; #U; #H1; #H2; #x; #P; napply H2; napply H1; nassumption.
  49 nqed.
  50
  51 include "properties/relations1.ma".
  52
  53 ndefinition seteq: ∀A. equivalence_relation1 (Ω^A).
  54  #A; @
  55   [ napply (λS,S'. S ⊆ S' ∧ S' ⊆ S)
  56   | #S; @; napply subseteq_refl
  57   | #S; #S'; *; #H1; #H2; @; nassumption
  58   | #S; #T; #U; *; #H1; #H2; *; #H3; #H4; @; napply subseteq_trans;
  59      ##[##2,5: nassumption |##1,4: ##skip |##*: nassumption]##]
  60 nqed.
  61
  62 include "sets/setoids1.ma".
  63
  64 (* this has to be declared here, so that it is combined with carr *)
  65 ncoercion full_set : ∀A:Type[0]. Ω^A ≝ full_set on A: Type[0] to (Ω^?).
  66
  67 ndefinition powerclass_setoid: Type[0] → setoid1.
  68  #A; @[ napply (Ω^A)| napply seteq ]
  69 nqed.
  70
  71 include "hints_declaration.ma".
  72
  73 alias symbol "hint_decl" = "hint_decl_Type2".
  74 unification hint 0 ≔ A ⊢ carr1 (mk_setoid1 (Ω^A) (eq1 (powerclass_setoid A))) ≡ Ω^A.
  75
  76 (************ SETS OVER SETOIDS ********************)
  77
  78 include "logic/cprop.ma".
  79
  80 nrecord ext_powerclass (A: setoid) : Type[1] ≝
  81  { ext_carr:> Ω^A; (* qui pc viene dichiarato con un target preciso...
  82                 forse lo si vorrebbe dichiarato con un target più lasco
  83                 ma la sintassi :> non lo supporta *)
  84    ext_prop: ∀x,x':A. x=x' → (x ∈ ext_carr) = (x' ∈ ext_carr)
  85  }.
  86
  87 notation > "𝛀 ^ term 90 A" non associative with precedence 70
  88 for @{ 'ext_powerclass $A }.
  89
  90 notation "Ω term 90 A \atop ≈" non associative with precedence 70
  91 for @{ 'ext_powerclass $A }.
  92
  93 interpretation "extensional powerclass" 'ext_powerclass a = (ext_powerclass a).
  94
  95 ndefinition Full_set: ∀A. 𝛀^A.
  96  #A; @[ napply A | #x; #x'; #H; napply refl1]
  97 nqed.
  98 ncoercion Full_set: ∀A. ext_powerclass A ≝ Full_set on A: setoid to ext_powerclass ?.
  99
 100 ndefinition ext_seteq: ∀A. equivalence_relation1 (𝛀^A).
 101  #A; @
 102   [ napply (λS,S'. S = S')
 103   | #S; napply (refl1 ? (seteq A))
 104   | #S; #S'; napply (sym1 ? (seteq A))
 105   | #S; #T; #U; napply (trans1 ? (seteq A))]
 106 nqed.
 107
 108 ndefinition ext_powerclass_setoid: setoid → setoid1.
 109  #A; @
 110   [ napply (ext_powerclass A)
 111   | napply (ext_seteq A) ]
 112 nqed.
 113
 114 unification hint 0 ≔ A;
 115       R ≟ (mk_setoid1 (𝛀^A) (eq1 (ext_powerclass_setoid A)))
 116   (* ----------------------------------------------------- *) ⊢
 117                  carr1 R ≡ ext_powerclass A.
 118
 119
 120 (*
 121 ncoercion ext_carr' : ∀A.∀x:ext_powerclass_setoid A. Ω^A ≝ ext_carr
 122 on _x : (carr1 (ext_powerclass_setoid ?)) to (Ω^?).
 123 *)
 124
 125 nlemma mem_ext_powerclass_setoid_is_morph:
 126  ∀A. binary_morphism1 (setoid1_of_setoid A) (ext_powerclass_setoid A) CPROP.
 127  #A; @
 128   [ napply (λx,S. x ∈ S)
 129   | #a; #a'; #b; #b'; #Ha; *; #Hb1; #Hb2; @; #H;
 130      ##[ napply Hb1; napply (. (ext_prop … Ha^-1)); nassumption;
 131      ##| napply Hb2; napply (. (ext_prop … Ha)); nassumption;
 132      ##]
 133   ##]
 134 nqed.
 135
 136 unification hint 0 ≔  A:setoid, x, S;
 137      SS ≟ (ext_carr ? S),
 138      TT ≟ (mk_binary_morphism1 ???
 139              (λx:setoid1_of_setoid ?.λS:ext_powerclass_setoid ?. x ∈ S)
 140              (prop21 ??? (mem_ext_powerclass_setoid_is_morph A))),
 141      XX ≟ (ext_powerclass_setoid A)
 142   (*-------------------------------------*) ⊢
 143       fun21 (setoid1_of_setoid A) XX CPROP TT x S
 144     ≡ mem A SS x.
 145
 146 nlemma subseteq_is_morph: ∀A. binary_morphism1 (ext_powerclass_setoid A) (ext_powerclass_setoid A) CPROP.
 147  #A; @
 148   [ napply (λS,S'. S ⊆ S')
 149   | #a; #a'; #b; #b'; *; #Ha1; #Ha2; *; #Hb1; #Hb2; @; #H
 150      [ napply (subseteq_trans … a)
 151         [ nassumption | napply (subseteq_trans … b); nassumption ]
 152    ##| napply (subseteq_trans … a')
 153         [ nassumption | napply (subseteq_trans … b'); nassumption ] ##]
 154 nqed.
 155
 156 unification hint 0 ≔ A,a,a'
 157  (*-----------------------------------------------------------------*) ⊢
 158   eq_rel ? (eq A) a a' ≡ eq_rel1 ? (eq1 (setoid1_of_setoid A)) a a'.
 159
 160 nlemma intersect_is_ext: ∀A. 𝛀^A → 𝛀^A → 𝛀^A.
 161  #A; #S; #S'; @ (S ∩ S');
 162  #a; #a'; #Ha; @; *; #H1; #H2; @
 163   [##1,2: napply (. Ha^-1‡#); nassumption;
 164 ##|##3,4: napply (. Ha‡#); nassumption]
 165 nqed.
 166
 167 alias symbol "hint_decl" = "hint_decl_Type1".
 168 unification hint 0 ≔
 169   A : setoid, B,C : ext_powerclass A;
 170   R ≟ (mk_ext_powerclass ? (B ∩ C) (ext_prop ? (intersect_is_ext ? B C)))
 171
 172   (* ------------------------------------------*)  ⊢
 173     ext_carr A R ≡ intersect ? (ext_carr ? B) (ext_carr ? C).
 174
 175 nlemma intersect_is_morph:
 176  ∀A. binary_morphism1 (powerclass_setoid A) (powerclass_setoid A) (powerclass_setoid A).
 177  #A; @ (λS,S'. S ∩ S');
 178  #a; #a'; #b; #b'; *; #Ha1; #Ha2; *; #Hb1; #Hb2; @; #x; nnormalize; *; #Ka; #Kb; @
 179   [ napply Ha1; nassumption
 180   | napply Hb1; nassumption
 181   | napply Ha2; nassumption
 182   | napply Hb2; nassumption]
 183 nqed.
 184
 185 alias symbol "hint_decl" = "hint_decl_Type1".
 186 unification hint 0 ≔
 187   A : Type[0], B,C : Ω^A;
 188   R ≟ (mk_binary_morphism1 …
 189        (λS,S'.S ∩ S')
 190        (prop21 … (intersect_is_morph A)))
 191    ⊢
 192     fun21 (powerclass_setoid A) (powerclass_setoid A) (powerclass_setoid A) R B C
 193   ≡ intersect ? B C.
 194
 195 interpretation "prop21 mem" 'prop2 l r = (prop21 (setoid1_of_setoid ?) (ext_powerclass_setoid ?) ? ???? l r).
 196 interpretation "prop21 ext" 'prop2 l r = (prop21 (ext_powerclass_setoid ?) (ext_powerclass_setoid ?) ? ???? l r).
 197
 198 nlemma intersect_is_ext_morph:
 199  ∀A. binary_morphism1 (ext_powerclass_setoid A) (ext_powerclass_setoid A) (ext_powerclass_setoid A).
 200  #A; @ (intersect_is_ext …); nlapply (prop21 … (intersect_is_morph A));
 201 #H; #a; #a'; #b; #b'; #H1; #H2; napply H; nassumption;
 202 nqed.
 203
 204 unification hint 1 ≔
 205       A:setoid, B,C : 𝛀^A;
 206       R ≟ (mk_binary_morphism1 (ext_powerclass_setoid A) (ext_powerclass_setoid A) (ext_powerclass_setoid A)
 207               (λS,S':carr1 (ext_powerclass_setoid A).
 208                 mk_ext_powerclass A (S∩S') (ext_prop A (intersect_is_ext ? S S')))
 209               (prop21 … (intersect_is_ext_morph A))) ,
 210        BB ≟ (ext_carr ? B),
 211        CC ≟ (ext_carr ? C)
 212    (* ------------------------------------------------------*) ⊢
 213             ext_carr A
 214              (fun21
 215               (ext_powerclass_setoid A)
 216               (ext_powerclass_setoid A)
 217               (ext_powerclass_setoid A) R B C) ≡
 218             intersect (carr A) BB CC.
 219
 220 (*
 221 alias symbol "hint_decl" = "hint_decl_Type2".
 222 unification hint 0 ≔
 223   A : setoid, B,C : 𝛀^A ;
 224   CC ≟ (ext_carr ? C),
 225   BB ≟ (ext_carr ? B),
 226   C1 ≟ (carr1 (powerclass_setoid (carr A))),
 227   C2 ≟ (carr1 (ext_powerclass_setoid A))
 228   ⊢
 229      eq_rel1 C1 (eq1 (powerclass_setoid (carr A))) BB CC ≡
 230           eq_rel1 C2 (eq1 (ext_powerclass_setoid A)) B C.
 231
 232 unification hint 0 ≔
 233   A, B : CPROP ⊢ iff A B ≡ eq_rel1 ? (eq1 CPROP) A B.
 234 *)
 235
 236 nlemma test: ∀U.∀A,B:𝛀^U. A ∩ B = A →
 237  ∀x,y. x=y → x ∈ A → y ∈ A ∩ B.
 238  #U; #A; #B; #H; #x; #y; #K; #K2;
 239 napply (. (prop21 ??? ? ???? K^-1 (H^-1‡#)));
 240   nassumption;
 241 nqed.
 242
 243
 244 nlemma intersect_ok: ∀A. binary_morphism1 (ext_powerclass_setoid A) (ext_powerclass_setoid A) (ext_powerclass_setoid A).
 245  #A; @
 246   [ #S; #S'; @
 247      [ napply (S ∩ S')
 248      | #a; #a'; #Ha;
 249         nwhd in ⊢ (? ? ? % %); @; *; #H1; #H2; @
 250         [##1,2: napply (. Ha^-1‡#); nassumption;
 251       ##|##3,4: napply (. Ha‡#); nassumption]##]
 252  ##| #a; #a'; #b; #b'; #Ha; #Hb; nwhd; @; #x; nwhd in ⊢ (% → %); #H
 253       [ alias symbol "invert" = "setoid1 symmetry".
 254         napply (. ((#‡Ha^-1)‡(#‡Hb^-1))); nassumption
 255       | napply (. ((#‡Ha)‡(#‡Hb))); nassumption ]##]
 256 nqed.
 257
 258 (* unfold if intersect, exposing fun21 *)
 259 alias symbol "hint_decl" = "hint_decl_Type1".
 260 unification hint 0 ≔
 261   A : setoid, B,C : qpowerclass A ⊢
 262     pc A (fun21 …
 263             (mk_binary_morphism1 …
 264               (λS,S':qpowerclass_setoid A.mk_qpowerclass ? (S ∩ S') (mem_ok' ? (intersect_ok ? S S')))
 265               (prop21 … (intersect_ok A)))
 266             B
 267             C)
 268     ≡ intersect ? (pc ? B) (pc ? C).
 269
 270 nlemma test: ∀A:setoid. ∀U,V:qpowerclass A. ∀x,x':setoid1_of_setoid A. x=x' → x ∈ U ∩ V → x' ∈ U ∩ V.
 271  #A; #U; #V; #x; #x'; #H; #p; napply (. (H^-1‡#)); nassumption.
 272 nqed.
 273 *)
 274 *)
 275
 276 ndefinition image: ∀A,B. (carr A → carr B) → Ω^A → Ω^B ≝
 277  λA,B:setoid.λf:carr A → carr B.λSa:Ω^A.
 278   {y | ∃x. x ∈ Sa ∧ eq_rel (carr B) (eq B) (f x) y}.
 279
 280 ndefinition counter_image: ∀A,B. (carr A → carr B) → Ω^B → Ω^A ≝
 281  λA,B,f,Sb. {x | ∃y. y ∈ Sb ∧ f x = y}.
 282
 283 (******************* compatible equivalence relations **********************)
 284
 285 nrecord compatible_equivalence_relation (A: setoid) : Type[1] ≝
 286  { rel:> equivalence_relation A;
 287    compatibility: ∀x,x':A. x=x' → rel x x'
 288  }.
 289
 290 ndefinition quotient: ∀A. compatible_equivalence_relation A → setoid.
 291  #A; #R; @ A R;
 292 nqed.
 293
 294 (******************* first omomorphism theorem for sets **********************)
 295
 296 ndefinition eqrel_of_morphism:
 297  ∀A,B. unary_morphism A B → compatible_equivalence_relation A.
 298  #A; #B; #f; @
 299   [ @
 300      [ napply (λx,y. f x = f y)
 301      | #x; napply refl | #x; #y; napply sym | #x; #y; #z; napply trans]
 302 ##| #x; #x'; #H; nwhd; alias symbol "prop1" = "prop1".
 303 napply (.= (†H)); napply refl ]
 304 nqed.
 305
 306 ndefinition canonical_proj: ∀A,R. unary_morphism A (quotient A R).
 307  #A; #R; @
 308   [ napply (λx.x) | #a; #a'; #H; napply (compatibility … R … H) ]
 309 nqed.
 310
 311 ndefinition quotiented_mor:
 312  ∀A,B.∀f:unary_morphism A B.
 313   unary_morphism (quotient … (eqrel_of_morphism … f)) B.
 314  #A; #B; #f; @
 315   [ napply f | #a; #a'; #H; nassumption]
 316 nqed.
 317
 318 nlemma first_omomorphism_theorem_functions1:
 319  ∀A,B.∀f: unary_morphism A B.
 320   ∀x. f x = quotiented_mor … (canonical_proj … (eqrel_of_morphism … f) x).
 321  #A; #B; #f; #x; napply refl;
 322 nqed.
 323
 324 ndefinition surjective ≝
 325  λA,B.λS: ext_powerclass A.λT: ext_powerclass B.λf:unary_morphism A B.
 326   ∀y. y ∈ T → ∃x. x ∈ S ∧ f x = y.
 327
 328 ndefinition injective ≝
 329  λA,B.λS: ext_powerclass A.λf:unary_morphism A B.
 330   ∀x,x'. x ∈ S → x' ∈ S → f x = f x' → x = x'.
 331
 332 nlemma first_omomorphism_theorem_functions2:
 333  ∀A,B.∀f: unary_morphism A B.
 334    surjective … (Full_set ?) (Full_set ?) (canonical_proj ? (eqrel_of_morphism … f)).
 335  #A; #B; #f; nwhd; #y; #Hy; @ y; @ I ; napply refl;
 336  (* bug, prova @ I refl *)
 337 nqed.
 338
 339 nlemma first_omomorphism_theorem_functions3:
 340  ∀A,B.∀f: unary_morphism A B.
 341    injective … (Full_set ?) (quotiented_mor … f).
 342  #A; #B; #f; nwhd; #x; #x'; #Hx; #Hx'; #K; nassumption.
 343 nqed.
 344
 345 nrecord isomorphism (A, B : setoid) (S: ext_powerclass A) (T: ext_powerclass B) : Type[0] ≝
 346  { iso_f:> unary_morphism A B;
 347    f_closed: ∀x. x ∈ S → iso_f x ∈ T;
 348    f_sur: surjective … S T iso_f;
 349    f_inj: injective … S iso_f
 350  }.
 351
 352 (*
 353 nrecord isomorphism (A, B : setoid) (S: qpowerclass A) (T: qpowerclass B) : CProp[0] ≝
 354  { iso_f:> unary_morphism A B;
 355    f_closed: ∀x. x ∈ pc A S → fun1 ?? iso_f x ∈ pc B T}.
 356
 357
 358 ncheck (λA:?.
 359    λB:?.
 360     λS:?.
 361      λT:?.
 362       λxxx:isomorphism A B S T.
 363        match xxx
 364        return λxxx:isomorphism A B S T.
 365                ∀x: carr A.
 366                 ∀x_72: mem (carr A) (pc A S) x.
 367                  mem (carr B) (pc B T) (fun1 A B ((λ_.?) A B S T xxx) x)
 368         with [ mk_isomorphism _ yyy ⇒ yyy ] ).
 369
 370    ;
 371  }.
 372 *)