helm/software/matita/nlibrary/sets/sets.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 (******************* SETS OVER TYPES *****************)
  16
  17 include "logic/connectives.ma".
  18
  19 nrecord powerclass (A: Type[0]) : Type[1] ≝ { mem: A → CProp[0] }.
  20
  21 interpretation "mem" 'mem a S = (mem ? S a).
  22 interpretation "powerclass" 'powerset A = (powerclass A).
  23 interpretation "subset construction" 'subset \eta.x = (mk_powerclass ? x).
  24
  25 ndefinition subseteq ≝ λA.λU,V.∀a:A. a ∈ U → a ∈ V.
  26 interpretation "subseteq" 'subseteq U V = (subseteq ? U V).
  27
  28 ndefinition overlaps ≝ λA.λU,V.∃x:A.x ∈ U ∧ x ∈ V.
  29 interpretation "overlaps" 'overlaps U V = (overlaps ? U V).
  30
  31 ndefinition intersect ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∧ x ∈ V }.
  32 interpretation "intersect" 'intersects U V = (intersect ? U V).
  33
  34 ndefinition union ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∨ x ∈ V }.
  35 interpretation "union" 'union U V = (union ? U V).
  36
  37 ndefinition substract ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∧ ¬ x ∈ V }.
  38 interpretation "substract" 'minus U V = (substract ? U V).
  39
  40
  41 ndefinition big_union ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∃i. i ∈ T ∧ x ∈ f i }.
  42
  43 ndefinition big_intersection ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∀i. i ∈ T → x ∈ f i }.
  44
  45 ndefinition full_set: ∀A. Ω^A ≝ λA.{ x | True }.
  46
  47 nlemma subseteq_refl: ∀A.∀S: Ω^A. S ⊆ S.
  48 //.nqed.
  49
  50 nlemma subseteq_trans: ∀A.∀S,T,U: Ω^A. S ⊆ T → T ⊆ U → S ⊆ U.
  51 /3/.nqed.
  52
  53 include "properties/relations1.ma".
  54
  55 ndefinition seteq: ∀A. equivalence_relation1 (Ω^A).
  56 #A; @(λS,S'. S ⊆ S' ∧ S' ⊆ S); /2/; ##[ #A B; *; /3/]
  57 #S T U; *; #H1 H2; *; /4/;
  58 nqed.
  59
  60 include "sets/setoids1.ma".
  61
  62 ndefinition singleton ≝ λA:setoid.λa:A.{ x | a = x }.
  63 interpretation "singl" 'singl a = (singleton ? a).
  64
  65 (* this has to be declared here, so that it is combined with carr *)
  66 ncoercion full_set : ∀A:Type[0]. Ω^A ≝ full_set on A: Type[0] to (Ω^?).
  67
  68 ndefinition powerclass_setoid: Type[0] → setoid1.
  69  #A; @(Ω^A);//.
  70 nqed.
  71
  72 alias symbol "hint_decl" = "hint_decl_Type2".
  73 unification hint 0 ≔ A;
  74   R ≟ (mk_setoid1 (Ω^A) (eq1 (powerclass_setoid A)))
  75 (*--------------------------------------------------*)⊢
  76      carr1 R ≡ Ω^A.
  77
  78 (************ SETS OVER SETOIDS ********************)
  79
  80 include "logic/cprop.ma".
  81
  82 nrecord ext_powerclass (A: setoid) : Type[1] ≝ {
  83    ext_carr:> Ω^A; (* qui pc viene dichiarato con un target preciso...
  84                       forse lo si vorrebbe dichiarato con un target più lasco
  85                       ma la sintassi :> non lo supporta *)
  86    ext_prop: ∀x,x':A. x=x' → (x ∈ ext_carr) = (x' ∈ ext_carr)
  87 }.
  88
  89 notation > "𝛀 ^ term 90 A" non associative with precedence 70
  90 for @{ 'ext_powerclass $A }.
  91
  92 notation < "Ω term 90 A \atop ≈" non associative with precedence 90
  93 for @{ 'ext_powerclass $A }.
  94
  95 interpretation "extensional powerclass" 'ext_powerclass a = (ext_powerclass a).
  96
  97 ndefinition Full_set: ∀A. 𝛀^A.
  98  #A; @[ napply A | #x; #x'; #H; napply refl1]
  99 nqed.
 100 ncoercion Full_set: ∀A. ext_powerclass A ≝ Full_set on A: setoid to ext_powerclass ?.
 101
 102 ndefinition ext_seteq: ∀A. equivalence_relation1 (𝛀^A).
 103  #A; @ [ napply (λS,S'. S = S') ] /2/.
 104 nqed.
 105
 106 ndefinition ext_powerclass_setoid: setoid → setoid1.
 107  #A; @ (ext_seteq A).
 108 nqed.
 109
 110 unification hint 0 ≔ A;
 111       R ≟ (mk_setoid1 (𝛀^A) (eq1 (ext_powerclass_setoid A)))
 112   (* ----------------------------------------------------- *) ⊢
 113                  carr1 R ≡ ext_powerclass A.
 114
 115 nlemma mem_ext_powerclass_setoid_is_morph:
 116  ∀A. (setoid1_of_setoid A) ⇒_1 ((𝛀^A) ⇒_1 CPROP).
 117 #A; napply (mk_binary_morphism1 … (λx:setoid1_of_setoid A.λS: 𝛀^A. x ∈ S));
 118 #a; #a'; #b; #b'; #Ha; *; #Hb1; #Hb2; @; #H
 119 [ napply (. (ext_prop … Ha^-1)) | napply (. (ext_prop … Ha)) ] /2/.
 120 nqed.
 121
 122 unification hint 0 ≔  AA, x, S;
 123      A ≟ carr AA,
 124      SS ≟ (ext_carr ? S),
 125      TT ≟ (mk_unary_morphism1 ??
 126              (λx:setoid1_of_setoid ?.
 127                mk_unary_morphism1 ??
 128                  (λS:ext_powerclass_setoid ?. x ∈ S)
 129                  (prop11 ?? (mem_ext_powerclass_setoid_is_morph AA x)))
 130              (prop11 ?? (mem_ext_powerclass_setoid_is_morph AA))),
 131      XX ≟ (ext_powerclass_setoid AA)
 132   (*-------------------------------------*) ⊢
 133       fun11 (setoid1_of_setoid AA)
 134        (unary_morphism1_setoid1 XX CPROP) TT x S
 135     ≡ mem A SS x.
 136
 137 nlemma set_ext : ∀S.∀A,B:Ω^S.A =_1 B → ∀x:S.(x ∈ A) =_1 (x ∈ B).
 138 #S A B; *; #H1 H2 x; @; ##[ napply H1 | napply H2] nqed.
 139
 140 nlemma ext_set : ∀S.∀A,B:Ω^S.(∀x:S. (x ∈ A) = (x ∈ B)) → A = B.
 141 #S A B H; @; #x; ncases (H x); #H1 H2; ##[ napply H1 | napply H2] nqed.
 142
 143 nlemma subseteq_is_morph: ∀A.  𝛀^A ⇒_1 𝛀^A ⇒_1 CPROP.
 144  #A; napply (mk_binary_morphism1 … (λS,S':𝛀^A. S ⊆ S'));
 145  #a; #a'; #b; #b'; *; #H1; #H2; *; /5/ by mk_iff, sym1, subseteq_trans;
 146 nqed.
 147
 148 (* hints for ∩ *)
 149 nlemma intersect_is_ext: ∀A. 𝛀^A → 𝛀^A → 𝛀^A.
 150 #S A B; @ (A ∩ B); #x y Exy; @; *; #H1 H2; @;
 151 ##[##1,2: napply (. Exy^-1‡#); nassumption;
 152 ##|##3,4: napply (. Exy‡#); nassumption]
 153 nqed.
 154
 155 alias symbol "hint_decl" = "hint_decl_Type1".
 156 unification hint 0 ≔
 157   A : setoid, B,C : ext_powerclass A;
 158   R ≟ (mk_ext_powerclass ? (B ∩ C) (ext_prop ? (intersect_is_ext ? B C)))
 159   (* ------------------------------------------*)  ⊢
 160     ext_carr A R ≡ intersect ? (ext_carr ? B) (ext_carr ? C).
 161
 162 nlemma intersect_is_morph: ∀A. Ω^A ⇒_1 Ω^A ⇒_1 Ω^A.
 163 #A; napply (mk_binary_morphism1 … (λS,S'. S ∩ S'));
 164 #a; #a'; #b; #b'; *; #Ha1; #Ha2; *; #Hb1; #Hb2; @; #x; nnormalize; *;/3/.
 165 nqed.
 166
 167 alias symbol "hint_decl" = "hint_decl_Type1".
 168 unification hint 0 ≔ A : Type[0], B,C : Ω^A;
 169   R ≟ mk_unary_morphism1 ??
 170        (λS. mk_unary_morphism1 ?? (λS'.S ∩ S') (prop11 ?? (intersect_is_morph A S)))
 171        (prop11 ?? (intersect_is_morph A))
 172 (*------------------------------------------------------------------------*) ⊢
 173     fun11 ?? (fun11 ?? R B) C  ≡ intersect A B C.
 174
 175 interpretation "prop21 ext" 'prop2 l r =
 176  (prop11 (ext_powerclass_setoid ?)
 177   (unary_morphism1_setoid1 (ext_powerclass_setoid ?) ?) ? ?? l ?? r).
 178
 179 nlemma intersect_is_ext_morph: ∀A. 𝛀^A ⇒_1 𝛀^A ⇒_1 𝛀^A.
 180  #A; napply (mk_binary_morphism1 … (intersect_is_ext …));
 181  #a; #a'; #b; #b'; #Ha; #Hb; napply (prop11 … (intersect_is_morph A)); nassumption.
 182 nqed.
 183
 184 unification hint 1 ≔
 185       AA : setoid, B,C : 𝛀^AA;
 186       A ≟ carr AA,
 187       R ≟ (mk_unary_morphism1 ??
 188               (λS:𝛀^AA.
 189                mk_unary_morphism1 ??
 190                 (λS':𝛀^AA.
 191                   mk_ext_powerclass AA (S∩S') (ext_prop AA (intersect_is_ext ? S S')))
 192                 (prop11 ?? (intersect_is_ext_morph AA S)))
 193               (prop11 ?? (intersect_is_ext_morph AA))) ,
 194        BB ≟ (ext_carr ? B),
 195        CC ≟ (ext_carr ? C)
 196    (* ------------------------------------------------------*) ⊢
 197             ext_carr AA (R B C) ≡ intersect A BB CC.
 198
 199
 200 (* hints for ∩ *)
 201 nlemma union_is_morph : ∀A. Ω^A ⇒_1 (Ω^A ⇒_1 Ω^A).
 202 #X; napply (mk_binary_morphism1 … (λA,B.A ∪ B));
 203 #A1 A2 B1 B2 EA EB; napply ext_set; #x;
 204 nchange in match (x ∈ (A1 ∪ B1)) with (?∨?);
 205 napply (.= (set_ext ??? EA x)‡#);
 206 napply (.= #‡(set_ext ??? EB x)); //;
 207 nqed.
 208
 209 nlemma union_is_ext: ∀A. 𝛀^A → 𝛀^A → 𝛀^A.
 210  #S A B; @ (A ∪ B); #x y Exy; @; *; #H1;
 211 ##[##1,3: @; ##|##*: @2 ]
 212 ##[##1,3: napply (. (Exy^-1)╪_1#)
 213 ##|##2,4: napply (. Exy╪_1#)]
 214 nassumption;
 215 nqed.
 216
 217 alias symbol "hint_decl" = "hint_decl_Type1".
 218 unification hint 0 ≔
 219    A : setoid, B,C :  𝛀^A;
 220    R ≟ (mk_ext_powerclass ? (B ∪ C) (ext_prop ? (union_is_ext ? B C)))
 221 (*-------------------------------------------------------------------------*)  ⊢
 222     ext_carr A R ≡ union ? (ext_carr ? B) (ext_carr ? C).
 223
 224 unification hint 0 ≔ S:Type[0], A,B:Ω^S;
 225   MM ≟ mk_unary_morphism1 ??
 226         (λA.mk_unary_morphism1 ?? (λB.A ∪ B) (prop11 ?? (union_is_morph S A)))
 227         (prop11 ?? (union_is_morph S))
 228 (*--------------------------------------------------------------------------*) ⊢
 229    fun11 ?? (fun11 ?? MM A) B ≡ A ∪ B.
 230
 231 nlemma union_is_ext_morph:∀A.𝛀^A ⇒_1 𝛀^A ⇒_1 𝛀^A.
 232 #A; napply (mk_binary_morphism1 …  (union_is_ext …));
 233 #x1 x2 y1 y2 Ex Ey; napply (prop11 … (union_is_morph A)); nassumption.
 234 nqed.
 235
 236 unification hint 1 ≔
 237   AA : setoid, B,C : 𝛀^AA;
 238   A ≟ carr AA,
 239   R ≟ (mk_unary_morphism1 ??
 240           (λS:𝛀^AA.
 241            mk_unary_morphism1 ??
 242             (λS':𝛀^AA.
 243               mk_ext_powerclass AA (S ∪ S') (ext_prop AA (union_is_ext ? S S')))
 244             (prop11 ?? (union_is_ext_morph AA S)))
 245           (prop11 ?? (union_is_ext_morph AA))) ,
 246    BB ≟ (ext_carr ? B),
 247    CC ≟ (ext_carr ? C)
 248 (*------------------------------------------------------*) ⊢
 249    ext_carr AA (R B C) ≡ union A BB CC.
 250
 251
 252 (* hints for - *)
 253 nlemma substract_is_morph : ∀A. Ω^A ⇒_1 (Ω^A ⇒_1 Ω^A).
 254 #X; napply (mk_binary_morphism1 … (λA,B.A - B));
 255 #A1 A2 B1 B2 EA EB; napply ext_set; #x;
 256 nchange in match (x ∈ (A1 - B1)) with (?∧?);
 257 napply (.= (set_ext ??? EA x)‡#); @; *; #H H1; @; //; #H2; napply H1;
 258 ##[ napply (. (set_ext ??? EB x)); ##| napply (. (set_ext ??? EB^-1 x)); ##] //;
 259 nqed.
 260
 261 nlemma substract_is_ext: ∀A. 𝛀^A → 𝛀^A → 𝛀^A.
 262  #S A B; @ (A - B); #x y Exy; @; *; #H1 H2; @; ##[##2,4: #H3; napply H2]
 263 ##[##1,4: napply (. Exy╪_1#); // ##|##2,3: napply (. Exy^-1╪_1#); //]
 264 nqed.
 265
 266 alias symbol "hint_decl" = "hint_decl_Type1".
 267 unification hint 0 ≔
 268    A : setoid, B,C :  𝛀^A;
 269    R ≟ (mk_ext_powerclass ? (B - C) (ext_prop ? (substract_is_ext ? B C)))
 270 (*-------------------------------------------------------------------------*)  ⊢
 271     ext_carr A R ≡ substract ? (ext_carr ? B) (ext_carr ? C).
 272
 273 unification hint 0 ≔ S:Type[0], A,B:Ω^S;
 274   MM ≟ mk_unary_morphism1 ??
 275         (λA.mk_unary_morphism1 ?? (λB.A - B) (prop11 ?? (substract_is_morph S A)))
 276         (prop11 ?? (substract_is_morph S))
 277 (*--------------------------------------------------------------------------*) ⊢
 278    fun11 ?? (fun11 ?? MM A) B ≡ A - B.
 279
 280 nlemma substract_is_ext_morph:∀A.𝛀^A ⇒_1 𝛀^A ⇒_1 𝛀^A.
 281 #A; napply (mk_binary_morphism1 …  (substract_is_ext …));
 282 #x1 x2 y1 y2 Ex Ey; napply (prop11 … (substract_is_morph A)); nassumption.
 283 nqed.
 284
 285 unification hint 1 ≔
 286   AA : setoid, B,C : 𝛀^AA;
 287   A ≟ carr AA,
 288   R ≟ (mk_unary_morphism1 ??
 289           (λS:𝛀^AA.
 290            mk_unary_morphism1 ??
 291             (λS':𝛀^AA.
 292               mk_ext_powerclass AA (S - S') (ext_prop AA (substract_is_ext ? S S')))
 293             (prop11 ?? (substract_is_ext_morph AA S)))
 294           (prop11 ?? (substract_is_ext_morph AA))) ,
 295    BB ≟ (ext_carr ? B),
 296    CC ≟ (ext_carr ? C)
 297 (*------------------------------------------------------*) ⊢
 298    ext_carr AA (R B C) ≡ substract A BB CC.
 299
 300 (* hints for {x} *)
 301 nlemma single_is_morph : ∀A:setoid. (setoid1_of_setoid A) ⇒_1 Ω^A.
 302 #X; @; ##[ napply (λx.{(x)}); ##]
 303 #a b E; napply ext_set; #x; @; #H; /3/; nqed.
 304
 305 nlemma single_is_ext: ∀A:setoid. A → 𝛀^A.
 306 #X a; @; ##[ napply ({(a)}); ##] #x y E; @; #H; /3/; nqed.
 307
 308 alias symbol "hint_decl" = "hint_decl_Type1".
 309 unification hint 0 ≔ A : setoid, a:A;
 310    R ≟ (mk_ext_powerclass ? {(a)} (ext_prop ? (single_is_ext ? a)))
 311 (*-------------------------------------------------------------------------*)  ⊢
 312     ext_carr A R ≡ singleton A a.
 313
 314 unification hint 0 ≔ A:setoid, a:A;
 315   MM ≟ mk_unary_morphism1 ??
 316          (λa:setoid1_of_setoid A.{(a)}) (prop11 ?? (single_is_morph A))
 317 (*--------------------------------------------------------------------------*) ⊢
 318    fun11 ?? MM a ≡ {(a)}.
 319
 320 nlemma single_is_ext_morph:∀A:setoid.(setoid1_of_setoid A) ⇒_1 𝛀^A.
 321 #A; @; ##[ #a; napply (single_is_ext ? a); ##] #a b E; @; #x; /3/; nqed.
 322
 323 unification hint 1 ≔
 324   AA : setoid, a: AA;
 325   R ≟ mk_unary_morphism1 ??
 326        (λa:setoid1_of_setoid AA.
 327          mk_ext_powerclass AA {(a)} (ext_prop ? (single_is_ext AA a)))
 328             (prop11 ?? (single_is_ext_morph AA))
 329 (*------------------------------------------------------*) ⊢
 330    ext_carr AA (R a) ≡ singleton AA a.
 331
 332
 333
 334
 335
 336
 337 (*
 338 alias symbol "hint_decl" = "hint_decl_Type2".
 339 unification hint 0 ≔
 340   A : setoid, B,C : 𝛀^A ;
 341   CC ≟ (ext_carr ? C),
 342   BB ≟ (ext_carr ? B),
 343   C1 ≟ (carr1 (powerclass_setoid (carr A))),
 344   C2 ≟ (carr1 (ext_powerclass_setoid A))
 345   ⊢
 346      eq_rel1 C1 (eq1 (powerclass_setoid (carr A))) BB CC ≡
 347           eq_rel1 C2 (eq1 (ext_powerclass_setoid A)) B C.
 348
 349 unification hint 0 ≔
 350   A, B : CPROP ⊢ iff A B ≡ eq_rel1 ? (eq1 CPROP) A B.
 351
 352 nlemma test: ∀U.∀A,B:𝛀^U. A ∩ B = A →
 353  ∀x,y. x=y → x ∈ A → y ∈ A ∩ B.
 354  #U; #A; #B; #H; #x; #y; #K; #K2;
 355   alias symbol "prop2" = "prop21 mem".
 356   alias symbol "invert" = "setoid1 symmetry".
 357   napply (. K^-1‡H);
 358   nassumption;
 359 nqed.
 360
 361
 362 nlemma intersect_ok: ∀A. binary_morphism1 (ext_powerclass_setoid A) (ext_powerclass_setoid A) (ext_powerclass_setoid A).
 363  #A; @
 364   [ #S; #S'; @
 365      [ napply (S ∩ S')
 366      | #a; #a'; #Ha;
 367         nwhd in ⊢ (? ? ? % %); @; *; #H1; #H2; @
 368         [##1,2: napply (. Ha^-1‡#); nassumption;
 369       ##|##3,4: napply (. Ha‡#); nassumption]##]
 370  ##| #a; #a'; #b; #b'; #Ha; #Hb; nwhd; @; #x; nwhd in ⊢ (% → %); #H
 371       [ alias symbol "invert" = "setoid1 symmetry".
 372         alias symbol "refl" = "refl".
 373 alias symbol "prop2" = "prop21".
 374 napply (. ((#‡Ha^-1)‡(#‡Hb^-1))); nassumption
 375       | napply (. ((#‡Ha)‡(#‡Hb))); nassumption ]##]
 376 nqed.
 377
 378 (* unfold if intersect, exposing fun21 *)
 379 alias symbol "hint_decl" = "hint_decl_Type1".
 380 unification hint 0 ≔
 381   A : setoid, B,C : ext_powerclass A ⊢
 382     pc A (fun21 …
 383             (mk_binary_morphism1 …
 384               (λS,S':qpowerclass_setoid A.mk_qpowerclass ? (S ∩ S') (mem_ok' ? (intersect_ok ? S S')))
 385               (prop21 … (intersect_ok A)))
 386             B
 387             C)
 388     ≡ intersect ? (pc ? B) (pc ? C).
 389
 390 nlemma test: ∀A:setoid. ∀U,V:qpowerclass A. ∀x,x':setoid1_of_setoid A. x=x' → x ∈ U ∩ V → x' ∈ U ∩ V.
 391  #A; #U; #V; #x; #x'; #H; #p; napply (. (H^-1‡#)); nassumption.
 392 nqed.
 393 *)
 394
 395 ndefinition image: ∀A,B. (carr A → carr B) → Ω^A → Ω^B ≝
 396  λA,B:setoid.λf:carr A → carr B.λSa:Ω^A.
 397   {y | ∃x. x ∈ Sa ∧ eq_rel (carr B) (eq0 B) (f x) y}.
 398
 399 ndefinition counter_image: ∀A,B. (carr A → carr B) → Ω^B → Ω^A ≝
 400  λA,B,f,Sb. {x | ∃y. y ∈ Sb ∧ f x = y}.
 401
 402 (******************* compatible equivalence relations **********************)
 403
 404 nrecord compatible_equivalence_relation (A: setoid) : Type[1] ≝
 405  { rel:> equivalence_relation A;
 406    compatibility: ∀x,x':A. x=x' → rel x x'
 407  }.
 408
 409 ndefinition quotient: ∀A. compatible_equivalence_relation A → setoid.
 410  #A; #R; @ A R;
 411 nqed.
 412
 413 (******************* first omomorphism theorem for sets **********************)
 414
 415 ndefinition eqrel_of_morphism:
 416  ∀A,B. A ⇒_0 B → compatible_equivalence_relation A.
 417  #A; #B; #f; @
 418   [ @ [ napply (λx,y. f x = f y) ] /2/;
 419 ##| #x; #x'; #H; nwhd; alias symbol "prop1" = "prop1".
 420 napply (.= (†H)); // ]
 421 nqed.
 422
 423 ndefinition canonical_proj: ∀A,R. A ⇒_0 (quotient A R).
 424  #A; #R; @
 425   [ napply (λx.x) |  #a; #a'; #H; napply (compatibility … R … H) ]
 426 nqed.
 427
 428 ndefinition quotiented_mor:
 429  ∀A,B.∀f:A ⇒_0 B.(quotient … (eqrel_of_morphism … f)) ⇒_0 B.
 430  #A; #B; #f; @ [ napply f ] //.
 431 nqed.
 432
 433 nlemma first_omomorphism_theorem_functions1:
 434  ∀A,B.∀f: unary_morphism A B.
 435   ∀x. f x = quotiented_mor … (canonical_proj … (eqrel_of_morphism … f) x).
 436 //. nqed.
 437
 438 alias symbol "eq" = "setoid eq".
 439 ndefinition surjective ≝
 440  λA,B.λS: ext_powerclass A.λT: ext_powerclass B.λf:A ⇒_0 B.
 441   ∀y. y ∈ T → ∃x. x ∈ S ∧ f x = y.
 442
 443 ndefinition injective ≝
 444  λA,B.λS: ext_powerclass A.λf:A ⇒_0 B.
 445   ∀x,x'. x ∈ S → x' ∈ S → f x = f x' → x = x'.
 446
 447 nlemma first_omomorphism_theorem_functions2:
 448  ∀A,B.∀f:A ⇒_0 B.
 449    surjective … (Full_set ?) (Full_set ?) (canonical_proj ? (eqrel_of_morphism … f)).
 450 /3/. nqed.
 451
 452 nlemma first_omomorphism_theorem_functions3:
 453  ∀A,B.∀f:A ⇒_0 B.
 454    injective … (Full_set ?) (quotiented_mor … f).
 455  #A; #B; #f; nwhd; #x; #x'; #Hx; #Hx'; #K; nassumption.
 456 nqed.
 457
 458 nrecord isomorphism (A, B : setoid) (S: ext_powerclass A) (T: ext_powerclass B) : Type[0] ≝
 459  { iso_f:> A ⇒_0 B;
 460    f_closed: ∀x. x ∈ S → iso_f x ∈ T;
 461    f_sur: surjective … S T iso_f;
 462    f_inj: injective … S iso_f
 463  }.
 464
 465
 466 (*
 467 nrecord isomorphism (A, B : setoid) (S: qpowerclass A) (T: qpowerclass B) : CProp[0] ≝
 468  { iso_f:> unary_morphism A B;
 469    f_closed: ∀x. x ∈ pc A S → fun1 ?? iso_f x ∈ pc B T}.
 470
 471
 472 ncheck (λA:?.
 473    λB:?.
 474     λS:?.
 475      λT:?.
 476       λxxx:isomorphism A B S T.
 477        match xxx
 478        return λxxx:isomorphism A B S T.
 479                ∀x: carr A.
 480                 ∀x_72: mem (carr A) (pc A S) x.
 481                  mem (carr B) (pc B T) (fun1 A B ((λ_.?) A B S T xxx) x)
 482         with [ mk_isomorphism _ yyy ⇒ yyy ] ).
 483
 484    ;
 485  }.
 486 *)
 487
 488 (* Set theory *)
 489
 490 nlemma subseteq_intersection_l: ∀A.∀U,V,W:Ω^A.U ⊆ W ∨ V ⊆ W → U ∩ V ⊆ W.
 491 #A; #U; #V; #W; *; #H; #x; *; /2/.
 492 nqed.
 493
 494 nlemma subseteq_union_l: ∀A.∀U,V,W:Ω^A.U ⊆ W → V ⊆ W → U ∪ V ⊆ W.
 495 #A; #U; #V; #W; #H; #H1; #x; *; /2/.
 496 nqed.
 497
 498 nlemma subseteq_intersection_r: ∀A.∀U,V,W:Ω^A.W ⊆ U → W ⊆ V → W ⊆ U ∩ V.
 499 /3/. nqed.
 500
 501 nlemma cupC : ∀S. ∀a,b:Ω^S.a ∪ b = b ∪ a.
 502 #S a b; @; #w; *; nnormalize; /2/; nqed.
 503
 504 nlemma cupID : ∀S. ∀a:Ω^S.a ∪ a = a.
 505 #S a; @; #w; ##[*; //] /2/; nqed.
 506
 507 (* XXX Bug notazione \cup, niente parentesi *)
 508 nlemma cupA : ∀S.∀a,b,c:Ω^S.a ∪ b ∪ c = a ∪ (b ∪ c).
 509 #S a b c; @; #w; *; /3/; *; /3/; nqed.
 510
 511 ndefinition Empty_set : ∀A.Ω^A ≝ λA.{ x | False }.
 512
 513 notation "∅" non associative with precedence 90 for @{ 'empty }.
 514 interpretation "empty set" 'empty = (Empty_set ?).
 515
 516 nlemma cup0 :∀S.∀A:Ω^S.A ∪ ∅ = A.
 517 #S p; @; #w; ##[*; //| #; @1; //] *; nqed.
 518