helm/software/matita/nlibrary/sets/sets.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 (******************* SETS OVER TYPES *****************)
  16
  17 include "logic/connectives.ma".
  18
  19 nrecord powerclass (A: Type[0]) : Type[1] ≝ { mem: A → CProp[0] }.
  20
  21 interpretation "mem" 'mem a S = (mem ? S a).
  22 interpretation "powerclass" 'powerset A = (powerclass A).
  23 interpretation "subset construction" 'subset \eta.x = (mk_powerclass ? x).
  24
  25 ndefinition subseteq ≝ λA.λU,V.∀a:A. a ∈ U → a ∈ V.
  26 interpretation "subseteq" 'subseteq U V = (subseteq ? U V).
  27
  28 ndefinition overlaps ≝ λA.λU,V.∃x:A.x ∈ U ∧ x ∈ V.
  29 interpretation "overlaps" 'overlaps U V = (overlaps ? U V).
  30
  31 ndefinition intersect ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∧ x ∈ V }.
  32 interpretation "intersect" 'intersects U V = (intersect ? U V).
  33
  34 ndefinition union ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∨ x ∈ V }.
  35 interpretation "union" 'union U V = (union ? U V).
  36
  37 ndefinition big_union ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∃i. i ∈ T ∧ x ∈ f i }.
  38
  39 ndefinition big_intersection ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∀i. i ∈ T → x ∈ f i }.
  40
  41 ndefinition full_set: ∀A. Ω^A ≝ λA.{ x | True }.
  42
  43 nlemma subseteq_refl: ∀A.∀S: Ω^A. S ⊆ S.
  44  #A; #S; #x; #H; nassumption.
  45 nqed.
  46
  47 nlemma subseteq_trans: ∀A.∀S,T,U: Ω^A. S ⊆ T → T ⊆ U → S ⊆ U.
  48  #A; #S; #T; #U; #H1; #H2; #x; #P; napply H2; napply H1; nassumption.
  49 nqed.
  50
  51 include "properties/relations1.ma".
  52
  53 ndefinition seteq: ∀A. equivalence_relation1 (Ω^A).
  54  #A; @
  55   [ napply (λS,S'. S ⊆ S' ∧ S' ⊆ S)
  56   | #S; @; napply subseteq_refl
  57   | #S; #S'; *; #H1; #H2; @; nassumption
  58   | #S; #T; #U; *; #H1; #H2; *; #H3; #H4; @; napply subseteq_trans;
  59      ##[##2,5: nassumption |##1,4: ##skip |##*: nassumption]##]
  60 nqed.
  61
  62 include "sets/setoids1.ma".
  63
  64 (* this has to be declared here, so that it is combined with carr *)
  65 ncoercion full_set : ∀A:Type[0]. Ω^A ≝ full_set on A: Type[0] to (Ω^?).
  66
  67 ndefinition powerclass_setoid: Type[0] → setoid1.
  68  #A; @[ napply (Ω^A)| napply seteq ]
  69 nqed.
  70
  71 include "hints_declaration.ma".
  72
  73 alias symbol "hint_decl" = "hint_decl_Type2".
  74 unification hint 0 ≔ A ⊢ carr1 (mk_setoid1 (Ω^A) (eq1 (powerclass_setoid A))) ≡ Ω^A.
  75
  76 (************ SETS OVER SETOIDS ********************)
  77
  78 include "logic/cprop.ma".
  79
  80 nrecord qpowerclass (A: setoid) : Type[1] ≝
  81  { pc:> Ω^A; (* qui pc viene dichiarato con un target preciso...
  82                 forse lo si vorrebbe dichiarato con un target più lasco
  83                 ma la sintassi :> non lo supporta *)
  84    mem_ok': ∀x,x':A. x=x' → (x ∈ pc) = (x' ∈ pc)
  85  }.
  86
  87 notation > "𝛀 ^ term 90 A" non associative with precedence 70
  88 for @{ 'qpowerclass $A }.
  89
  90 notation "Ω term 90 A \atop ≈" non associative with precedence 70
  91 for @{ 'qpowerclass $A }.
  92
  93 interpretation "qpowerclass" 'qpowerclass a = (qpowerclass a).
  94
  95 ndefinition Full_set: ∀A. 𝛀^A.
  96  #A; @[ napply A | #x; #x'; #H; napply refl1]
  97 nqed.
  98 ncoercion Full_set: ∀A. qpowerclass A ≝ Full_set on A: setoid to qpowerclass ?.
  99
 100 ndefinition qseteq: ∀A. equivalence_relation1 (𝛀^A).
 101  #A; @
 102   [ napply (λS,S'. S = S')
 103   | #S; napply (refl1 ? (seteq A))
 104   | #S; #S'; napply (sym1 ? (seteq A))
 105   | #S; #T; #U; napply (trans1 ? (seteq A))]
 106 nqed.
 107
 108 ndefinition qpowerclass_setoid: setoid → setoid1.
 109  #A; @
 110   [ napply (qpowerclass A)
 111   | napply (qseteq A) ]
 112 nqed.
 113
 114 unification hint 0 ≔ A ⊢
 115   carr1 (mk_setoid1 (𝛀^A) (eq1 (qpowerclass_setoid A)))
 116 ≡ qpowerclass A.
 117
 118 ncoercion pc' : ∀A.∀x:qpowerclass_setoid A. Ω^A ≝ pc
 119 on _x : (carr1 (qpowerclass_setoid ?)) to (Ω^?).
 120
 121 nlemma mem_ok: ∀A. binary_morphism1 (setoid1_of_setoid A) (qpowerclass_setoid A) CPROP.
 122  #A; @
 123   [ napply (λx,S. x ∈ S)
 124   | #a; #a'; #b; #b'; #Ha; *; #Hb1; #Hb2; @; #H;
 125      ##[ napply Hb1; napply (. (mem_ok' …)); ##[##3: napply H| napply Ha^-1;##]
 126      ##| napply Hb2; napply (. (mem_ok' …)); ##[##3: napply H| napply Ha;##]
 127      ##]
 128   ##]
 129 nqed.
 130
 131 unification hint 0 ≔  A:setoid, x, S;
 132          SS ≟ (pc ? S),
 133          TT ≟ (mk_binary_morphism1 ???
 134                  (λx:setoid1_of_setoid ?.λS:qpowerclass_setoid ?. x ∈ S)
 135                  (prop21 ??? (mem_ok A)))
 136
 137   (*-------------------------------------*) ⊢
 138     fun21 ? ? ? TT x S
 139   ≡ mem A SS x.
 140
 141 nlemma subseteq_ok: ∀A. binary_morphism1 (qpowerclass_setoid A) (qpowerclass_setoid A) CPROP.
 142  #A; @
 143   [ napply (λS,S'. S ⊆ S')
 144   | #a; #a'; #b; #b'; *; #Ha1; #Ha2; *; #Hb1; #Hb2; @; #H
 145      [ napply (subseteq_trans … a)
 146         [ nassumption | napply (subseteq_trans … b); nassumption ]
 147    ##| napply (subseteq_trans … a')
 148         [ nassumption | napply (subseteq_trans … b'); nassumption ] ##]
 149 nqed.
 150
 151 unification hint 0 ≔ A,a,a'
 152  (*-----------------------------------------------------------------*) ⊢
 153   eq_rel ? (eq A) a a' ≡ eq_rel1 ? (eq1 (setoid1_of_setoid A)) a a'.
 154
 155 nlemma intersect_ok: ∀A. 𝛀^A → 𝛀^A → 𝛀^A.
 156  #A; #S; #S'; @ (S ∩ S');
 157  #a; #a'; #Ha; @; *; #H1; #H2; @
 158   [##1,2: napply (. Ha^-1‡#); nassumption;
 159 ##|##3,4: napply (. Ha‡#); nassumption]
 160 nqed.
 161
 162 alias symbol "hint_decl" = "hint_decl_Type1".
 163 unification hint 1 ≔
 164   A : setoid, B,C : qpowerclass A ⊢
 165     pc A (mk_qpowerclass ? (B ∩ C) (mem_ok' ? (intersect_ok ? B C)))
 166     ≡ intersect ? (pc ? B) (pc ? C).
 167
 168 unification hint 1 ≔
 169   A : setoid, B,C : qpowerclass A;
 170   DX ≟ (intersect ? (pc ? B) (pc ? C)),
 171   SX ≟ (mk_qpowerclass ? (B ∩ C) (mem_ok' ? (intersect_ok ? B C)))
 172  (*-----------------------------------------------------------------*) ⊢
 173   pc A SX  ≡ DX.
 174
 175 nlemma intersect_ok': ∀A. binary_morphism1 (powerclass_setoid A) (powerclass_setoid A) (powerclass_setoid A).
 176  #A; @ (λS,S'. S ∩ S');
 177  #a; #a'; #b; #b'; *; #Ha1; #Ha2; *; #Hb1; #Hb2; @; #x; nnormalize; *; #Ka; #Kb; @
 178   [ napply Ha1; nassumption
 179   | napply Hb1; nassumption
 180   | napply Ha2; nassumption
 181   | napply Hb2; nassumption]
 182 nqed.
 183
 184 alias symbol "hint_decl" = "hint_decl_Type1".
 185 unification hint 0 ≔
 186   A : Type[0], B,C : powerclass A ⊢
 187     fun21 …
 188      (mk_binary_morphism1 …
 189        (λS,S'.S ∩ S')
 190        (prop21 … (intersect_ok' A))) B C
 191     ≡ intersect ? B C.
 192
 193 ndefinition prop21_mem :
 194   ∀A,C.∀f:binary_morphism1 (setoid1_of_setoid A) (qpowerclass_setoid A) C.
 195    ∀a,a':setoid1_of_setoid A.
 196     ∀b,b':qpowerclass_setoid A.a = a' → b = b' → f a b = f a' b'.
 197 #A; #C; #f; #a; #a'; #b; #b'; #H1; #H2; napply prop21; nassumption;
 198 nqed.
 199
 200 interpretation "prop21 mem" 'prop2 l r = (prop21_mem ??????? l r).
 201
 202 nlemma intersect_ok'':
 203   ∀A. binary_morphism1 (qpowerclass_setoid A) (qpowerclass_setoid A) (qpowerclass_setoid A).
 204  #A; @ (intersect_ok A); nlapply (prop21 … (intersect_ok' A)); #H;
 205  #a; #a'; #b; #b'; #H1; #H2; napply H; nassumption;
 206 nqed.
 207
 208 unification hint 1 ≔
 209   A:?, B,C : 𝛀^A ⊢
 210     fun21 …
 211      (mk_binary_morphism1 …
 212        (λS,S':qpowerclass_setoid A.S ∩ S')
 213        (prop21 … (intersect_ok'' A))) B C
 214     ≡ intersect ? B C.
 215
 216
 217
 218
 219 nlemma test: ∀U.∀A,B:qpowerclass U. A ∩ B = A →
 220  ∀x,y. x=y → x ∈ A → y ∈ A ∩ B.
 221  #U; #A; #B; #H; #x; #y; #K; #K2; napply (. #‡(?));
 222 ##[ nchange with (A ∩ B = ?);
 223     napply (prop21 ??? (mk_binary_morphism1 … (λS,S'.S ∩ S') (prop21 … (intersect_ok' U))) A A B B ##);
 224     #H; napply H;
 225   nassumption;
 226 nqed.
 227
 228 (*
 229 nlemma intersect_ok: ∀A. binary_morphism1 (qpowerclass_setoid A) (qpowerclass_setoid A) (qpowerclass_setoid A).
 230  #A; @
 231   [ #S; #S'; @
 232      [ napply (S ∩ S')
 233      | #a; #a'; #Ha;
 234         nwhd in ⊢ (? ? ? % %); @; *; #H1; #H2; @
 235         [##1,2: napply (. Ha^-1‡#); nassumption;
 236       ##|##3,4: napply (. Ha‡#); nassumption]##]
 237  ##| #a; #a'; #b; #b'; #Ha; #Hb; nwhd; @; #x; nwhd in ⊢ (% → %); #H
 238       [ alias symbol "invert" = "setoid1 symmetry".
 239         napply (. ((#‡Ha^-1)‡(#‡Hb^-1))); nassumption
 240       | napply (. ((#‡Ha)‡(#‡Hb))); nassumption ]##]
 241 nqed.
 242
 243 (* unfold if intersect, exposing fun21 *)
 244 alias symbol "hint_decl" = "hint_decl_Type1".
 245 unification hint 0 ≔
 246   A : setoid, B,C : qpowerclass A ⊢
 247     pc A (fun21 …
 248             (mk_binary_morphism1 …
 249               (λS,S':qpowerclass_setoid A.mk_qpowerclass ? (S ∩ S') (mem_ok' ? (intersect_ok ? S S')))
 250               (prop21 … (intersect_ok A)))
 251             B
 252             C)
 253     ≡ intersect ? (pc ? B) (pc ? C).
 254
 255 nlemma test: ∀A:setoid. ∀U,V:qpowerclass A. ∀x,x':setoid1_of_setoid A. x=x' → x ∈ U ∩ V → x' ∈ U ∩ V.
 256  #A; #U; #V; #x; #x'; #H; #p; napply (. (H^-1‡#)); nassumption.
 257 nqed.
 258 *)
 259
 260 ndefinition image: ∀A,B. (carr A → carr B) → Ω^A → Ω^B ≝
 261  λA,B:setoid.λf:carr A → carr B.λSa:Ω^A.
 262   {y | ∃x. x ∈ Sa ∧ eq_rel (carr B) (eq B) (f x) y}.
 263
 264 ndefinition counter_image: ∀A,B. (carr A → carr B) → Ω^B → Ω^A ≝
 265  λA,B,f,Sb. {x | ∃y. y ∈ Sb ∧ f x = y}.
 266
 267 (******************* compatible equivalence relations **********************)
 268
 269 nrecord compatible_equivalence_relation (A: setoid) : Type[1] ≝
 270  { rel:> equivalence_relation A;
 271    compatibility: ∀x,x':A. x=x' → rel x x'
 272  }.
 273
 274 ndefinition quotient: ∀A. compatible_equivalence_relation A → setoid.
 275  #A; #R; @ A R;
 276 nqed.
 277
 278 (******************* first omomorphism theorem for sets **********************)
 279
 280 ndefinition eqrel_of_morphism:
 281  ∀A,B. unary_morphism A B → compatible_equivalence_relation A.
 282  #A; #B; #f; @
 283   [ @
 284      [ napply (λx,y. f x = f y)
 285      | #x; napply refl | #x; #y; napply sym | #x; #y; #z; napply trans]
 286 ##| #x; #x'; #H; nwhd; alias symbol "prop1" = "prop1".
 287 napply (.= (†H)); napply refl ]
 288 nqed.
 289
 290 ndefinition canonical_proj: ∀A,R. unary_morphism A (quotient A R).
 291  #A; #R; @
 292   [ napply (λx.x) | #a; #a'; #H; napply (compatibility … R … H) ]
 293 nqed.
 294
 295 ndefinition quotiented_mor:
 296  ∀A,B.∀f:unary_morphism A B.
 297   unary_morphism (quotient … (eqrel_of_morphism … f)) B.
 298  #A; #B; #f; @
 299   [ napply f | #a; #a'; #H; nassumption]
 300 nqed.
 301
 302 nlemma first_omomorphism_theorem_functions1:
 303  ∀A,B.∀f: unary_morphism A B.
 304   ∀x. f x = quotiented_mor … (canonical_proj … (eqrel_of_morphism … f) x).
 305  #A; #B; #f; #x; napply refl;
 306 nqed.
 307
 308 ndefinition surjective ≝
 309  λA,B.λS: qpowerclass A.λT: qpowerclass B.λf:unary_morphism A B.
 310   ∀y. y ∈ T → ∃x. x ∈ S ∧ f x = y.
 311
 312 ndefinition injective ≝
 313  λA,B.λS: qpowerclass A.λf:unary_morphism A B.
 314   ∀x,x'. x ∈ S → x' ∈ S → f x = f x' → x = x'.
 315
 316 nlemma first_omomorphism_theorem_functions2:
 317  ∀A,B.∀f: unary_morphism A B.
 318    surjective … (Full_set ?) (Full_set ?) (canonical_proj ? (eqrel_of_morphism … f)).
 319  #A; #B; #f; nwhd; #y; #Hy; @ y; @ I ; napply refl;
 320  (* bug, prova @ I refl *)
 321 nqed.
 322
 323 nlemma first_omomorphism_theorem_functions3:
 324  ∀A,B.∀f: unary_morphism A B.
 325    injective … (Full_set ?) (quotiented_mor … f).
 326  #A; #B; #f; nwhd; #x; #x'; #Hx; #Hx'; #K; nassumption.
 327 nqed.
 328
 329 nrecord isomorphism (A, B : setoid) (S: qpowerclass A) (T: qpowerclass B) : Type[0] ≝
 330  { iso_f:> unary_morphism A B;
 331    f_closed: ∀x. x ∈ S → iso_f x ∈ T;
 332    f_sur: surjective … S T iso_f;
 333    f_inj: injective … S iso_f
 334  }.
 335
 336 (*
 337 nrecord isomorphism (A, B : setoid) (S: qpowerclass A) (T: qpowerclass B) : CProp[0] ≝
 338  { iso_f:> unary_morphism A B;
 339    f_closed: ∀x. x ∈ pc A S → fun1 ?? iso_f x ∈ pc B T}.
 340
 341
 342 ncheck (λA:?.
 343    λB:?.
 344     λS:?.
 345      λT:?.
 346       λxxx:isomorphism A B S T.
 347        match xxx
 348        return λxxx:isomorphism A B S T.
 349                ∀x: carr A.
 350                 ∀x_72: mem (carr A) (pc A S) x.
 351                  mem (carr B) (pc B T) (fun1 A B ((λ_.?) A B S T xxx) x)
 352         with [ mk_isomorphism _ yyy ⇒ yyy ] ).
 353
 354    ;
 355  }.
 356 *)