helm/software/matita/nlibrary/sets/sets.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 (******************* SETS OVER TYPES *****************)
  16
  17 include "logic/connectives.ma".
  18
  19 nrecord powerclass (A: Type[0]) : Type[1] ≝ { mem: A → CProp[0] }.
  20
  21 interpretation "mem" 'mem a S = (mem ? S a).
  22 interpretation "powerclass" 'powerset A = (powerclass A).
  23 interpretation "subset construction" 'subset \eta.x = (mk_powerclass ? x).
  24
  25 ndefinition subseteq ≝ λA.λU,V.∀a:A. a ∈ U → a ∈ V.
  26 interpretation "subseteq" 'subseteq U V = (subseteq ? U V).
  27
  28 ndefinition overlaps ≝ λA.λU,V.∃x:A.x ∈ U ∧ x ∈ V.
  29 interpretation "overlaps" 'overlaps U V = (overlaps ? U V).
  30
  31 ndefinition intersect ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∧ x ∈ V }.
  32 interpretation "intersect" 'intersects U V = (intersect ? U V).
  33
  34 ndefinition union ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∨ x ∈ V }.
  35 interpretation "union" 'union U V = (union ? U V).
  36
  37 ndefinition big_union ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∃i. i ∈ T ∧ x ∈ f i }.
  38
  39 ndefinition big_intersection ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∀i. i ∈ T → x ∈ f i }.
  40
  41 ndefinition full_set: ∀A. Ω^A ≝ λA.{ x | True }.
  42 ncoercion full_set : ∀A:Type[0]. Ω^A ≝ full_set on A: Type[0] to (Ω^?).
  43
  44 nlemma subseteq_refl: ∀A.∀S: Ω^A. S ⊆ S.
  45  #A; #S; #x; #H; nassumption.
  46 nqed.
  47
  48 nlemma subseteq_trans: ∀A.∀S,T,U: Ω^A. S ⊆ T → T ⊆ U → S ⊆ U.
  49  #A; #S; #T; #U; #H1; #H2; #x; #P; napply H2; napply H1; nassumption.
  50 nqed.
  51
  52 include "properties/relations1.ma".
  53
  54 ndefinition seteq: ∀A. equivalence_relation1 (Ω^A).
  55  #A; napply mk_equivalence_relation1
  56   [ napply (λS,S'. S ⊆ S' ∧ S' ⊆ S)
  57   | #S; @; napply subseteq_refl
  58   | #S; #S'; *; #H1; #H2; @; nassumption
  59   | #S; #T; #U; *; #H1; #H2; *; #H3; #H4; @; napply subseteq_trans;
  60      ##[##2,5: nassumption |##1,4: ##skip |##*: nassumption]##]
  61 nqed.
  62
  63 include "sets/setoids1.ma".
  64
  65 ndefinition powerclass_setoid: Type[0] → setoid1.
  66  #A; @[ napply (Ω^A)| napply seteq ]
  67 nqed.
  68
  69 include "hints_declaration.ma".
  70
  71 alias symbol "hint_decl" = "hint_decl_Type2".
  72 unification hint 0 ≔ A ⊢ carr1 (powerclass_setoid A) ≡ Ω^A.
  73
  74 (************ SETS OVER SETOIDS ********************)
  75
  76 include "logic/cprop.ma".
  77
  78 nrecord qpowerclass (A: setoid) : Type[1] ≝
  79  { pc:> Ω^A; (* qui pc viene dichiarato con un target preciso...
  80                 forse lo si vorrebbe dichiarato con un target più lasco
  81                 ma la sintassi :> non lo supporta *)
  82    mem_ok': ∀x,x':A. x=x' → (x ∈ pc) = (x' ∈ pc)
  83  }.
  84
  85 ndefinition Full_set: ∀A. qpowerclass A.
  86  #A; @
  87   [ napply (full_set A)
  88   | #x; #x'; #H; napply refl1; ##]
  89 nqed.
  90
  91 ndefinition qseteq: ∀A. equivalence_relation1 (qpowerclass A).
  92  #A; @
  93   [ napply (λS,S'. S = S')
  94   | #S; napply (refl1 ? (seteq A))
  95   | #S; #S'; napply (sym1 ? (seteq A))
  96   | #S; #T; #U; napply (trans1 ? (seteq A))]
  97 nqed.
  98
  99 ndefinition qpowerclass_setoid: setoid → setoid1.
 100  #A; @
 101   [ napply (qpowerclass A)
 102   | napply (qseteq A) ]
 103 nqed.
 104
 105 unification hint 0 ≔ A ⊢
 106   carr1 (qpowerclass_setoid A) ≡ qpowerclass A.
 107
 108 nlemma mem_ok: ∀A. binary_morphism1 (setoid1_of_setoid A) (qpowerclass_setoid A) CPROP.
 109  #A; @
 110   [ napply (λx,S. x ∈ S)
 111   | #a; #a'; #b; #b'; #Ha; *; #Hb1; #Hb2; napply mk_iff; #H;
 112      ##[ napply Hb1; napply (. (mem_ok' …)); ##[##3: napply H| napply Ha^-1;##]
 113      ##| napply Hb2; napply (. (mem_ok' …)); ##[##3: napply H| napply Ha;##]
 114      ##]
 115   ##]
 116 nqed.
 117
 118 unification hint 0 ≔
 119   A : setoid, x, S ⊢ (mem_ok A) x S ≡ mem A S x.
 120
 121 nlemma subseteq_ok: ∀A. binary_morphism1 (qpowerclass_setoid A) (qpowerclass_setoid A) CPROP.
 122  #A; @
 123   [ napply (λS,S'. S ⊆ S')
 124   | #a; #a'; #b; #b'; *; #Ha1; #Ha2; *; #Hb1; #Hb2; napply mk_iff; #H
 125      [ napply (subseteq_trans … a)
 126         [ nassumption | napply (subseteq_trans … b); nassumption ]
 127    ##| napply (subseteq_trans … a')
 128         [ nassumption | napply (subseteq_trans … b'); nassumption ] ##]
 129 nqed.
 130
 131 nlemma intersect_ok: ∀A. binary_morphism1 (qpowerclass_setoid A) (qpowerclass_setoid A) (qpowerclass_setoid A).
 132  #A; @
 133   [ #S; #S'; @
 134      [ napply (S ∩ S')
 135      | #a; #a'; #Ha; nwhd in ⊢ (? ? ? % %); napply mk_iff; *; #H1; #H2; @
 136         [##1,2: napply (. (mem_ok' …)^-1) [##3,6: nassumption |##2,5: nassumption |##*: ##skip]
 137       ##|##3,4: napply (. (mem_ok' …)) [##1,3,4,6: nassumption |##*: ##skip]##]##]
 138  ##| #a; #a'; #b; #b'; #Ha; #Hb; nwhd; @; #x; nwhd in ⊢ (% → %); #H
 139       [ napply (. ((#‡Ha^-1)‡(#‡Hb^-1))); nassumption
 140       | napply (. ((#‡Ha)‡(#‡Hb))); nassumption ]##]
 141 nqed.
 142
 143 (* unfold if intersect, exposing fun21 *)
 144 alias symbol "hint_decl" = "hint_decl_Type1".
 145 unification hint 0 ≔
 146   A : setoid, B,C : qpowerclass A ⊢
 147     pc A (intersect_ok A B C) ≡ intersect ? (pc ? B) (pc ? C).
 148
 149 (* hints can pass under mem *) (* ??? XXX why is it needed? *)
 150 unification hint 0 ≔ A,B,x ;
 151            C ≟ B
 152  (*---------------------*) ⊢
 153    mem A B x ≡ mem A C x.
 154
 155 nlemma test: ∀A:setoid. ∀U,V:qpowerclass A. ∀x,x':setoid1_of_setoid A. x=x' → x ∈ U ∩ V → x' ∈ U ∩ V.
 156  #A; #U; #V; #x; #x'; #H; #p; napply (. (H^-1‡#)); nassumption.
 157 nqed.
 158
 159 ndefinition image: ∀A,B. (carr A → carr B) → Ω^A → Ω^B ≝
 160  λA,B:setoid.λf:carr A → carr B.λSa:Ω^A.
 161   {y | ∃x. x ∈ Sa ∧ eq_rel (carr B) (eq B) (f x) y}.
 162
 163 ndefinition counter_image: ∀A,B. (carr A → carr B) → Ω^B → Ω^A ≝
 164  λA,B,f,Sb. {x | ∃y. y ∈ Sb ∧ f x = y}.
 165
 166 (******************* compatible equivalence relations **********************)
 167
 168 nrecord compatible_equivalence_relation (A: setoid) : Type[1] ≝
 169  { rel:> equivalence_relation A;
 170    compatibility: ∀x,x':A. x=x' → rel x x'
 171     (* coercion qui non andava per via di un Failure invece di Uncertain
 172        ritornato dall'unificazione per il problema:
 173          ?[] A =?= ?[Γ]->?[Γ+1]
 174     *)
 175  }.
 176
 177 ndefinition quotient: ∀A. compatible_equivalence_relation A → setoid.
 178  #A; #R; @ A R;
 179 nqed.
 180
 181 (******************* first omomorphism theorem for sets **********************)
 182
 183 ndefinition eqrel_of_morphism:
 184  ∀A,B. unary_morphism A B → compatible_equivalence_relation A.
 185  #A; #B; #f; napply mk_compatible_equivalence_relation
 186   [ @
 187      [ napply (λx,y. f x = f y)
 188      | #x; napply refl | #x; #y; napply sym | #x; #y; #z; napply trans]
 189 ##| #x; #x'; #H; nwhd; napply (.= (†H)); napply refl ]
 190 nqed.
 191
 192 ndefinition canonical_proj: ∀A,R. unary_morphism A (quotient A R).
 193  #A; #R; @
 194   [ napply (λx.x) | #a; #a'; #H; napply (compatibility … R … H) ]
 195 nqed.
 196
 197 ndefinition quotiented_mor:
 198  ∀A,B.∀f:unary_morphism A B.
 199   unary_morphism (quotient … (eqrel_of_morphism … f)) B.
 200  #A; #B; #f; @
 201   [ napply f | #a; #a'; #H; nassumption]
 202 nqed.
 203
 204 nlemma first_omomorphism_theorem_functions1:
 205  ∀A,B.∀f: unary_morphism A B.
 206   ∀x. f x = quotiented_mor … (canonical_proj … (eqrel_of_morphism … f) x).
 207  #A; #B; #f; #x; napply refl;
 208 nqed.
 209
 210 ndefinition surjective ≝
 211  λA,B.λS: qpowerclass A.λT: qpowerclass B.λf:unary_morphism A B.
 212   ∀y. y ∈ T → ∃x. x ∈ S ∧ f x = y.
 213
 214 ndefinition injective ≝
 215  λA,B.λS: qpowerclass A.λf:unary_morphism A B.
 216   ∀x,x'. x ∈ S → x' ∈ S → f x = f x' → x = x'.
 217
 218 nlemma first_omomorphism_theorem_functions2:
 219  ∀A,B.∀f: unary_morphism A B.
 220    surjective … (Full_set ?) (Full_set ?) (canonical_proj ? (eqrel_of_morphism … f)).
 221  #A; #B; #f; nwhd; #y; #Hy; @ y; @ [ napply I | napply refl]
 222  (* bug, prova @ I refl *)
 223 nqed.
 224
 225 nlemma first_omomorphism_theorem_functions3:
 226  ∀A,B.∀f: unary_morphism A B.
 227    injective … (Full_set ?) (quotiented_mor … f).
 228  #A; #B; #f; nwhd; #x; #x'; #Hx; #Hx'; #K; nassumption.
 229 nqed.
 230
 231 nrecord isomorphism (A) (B) (S: qpowerclass A) (T: qpowerclass B) : CProp[0] ≝
 232  { iso_f:> unary_morphism A B;
 233    f_closed: ∀x. x ∈ S → iso_f x ∈ T;
 234    f_sur: surjective … S T iso_f;
 235    f_inj: injective … S iso_f
 236  }.