helm/software/matita/nlibrary/sets/sets.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 (******************* SETS OVER TYPES *****************)
  16
  17 include "logic/connectives.ma".
  18
  19 nrecord powerclass (A: Type[0]) : Type[1] ≝ { mem: A → CProp[0] }.
  20
  21 interpretation "mem" 'mem a S = (mem ? S a).
  22 interpretation "powerclass" 'powerset A = (powerclass A).
  23 interpretation "subset construction" 'subset \eta.x = (mk_powerclass ? x).
  24
  25 ndefinition subseteq ≝ λA.λU,V.∀a:A. a ∈ U → a ∈ V.
  26 interpretation "subseteq" 'subseteq U V = (subseteq ? U V).
  27
  28 ndefinition overlaps ≝ λA.λU,V.∃x:A.x ∈ U ∧ x ∈ V.
  29 interpretation "overlaps" 'overlaps U V = (overlaps ? U V).
  30
  31 ndefinition intersect ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∧ x ∈ V }.
  32 interpretation "intersect" 'intersects U V = (intersect ? U V).
  33
  34 ndefinition union ≝ λA.λU,V:Ω^A.{ x | x ∈ U ∨ x ∈ V }.
  35 interpretation "union" 'union U V = (union ? U V).
  36
  37 ndefinition big_union ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∃i. i ∈ T ∧ x ∈ f i }.
  38
  39 ndefinition big_intersection ≝ λA,B.λT:Ω^A.λf:A → Ω^B.{ x | ∀i. i ∈ T → x ∈ f i }.
  40
  41 ndefinition full_set: ∀A. Ω^A ≝ λA.{ x | True }.
  42
  43 nlemma subseteq_refl: ∀A.∀S: Ω^A. S ⊆ S.
  44  #A; #S; #x; #H; nassumption.
  45 nqed.
  46
  47 nlemma subseteq_trans: ∀A.∀S,T,U: Ω^A. S ⊆ T → T ⊆ U → S ⊆ U.
  48  #A; #S; #T; #U; #H1; #H2; #x; #P; napply H2; napply H1; nassumption.
  49 nqed.
  50
  51 include "properties/relations1.ma".
  52
  53 ndefinition seteq: ∀A. equivalence_relation1 (Ω^A).
  54  #A; @
  55   [ napply (λS,S'. S ⊆ S' ∧ S' ⊆ S)
  56   | #S; @; napply subseteq_refl
  57   | #S; #S'; *; #H1; #H2; @; nassumption
  58   | #S; #T; #U; *; #H1; #H2; *; #H3; #H4; @; napply subseteq_trans;
  59      ##[##2,5: nassumption |##1,4: ##skip |##*: nassumption]##]
  60 nqed.
  61
  62 include "sets/setoids1.ma".
  63
  64 (* this has to be declared here, so that it is combined with carr *)
  65 ncoercion full_set : ∀A:Type[0]. Ω^A ≝ full_set on A: Type[0] to (Ω^?).
  66
  67 ndefinition powerclass_setoid: Type[0] → setoid1.
  68  #A; @[ napply (Ω^A)| napply seteq ]
  69 nqed.
  70
  71 include "hints_declaration.ma".
  72
  73 alias symbol "hint_decl" = "hint_decl_Type2".
  74 unification hint 0 ≔ A ⊢ carr1 (powerclass_setoid A) ≡ Ω^A.
  75
  76 (************ SETS OVER SETOIDS ********************)
  77
  78 include "logic/cprop.ma".
  79
  80 nrecord qpowerclass (A: setoid) : Type[1] ≝
  81  { pc:> Ω^A; (* qui pc viene dichiarato con un target preciso...
  82                 forse lo si vorrebbe dichiarato con un target più lasco
  83                 ma la sintassi :> non lo supporta *)
  84    mem_ok': ∀x,x':A. x=x' → (x ∈ pc) = (x' ∈ pc)
  85  }.
  86
  87 ndefinition Full_set: ∀A. qpowerclass A.
  88  #A; @[ napply A | #x; #x'; #H; napply refl1]
  89 nqed.
  90 ncoercion Full_set: ∀A. qpowerclass A ≝ Full_set on A: setoid to qpowerclass ?.
  91
  92 ndefinition qseteq: ∀A. equivalence_relation1 (qpowerclass A).
  93  #A; @
  94   [ napply (λS,S'. S = S')
  95   | #S; napply (refl1 ? (seteq A))
  96   | #S; #S'; napply (sym1 ? (seteq A))
  97   | #S; #T; #U; napply (trans1 ? (seteq A))]
  98 nqed.
  99
 100 ndefinition qpowerclass_setoid: setoid → setoid1.
 101  #A; @
 102   [ napply (qpowerclass A)
 103   | napply (qseteq A) ]
 104 nqed.
 105
 106 unification hint 0 ≔ A ⊢
 107   carr1 (qpowerclass_setoid A) ≡ qpowerclass A.
 108
 109 nlemma mem_ok: ∀A. binary_morphism1 (setoid1_of_setoid A) (qpowerclass_setoid A) CPROP.
 110  #A; @
 111   [ napply (λx,S. x ∈ S)
 112   | #a; #a'; #b; #b'; #Ha; *; #Hb1; #Hb2; @; #H;
 113      ##[ napply Hb1; napply (. (mem_ok' …)); ##[##3: napply H| napply Ha^-1;##]
 114      ##| napply Hb2; napply (. (mem_ok' …)); ##[##3: napply H| napply Ha;##]
 115      ##]
 116   ##]
 117 nqed.
 118
 119 unification hint 0 ≔
 120   A : setoid, x, S ⊢ (mem_ok A) x S ≡ mem A S x.
 121
 122 nlemma subseteq_ok: ∀A. binary_morphism1 (qpowerclass_setoid A) (qpowerclass_setoid A) CPROP.
 123  #A; @
 124   [ napply (λS,S'. S ⊆ S')
 125   | #a; #a'; #b; #b'; *; #Ha1; #Ha2; *; #Hb1; #Hb2; @; #H
 126      [ napply (subseteq_trans … a)
 127         [ nassumption | napply (subseteq_trans … b); nassumption ]
 128    ##| napply (subseteq_trans … a')
 129         [ nassumption | napply (subseteq_trans … b'); nassumption ] ##]
 130 nqed.
 131
 132 nlemma intersect_ok: ∀A. binary_morphism1 (qpowerclass_setoid A) (qpowerclass_setoid A) (qpowerclass_setoid A).
 133  #A; @
 134   [ #S; #S'; @
 135      [ napply (S ∩ S')
 136      | #a; #a'; #Ha; nwhd in ⊢ (? ? ? % %); @; *; #H1; #H2; @
 137         [##1,2: napply (. (mem_ok' …)^-1) [##3,6: nassumption |##2,5: nassumption |##*: ##skip]
 138       ##|##3,4: napply (. (mem_ok' …)) [##1,3,4,6: nassumption |##*: ##skip]##]##]
 139  ##| #a; #a'; #b; #b'; #Ha; #Hb; nwhd; @; #x; nwhd in ⊢ (% → %); #H
 140       [ napply (. ((#‡Ha^-1)‡(#‡Hb^-1))); nassumption
 141       | napply (. ((#‡Ha)‡(#‡Hb))); nassumption ]##]
 142 nqed.
 143
 144 (* unfold if intersect, exposing fun21 *)
 145 alias symbol "hint_decl" = "hint_decl_Type1".
 146 unification hint 0 ≔
 147   A : setoid, B,C : qpowerclass A ⊢
 148     pc A (intersect_ok A B C) ≡ intersect ? (pc ? B) (pc ? C).
 149
 150 (* hints can pass under mem *) (* ??? XXX why is it needed? *)
 151 unification hint 0 ≔ A,B,x ;
 152            C ≟ B
 153  (*---------------------*) ⊢
 154    mem A B x ≡ mem A C x.
 155
 156 nlemma test: ∀A:setoid. ∀U,V:qpowerclass A. ∀x,x':setoid1_of_setoid A. x=x' → x ∈ U ∩ V → x' ∈ U ∩ V.
 157  #A; #U; #V; #x; #x'; #H; #p; napply (. (H^-1‡#)); nassumption.
 158 nqed.
 159
 160 ndefinition image: ∀A,B. (carr A → carr B) → Ω^A → Ω^B ≝
 161  λA,B:setoid.λf:carr A → carr B.λSa:Ω^A.
 162   {y | ∃x. x ∈ Sa ∧ eq_rel (carr B) (eq B) (f x) y}.
 163
 164 ndefinition counter_image: ∀A,B. (carr A → carr B) → Ω^B → Ω^A ≝
 165  λA,B,f,Sb. {x | ∃y. y ∈ Sb ∧ f x = y}.
 166
 167 (******************* compatible equivalence relations **********************)
 168
 169 nrecord compatible_equivalence_relation (A: setoid) : Type[1] ≝
 170  { rel:> equivalence_relation A;
 171    compatibility: ∀x,x':A. x=x' → rel x x'
 172     (* coercion qui non andava per via di un Failure invece di Uncertain
 173        ritornato dall'unificazione per il problema:
 174          ?[] A =?= ?[Γ]->?[Γ+1]
 175     *)
 176  }.
 177
 178 ndefinition quotient: ∀A. compatible_equivalence_relation A → setoid.
 179  #A; #R; @ A R;
 180 nqed.
 181
 182 (******************* first omomorphism theorem for sets **********************)
 183
 184 ndefinition eqrel_of_morphism:
 185  ∀A,B. unary_morphism A B → compatible_equivalence_relation A.
 186  #A; #B; #f; @
 187   [ @
 188      [ napply (λx,y. f x = f y)
 189      | #x; napply refl | #x; #y; napply sym | #x; #y; #z; napply trans]
 190 ##| #x; #x'; #H; nwhd; napply (.= (†H)); napply refl ]
 191 nqed.
 192
 193 ndefinition canonical_proj: ∀A,R. unary_morphism A (quotient A R).
 194  #A; #R; @
 195   [ napply (λx.x) | #a; #a'; #H; napply (compatibility … R … H) ]
 196 nqed.
 197
 198 ndefinition quotiented_mor:
 199  ∀A,B.∀f:unary_morphism A B.
 200   unary_morphism (quotient … (eqrel_of_morphism … f)) B.
 201  #A; #B; #f; @
 202   [ napply f | #a; #a'; #H; nassumption]
 203 nqed.
 204
 205 nlemma first_omomorphism_theorem_functions1:
 206  ∀A,B.∀f: unary_morphism A B.
 207   ∀x. f x = quotiented_mor … (canonical_proj … (eqrel_of_morphism … f) x).
 208  #A; #B; #f; #x; napply refl;
 209 nqed.
 210
 211 ndefinition surjective ≝
 212  λA,B.λS: qpowerclass A.λT: qpowerclass B.λf:unary_morphism A B.
 213   ∀y. y ∈ T → ∃x. x ∈ S ∧ f x = y.
 214
 215 ndefinition injective ≝
 216  λA,B.λS: qpowerclass A.λf:unary_morphism A B.
 217   ∀x,x'. x ∈ S → x' ∈ S → f x = f x' → x = x'.
 218
 219 nlemma first_omomorphism_theorem_functions2:
 220  ∀A,B.∀f: unary_morphism A B.
 221    surjective … (Full_set ?) (Full_set ?) (canonical_proj ? (eqrel_of_morphism … f)).
 222  #A; #B; #f; nwhd; #y; #Hy; @ y; @ [ napply I | napply refl]
 223  (* bug, prova @ I refl *)
 224 nqed.
 225
 226 nlemma first_omomorphism_theorem_functions3:
 227  ∀A,B.∀f: unary_morphism A B.
 228    injective … (Full_set ?) (quotiented_mor … f).
 229  #A; #B; #f; nwhd; #x; #x'; #Hx; #Hx'; #K; nassumption.
 230 nqed.
 231
 232 nrecord isomorphism (A) (B) (S: qpowerclass A) (T: qpowerclass B) : CProp[0] ≝
 233  { iso_f:> unary_morphism A B;
 234    f_closed: ∀x. x ∈ S → iso_f x ∈ T;
 235    f_sur: surjective … S T iso_f;
 236    f_inj: injective … S iso_f
 237  }.