helm/software/matita/nlibrary/topology/igft.ma

   1 include "sets/sets.ma".
   2
   3 nrecord Ax : Type[1] ≝ {
   4   S:> setoid; (* Type[0]; *)
   5   I: S → Type[0];
   6   C: ∀a:S. I a → Ω ^ S
   7 }.
   8
   9 notation "𝐈  \sub( ❨a❩ )" non associative with precedence 70 for @{ 'I $a }.
  10 notation "𝐂 \sub ( ❨a,\emsp i❩ )" non associative with precedence 70 for @{ 'C $a $i }.
  11
  12 notation > "𝐈 term 90 a" non associative with precedence 70 for @{ 'I $a }.
  13 notation > "𝐂 term 90 a term 90 i" non associative with precedence 70 for @{ 'C $a $i }.
  14
  15 interpretation "I" 'I a = (I ? a).
  16 interpretation "C" 'C a i = (C ? a i).
  17
  18 ndefinition cover_set ≝ λc:∀A:Ax.Ω^A → A → CProp[0].λA,C,U.
  19   ∀y.y ∈ C → c A U y.
  20
  21 (* a \ltri b *)
  22 notation "hvbox(a break ◃ b)" non associative with precedence 45
  23 for @{ 'covers $a $b }.
  24
  25 interpretation "covers set temp" 'covers C U = (cover_set ?? C U).
  26
  27 ninductive cover (A : Ax) (U : Ω^A) : A → CProp[0] ≝
  28 | creflexivity : ∀a:A. a ∈ U → cover ? U a
  29 | cinfinity    : ∀a:A.∀i:𝐈 a. 𝐂 a i ◃ U → cover ? U a.
  30 napply cover;
  31 nqed.
  32
  33 interpretation "covers" 'covers a U = (cover ? U a).
  34 interpretation "covers set" 'covers a U = (cover_set cover ? a U).
  35
  36 ndefinition fish_set ≝ λf:∀A:Ax.Ω^A → A → CProp[0].
  37  λA,U,V.
  38   ∃a.a ∈ V ∧ f A U a.
  39
  40 (* a \ltimes b *)
  41 notation "hvbox(a break ⋉ b)" non associative with precedence 45
  42 for @{ 'fish $a $b }.
  43
  44 interpretation "fish set temp" 'fish A U = (fish_set ?? U A).
  45
  46 ncoinductive fish (A : Ax) (F : Ω^A) : A → CProp[0] ≝
  47 | cfish : ∀a. a ∈ F → (∀i:𝐈 a .𝐂  a i ⋉ F) → fish A F a.
  48 napply fish;
  49 nqed.
  50
  51 interpretation "fish set" 'fish A U = (fish_set fish ? U A).
  52 interpretation "fish" 'fish a U = (fish ? U a).
  53
  54 nlet corec fish_rec (A:Ax) (U: Ω^A)
  55  (P: Ω^A) (H1: P ⊆ U)
  56   (H2: ∀a:A. a ∈ P → ∀j: 𝐈 a. 𝐂 a j ≬ P):
  57    ∀a:A. ∀p: a ∈ P. a ⋉ U ≝ ?.
  58 #a; #p; napply cfish;
  59 ##[ napply H1; napply p;
  60 ##| #i; ncases (H2 a p i); #x; *; #xC; #xP; @; ##[napply x]
  61     @; ##[ napply xC ] napply (fish_rec ? U P); nassumption;
  62 ##]
  63 nqed.
  64
  65 notation "◃U" non associative with precedence 55
  66 for @{ 'coverage $U }.
  67
  68 ndefinition coverage : ∀A:Ax.∀U:Ω^A.Ω^A ≝ λA,U.{ a | a ◃ U }.
  69
  70 interpretation "coverage cover" 'coverage U = (coverage ? U).
  71
  72 ndefinition cover_equation : ∀A:Ax.∀U,X:Ω^A.CProp[0] ≝  λA,U,X.
  73   ∀a.a ∈ X ↔ (a ∈ U ∨ ∃i:𝐈 a.∀y.y ∈ 𝐂 a i → y ∈ X).
  74
  75 ntheorem coverage_cover_equation : ∀A,U. cover_equation A U (◃U).
  76 #A; #U; #a; @; #H;
  77 ##[ nelim H; #b; (* manca clear *)
  78     ##[ #bU; @1; nassumption;
  79     ##| #i; #CaiU; #IH; @2; @ i; #c; #cCbi; ncases (IH ? cCbi);
  80         ##[ #E; @; napply E;
  81         ##| #_; napply CaiU; nassumption; ##] ##]
  82 ##| ncases H; ##[ #E; @; nassumption]
  83     *; #j; #Hj; @2 j; #w; #wC; napply Hj; nassumption;
  84 ##]
  85 nqed.
  86
  87 ntheorem coverage_min_cover_equation :
  88   ∀A,U,W. cover_equation A U W → ◃U ⊆ W.
  89 #A; #U; #W; #H; #a; #aU; nelim aU; #b;
  90 ##[ #bU; ncases (H b); #_; #H1; napply H1; @1; nassumption;
  91 ##| #i; #CbiU; #IH; ncases (H b); #_; #H1; napply H1; @2; @i; napply IH;
  92 ##]
  93 nqed.
  94
  95 notation "⋉F" non associative with precedence 55
  96 for @{ 'fished $F }.
  97
  98 ndefinition fished : ∀A:Ax.∀F:Ω^A.Ω^A ≝ λA,F.{ a | a ⋉ F }.
  99
 100 interpretation "fished fish" 'fished F = (fished ? F).
 101
 102 ndefinition fish_equation : ∀A:Ax.∀F,X:Ω^A.CProp[0] ≝ λA,F,X.
 103   ∀a. a ∈ X ↔ a ∈ F ∧ ∀i:𝐈 a.∃y.y ∈ 𝐂 a i ∧ y ∈ X.
 104
 105 ntheorem fised_fish_equation : ∀A,F. fish_equation A F (⋉F).
 106 #A; #F; #a; @; (* bug, fare case sotto diverso da farlo sopra *) #H; ncases H;
 107 ##[ #b; #bF; #H2; @ bF; #i; ncases (H2 i); #c; *; #cC; #cF; @c; @ cC;
 108     napply cF;
 109 ##| #aF; #H1; @ aF; napply H1;
 110 ##]
 111 nqed.
 112
 113 ntheorem fised_max_fish_equation : ∀A,F,G. fish_equation A F G → G ⊆ ⋉F.
 114 #A; #F; #G; #H; #a; #aG; napply (fish_rec … aG);
 115 #b; ncases (H b); #H1; #_; #bG; ncases (H1 bG); #E1; #E2; nassumption;
 116 nqed.
 117
 118 nrecord nAx : Type[2] ≝ {
 119   nS:> setoid; (*Type[0];*)
 120   nI: nS → Type[0];
 121   nD: ∀a:nS. nI a → Type[0];
 122   nd: ∀a:nS. ∀i:nI a. nD a i → nS
 123 }.
 124
 125 notation "𝐃 \sub ( ❨a,\emsp i❩ )" non associative with precedence 70 for @{ 'D $a $i }.
 126 notation "𝐝 \sub ( ❨a,\emsp i,\emsp j❩ )" non associative with precedence 70 for @{ 'd $a $i $j}.
 127
 128 notation > "𝐃 term 90 a term 90 i" non associative with precedence 70 for @{ 'D $a $i }.
 129 notation > "𝐝 term 90 a term 90 i term 90 j" non associative with precedence 70 for @{ 'd $a $i $j}.
 130
 131 interpretation "D" 'D a i = (nD ? a i).
 132 interpretation "d" 'd a i j = (nd ? a i j).
 133
 134 ndefinition image ≝ λA:nAx.λa:A.λi. { x | ∃j:𝐃 a i. x = 𝐝 a i j }.
 135
 136 notation > "𝐈𝐦  [𝐝 term 90 a term 90 i]" non associative with precedence 70 for @{ 'Im $a $i }.
 137 notation "𝐈𝐦  [𝐝 \sub ( ❨a,\emsp i❩ )]" non associative with precedence 70 for @{ 'Im $a $i }.
 138
 139 interpretation "image" 'Im a i = (image ? a i).
 140
 141 ndefinition Ax_of_nAx : nAx → Ax.
 142 #A; @ A (nI ?); #a; #i; napply (𝐈𝐦 [𝐝 a i]);
 143 nqed.
 144
 145 ninductive sigma (A : Type[0]) (P : A → CProp[0]) : Type[0] ≝
 146  sig_intro : ∀x:A.P x → sigma A P.
 147
 148 interpretation "sigma" 'sigma \eta.p = (sigma ? p).
 149
 150 ndefinition nAx_of_Ax : Ax → nAx.
 151 #A; @ A (I ?);
 152 ##[ #a; #i; napply (Σx:A.x ∈ 𝐂 a i);
 153 ##| #a; #i; *; #x; #_; napply x;
 154 ##]
 155 nqed.
 156
 157 ninductive ord (A : nAx) : Type[0] ≝
 158  | oO : ord A
 159  | oS : ord A → ord A
 160  | oL : ∀a:A.∀i.∀f:𝐃 a i → ord A. ord A.
 161
 162 nlet rec famU (A : nAx) (U : Ω^A) (x : ord A) on x : Ω^A ≝
 163   match x with
 164   [ oO ⇒ U
 165   | oS y ⇒ let Un ≝ famU A U y in Un ∪ { x | ∃i.∀j:𝐃 x i.𝐝 x i j ∈ Un}
 166   | oL a i f ⇒ { x | ∃j.x ∈ famU A U (f j) } ].
 167
 168 ndefinition ord_coverage ≝ λA,U.{ y | ∃x:ord A. y ∈ famU ? U x }.