helm/software/matita/nlibrary/sets/sets.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 (******************* SETS OVER TYPES *****************)
  16
  17 include "logic/connectives.ma".
  18
  19 nrecord powerclass (A: Type[0]) : Type[1] ≝ { mem: A → CProp[0] }.
  20
  21 interpretation "mem" 'mem a S = (mem ? S a).
  22 interpretation "powerclass" 'powerset A = (powerclass A).
  23 interpretation "subset construction" 'subset \eta.x = (mk_powerclass ? x).
  24
  25 ndefinition subseteq ≝ λA.λU,V.∀a:A. a ∈ U → a ∈ V.
  26 interpretation "subseteq" 'subseteq U V = (subseteq ? U V).
  27
  28 ndefinition overlaps ≝ λA.λU,V.∃x:A.x ∈ U ∧ x ∈ V.
  29 interpretation "overlaps" 'overlaps U V = (overlaps ? U V).
  30
  31 ndefinition intersect ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∧ x ∈ V }.
  32 interpretation "intersect" 'intersects U V = (intersect ? U V).
  33
  34 ndefinition union ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∨ x ∈ V }.
  35 interpretation "union" 'union U V = (union ? U V).
  36
  37 ndefinition big_union ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∃i. i ∈ T ∧ x ∈ f i }.
  38
  39 ndefinition big_intersection ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∀i. i ∈ T → x ∈ f i }.
  40
  41 ndefinition full_set: ∀A. Ω^A ≝ λA.{ x | True }.
  42 ncoercion full_set : ∀A:Type[0]. Ω^A ≝ full_set on A: Type[0] to (Ω^?).
  43
  44 nlemma subseteq_refl: ∀A.∀S: Ω^A. S ⊆ S.
  45  #A; #S; #x; #H; nassumption.
  46 nqed.
  47
  48 nlemma subseteq_trans: ∀A.∀S,T,U: Ω^A. S ⊆ T → T ⊆ U → S ⊆ U.
  49  #A; #S; #T; #U; #H1; #H2; #x; #P; napply H2; napply H1; nassumption.
  50 nqed.
  51
  52 include "properties/relations1.ma".
  53
  54 ndefinition seteq: ∀A. equivalence_relation1 (Ω^A).
  55  #A; napply mk_equivalence_relation1
  56   [ napply (λS,S'. S ⊆ S' ∧ S' ⊆ S)
  57   | #S; napply conj; napply subseteq_refl
  58   | #S; #S'; *; #H1; #H2; napply conj; nassumption
  59   | #S; #T; #U; *; #H1; #H2; *; #H3; #H4; napply conj; napply subseteq_trans;
  60      ##[##2,5: nassumption |##1,4: ##skip |##*: nassumption]##]
  61 nqed.
  62
  63 include "sets/setoids1.ma".
  64
  65 ndefinition powerclass_setoid: Type[0] → setoid1.
  66  #A; napply mk_setoid1
  67   [ napply (Ω^A)
  68   | napply seteq ]
  69 nqed.
  70
  71 include "hints_declaration.ma".
  72
  73 alias symbol "hint_decl" = "hint_decl_Type2".
  74 unification hint 0 ≔ A : ? ⊢ carr1 (powerclass_setoid A) ≡ Ω^A.
  75
  76 (************ SETS OVER SETOIDS ********************)
  77
  78 include "logic/cprop.ma".
  79
  80 nrecord qpowerclass (A: setoid) : Type[1] ≝
  81  { pc:> Ω^A; (* qui pc viene dichiarato con un target preciso...
  82                 forse lo si vorrebbe dichiarato con un target più lasco
  83                 ma la sintassi :> non lo supporta *)
  84    mem_ok': ∀x,x':A. x=x' → (x ∈ pc) = (x' ∈ pc)
  85  }.
  86
  87 ndefinition Full_set: ∀A. qpowerclass A.
  88  #A; napply mk_qpowerclass
  89   [ napply (full_set A)
  90   | #x; #x'; #H; napply refl1; ##]
  91 nqed.
  92
  93 ndefinition qseteq: ∀A. equivalence_relation1 (qpowerclass A).
  94  #A; napply mk_equivalence_relation1
  95   [ napply (λS,S'. S = S')
  96   | #S; napply (refl1 ? (seteq A))
  97   | #S; #S'; napply (sym1 ? (seteq A))
  98   | #S; #T; #U; napply (trans1 ? (seteq A))]
  99 nqed.
 100
 101 ndefinition qpowerclass_setoid: setoid → setoid1.
 102  #A; napply mk_setoid1
 103   [ napply (qpowerclass A)
 104   | napply (qseteq A) ]
 105 nqed.
 106
 107 unification hint 0 ≔ A : ? ⊢
 108   carr1 (qpowerclass_setoid A) ≡ qpowerclass A.
 109
 110 nlemma mem_ok: ∀A. binary_morphism1 (setoid1_of_setoid A) (qpowerclass_setoid A) CPROP.
 111  #A; napply mk_binary_morphism1
 112   [ napply (λx,S. x ∈ S)
 113   | #a; #a'; #b; #b'; #Ha; *; #Hb1; #Hb2; napply mk_iff; #H;
 114      ##[ napply Hb1; napply (. (mem_ok' …)); ##[##3: napply H| napply Ha^-1;##]
 115      ##| napply Hb2; napply (. (mem_ok' …)); ##[##3: napply H| napply Ha;##]
 116      ##]
 117   ##]
 118 nqed.
 119
 120 unification hint 0 ≔
 121   A : setoid, x : ?, S : ? ⊢ (mem_ok A) x S ≡ mem A S x.
 122
 123 nlemma subseteq_ok: ∀A. binary_morphism1 (qpowerclass_setoid A) (qpowerclass_setoid A) CPROP.
 124  #A; napply mk_binary_morphism1
 125   [ napply (λS,S'. S ⊆ S')
 126   | #a; #a'; #b; #b'; *; #Ha1; #Ha2; *; #Hb1; #Hb2; napply mk_iff; #H
 127      [ napply (subseteq_trans … a)
 128         [ nassumption | napply (subseteq_trans … b); nassumption ]
 129    ##| napply (subseteq_trans … a')
 130         [ nassumption | napply (subseteq_trans … b'); nassumption ] ##]
 131 nqed.
 132
 133 nlemma intersect_ok: ∀A. binary_morphism1 (qpowerclass_setoid A) (qpowerclass_setoid A) (qpowerclass_setoid A).
 134  #A; napply mk_binary_morphism1
 135   [ #S; #S'; napply mk_qpowerclass
 136      [ napply (S ∩ S')
 137      | #a; #a'; #Ha; nwhd in ⊢ (? ? ? % %); napply mk_iff; *; #H1; #H2; napply conj
 138         [##1,2: napply (. (mem_ok' …)^-1) [##3,6: nassumption |##2,5: nassumption |##*: ##skip]
 139       ##|##3,4: napply (. (mem_ok' …)) [##1,3,4,6: nassumption |##*: ##skip]##]##]
 140  ##| #a; #a'; #b; #b'; #Ha; #Hb; nwhd; napply conj; #x; nwhd in ⊢ (% → %); #H
 141       [ napply (. ((#‡Ha^-1)‡(#‡Hb^-1))); nassumption
 142       | napply (. ((#‡Ha)‡(#‡Hb))); nassumption ]##]
 143 nqed.
 144
 145 (* unfold if intersect, exposing fun21 *)
 146 alias symbol "hint_decl" = "hint_decl_Type1".
 147 unification hint 0 ≔
 148   A : setoid, B : qpowerclass A, C : qpowerclass A ⊢
 149     pc A (intersect_ok A B C) ≡ intersect ? (pc ? B) (pc ? C).
 150
 151 (* hints can pass under mem *) (* ??? XXX why is it needed? *)
 152 unification hint 0 ≔ A:?, B:?, x:?;
 153            C ≟ B
 154  (*---------------------*) ⊢
 155    mem A B x ≡ mem A C x.
 156
 157 nlemma test: ∀A:setoid. ∀U,V:qpowerclass A. ∀x,x':setoid1_of_setoid A. x=x' → x ∈ U ∩ V → x' ∈ U ∩ V.
 158  #A; #U; #V; #x; #x'; #H; #p; napply (. (H^-1‡#)); nassumption.
 159 nqed.
 160
 161 ndefinition image: ∀A,B. (carr A → carr B) → Ω^A → Ω^B ≝
 162  λA,B:setoid.λf:carr A → carr B.λSa:Ω^A.
 163   {y | ∃x. x ∈ Sa ∧ eq_rel (carr B) (eq B) (f x) y}.
 164
 165 ndefinition counter_image: ∀A,B. (carr A → carr B) → Ω^B → Ω^A ≝
 166  λA,B,f,Sb. {x | ∃y. y ∈ Sb ∧ f x = y}.
 167
 168 (******************* compatible equivalence relations **********************)
 169
 170 nrecord compatible_equivalence_relation (A: setoid) : Type[1] ≝
 171  { rel:> equivalence_relation A;
 172    compatibility: ∀x,x':A. x=x' → rel x x'
 173     (* coercion qui non andava per via di un Failure invece di Uncertain
 174        ritornato dall'unificazione per il problema:
 175          ?[] A =?= ?[Γ]->?[Γ+1]
 176     *)
 177  }.
 178
 179 ndefinition quotient: ∀A. compatible_equivalence_relation A → setoid.
 180  #A; #R; napply mk_setoid
 181   [ napply A
 182   | napply R]
 183 nqed.
 184
 185 (******************* first omomorphism theorem for sets **********************)
 186
 187 ndefinition eqrel_of_morphism:
 188  ∀A,B. unary_morphism A B → compatible_equivalence_relation A.
 189  #A; #B; #f; napply mk_compatible_equivalence_relation
 190   [ napply mk_equivalence_relation
 191      [ napply (λx,y. f x = f y)
 192      | #x; napply refl | #x; #y; napply sym | #x; #y; #z; napply trans]
 193 ##| #x; #x'; #H; nwhd; napply (.= (†H)); napply refl ]
 194 nqed.
 195
 196 ndefinition canonical_proj: ∀A,R. unary_morphism A (quotient A R).
 197  #A; #R; napply mk_unary_morphism
 198   [ napply (λx.x) | #a; #a'; #H; napply (compatibility … R … H) ]
 199 nqed.
 200
 201 ndefinition quotiented_mor:
 202  ∀A,B.∀f:unary_morphism A B.
 203   unary_morphism (quotient … (eqrel_of_morphism … f)) B.
 204  #A; #B; #f; napply mk_unary_morphism
 205   [ napply f | #a; #a'; #H; nassumption]
 206 nqed.
 207
 208 nlemma first_omomorphism_theorem_functions1:
 209  ∀A,B.∀f: unary_morphism A B.
 210   ∀x. f x = quotiented_mor … (canonical_proj … (eqrel_of_morphism … f) x).
 211  #A; #B; #f; #x; napply refl;
 212 nqed.
 213
 214 ndefinition surjective ≝
 215  λA,B.λS: qpowerclass A.λT: qpowerclass B.λf:unary_morphism A B.
 216   ∀y. y ∈ T → ∃x. x ∈ S ∧ f x = y.
 217
 218 ndefinition injective ≝
 219  λA,B.λS: qpowerclass A.λf:unary_morphism A B.
 220   ∀x,x'. x ∈ S → x' ∈ S → f x = f x' → x = x'.
 221
 222 nlemma first_omomorphism_theorem_functions2:
 223  ∀A,B.∀f: unary_morphism A B.
 224    surjective … (Full_set ?) (Full_set ?) (canonical_proj ? (eqrel_of_morphism … f)).
 225  #A; #B; #f; nwhd; #y; #Hy; napply (ex_intro … y); napply conj
 226   [ napply I | napply refl]
 227 nqed.
 228
 229 nlemma first_omomorphism_theorem_functions3:
 230  ∀A,B.∀f: unary_morphism A B.
 231    injective … (Full_set ?) (quotiented_mor … f).
 232  #A; #B; #f; nwhd; #x; #x'; #Hx; #Hx'; #K; nassumption.
 233 nqed.
 234
 235 nrecord isomorphism (A) (B) (S: qpowerclass A) (T: qpowerclass B) : CProp[0] ≝
 236  { iso_f:> unary_morphism A B;
 237    f_closed: ∀x. x ∈ S → iso_f x ∈ T;
 238    f_sur: surjective … S T iso_f;
 239    f_inj: injective … S iso_f
 240  }.