helm/software/matita/nlibrary/sets/sets.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 (******************* SETS OVER TYPES *****************)
  16
  17 include "logic/connectives.ma".
  18
  19 nrecord powerclass (A: Type[0]) : Type[1] ≝ { mem: A → CProp[0] }.
  20
  21 interpretation "mem" 'mem a S = (mem ? S a).
  22 interpretation "powerclass" 'powerset A = (powerclass A).
  23 interpretation "subset construction" 'subset \eta.x = (mk_powerclass ? x).
  24
  25 ndefinition subseteq ≝ λA.λU,V.∀a:A. a ∈ U → a ∈ V.
  26 interpretation "subseteq" 'subseteq U V = (subseteq ? U V).
  27
  28 ndefinition overlaps ≝ λA.λU,V.∃x:A.x ∈ U ∧ x ∈ V.
  29 interpretation "overlaps" 'overlaps U V = (overlaps ? U V).
  30
  31 ndefinition intersect ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∧ x ∈ V }.
  32 interpretation "intersect" 'intersects U V = (intersect ? U V).
  33
  34 ndefinition union ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∨ x ∈ V }.
  35 interpretation "union" 'union U V = (union ? U V).
  36
  37 ndefinition big_union ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∃i. i ∈ T ∧ x ∈ f i }.
  38
  39 ndefinition big_intersection ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∀i. i ∈ T → x ∈ f i }.
  40
  41 ndefinition full_set: ∀A. Ω^A ≝ λA.{ x | True }.
  42
  43 nlemma subseteq_refl: ∀A.∀S: Ω^A. S ⊆ S.
  44 //.nqed.
  45
  46 nlemma subseteq_trans: ∀A.∀S,T,U: Ω^A. S ⊆ T → T ⊆ U → S ⊆ U.
  47 /3/.nqed.
  48
  49 include "properties/relations1.ma".
  50
  51 ndefinition seteq: ∀A. equivalence_relation1 (Ω^A).
  52  #A; @
  53   [ napply (λS,S'. S ⊆ S' ∧ S' ⊆ S)
  54   | /2/
  55   | #S; #S'; *; /3/
  56   | #S; #T; #U; *; #H1; #H2; *; /4/]
  57 nqed.
  58
  59 include "sets/setoids1.ma".
  60
  61 (* this has to be declared here, so that it is combined with carr *)
  62 ncoercion full_set : ∀A:Type[0]. Ω^A ≝ full_set on A: Type[0] to (Ω^?).
  63
  64 ndefinition powerclass_setoid: Type[0] → setoid1.
  65  #A; @(Ω^A);//.
  66 nqed.
  67
  68 include "hints_declaration.ma".
  69
  70 alias symbol "hint_decl" = "hint_decl_Type2".
  71 unification hint 0 ≔ A ⊢ carr1 (mk_setoid1 (Ω^A) (eq1 (powerclass_setoid A))) ≡ Ω^A.
  72
  73 (************ SETS OVER SETOIDS ********************)
  74
  75 include "logic/cprop.ma".
  76
  77 nrecord ext_powerclass (A: setoid) : Type[1] ≝
  78  { ext_carr:> Ω^A; (* qui pc viene dichiarato con un target preciso...
  79                 forse lo si vorrebbe dichiarato con un target più lasco
  80                 ma la sintassi :> non lo supporta *)
  81    ext_prop: ∀x,x':A. x=x' → (x ∈ ext_carr) = (x' ∈ ext_carr)
  82  }.
  83
  84 notation > "𝛀 ^ term 90 A" non associative with precedence 70
  85 for @{ 'ext_powerclass $A }.
  86
  87 notation < "Ω term 90 A \atop ≈" non associative with precedence 90
  88 for @{ 'ext_powerclass $A }.
  89
  90 interpretation "extensional powerclass" 'ext_powerclass a = (ext_powerclass a).
  91
  92 ndefinition Full_set: ∀A. 𝛀^A.
  93  #A; @[ napply A | #x; #x'; #H; napply refl1]
  94 nqed.
  95 ncoercion Full_set: ∀A. ext_powerclass A ≝ Full_set on A: setoid to ext_powerclass ?.
  96
  97 ndefinition ext_seteq: ∀A. equivalence_relation1 (𝛀^A).
  98  #A; @ [ napply (λS,S'. S = S') ] /2/.
  99 nqed.
 100
 101 ndefinition ext_powerclass_setoid: setoid → setoid1.
 102  #A; @ (ext_seteq A).
 103 nqed.
 104
 105 unification hint 0 ≔ A;
 106       R ≟ (mk_setoid1 (𝛀^A) (eq1 (ext_powerclass_setoid A)))
 107   (* ----------------------------------------------------- *) ⊢
 108                  carr1 R ≡ ext_powerclass A.
 109
 110 (*
 111 interpretation "prop21 mem" 'prop2 l r = (prop21 (setoid1_of_setoid ?) (ext_powerclass_setoid ?) ? ? ???? l r).
 112 *)
 113
 114 (*
 115 ncoercion ext_carr' : ∀A.∀x:ext_powerclass_setoid A. Ω^A ≝ ext_carr
 116 on _x : (carr1 (ext_powerclass_setoid ?)) to (Ω^?).
 117 *)
 118
 119 nlemma mem_ext_powerclass_setoid_is_morph:
 120  ∀A. unary_morphism1 (setoid1_of_setoid A) (unary_morphism1_setoid1 (ext_powerclass_setoid A) CPROP).
 121  #A; napply (mk_binary_morphism1 … (λx:setoid1_of_setoid A.λS: 𝛀^A. x ∈ S));
 122  #a; #a'; #b; #b'; #Ha; *; #Hb1; #Hb2; @; #H
 123   [ napply (. (ext_prop … Ha^-1)) | napply (. (ext_prop … Ha)) ] /2/.
 124 nqed.
 125
 126 unification hint 0 ≔  A:setoid, x, S;
 127      SS ≟ (ext_carr ? S),
 128      TT ≟ (mk_unary_morphism1 …
 129              (λx:setoid1_of_setoid ?.
 130                mk_unary_morphism1 …
 131                  (λS:ext_powerclass_setoid ?. x ∈ S)
 132                  (prop11 … (mem_ext_powerclass_setoid_is_morph A x)))
 133              (prop11 … (mem_ext_powerclass_setoid_is_morph A))),
 134      XX ≟ (ext_powerclass_setoid A)
 135   (*-------------------------------------*) ⊢
 136       fun11 (setoid1_of_setoid A)
 137        (unary_morphism1_setoid1 XX CPROP) TT x S
 138     ≡ mem A SS x.
 139
 140 nlemma subseteq_is_morph: ∀A. unary_morphism1 (ext_powerclass_setoid A)
 141  (unary_morphism1_setoid1 (ext_powerclass_setoid A) CPROP).
 142  #A; napply (mk_binary_morphism1 … (λS,S':𝛀^A. S ⊆ S'));
 143  #a; #a'; #b; #b'; *; #H1; #H2; *; /5/ by mk_iff, sym1, subseteq_trans;
 144 nqed.
 145
 146 unification hint 0 ≔ A,a,a'
 147  (*-----------------------------------------------------------------*) ⊢
 148   eq_rel ? (eq0 A) a a' ≡ eq_rel1 ? (eq1 (setoid1_of_setoid A)) a a'.
 149
 150 nlemma intersect_is_ext: ∀A. 𝛀^A → 𝛀^A → 𝛀^A.
 151  #A; #S; #S'; @ (S ∩ S');
 152  #a; #a'; #Ha; @; *; #H1; #H2; @
 153   [##1,2: napply (. Ha^-1‡#); nassumption;
 154 ##|##3,4: napply (. Ha‡#); nassumption]
 155 nqed.
 156
 157 alias symbol "hint_decl" = "hint_decl_Type1".
 158 unification hint 0 ≔
 159   A : setoid, B,C : ext_powerclass A;
 160   R ≟ (mk_ext_powerclass ? (B ∩ C) (ext_prop ? (intersect_is_ext ? B C)))
 161
 162   (* ------------------------------------------*)  ⊢
 163     ext_carr A R ≡ intersect ? (ext_carr ? B) (ext_carr ? C).
 164
 165 nlemma intersect_is_morph:
 166  ∀A. unary_morphism1 (powerclass_setoid A) (unary_morphism1_setoid1 (powerclass_setoid A) (powerclass_setoid A)).
 167  #A; napply (mk_binary_morphism1 … (λS,S'. S ∩ S'));
 168  #a; #a'; #b; #b'; *; #Ha1; #Ha2; *; #Hb1; #Hb2; @; #x; nnormalize; *;/3/.
 169 nqed.
 170
 171 alias symbol "hint_decl" = "hint_decl_Type1".
 172 unification hint 0 ≔
 173   A : Type[0], B,C : Ω^A;
 174   R ≟ (mk_unary_morphism1 …
 175        (λS. mk_unary_morphism1 … (λS'.S ∩ S') (prop11 … (intersect_is_morph A S)))
 176        (prop11 … (intersect_is_morph A)))
 177    ⊢
 178     R B C  ≡ intersect ? B C.
 179
 180 interpretation "prop21 ext" 'prop2 l r =
 181  (prop11 (ext_powerclass_setoid ?)
 182   (unary_morphism1_setoid1 (ext_powerclass_setoid ?) ?) ? ?? l ?? r).
 183
 184 nlemma intersect_is_ext_morph:
 185  ∀A. unary_morphism1 (ext_powerclass_setoid A)
 186   (unary_morphism1_setoid1 (ext_powerclass_setoid A) (ext_powerclass_setoid A)).
 187  #A; napply (mk_binary_morphism1 … (intersect_is_ext …));
 188  #a; #a'; #b; #b'; #Ha; #Hb; napply (prop11 … (intersect_is_morph A)); nassumption.
 189 nqed.
 190
 191 unification hint 1 ≔
 192       A:setoid, B,C : 𝛀^A;
 193       R ≟ (mk_unary_morphism1 …
 194               (λS:ext_powerclass_setoid A.
 195                mk_unary_morphism1 ??
 196                 (λS':ext_powerclass_setoid A.
 197                   mk_ext_powerclass A (S∩S') (ext_prop A (intersect_is_ext ? S S')))
 198                 (prop11 … (intersect_is_ext_morph A S)))
 199               (prop11 … (intersect_is_ext_morph A))) ,
 200        BB ≟ (ext_carr ? B),
 201        CC ≟ (ext_carr ? C)
 202    (* ------------------------------------------------------*) ⊢
 203             ext_carr A (R B C) ≡ intersect (carr A) BB CC.
 204
 205 (*
 206 alias symbol "hint_decl" = "hint_decl_Type2".
 207 unification hint 0 ≔
 208   A : setoid, B,C : 𝛀^A ;
 209   CC ≟ (ext_carr ? C),
 210   BB ≟ (ext_carr ? B),
 211   C1 ≟ (carr1 (powerclass_setoid (carr A))),
 212   C2 ≟ (carr1 (ext_powerclass_setoid A))
 213   ⊢
 214      eq_rel1 C1 (eq1 (powerclass_setoid (carr A))) BB CC ≡
 215           eq_rel1 C2 (eq1 (ext_powerclass_setoid A)) B C.
 216
 217 unification hint 0 ≔
 218   A, B : CPROP ⊢ iff A B ≡ eq_rel1 ? (eq1 CPROP) A B.
 219
 220 nlemma test: ∀U.∀A,B:𝛀^U. A ∩ B = A →
 221  ∀x,y. x=y → x ∈ A → y ∈ A ∩ B.
 222  #U; #A; #B; #H; #x; #y; #K; #K2;
 223   alias symbol "prop2" = "prop21 mem".
 224   alias symbol "invert" = "setoid1 symmetry".
 225   napply (. K^-1‡H);
 226   nassumption;
 227 nqed.
 228
 229
 230 nlemma intersect_ok: ∀A. binary_morphism1 (ext_powerclass_setoid A) (ext_powerclass_setoid A) (ext_powerclass_setoid A).
 231  #A; @
 232   [ #S; #S'; @
 233      [ napply (S ∩ S')
 234      | #a; #a'; #Ha;
 235         nwhd in ⊢ (? ? ? % %); @; *; #H1; #H2; @
 236         [##1,2: napply (. Ha^-1‡#); nassumption;
 237       ##|##3,4: napply (. Ha‡#); nassumption]##]
 238  ##| #a; #a'; #b; #b'; #Ha; #Hb; nwhd; @; #x; nwhd in ⊢ (% → %); #H
 239       [ alias symbol "invert" = "setoid1 symmetry".
 240         alias symbol "refl" = "refl".
 241 alias symbol "prop2" = "prop21".
 242 napply (. ((#‡Ha^-1)‡(#‡Hb^-1))); nassumption
 243       | napply (. ((#‡Ha)‡(#‡Hb))); nassumption ]##]
 244 nqed.
 245
 246 (* unfold if intersect, exposing fun21 *)
 247 alias symbol "hint_decl" = "hint_decl_Type1".
 248 unification hint 0 ≔
 249   A : setoid, B,C : ext_powerclass A ⊢
 250     pc A (fun21 …
 251             (mk_binary_morphism1 …
 252               (λS,S':qpowerclass_setoid A.mk_qpowerclass ? (S ∩ S') (mem_ok' ? (intersect_ok ? S S')))
 253               (prop21 … (intersect_ok A)))
 254             B
 255             C)
 256     ≡ intersect ? (pc ? B) (pc ? C).
 257
 258 nlemma test: ∀A:setoid. ∀U,V:qpowerclass A. ∀x,x':setoid1_of_setoid A. x=x' → x ∈ U ∩ V → x' ∈ U ∩ V.
 259  #A; #U; #V; #x; #x'; #H; #p; napply (. (H^-1‡#)); nassumption.
 260 nqed.
 261 *)
 262
 263 ndefinition image: ∀A,B. (carr A → carr B) → Ω^A → Ω^B ≝
 264  λA,B:setoid.λf:carr A → carr B.λSa:Ω^A.
 265   {y | ∃x. x ∈ Sa ∧ eq_rel (carr B) (eq0 B) (f x) y}.
 266
 267 ndefinition counter_image: ∀A,B. (carr A → carr B) → Ω^B → Ω^A ≝
 268  λA,B,f,Sb. {x | ∃y. y ∈ Sb ∧ f x = y}.
 269
 270 (******************* compatible equivalence relations **********************)
 271
 272 nrecord compatible_equivalence_relation (A: setoid) : Type[1] ≝
 273  { rel:> equivalence_relation A;
 274    compatibility: ∀x,x':A. x=x' → rel x x'
 275  }.
 276
 277 ndefinition quotient: ∀A. compatible_equivalence_relation A → setoid.
 278  #A; #R; @ A R;
 279 nqed.
 280
 281 (******************* first omomorphism theorem for sets **********************)
 282
 283 ndefinition eqrel_of_morphism:
 284  ∀A,B. unary_morphism A B → compatible_equivalence_relation A.
 285  #A; #B; #f; @
 286   [ @ [ napply (λx,y. f x = f y) ] /2/;
 287 ##| #x; #x'; #H; nwhd; alias symbol "prop1" = "prop1".
 288 napply (.= (†H)); // ]
 289 nqed.
 290
 291 ndefinition canonical_proj: ∀A,R. unary_morphism A (quotient A R).
 292  #A; #R; @
 293   [ napply (λx.x) |  #a; #a'; #H; napply (compatibility … R … H) ]
 294 nqed.
 295
 296 ndefinition quotiented_mor:
 297  ∀A,B.∀f:unary_morphism A B.
 298   unary_morphism (quotient … (eqrel_of_morphism … f)) B.
 299  #A; #B; #f; @ [ napply f ] //.
 300 nqed.
 301
 302 nlemma first_omomorphism_theorem_functions1:
 303  ∀A,B.∀f: unary_morphism A B.
 304   ∀x. f x = quotiented_mor … (canonical_proj … (eqrel_of_morphism … f) x).
 305 //. nqed.
 306
 307 alias symbol "eq" = "setoid eq".
 308 ndefinition surjective ≝
 309  λA,B.λS: ext_powerclass A.λT: ext_powerclass B.λf:unary_morphism A B.
 310   ∀y. y ∈ T → ∃x. x ∈ S ∧ f x = y.
 311
 312 ndefinition injective ≝
 313  λA,B.λS: ext_powerclass A.λf:unary_morphism A B.
 314   ∀x,x'. x ∈ S → x' ∈ S → f x = f x' → x = x'.
 315
 316 nlemma first_omomorphism_theorem_functions2:
 317  ∀A,B.∀f: unary_morphism A B.
 318    surjective … (Full_set ?) (Full_set ?) (canonical_proj ? (eqrel_of_morphism … f)).
 319 /3/. nqed.
 320
 321 nlemma first_omomorphism_theorem_functions3:
 322  ∀A,B.∀f: unary_morphism A B.
 323    injective … (Full_set ?) (quotiented_mor … f).
 324  #A; #B; #f; nwhd; #x; #x'; #Hx; #Hx'; #K; nassumption.
 325 nqed.
 326
 327 nrecord isomorphism (A, B : setoid) (S: ext_powerclass A) (T: ext_powerclass B) : Type[0] ≝
 328  { iso_f:> unary_morphism A B;
 329    f_closed: ∀x. x ∈ S → iso_f x ∈ T;
 330    f_sur: surjective … S T iso_f;
 331    f_inj: injective … S iso_f
 332  }.
 333
 334 nlemma subseteq_intersection_l: ∀A.∀U,V,W:Ω^A.U ⊆ W ∨ V ⊆ W → U ∩ V ⊆ W.
 335 #A; #U; #V; #W; *; #H; #x; *; /2/.
 336 nqed.
 337
 338 nlemma subseteq_union_l: ∀A.∀U,V,W:Ω^A.U ⊆ W → V ⊆ W → U ∪ V ⊆ W.
 339 #A; #U; #V; #W; #H; #H1; #x; *; /2/.
 340 nqed.
 341
 342 nlemma subseteq_intersection_r: ∀A.∀U,V,W:Ω^A.W ⊆ U → W ⊆ V → W ⊆ U ∩ V.
 343 /3/. nqed.
 344
 345 (*
 346 nrecord isomorphism (A, B : setoid) (S: qpowerclass A) (T: qpowerclass B) : CProp[0] ≝
 347  { iso_f:> unary_morphism A B;
 348    f_closed: ∀x. x ∈ pc A S → fun1 ?? iso_f x ∈ pc B T}.
 349
 350
 351 ncheck (λA:?.
 352    λB:?.
 353     λS:?.
 354      λT:?.
 355       λxxx:isomorphism A B S T.
 356        match xxx
 357        return λxxx:isomorphism A B S T.
 358                ∀x: carr A.
 359                 ∀x_72: mem (carr A) (pc A S) x.
 360                  mem (carr B) (pc B T) (fun1 A B ((λ_.?) A B S T xxx) x)
 361         with [ mk_isomorphism _ yyy ⇒ yyy ] ).
 362
 363    ;
 364  }.
 365 *)