helm/software/matita/nlibrary/sets/sets.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 (******************* SETS OVER TYPES *****************)
  16
  17 include "logic/connectives.ma".
  18
  19 nrecord powerclass (A: Type[0]) : Type[1] ≝ { mem: A → CProp[0] }.
  20
  21 interpretation "mem" 'mem a S = (mem ? S a).
  22 interpretation "powerclass" 'powerset A = (powerclass A).
  23 interpretation "subset construction" 'subset \eta.x = (mk_powerclass ? x).
  24
  25 ndefinition subseteq ≝ λA.λU,V.∀a:A. a ∈ U → a ∈ V.
  26 interpretation "subseteq" 'subseteq U V = (subseteq ? U V).
  27
  28 ndefinition overlaps ≝ λA.λU,V.∃x:A.x ∈ U ∧ x ∈ V.
  29 interpretation "overlaps" 'overlaps U V = (overlaps ? U V).
  30
  31 ndefinition intersect ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∧ x ∈ V }.
  32 interpretation "intersect" 'intersects U V = (intersect ? U V).
  33
  34 ndefinition union ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∨ x ∈ V }.
  35 interpretation "union" 'union U V = (union ? U V).
  36
  37 ndefinition substract ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∧ ¬ x ∈ V }.
  38 interpretation "substract" 'minus U V = (substract ? U V).
  39
  40
  41 ndefinition big_union ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∃i. i ∈ T ∧ x ∈ f i }.
  42
  43 ndefinition big_intersection ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∀i. i ∈ T → x ∈ f i }.
  44
  45 ndefinition full_set: ∀A. Ω^A ≝ λA.{ x | True }.
  46
  47 nlemma subseteq_refl: ∀A.∀S: Ω^A. S ⊆ S.
  48 //.nqed.
  49
  50 nlemma subseteq_trans: ∀A.∀S,T,U: Ω^A. S ⊆ T → T ⊆ U → S ⊆ U.
  51 /3/.nqed.
  52
  53 include "properties/relations1.ma".
  54
  55 ndefinition seteq: ∀A. equivalence_relation1 (Ω^A).
  56 #A; @(λS,S'. S ⊆ S' ∧ S' ⊆ S); /2/; ##[ #A B; *; /3/]
  57 #S T U; *; #H1 H2; *; /4/;
  58 nqed.
  59
  60 include "sets/setoids1.ma".
  61
  62 ndefinition singleton ≝ λA:setoid.λa:A.{ x | a = x }.
  63 interpretation "singl" 'singl a = (singleton ? a).
  64
  65 (* this has to be declared here, so that it is combined with carr *)
  66 ncoercion full_set : ∀A:Type[0]. Ω^A ≝ full_set on A: Type[0] to (Ω^?).
  67
  68 ndefinition powerclass_setoid: Type[0] → setoid1.
  69  #A; @(Ω^A);//.
  70 nqed.
  71
  72 alias symbol "hint_decl" = "hint_decl_Type2".
  73 unification hint 0 ≔ A;
  74   R ≟ (mk_setoid1 (Ω^A) (eq1 (powerclass_setoid A)))
  75 (*--------------------------------------------------*)⊢
  76      carr1 R ≡ Ω^A.
  77
  78 (************ SETS OVER SETOIDS ********************)
  79
  80 include "logic/cprop.ma".
  81
  82 nrecord ext_powerclass (A: setoid) : Type[1] ≝ {
  83    ext_carr:> Ω^A; (* qui pc viene dichiarato con un target preciso...
  84                       forse lo si vorrebbe dichiarato con un target più lasco
  85                       ma la sintassi :> non lo supporta *)
  86    ext_prop: ∀x,x':A. x=x' → (x ∈ ext_carr) = (x' ∈ ext_carr)
  87 }.
  88
  89 notation > "𝛀 ^ term 90 A" non associative with precedence 70
  90 for @{ 'ext_powerclass $A }.
  91
  92 notation < "Ω term 90 A \atop ≈" non associative with precedence 90
  93 for @{ 'ext_powerclass $A }.
  94
  95 interpretation "extensional powerclass" 'ext_powerclass a = (ext_powerclass a).
  96
  97 ndefinition Full_set: ∀A. 𝛀^A.
  98  #A; @[ napply A | #x; #x'; #H; napply refl1]
  99 nqed.
 100 ncoercion Full_set: ∀A. ext_powerclass A ≝ Full_set on A: setoid to ext_powerclass ?.
 101
 102 ndefinition ext_seteq: ∀A. equivalence_relation1 (𝛀^A).
 103  #A; @ [ napply (λS,S'. S = S') ] /2/.
 104 nqed.
 105
 106 ndefinition ext_powerclass_setoid: setoid → setoid1.
 107  #A; @ (ext_seteq A).
 108 nqed.
 109
 110 unification hint 0 ≔ A;
 111       R ≟ (mk_setoid1 (𝛀^A) (eq1 (ext_powerclass_setoid A)))
 112   (* ----------------------------------------------------- *) ⊢
 113                  carr1 R ≡ ext_powerclass A.
 114
 115 nlemma mem_ext_powerclass_setoid_is_morph:
 116  ∀A. (setoid1_of_setoid A) ⇒_1 ((𝛀^A) ⇒_1 CPROP).
 117 #A; napply (mk_binary_morphism1 … (λx:setoid1_of_setoid A.λS: 𝛀^A. x ∈ S));
 118 #a; #a'; #b; #b'; #Ha; *; #Hb1; #Hb2; @; #H
 119 [ napply (. (ext_prop … Ha^-1)) | napply (. (ext_prop … Ha)) ] /2/.
 120 nqed.
 121
 122 unification hint 0 ≔  AA, x, S;
 123      A ≟ carr AA,
 124      SS ≟ (ext_carr ? S),
 125      TT ≟ (mk_unary_morphism1 ??
 126              (λx:setoid1_of_setoid ?.
 127                mk_unary_morphism1 ??
 128                  (λS:ext_powerclass_setoid ?. x ∈ S)
 129                  (prop11 ?? (mem_ext_powerclass_setoid_is_morph AA x)))
 130              (prop11 ?? (mem_ext_powerclass_setoid_is_morph AA))),
 131      XX ≟ (ext_powerclass_setoid AA)
 132   (*-------------------------------------*) ⊢
 133       fun11 (setoid1_of_setoid AA)
 134        (unary_morphism1_setoid1 XX CPROP) TT x S
 135     ≡ mem A SS x.
 136
 137 nlemma set_ext : ∀S.∀A,B:Ω^S.A =_1 B → ∀x:S.(x ∈ A) =_1 (x ∈ B).
 138 #S A B; *; #H1 H2 x; @; ##[ napply H1 | napply H2] nqed.
 139
 140 nlemma ext_set : ∀S.∀A,B:Ω^S.(∀x:S. (x ∈ A) = (x ∈ B)) → A = B.
 141 #S A B H; @; #x; ncases (H x); #H1 H2; ##[ napply H1 | napply H2] nqed.
 142
 143 nlemma subseteq_is_morph: ∀A.  𝛀^A ⇒_1 𝛀^A ⇒_1 CPROP.
 144  #A; napply (mk_binary_morphism1 … (λS,S':𝛀^A. S ⊆ S'));
 145  #a; #a'; #b; #b'; *; #H1; #H2; *; /5/ by mk_iff, sym1, subseteq_trans;
 146 nqed.
 147
 148 (* hints for ∩ *)
 149 nlemma intersect_is_ext: ∀A. 𝛀^A → 𝛀^A → 𝛀^A.
 150 #S A B; @ (A ∩ B); #x y Exy; @; *; #H1 H2; @;
 151 ##[##1,2: napply (. Exy^-1╪_1#); nassumption;
 152 ##|##3,4: napply (. Exy‡#); nassumption]
 153 nqed.
 154
 155 alias symbol "hint_decl" = "hint_decl_Type1".
 156 unification hint 0 ≔
 157   A : setoid, B,C : ext_powerclass A;
 158   R ≟ (mk_ext_powerclass ? (B ∩ C) (ext_prop ? (intersect_is_ext ? B C)))
 159   (* ------------------------------------------*)  ⊢
 160     ext_carr A R ≡ intersect ? (ext_carr ? B) (ext_carr ? C).
 161
 162 nlemma intersect_is_morph: ∀A. Ω^A ⇒_1 Ω^A ⇒_1 Ω^A.
 163 #A; napply (mk_binary_morphism1 … (λS,S'. S ∩ S'));
 164 #a; #a'; #b; #b'; *; #Ha1; #Ha2; *; #Hb1; #Hb2; @; #x; nnormalize; *;/3/.
 165 nqed.
 166
 167 alias symbol "hint_decl" = "hint_decl_Type1".
 168 unification hint 0 ≔ A : Type[0], B,C : Ω^A;
 169   T ≟ powerclass_setoid A,
 170   R ≟ mk_unary_morphism1 ??
 171        (λS. mk_unary_morphism1 ?? (λS'.S ∩ S') (prop11 ?? (intersect_is_morph A S)))
 172        (prop11 ?? (intersect_is_morph A))
 173 (*------------------------------------------------------------------------*) ⊢
 174     fun11 T T (fun11 T (unary_morphism1_setoid1 T T) R B) C  ≡ intersect A B C.
 175
 176 interpretation "prop21 ext" 'prop2 l r =
 177  (prop11 (ext_powerclass_setoid ?)
 178   (unary_morphism1_setoid1 (ext_powerclass_setoid ?) ?) ? ?? l ?? r).
 179
 180 nlemma intersect_is_ext_morph: ∀A. 𝛀^A ⇒_1 𝛀^A ⇒_1 𝛀^A.
 181  #A; napply (mk_binary_morphism1 … (intersect_is_ext …));
 182  #a; #a'; #b; #b'; #Ha; #Hb; napply (prop11 … (intersect_is_morph A)); nassumption.
 183 nqed.
 184
 185 unification hint 1 ≔
 186       AA : setoid, B,C : 𝛀^AA;
 187       A ≟ carr AA,
 188       R ≟ (mk_unary_morphism1 ??
 189               (λS:𝛀^AA.
 190                mk_unary_morphism1 ??
 191                 (λS':𝛀^AA.
 192                   mk_ext_powerclass AA (S∩S') (ext_prop AA (intersect_is_ext ? S S')))
 193                 (prop11 ?? (intersect_is_ext_morph AA S)))
 194               (prop11 ?? (intersect_is_ext_morph AA))) ,
 195        BB ≟ (ext_carr ? B),
 196        CC ≟ (ext_carr ? C)
 197    (* ------------------------------------------------------*) ⊢
 198             ext_carr AA (R B C) ≡ intersect A BB CC.
 199
 200
 201 (* hints for ∩ *)
 202 nlemma union_is_morph : ∀A. Ω^A ⇒_1 (Ω^A ⇒_1 Ω^A).
 203 #X; napply (mk_binary_morphism1 … (λA,B.A ∪ B));
 204 #A1 A2 B1 B2 EA EB; napply ext_set; #x;
 205 nchange in match (x ∈ (A1 ∪ B1)) with (?∨?);
 206 napply (.= (set_ext ??? EA x)‡#);
 207 napply (.= #‡(set_ext ??? EB x)); //;
 208 nqed.
 209
 210 nlemma union_is_ext: ∀A. 𝛀^A → 𝛀^A → 𝛀^A.
 211  #S A B; @ (A ∪ B); #x y Exy; @; *; #H1;
 212 ##[##1,3: @; ##|##*: @2 ]
 213 ##[##1,3: napply (. (Exy^-1)╪_1#)
 214 ##|##2,4: napply (. Exy╪_1#)]
 215 nassumption;
 216 nqed.
 217
 218 alias symbol "hint_decl" = "hint_decl_Type1".
 219 unification hint 0 ≔
 220    A : setoid, B,C :  𝛀^A;
 221    R ≟ (mk_ext_powerclass ? (B ∪ C) (ext_prop ? (union_is_ext ? B C)))
 222 (*-------------------------------------------------------------------------*)  ⊢
 223     ext_carr A R ≡ union ? (ext_carr ? B) (ext_carr ? C).
 224
 225 unification hint 0 ≔ S:Type[0], A,B:Ω^S;
 226   T ≟ powerclass_setoid S,
 227   MM ≟ mk_unary_morphism1 ??
 228         (λA.mk_unary_morphism1 ?? (λB.A ∪ B) (prop11 ?? (union_is_morph S A)))
 229         (prop11 ?? (union_is_morph S))
 230 (*--------------------------------------------------------------------------*) ⊢
 231    fun11 T T (fun11 T (unary_morphism1_setoid1 T T) MM A) B ≡ A ∪ B.
 232
 233 nlemma union_is_ext_morph:∀A.𝛀^A ⇒_1 𝛀^A ⇒_1 𝛀^A.
 234 #A; napply (mk_binary_morphism1 …  (union_is_ext …));
 235 #x1 x2 y1 y2 Ex Ey; napply (prop11 … (union_is_morph A)); nassumption.
 236 nqed.
 237
 238 unification hint 1 ≔
 239   AA : setoid, B,C : 𝛀^AA;
 240   A ≟ carr AA,
 241   R ≟ (mk_unary_morphism1 ??
 242           (λS:𝛀^AA.
 243            mk_unary_morphism1 ??
 244             (λS':𝛀^AA.
 245               mk_ext_powerclass AA (S ∪ S') (ext_prop AA (union_is_ext ? S S')))
 246             (prop11 ?? (union_is_ext_morph AA S)))
 247           (prop11 ?? (union_is_ext_morph AA))) ,
 248    BB ≟ (ext_carr ? B),
 249    CC ≟ (ext_carr ? C)
 250 (*------------------------------------------------------*) ⊢
 251    ext_carr AA (R B C) ≡ union A BB CC.
 252
 253
 254 (* hints for - *)
 255 nlemma substract_is_morph : ∀A. Ω^A ⇒_1 (Ω^A ⇒_1 Ω^A).
 256 #X; napply (mk_binary_morphism1 … (λA,B.A - B));
 257 #A1 A2 B1 B2 EA EB; napply ext_set; #x;
 258 nchange in match (x ∈ (A1 - B1)) with (?∧?);
 259 napply (.= (set_ext ??? EA x)‡#); @; *; #H H1; @; //; #H2; napply H1;
 260 ##[ napply (. (set_ext ??? EB x)); ##| napply (. (set_ext ??? EB^-1 x)); ##] //;
 261 nqed.
 262
 263 nlemma substract_is_ext: ∀A. 𝛀^A → 𝛀^A → 𝛀^A.
 264  #S A B; @ (A - B); #x y Exy; @; *; #H1 H2; @; ##[##2,4: #H3; napply H2]
 265 ##[##1,4: napply (. Exy╪_1#); // ##|##2,3: napply (. Exy^-1╪_1#); //]
 266 nqed.
 267
 268 alias symbol "hint_decl" = "hint_decl_Type1".
 269 unification hint 0 ≔
 270    A : setoid, B,C :  𝛀^A;
 271    R ≟ (mk_ext_powerclass ? (B - C) (ext_prop ? (substract_is_ext ? B C)))
 272 (*-------------------------------------------------------------------------*)  ⊢
 273     ext_carr A R ≡ substract ? (ext_carr ? B) (ext_carr ? C).
 274
 275 unification hint 0 ≔ S:Type[0], A,B:Ω^S;
 276   T ≟ powerclass_setoid S,
 277   MM ≟ mk_unary_morphism1 ??
 278         (λA.mk_unary_morphism1 ?? (λB.A - B) (prop11 ?? (substract_is_morph S A)))
 279         (prop11 ?? (substract_is_morph S))
 280 (*--------------------------------------------------------------------------*) ⊢
 281    fun11 T T (fun11 T (unary_morphism1_setoid1 T T) MM A) B ≡ A - B.
 282
 283 nlemma substract_is_ext_morph:∀A.𝛀^A ⇒_1 𝛀^A ⇒_1 𝛀^A.
 284 #A; napply (mk_binary_morphism1 …  (substract_is_ext …));
 285 #x1 x2 y1 y2 Ex Ey; napply (prop11 … (substract_is_morph A)); nassumption.
 286 nqed.
 287
 288 unification hint 1 ≔
 289   AA : setoid, B,C : 𝛀^AA;
 290   A ≟ carr AA,
 291   R ≟ (mk_unary_morphism1 ??
 292           (λS:𝛀^AA.
 293            mk_unary_morphism1 ??
 294             (λS':𝛀^AA.
 295               mk_ext_powerclass AA (S - S') (ext_prop AA (substract_is_ext ? S S')))
 296             (prop11 ?? (substract_is_ext_morph AA S)))
 297           (prop11 ?? (substract_is_ext_morph AA))) ,
 298    BB ≟ (ext_carr ? B),
 299    CC ≟ (ext_carr ? C)
 300 (*------------------------------------------------------*) ⊢
 301    ext_carr AA (R B C) ≡ substract A BB CC.
 302
 303 (* hints for {x} *)
 304 nlemma single_is_morph : ∀A:setoid. (setoid1_of_setoid A) ⇒_1 Ω^A.
 305 #X; @; ##[ napply (λx.{(x)}); ##]
 306 #a b E; napply ext_set; #x; @; #H; /3/; nqed.
 307
 308 nlemma single_is_ext: ∀A:setoid. A → 𝛀^A.
 309 #X a; @; ##[ napply ({(a)}); ##] #x y E; @; #H; /3/; nqed.
 310
 311 alias symbol "hint_decl" = "hint_decl_Type1".
 312 unification hint 0 ≔ A : setoid, a:A;
 313    R ≟ (mk_ext_powerclass ? {(a)} (ext_prop ? (single_is_ext ? a)))
 314 (*-------------------------------------------------------------------------*)  ⊢
 315     ext_carr A R ≡ singleton A a.
 316
 317 unification hint 0 ≔ A:setoid, a:A;
 318   T ≟ setoid1_of_setoid A,
 319   MM ≟ mk_unary_morphism1 ??
 320          (λa:setoid1_of_setoid A.{(a)}) (prop11 ?? (single_is_morph A))
 321 (*--------------------------------------------------------------------------*) ⊢
 322    fun11 T (powerclass_setoid A) MM a ≡ {(a)}.
 323
 324 nlemma single_is_ext_morph:∀A:setoid.(setoid1_of_setoid A) ⇒_1 𝛀^A.
 325 #A; @; ##[ #a; napply (single_is_ext ? a); ##] #a b E; @; #x; /3/; nqed.
 326
 327 unification hint 1 ≔
 328   AA : setoid, a: AA;
 329   R ≟ mk_unary_morphism1 ??
 330        (λa:setoid1_of_setoid AA.
 331          mk_ext_powerclass AA {(a)} (ext_prop ? (single_is_ext AA a)))
 332             (prop11 ?? (single_is_ext_morph AA))
 333 (*------------------------------------------------------*) ⊢
 334    ext_carr AA (R a) ≡ singleton AA a.
 335
 336
 337
 338
 339
 340
 341 (*
 342 alias symbol "hint_decl" = "hint_decl_Type2".
 343 unification hint 0 ≔
 344   A : setoid, B,C : 𝛀^A ;
 345   CC ≟ (ext_carr ? C),
 346   BB ≟ (ext_carr ? B),
 347   C1 ≟ (carr1 (powerclass_setoid (carr A))),
 348   C2 ≟ (carr1 (ext_powerclass_setoid A))
 349   ⊢
 350      eq_rel1 C1 (eq1 (powerclass_setoid (carr A))) BB CC ≡
 351           eq_rel1 C2 (eq1 (ext_powerclass_setoid A)) B C.
 352
 353 unification hint 0 ≔
 354   A, B : CPROP ⊢ iff A B ≡ eq_rel1 ? (eq1 CPROP) A B.
 355
 356 nlemma test: ∀U.∀A,B:𝛀^U. A ∩ B = A →
 357  ∀x,y. x=y → x ∈ A → y ∈ A ∩ B.
 358  #U; #A; #B; #H; #x; #y; #K; #K2;
 359   alias symbol "prop2" = "prop21 mem".
 360   alias symbol "invert" = "setoid1 symmetry".
 361   napply (. K^-1‡H);
 362   nassumption;
 363 nqed.
 364
 365
 366 nlemma intersect_ok: ∀A. binary_morphism1 (ext_powerclass_setoid A) (ext_powerclass_setoid A) (ext_powerclass_setoid A).
 367  #A; @
 368   [ #S; #S'; @
 369      [ napply (S ∩ S')
 370      | #a; #a'; #Ha;
 371         nwhd in ⊢ (? ? ? % %); @; *; #H1; #H2; @
 372         [##1,2: napply (. Ha^-1‡#); nassumption;
 373       ##|##3,4: napply (. Ha‡#); nassumption]##]
 374  ##| #a; #a'; #b; #b'; #Ha; #Hb; nwhd; @; #x; nwhd in ⊢ (% → %); #H
 375       [ alias symbol "invert" = "setoid1 symmetry".
 376         alias symbol "refl" = "refl".
 377 alias symbol "prop2" = "prop21".
 378 napply (. ((#‡Ha^-1)‡(#‡Hb^-1))); nassumption
 379       | napply (. ((#‡Ha)‡(#‡Hb))); nassumption ]##]
 380 nqed.
 381
 382 (* unfold if intersect, exposing fun21 *)
 383 alias symbol "hint_decl" = "hint_decl_Type1".
 384 unification hint 0 ≔
 385   A : setoid, B,C : ext_powerclass A ⊢
 386     pc A (fun21 …
 387             (mk_binary_morphism1 …
 388               (λS,S':qpowerclass_setoid A.mk_qpowerclass ? (S ∩ S') (mem_ok' ? (intersect_ok ? S S')))
 389               (prop21 … (intersect_ok A)))
 390             B
 391             C)
 392     ≡ intersect ? (pc ? B) (pc ? C).
 393
 394 nlemma test: ∀A:setoid. ∀U,V:qpowerclass A. ∀x,x':setoid1_of_setoid A. x=x' → x ∈ U ∩ V → x' ∈ U ∩ V.
 395  #A; #U; #V; #x; #x'; #H; #p; napply (. (H^-1‡#)); nassumption.
 396 nqed.
 397 *)
 398
 399 ndefinition image: ∀A,B. (carr A → carr B) → Ω^A → Ω^B ≝
 400  λA,B:setoid.λf:carr A → carr B.λSa:Ω^A.
 401   {y | ∃x. x ∈ Sa ∧ eq_rel (carr B) (eq0 B) (f x) y}.
 402
 403 ndefinition counter_image: ∀A,B. (carr A → carr B) → Ω^B → Ω^A ≝
 404  λA,B,f,Sb. {x | ∃y. y ∈ Sb ∧ f x = y}.
 405
 406 (******************* compatible equivalence relations **********************)
 407
 408 nrecord compatible_equivalence_relation (A: setoid) : Type[1] ≝
 409  { rel:> equivalence_relation A;
 410    compatibility: ∀x,x':A. x=x' → rel x x'
 411  }.
 412
 413 ndefinition quotient: ∀A. compatible_equivalence_relation A → setoid.
 414  #A; #R; @ A R;
 415 nqed.
 416
 417 (******************* first omomorphism theorem for sets **********************)
 418
 419 ndefinition eqrel_of_morphism:
 420  ∀A,B. A ⇒_0 B → compatible_equivalence_relation A.
 421  #A; #B; #f; @
 422   [ @ [ napply (λx,y. f x = f y) ] /2/;
 423 ##| #x; #x'; #H; nwhd; alias symbol "prop1" = "prop1".
 424 napply (.= (†H)); // ]
 425 nqed.
 426
 427 ndefinition canonical_proj: ∀A,R. A ⇒_0 (quotient A R).
 428  #A; #R; @
 429   [ napply (λx.x) |  #a; #a'; #H; napply (compatibility … R … H) ]
 430 nqed.
 431
 432 ndefinition quotiented_mor:
 433  ∀A,B.∀f:A ⇒_0 B.(quotient … (eqrel_of_morphism … f)) ⇒_0 B.
 434  #A; #B; #f; @ [ napply f ] //.
 435 nqed.
 436
 437 nlemma first_omomorphism_theorem_functions1:
 438  ∀A,B.∀f: unary_morphism A B.
 439   ∀x. f x = quotiented_mor … (canonical_proj … (eqrel_of_morphism … f) x).
 440 //. nqed.
 441
 442 alias symbol "eq" = "setoid eq".
 443 ndefinition surjective ≝
 444  λA,B.λS: ext_powerclass A.λT: ext_powerclass B.λf:A ⇒_0 B.
 445   ∀y. y ∈ T → ∃x. x ∈ S ∧ f x = y.
 446
 447 ndefinition injective ≝
 448  λA,B.λS: ext_powerclass A.λf:A ⇒_0 B.
 449   ∀x,x'. x ∈ S → x' ∈ S → f x = f x' → x = x'.
 450
 451 nlemma first_omomorphism_theorem_functions2:
 452  ∀A,B.∀f:A ⇒_0 B.
 453    surjective … (Full_set ?) (Full_set ?) (canonical_proj ? (eqrel_of_morphism … f)).
 454 /3/. nqed.
 455
 456 nlemma first_omomorphism_theorem_functions3:
 457  ∀A,B.∀f:A ⇒_0 B.
 458    injective … (Full_set ?) (quotiented_mor … f).
 459  #A; #B; #f; nwhd; #x; #x'; #Hx; #Hx'; #K; nassumption.
 460 nqed.
 461
 462 nrecord isomorphism (A, B : setoid) (S: ext_powerclass A) (T: ext_powerclass B) : Type[0] ≝
 463  { iso_f:> A ⇒_0 B;
 464    f_closed: ∀x. x ∈ S → iso_f x ∈ T;
 465    f_sur: surjective … S T iso_f;
 466    f_inj: injective … S iso_f
 467  }.
 468
 469
 470 (*
 471 nrecord isomorphism (A, B : setoid) (S: qpowerclass A) (T: qpowerclass B) : CProp[0] ≝
 472  { iso_f:> unary_morphism A B;
 473    f_closed: ∀x. x ∈ pc A S → fun1 ?? iso_f x ∈ pc B T}.
 474
 475
 476 ncheck (λA:?.
 477    λB:?.
 478     λS:?.
 479      λT:?.
 480       λxxx:isomorphism A B S T.
 481        match xxx
 482        return λxxx:isomorphism A B S T.
 483                ∀x: carr A.
 484                 ∀x_72: mem (carr A) (pc A S) x.
 485                  mem (carr B) (pc B T) (fun1 A B ((λ_.?) A B S T xxx) x)
 486         with [ mk_isomorphism _ yyy ⇒ yyy ] ).
 487
 488    ;
 489  }.
 490 *)
 491
 492 (* Set theory *)
 493
 494 nlemma subseteq_intersection_l: ∀A.∀U,V,W:Ω^A.U ⊆ W ∨ V ⊆ W → U ∩ V ⊆ W.
 495 #A; #U; #V; #W; *; #H; #x; *; /2/.
 496 nqed.
 497
 498 nlemma subseteq_union_l: ∀A.∀U,V,W:Ω^A.U ⊆ W → V ⊆ W → U ∪ V ⊆ W.
 499 #A; #U; #V; #W; #H; #H1; #x; *; /2/.
 500 nqed.
 501
 502 nlemma subseteq_intersection_r: ∀A.∀U,V,W:Ω^A.W ⊆ U → W ⊆ V → W ⊆ U ∩ V.
 503 /3/. nqed.
 504
 505 nlemma cupC : ∀S. ∀a,b:Ω^S.a ∪ b = b ∪ a.
 506 #S a b; @; #w; *; nnormalize; /2/; nqed.
 507
 508 nlemma cupID : ∀S. ∀a:Ω^S.a ∪ a = a.
 509 #S a; @; #w; ##[*; //] /2/; nqed.
 510
 511 (* XXX Bug notazione \cup, niente parentesi *)
 512 nlemma cupA : ∀S.∀a,b,c:Ω^S.a ∪ b ∪ c = a ∪ (b ∪ c).
 513 #S a b c; @; #w; *; /3/; *; /3/; nqed.
 514
 515 ndefinition Empty_set : ∀A.Ω^A ≝ λA.{ x | False }.
 516
 517 notation "∅" non associative with precedence 90 for @{ 'empty }.
 518 interpretation "empty set" 'empty = (Empty_set ?).
 519
 520 nlemma cup0 :∀S.∀A:Ω^S.A ∪ ∅ = A.
 521 #S p; @; #w; ##[*; //| #; @1; //] *; nqed.
 522