helm/software/matita/nlibrary/sets/sets.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 (******************* SETS OVER TYPES *****************)
  16
  17 include "logic/connectives.ma".
  18
  19 nrecord powerclass (A: Type[0]) : Type[1] ≝ { mem: A → CProp[0] }.
  20
  21 interpretation "mem" 'mem a S = (mem ? S a).
  22 interpretation "powerclass" 'powerset A = (powerclass A).
  23 interpretation "subset construction" 'subset \eta.x = (mk_powerclass ? x).
  24
  25 ndefinition subseteq ≝ λA.λU,V.∀a:A. a ∈ U → a ∈ V.
  26 interpretation "subseteq" 'subseteq U V = (subseteq ? U V).
  27
  28 ndefinition overlaps ≝ λA.λU,V.∃x:A.x ∈ U ∧ x ∈ V.
  29 interpretation "overlaps" 'overlaps U V = (overlaps ? U V).
  30
  31 ndefinition intersect ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∧ x ∈ V }.
  32 interpretation "intersect" 'intersects U V = (intersect ? U V).
  33
  34 ndefinition union ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∨ x ∈ V }.
  35 interpretation "union" 'union U V = (union ? U V).
  36
  37 ndefinition big_union ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∃i. i ∈ T ∧ x ∈ f i }.
  38
  39 ndefinition big_intersection ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∀i. i ∈ T → x ∈ f i }.
  40
  41 ndefinition full_set: ∀A. Ω^A ≝ λA.{ x | True }.
  42
  43 nlemma subseteq_refl: ∀A.∀S: Ω^A. S ⊆ S.
  44  #A; #S; #x; #H; nassumption.
  45 nqed.
  46
  47 nlemma subseteq_trans: ∀A.∀S,T,U: Ω^A. S ⊆ T → T ⊆ U → S ⊆ U.
  48  #A; #S; #T; #U; #H1; #H2; #x; #P; napply H2; napply H1; nassumption.
  49 nqed.
  50
  51 include "properties/relations1.ma".
  52
  53 ndefinition seteq: ∀A. equivalence_relation1 (Ω^A).
  54  #A; @
  55   [ napply (λS,S'. S ⊆ S' ∧ S' ⊆ S)
  56   | #S; @; napply subseteq_refl
  57   | #S; #S'; *; #H1; #H2; @; nassumption
  58   | #S; #T; #U; *; #H1; #H2; *; #H3; #H4; @; napply subseteq_trans;
  59      ##[##2,5: nassumption |##1,4: ##skip |##*: nassumption]##]
  60 nqed.
  61
  62 include "sets/setoids1.ma".
  63
  64 (* this has to be declared here, so that it is combined with carr *)
  65 ncoercion full_set : ∀A:Type[0]. Ω^A ≝ full_set on A: Type[0] to (Ω^?).
  66
  67 ndefinition powerclass_setoid: Type[0] → setoid1.
  68  #A; @[ napply (Ω^A)| napply seteq ]
  69 nqed.
  70
  71 include "hints_declaration.ma".
  72
  73 alias symbol "hint_decl" = "hint_decl_Type2".
  74 unification hint 0 ≔ A ⊢ carr1 (mk_setoid1 (Ω^A) (eq1 (powerclass_setoid A))) ≡ Ω^A.
  75
  76 (************ SETS OVER SETOIDS ********************)
  77
  78 include "logic/cprop.ma".
  79
  80 nrecord qpowerclass (A: setoid) : Type[1] ≝
  81  { pc:> Ω^A; (* qui pc viene dichiarato con un target preciso...
  82                 forse lo si vorrebbe dichiarato con un target più lasco
  83                 ma la sintassi :> non lo supporta *)
  84    mem_ok': ∀x,x':A. x=x' → (x ∈ pc) = (x' ∈ pc)
  85  }.
  86
  87 ndefinition Full_set: ∀A. qpowerclass A.
  88  #A; @[ napply A | #x; #x'; #H; napply refl1]
  89 nqed.
  90 ncoercion Full_set: ∀A. qpowerclass A ≝ Full_set on A: setoid to qpowerclass ?.
  91
  92 ndefinition qseteq: ∀A. equivalence_relation1 (qpowerclass A).
  93  #A; @
  94   [ napply (λS,S'. S = S')
  95   | #S; napply (refl1 ? (seteq A))
  96   | #S; #S'; napply (sym1 ? (seteq A))
  97   | #S; #T; #U; napply (trans1 ? (seteq A))]
  98 nqed.
  99
 100 ndefinition qpowerclass_setoid: setoid → setoid1.
 101  #A; @
 102   [ napply (qpowerclass A)
 103   | napply (qseteq A) ]
 104 nqed.
 105
 106 unification hint 0 ≔ A ⊢
 107   carr1 (qpowerclass_setoid A) ≡ qpowerclass A.
 108
 109 (*CSC: non va!
 110 unification hint 0 ≔ A ⊢
 111   carr1 (mk_setoid1 (qpowerclass A) (eq1 (qpowerclass_setoid A))) ≡ qpowerclass A.*)
 112
 113 nlemma mem_ok: ∀A. binary_morphism1 (setoid1_of_setoid A) (qpowerclass_setoid A) CPROP.
 114  #A; @
 115   [ napply (λx,S. x ∈ S)
 116   | #a; #a'; #b; #b'; #Ha; *; #Hb1; #Hb2; @; #H;
 117      ##[ napply Hb1; napply (. (mem_ok' …)); ##[##3: napply H| napply Ha^-1;##]
 118      ##| napply Hb2; napply (. (mem_ok' …)); ##[##3: napply H| napply Ha;##]
 119      ##]
 120   ##]
 121 nqed.
 122
 123 (*CSC: bug qui se metto x o S al posto di ?
 124 nlemma foo: True.
 125 nletin xxx ≝ (λA:setoid.λx,S. let SS ≝ pc ? S in
 126     fun21 ??? (mk_binary_morphism1 ??? (λx.λS. ? ∈ ?) (prop21 ??? (mem_ok A))) x S);
 127 *)
 128 unification hint 0 ≔  A:setoid, x, S;
 129          SS ≟ (pc ? S)
 130   (*-------------------------------------*) ⊢
 131     fun21 ??? (mk_binary_morphism1 ??? (λx,S. x ∈ S) (prop21 ??? (mem_ok A))) x S ≡ mem A SS x.
 132
 133 nlemma subseteq_ok: ∀A. binary_morphism1 (qpowerclass_setoid A) (qpowerclass_setoid A) CPROP.
 134  #A; @
 135   [ napply (λS,S'. S ⊆ S')
 136   | #a; #a'; #b; #b'; *; #Ha1; #Ha2; *; #Hb1; #Hb2; @; #H
 137      [ napply (subseteq_trans … a)
 138         [ nassumption | napply (subseteq_trans … b); nassumption ]
 139    ##| napply (subseteq_trans … a')
 140         [ nassumption | napply (subseteq_trans … b'); nassumption ] ##]
 141 nqed.
 142
 143 unification hint 0 ≔ A,a,a'
 144  (*-----------------------------------------------------------------*) ⊢
 145   eq_rel ? (eq A) a a' ≡ eq_rel1 ? (eq1 (setoid1_of_setoid A)) a a'.
 146
 147 nlemma intersect_ok: ∀A. binary_morphism1 (qpowerclass_setoid A) (qpowerclass_setoid A) (qpowerclass_setoid A).
 148  #A; @
 149   [ #S; #S'; @
 150      [ napply (S ∩ S')
 151      | #a; #a'; #Ha;
 152         nwhd in ⊢ (? ? ? % %); @; *; #H1; #H2; @
 153         [##1,2: napply (. Ha^-1‡#); nassumption;
 154       ##|##3,4: napply (. Ha‡#); nassumption]##]
 155  ##| #a; #a'; #b; #b'; #Ha; #Hb; nwhd; @; #x; nwhd in ⊢ (% → %); #H
 156       [ alias symbol "invert" = "setoid1 symmetry".
 157         napply (. ((#‡Ha^-1)‡(#‡Hb^-1))); nassumption
 158       | napply (. ((#‡Ha)‡(#‡Hb))); nassumption ]##]
 159 nqed.
 160
 161 (* unfold if intersect, exposing fun21 *)
 162 alias symbol "hint_decl" = "hint_decl_Type1".
 163 unification hint 0 ≔
 164   A : setoid, B,C : qpowerclass A ⊢
 165     pc A (intersect_ok A B C) ≡ intersect ? (pc ? B) (pc ? C).
 166
 167 nlemma test: ∀A:setoid. ∀U,V:qpowerclass A. ∀x,x':setoid1_of_setoid A. x=x' → x ∈ U ∩ V → x' ∈ U ∩ V.
 168  #A; #U; #V; #x; #x'; #H; #p; napply (. (H^-1‡#)); nassumption.
 169 nqed.
 170
 171 ndefinition image: ∀A,B. (carr A → carr B) → Ω^A → Ω^B ≝
 172  λA,B:setoid.λf:carr A → carr B.λSa:Ω^A.
 173   {y | ∃x. x ∈ Sa ∧ eq_rel (carr B) (eq B) (f x) y}.
 174
 175 ndefinition counter_image: ∀A,B. (carr A → carr B) → Ω^B → Ω^A ≝
 176  λA,B,f,Sb. {x | ∃y. y ∈ Sb ∧ f x = y}.
 177
 178 (******************* compatible equivalence relations **********************)
 179
 180 nrecord compatible_equivalence_relation (A: setoid) : Type[1] ≝
 181  { rel:> equivalence_relation A;
 182    compatibility: ∀x,x':A. x=x' → rel x x'
 183  }.
 184
 185 ndefinition quotient: ∀A. compatible_equivalence_relation A → setoid.
 186  #A; #R; @ A R;
 187 nqed.
 188
 189 (******************* first omomorphism theorem for sets **********************)
 190
 191 ndefinition eqrel_of_morphism:
 192  ∀A,B. unary_morphism A B → compatible_equivalence_relation A.
 193  #A; #B; #f; @
 194   [ @
 195      [ napply (λx,y. f x = f y)
 196      | #x; napply refl | #x; #y; napply sym | #x; #y; #z; napply trans]
 197 ##| #x; #x'; #H; nwhd; alias symbol "prop1" = "prop1".
 198 napply (.= (†H)); napply refl ]
 199 nqed.
 200
 201 ndefinition canonical_proj: ∀A,R. unary_morphism A (quotient A R).
 202  #A; #R; @
 203   [ napply (λx.x) | #a; #a'; #H; napply (compatibility … R … H) ]
 204 nqed.
 205
 206 ndefinition quotiented_mor:
 207  ∀A,B.∀f:unary_morphism A B.
 208   unary_morphism (quotient … (eqrel_of_morphism … f)) B.
 209  #A; #B; #f; @
 210   [ napply f | #a; #a'; #H; nassumption]
 211 nqed.
 212
 213 nlemma first_omomorphism_theorem_functions1:
 214  ∀A,B.∀f: unary_morphism A B.
 215   ∀x. f x = quotiented_mor … (canonical_proj … (eqrel_of_morphism … f) x).
 216  #A; #B; #f; #x; napply refl;
 217 nqed.
 218
 219 ndefinition surjective ≝
 220  λA,B.λS: qpowerclass A.λT: qpowerclass B.λf:unary_morphism A B.
 221   ∀y. y ∈ T → ∃x. x ∈ S ∧ f x = y.
 222
 223 ndefinition injective ≝
 224  λA,B.λS: qpowerclass A.λf:unary_morphism A B.
 225   ∀x,x'. x ∈ S → x' ∈ S → f x = f x' → x = x'.
 226
 227 nlemma first_omomorphism_theorem_functions2:
 228  ∀A,B.∀f: unary_morphism A B.
 229    surjective … (Full_set ?) (Full_set ?) (canonical_proj ? (eqrel_of_morphism … f)).
 230  #A; #B; #f; nwhd; #y; #Hy; @ y; @ I ; napply refl;
 231  (* bug, prova @ I refl *)
 232 nqed.
 233
 234 nlemma first_omomorphism_theorem_functions3:
 235  ∀A,B.∀f: unary_morphism A B.
 236    injective … (Full_set ?) (quotiented_mor … f).
 237  #A; #B; #f; nwhd; #x; #x'; #Hx; #Hx'; #K; nassumption.
 238 nqed.
 239
 240 nrecord isomorphism (A, B : setoid) (S: qpowerclass A) (T: qpowerclass B) : Type[0] ≝
 241  { iso_f:> unary_morphism A B;
 242    f_closed: ∀x. x ∈ S → iso_f x ∈ T;
 243    f_sur: surjective … S T iso_f;
 244    f_inj: injective … S iso_f
 245  }.
 246
 247 (*
 248 nrecord isomorphism (A, B : setoid) (S: qpowerclass A) (T: qpowerclass B) : CProp[0] ≝
 249  { iso_f:> unary_morphism A B;
 250    f_closed: ∀x. x ∈ pc A S → fun1 ?? iso_f x ∈ pc B T}.
 251
 252
 253 ncheck (λA:?.
 254    λB:?.
 255     λS:?.
 256      λT:?.
 257       λxxx:isomorphism A B S T.
 258        match xxx
 259        return λxxx:isomorphism A B S T.
 260                ∀x: carr A.
 261                 ∀x_72: mem (carr A) (pc A S) x.
 262                  mem (carr B) (pc B T) (fun1 A B ((λ_.?) A B S T xxx) x)
 263         with [ mk_isomorphism _ yyy ⇒ yyy ] ).
 264
 265    ;
 266  }.
 267 *)