helm/software/matita/nlibrary/sets/sets.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 (******************* SETS OVER TYPES *****************)
  16
  17 include "logic/connectives.ma".
  18
  19 nrecord powerclass (A: Type[0]) : Type[1] ≝ { mem: A → CProp[0] }.
  20
  21 interpretation "mem" 'mem a S = (mem ? S a).
  22 interpretation "powerclass" 'powerset A = (powerclass A).
  23 interpretation "subset construction" 'subset \eta.x = (mk_powerclass ? x).
  24
  25 ndefinition subseteq ≝ λA.λU,V.∀a:A. a ∈ U → a ∈ V.
  26 interpretation "subseteq" 'subseteq U V = (subseteq ? U V).
  27
  28 ndefinition overlaps ≝ λA.λU,V.∃x:A.x ∈ U ∧ x ∈ V.
  29 interpretation "overlaps" 'overlaps U V = (overlaps ? U V).
  30
  31 ndefinition intersect ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∧ x ∈ V }.
  32 interpretation "intersect" 'intersects U V = (intersect ? U V).
  33
  34 ndefinition union ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∨ x ∈ V }.
  35 interpretation "union" 'union U V = (union ? U V).
  36
  37 ndefinition big_union ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∃i. i ∈ T ∧ x ∈ f i }.
  38
  39 ndefinition big_intersection ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∀i. i ∈ T → x ∈ f i }.
  40
  41 ndefinition full_set: ∀A. Ω^A ≝ λA.{ x | True }.
  42
  43 nlemma subseteq_refl: ∀A.∀S: Ω^A. S ⊆ S.
  44  #A; #S; #x; #H; nassumption.
  45 nqed.
  46
  47 nlemma subseteq_trans: ∀A.∀S,T,U: Ω^A. S ⊆ T → T ⊆ U → S ⊆ U.
  48  #A; #S; #T; #U; #H1; #H2; #x; #P; napply H2; napply H1; nassumption.
  49 nqed.
  50
  51 include "properties/relations1.ma".
  52
  53 ndefinition seteq: ∀A. equivalence_relation1 (Ω^A).
  54  #A; @
  55   [ napply (λS,S'. S ⊆ S' ∧ S' ⊆ S)
  56   | #S; @; napply subseteq_refl
  57   | #S; #S'; *; #H1; #H2; @; nassumption
  58   | #S; #T; #U; *; #H1; #H2; *; #H3; #H4; @; napply subseteq_trans;
  59      ##[##2,5: nassumption |##1,4: ##skip |##*: nassumption]##]
  60 nqed.
  61
  62 include "sets/setoids1.ma".
  63
  64 (* this has to be declared here, so that it is combined with carr *)
  65 ncoercion full_set : ∀A:Type[0]. Ω^A ≝ full_set on A: Type[0] to (Ω^?).
  66
  67 ndefinition powerclass_setoid: Type[0] → setoid1.
  68  #A; @[ napply (Ω^A)| napply seteq ]
  69 nqed.
  70
  71 include "hints_declaration.ma".
  72
  73 alias symbol "hint_decl" = "hint_decl_Type2".
  74 unification hint 0 ≔ A ⊢ carr1 (mk_setoid1 (Ω^A) (eq1 (powerclass_setoid A))) ≡ Ω^A.
  75
  76 (************ SETS OVER SETOIDS ********************)
  77
  78 include "logic/cprop.ma".
  79
  80 nrecord qpowerclass (A: setoid) : Type[1] ≝
  81  { pc:> Ω^A; (* qui pc viene dichiarato con un target preciso...
  82                 forse lo si vorrebbe dichiarato con un target più lasco
  83                 ma la sintassi :> non lo supporta *)
  84    mem_ok': ∀x,x':A. x=x' → (x ∈ pc) = (x' ∈ pc)
  85  }.
  86
  87 ndefinition Full_set: ∀A. qpowerclass A.
  88  #A; @[ napply A | #x; #x'; #H; napply refl1]
  89 nqed.
  90 ncoercion Full_set: ∀A. qpowerclass A ≝ Full_set on A: setoid to qpowerclass ?.
  91
  92 ndefinition qseteq: ∀A. equivalence_relation1 (qpowerclass A).
  93  #A; @
  94   [ napply (λS,S'. S = S')
  95   | #S; napply (refl1 ? (seteq A))
  96   | #S; #S'; napply (sym1 ? (seteq A))
  97   | #S; #T; #U; napply (trans1 ? (seteq A))]
  98 nqed.
  99
 100 ndefinition qpowerclass_setoid: setoid → setoid1.
 101  #A; @
 102   [ napply (qpowerclass A)
 103   | napply (qseteq A) ]
 104 nqed.
 105
 106 unification hint 0 ≔ A ⊢
 107   carr1 (mk_setoid1 (qpowerclass A) (eq1 (qpowerclass_setoid A)))
 108 ≡ qpowerclass A.
 109
 110 ncoercion pc' : ∀A.∀x:qpowerclass_setoid A. Ω^A ≝ pc
 111 on _x : (carr1 (qpowerclass_setoid ?)) to (Ω^?).
 112
 113 nlemma mem_ok: ∀A. binary_morphism1 (setoid1_of_setoid A) (qpowerclass_setoid A) CPROP.
 114  #A; @
 115   [ napply (λx,S. x ∈ S)
 116   | #a; #a'; #b; #b'; #Ha; *; #Hb1; #Hb2; @; #H;
 117      ##[ napply Hb1; napply (. (mem_ok' …)); ##[##3: napply H| napply Ha^-1;##]
 118      ##| napply Hb2; napply (. (mem_ok' …)); ##[##3: napply H| napply Ha;##]
 119      ##]
 120   ##]
 121 nqed.
 122
 123 unification hint 0 ≔  A:setoid, x, S;
 124          SS ≟ (pc ? S),
 125          TT ≟ (mk_binary_morphism1 ???
 126                  (λx:setoid1_of_setoid ?.λS:qpowerclass_setoid ?. x ∈ S)
 127                  (prop21 ??? (mem_ok A)))
 128
 129   (*-------------------------------------*) ⊢
 130     fun21 ? ? ? TT x S
 131   ≡ mem A SS x.
 132
 133 nlemma subseteq_ok: ∀A. binary_morphism1 (qpowerclass_setoid A) (qpowerclass_setoid A) CPROP.
 134  #A; @
 135   [ napply (λS,S'. S ⊆ S')
 136   | #a; #a'; #b; #b'; *; #Ha1; #Ha2; *; #Hb1; #Hb2; @; #H
 137      [ napply (subseteq_trans … a)
 138         [ nassumption | napply (subseteq_trans … b); nassumption ]
 139    ##| napply (subseteq_trans … a')
 140         [ nassumption | napply (subseteq_trans … b'); nassumption ] ##]
 141 nqed.
 142
 143 unification hint 0 ≔ A,a,a'
 144  (*-----------------------------------------------------------------*) ⊢
 145   eq_rel ? (eq A) a a' ≡ eq_rel1 ? (eq1 (setoid1_of_setoid A)) a a'.
 146
 147 nlemma intersect_ok: ∀A. qpowerclass A → qpowerclass A → qpowerclass A.
 148  #A; #S; #S'; @ (S ∩ S');
 149  #a; #a'; #Ha; @; *; #H1; #H2; @
 150   [##1,2: napply (. Ha^-1‡#); nassumption;
 151 ##|##3,4: napply (. Ha‡#); nassumption]
 152 nqed.
 153
 154 alias symbol "hint_decl" = "hint_decl_Type1".
 155 unification hint 1 ≔
 156   A : setoid, B,C : qpowerclass A ⊢
 157     pc A (mk_qpowerclass ? (B ∩ C) (mem_ok' ? (intersect_ok ? B C)))
 158     ≡ intersect ? (pc ? B) (pc ? C).
 159
 160 nlemma intersect_ok': ∀A. binary_morphism1 (powerclass_setoid A) (powerclass_setoid A) (powerclass_setoid A).
 161  #A; @ (λS,S'. S ∩ S');
 162  #a; #a'; #b; #b'; *; #Ha1; #Ha2; *; #Hb1; #Hb2; @; #x; nnormalize; *; #Ka; #Kb; @
 163   [ napply Ha1; nassumption
 164   | napply Hb1; nassumption
 165   | napply Ha2; nassumption
 166   | napply Hb2; nassumption]
 167 nqed.
 168
 169 alias symbol "hint_decl" = "hint_decl_Type1".
 170 unification hint 0 ≔
 171   A : Type[0], B,C : powerclass A ⊢
 172     fun21 …
 173      (mk_binary_morphism1 …
 174        (λS,S'.S ∩ S')
 175        (prop21 … (intersect_ok' A))) B C
 176     ≡ intersect ? B C.
 177
 178 ndefinition prop21_mem :
 179   ∀A,C.∀f:binary_morphism1 (setoid1_of_setoid A) (qpowerclass_setoid A) C.
 180    ∀a,a':setoid1_of_setoid A.
 181     ∀b,b':qpowerclass_setoid A.a = a' → b = b' → f a b = f a' b'.
 182 #A; #C; #f; #a; #a'; #b; #b'; #H1; #H2; napply prop21; nassumption;
 183 nqed.
 184
 185 interpretation "prop21 mem" 'prop2 l r = (prop21_mem ??????? l r).
 186
 187
 188 nlemma test: ∀U.∀A,B:qpowerclass U. A ∩ B = A →
 189  ∀x,y. x=y → x ∈ A → y ∈ A ∩ B.
 190  #U; #A; #B; #H; #x; #y; #K; #K2; napply (. K^-1‡H); nassumption;
 191 nqed.
 192
 193 (*
 194 nlemma intersect_ok: ∀A. binary_morphism1 (qpowerclass_setoid A) (qpowerclass_setoid A) (qpowerclass_setoid A).
 195  #A; @
 196   [ #S; #S'; @
 197      [ napply (S ∩ S')
 198      | #a; #a'; #Ha;
 199         nwhd in ⊢ (? ? ? % %); @; *; #H1; #H2; @
 200         [##1,2: napply (. Ha^-1‡#); nassumption;
 201       ##|##3,4: napply (. Ha‡#); nassumption]##]
 202  ##| #a; #a'; #b; #b'; #Ha; #Hb; nwhd; @; #x; nwhd in ⊢ (% → %); #H
 203       [ alias symbol "invert" = "setoid1 symmetry".
 204         napply (. ((#‡Ha^-1)‡(#‡Hb^-1))); nassumption
 205       | napply (. ((#‡Ha)‡(#‡Hb))); nassumption ]##]
 206 nqed.
 207
 208 (* unfold if intersect, exposing fun21 *)
 209 alias symbol "hint_decl" = "hint_decl_Type1".
 210 unification hint 0 ≔
 211   A : setoid, B,C : qpowerclass A ⊢
 212     pc A (fun21 …
 213             (mk_binary_morphism1 …
 214               (λS,S':qpowerclass_setoid A.mk_qpowerclass ? (S ∩ S') (mem_ok' ? (intersect_ok ? S S')))
 215               (prop21 … (intersect_ok A)))
 216             B
 217             C)
 218     ≡ intersect ? (pc ? B) (pc ? C).
 219
 220 nlemma test: ∀A:setoid. ∀U,V:qpowerclass A. ∀x,x':setoid1_of_setoid A. x=x' → x ∈ U ∩ V → x' ∈ U ∩ V.
 221  #A; #U; #V; #x; #x'; #H; #p; napply (. (H^-1‡#)); nassumption.
 222 nqed.
 223 *)
 224
 225 ndefinition image: ∀A,B. (carr A → carr B) → Ω^A → Ω^B ≝
 226  λA,B:setoid.λf:carr A → carr B.λSa:Ω^A.
 227   {y | ∃x. x ∈ Sa ∧ eq_rel (carr B) (eq B) (f x) y}.
 228
 229 ndefinition counter_image: ∀A,B. (carr A → carr B) → Ω^B → Ω^A ≝
 230  λA,B,f,Sb. {x | ∃y. y ∈ Sb ∧ f x = y}.
 231
 232 (******************* compatible equivalence relations **********************)
 233
 234 nrecord compatible_equivalence_relation (A: setoid) : Type[1] ≝
 235  { rel:> equivalence_relation A;
 236    compatibility: ∀x,x':A. x=x' → rel x x'
 237  }.
 238
 239 ndefinition quotient: ∀A. compatible_equivalence_relation A → setoid.
 240  #A; #R; @ A R;
 241 nqed.
 242
 243 (******************* first omomorphism theorem for sets **********************)
 244
 245 ndefinition eqrel_of_morphism:
 246  ∀A,B. unary_morphism A B → compatible_equivalence_relation A.
 247  #A; #B; #f; @
 248   [ @
 249      [ napply (λx,y. f x = f y)
 250      | #x; napply refl | #x; #y; napply sym | #x; #y; #z; napply trans]
 251 ##| #x; #x'; #H; nwhd; alias symbol "prop1" = "prop1".
 252 napply (.= (†H)); napply refl ]
 253 nqed.
 254
 255 ndefinition canonical_proj: ∀A,R. unary_morphism A (quotient A R).
 256  #A; #R; @
 257   [ napply (λx.x) | #a; #a'; #H; napply (compatibility … R … H) ]
 258 nqed.
 259
 260 ndefinition quotiented_mor:
 261  ∀A,B.∀f:unary_morphism A B.
 262   unary_morphism (quotient … (eqrel_of_morphism … f)) B.
 263  #A; #B; #f; @
 264   [ napply f | #a; #a'; #H; nassumption]
 265 nqed.
 266
 267 nlemma first_omomorphism_theorem_functions1:
 268  ∀A,B.∀f: unary_morphism A B.
 269   ∀x. f x = quotiented_mor … (canonical_proj … (eqrel_of_morphism … f) x).
 270  #A; #B; #f; #x; napply refl;
 271 nqed.
 272
 273 ndefinition surjective ≝
 274  λA,B.λS: qpowerclass A.λT: qpowerclass B.λf:unary_morphism A B.
 275   ∀y. y ∈ T → ∃x. x ∈ S ∧ f x = y.
 276
 277 ndefinition injective ≝
 278  λA,B.λS: qpowerclass A.λf:unary_morphism A B.
 279   ∀x,x'. x ∈ S → x' ∈ S → f x = f x' → x = x'.
 280
 281 nlemma first_omomorphism_theorem_functions2:
 282  ∀A,B.∀f: unary_morphism A B.
 283    surjective … (Full_set ?) (Full_set ?) (canonical_proj ? (eqrel_of_morphism … f)).
 284  #A; #B; #f; nwhd; #y; #Hy; @ y; @ I ; napply refl;
 285  (* bug, prova @ I refl *)
 286 nqed.
 287
 288 nlemma first_omomorphism_theorem_functions3:
 289  ∀A,B.∀f: unary_morphism A B.
 290    injective … (Full_set ?) (quotiented_mor … f).
 291  #A; #B; #f; nwhd; #x; #x'; #Hx; #Hx'; #K; nassumption.
 292 nqed.
 293
 294 nrecord isomorphism (A, B : setoid) (S: qpowerclass A) (T: qpowerclass B) : Type[0] ≝
 295  { iso_f:> unary_morphism A B;
 296    f_closed: ∀x. x ∈ S → iso_f x ∈ T;
 297    f_sur: surjective … S T iso_f;
 298    f_inj: injective … S iso_f
 299  }.
 300
 301 (*
 302 nrecord isomorphism (A, B : setoid) (S: qpowerclass A) (T: qpowerclass B) : CProp[0] ≝
 303  { iso_f:> unary_morphism A B;
 304    f_closed: ∀x. x ∈ pc A S → fun1 ?? iso_f x ∈ pc B T}.
 305
 306
 307 ncheck (λA:?.
 308    λB:?.
 309     λS:?.
 310      λT:?.
 311       λxxx:isomorphism A B S T.
 312        match xxx
 313        return λxxx:isomorphism A B S T.
 314                ∀x: carr A.
 315                 ∀x_72: mem (carr A) (pc A S) x.
 316                  mem (carr B) (pc B T) (fun1 A B ((λ_.?) A B S T xxx) x)
 317         with [ mk_isomorphism _ yyy ⇒ yyy ] ).
 318
 319    ;
 320  }.
 321 *)