matita/components/content_pres/cicNotationParser.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = NotationPt
  31 module Env = NotationEnv
  32
  33 exception Parse_error of string
  34 exception Level_not_found of int
  35
  36 let min_precedence = 0
  37 let max_precedence = 100
  38
  39 type ('a,'b,'c,'d,'e) grammars = {
  40   level1_pattern: 'a Grammar.Entry.e;
  41   level2_ast: 'b Grammar.Entry.e;
  42   level2_ast_grammar : Grammar.g;
  43   term: 'b Grammar.Entry.e;
  44   ident: 'e Grammar.Entry.e;
  45   let_defs: 'c Grammar.Entry.e;
  46   protected_binder_vars: 'd Grammar.Entry.e;
  47   level2_meta: 'b Grammar.Entry.e;
  48 }
  49
  50 type checked_l1_pattern = CL1P of NotationPt.term * int
  51
  52 let refresh_uri_in_checked_l1_pattern ~refresh_uri_in_term
  53      ~refresh_uri_in_reference (CL1P (t,n))
  54 =
  55  CL1P (NotationUtil.refresh_uri_in_term ~refresh_uri_in_term
  56  ~refresh_uri_in_reference t, n)
  57
  58 type binding =
  59   | NoBinding
  60   | Binding of string * Env.value_type
  61   | Env of (string * Env.value_type) list
  62
  63 type db = {
  64   grammars:
  65     (int -> NotationPt.term,
  66     Ast.term,
  67     (Ast.term Ast.capture_variable list *
  68       Ast.term Ast.capture_variable * Ast.term * int) list,
  69     Ast.term list * Ast.term option, Env.ident_or_var) grammars;
  70   keywords: string list;
  71   items: (string * Ast.term * (NotationEnv.t -> Ast.location -> Ast.term)) list
  72 }
  73
  74 let int_of_string s =
  75   try
  76     Pervasives.int_of_string s
  77   with Failure _ ->
  78     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  79
  80 (** {2 Grammar extension} *)
  81
  82 let level_of precedence =
  83   if precedence < min_precedence || precedence > max_precedence then
  84     raise (Level_not_found precedence);
  85   string_of_int precedence
  86
  87 let gram_symbol s = Gramext.Stoken ("SYMBOL", s)
  88 let gram_ident status =
  89  Gramext.Snterm (Grammar.Entry.obj
  90   (status#notation_parser_db.grammars.ident : 'a Grammar.Entry.e))
  91   (*Gramext.Stoken ("IDENT", s)*)
  92 let gram_number s = Gramext.Stoken ("NUMBER", s)
  93 let gram_keyword s = Gramext.Stoken ("", s)
  94 let gram_term status = function
  95   | Ast.Self _ -> Gramext.Sself
  96   | Ast.Level precedence ->
  97       Gramext.Snterml
  98         (Grammar.Entry.obj
  99           (status#notation_parser_db.grammars.term : 'a Grammar.Entry.e),
 100          level_of precedence)
 101 ;;
 102
 103 let gram_of_literal =
 104   function
 105   | `Symbol s -> gram_symbol s
 106   | `Keyword s -> gram_keyword s
 107   | `Number s -> gram_number s
 108
 109 let make_action action bindings =
 110   let rec aux (vl : NotationEnv.t) =
 111     function
 112       [] -> Gramext.action (fun (loc: Ast.location) -> action vl loc)
 113     | NoBinding :: tl -> Gramext.action (fun _ -> aux vl tl)
 114     (* LUCA: DEFCON 3 BEGIN *)
 115     | Binding (name, Env.TermType l) :: tl ->
 116         Gramext.action
 117           (fun (v:Ast.term) ->
 118             aux ((name, (Env.TermType l, Env.TermValue v))::vl) tl)
 119     | Binding (name, Env.StringType) :: tl ->
 120         Gramext.action
 121           (fun (v:Env.ident_or_var) ->
 122             aux ((name, (Env.StringType, Env.StringValue v)) :: vl) tl)
 123     | Binding (name, Env.NumType) :: tl ->
 124         Gramext.action
 125           (fun (v:string) ->
 126             aux ((name, (Env.NumType, Env.NumValue v)) :: vl) tl)
 127     | Binding (name, Env.OptType t) :: tl ->
 128         Gramext.action
 129           (fun (v:'a option) ->
 130             aux ((name, (Env.OptType t, Env.OptValue v)) :: vl) tl)
 131     | Binding (name, Env.ListType t) :: tl ->
 132         Gramext.action
 133           (fun (v:'a list) ->
 134             aux ((name, (Env.ListType t, Env.ListValue v)) :: vl) tl)
 135     | Env _ :: tl ->
 136         Gramext.action (fun (v:NotationEnv.t) -> aux (v @ vl) tl)
 137     (* LUCA: DEFCON 3 END *)
 138   in
 139     aux [] (List.rev bindings)
 140
 141 let flatten_opt =
 142   let rec aux acc =
 143     function
 144       [] -> List.rev acc
 145     | NoBinding :: tl -> aux acc tl
 146     | Env names :: tl -> aux (List.rev names @ acc) tl
 147     | Binding (name, ty) :: tl -> aux ((name, ty) :: acc) tl
 148   in
 149   aux []
 150
 151   (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
 152 let extract_term_production status pattern =
 153   let rec aux = function
 154     | Ast.AttributedTerm (_, t) -> aux t
 155     | Ast.Literal l -> aux_literal l
 156     | Ast.Layout l -> aux_layout l
 157     | Ast.Magic m -> aux_magic m
 158     | Ast.Variable v -> aux_variable v
 159     | t ->
 160         prerr_endline (NotationPp.pp_term status t);
 161         assert false
 162   and aux_literal =
 163     function
 164     | `Symbol s -> [NoBinding, gram_symbol s]
 165     | `Keyword s ->
 166         (* assumption: s will be registered as a keyword with the lexer *)
 167         [NoBinding, gram_keyword s]
 168     | `Number s -> [NoBinding, gram_number s]
 169   and aux_layout = function
 170     | Ast.Sub (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sub "] @ aux p2
 171     | Ast.Sup (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sup "] @ aux p2
 172     | Ast.Below (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\below "] @ aux p2
 173     | Ast.Above (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\above "] @ aux p2
 174     | Ast.Frac (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\frac "] @ aux p2
 175     | Ast.InfRule (p1, p2, p3) -> [NoBinding, gram_symbol "\\infrule "] @ aux p1 @ aux p2 @ aux p3
 176     | Ast.Atop (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\atop "] @ aux p2
 177     | Ast.Over (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\over "] @ aux p2
 178     | Ast.Root (p1, p2) ->
 179         [NoBinding, gram_symbol "\\root "] @ aux p2
 180         @ [NoBinding, gram_symbol "\\of "] @ aux p1
 181     | Ast.Sqrt p -> [NoBinding, gram_symbol "\\sqrt "] @ aux p
 182     | Ast.Break -> []
 183     | Ast.Box (_, pl) -> List.flatten (List.map aux pl)
 184     | Ast.Group pl -> List.flatten (List.map aux pl)
 185     | Ast.Mstyle (_,pl) -> List.flatten (List.map aux pl)
 186     | Ast.Mpadded (_,pl) -> List.flatten (List.map aux pl)
 187     | Ast.Maction l -> List.flatten (List.map aux l)
 188   and aux_magic magic =
 189     match magic with
 190     | Ast.Opt p ->
 191         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 192         let action (env_opt : NotationEnv.t option) (loc : Ast.location) =
 193           match env_opt with
 194           | Some env -> List.map Env.opt_binding_some env
 195           | None -> List.map Env.opt_binding_of_name p_names
 196         in
 197         [ Env (List.map Env.opt_declaration p_names),
 198           Gramext.srules
 199             [ [ Gramext.Sopt (Gramext.srules [ p_atoms, p_action ]) ],
 200               Gramext.action action ] ]
 201     | Ast.List0 (p, _)
 202     | Ast.List1 (p, _) ->
 203         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 204         let action (env_list : NotationEnv.t list) (loc : Ast.location) =
 205           NotationEnv.coalesce_env p_names env_list
 206         in
 207         let gram_of_list s =
 208           match magic with
 209           | Ast.List0 (_, None) -> Gramext.Slist0 s
 210           | Ast.List1 (_, None) -> Gramext.Slist1 s
 211           | Ast.List0 (_, Some l) -> Gramext.Slist0sep (s, gram_of_literal l,false)
 212           | Ast.List1 (_, Some l) -> Gramext.Slist1sep (s, gram_of_literal l,false)
 213           | _ -> assert false
 214         in
 215         [ Env (List.map Env.list_declaration p_names),
 216           Gramext.srules
 217             [ [ gram_of_list (Gramext.srules [ p_atoms, p_action ]) ],
 218               Gramext.action action ] ]
 219     | _ -> assert false
 220   and aux_variable =
 221     function
 222     | Ast.NumVar s -> [Binding (s, Env.NumType), gram_number ""]
 223     | Ast.TermVar (s,(Ast.Self level|Ast.Level level as lv)) ->
 224         [Binding (s, Env.TermType level), gram_term status lv]
 225     | Ast.IdentVar s -> [Binding (s, Env.StringType), gram_ident status]
 226     | Ast.Ascription (p, s) -> assert false (* TODO *)
 227     | Ast.FreshVar _ -> assert false
 228   and inner_pattern p =
 229     let p_bindings, p_atoms = List.split (aux p) in
 230     let p_names = flatten_opt p_bindings in
 231     let action =
 232       make_action (fun (env : NotationEnv.t) (loc : Ast.location) -> env)
 233         p_bindings
 234     in
 235     p_bindings, p_atoms, p_names, action
 236   in
 237   aux pattern
 238
 239 type rule_id = Grammar.token Gramext.g_symbol list
 240
 241 let compare_rule_id x y =
 242   let rec aux = function
 243     | [],[] -> 0
 244     | [],_ -> ~-1
 245     | _,[] -> 1
 246     | ((s1::tl1) as x),((s2::tl2) as y) ->
 247         if Gramext.eq_symbol s1 s2 then aux (tl1,tl2)
 248         else Pervasives.compare x y
 249   in
 250     aux (x,y)
 251
 252
 253 let check_l1_pattern level1_pattern pponly level associativity =
 254   let variables = ref 0 in
 255   let symbols = ref 0 in
 256   let rec aux = function
 257     | Ast.AttributedTerm (att, t) -> Ast.AttributedTerm (att,aux t)
 258     | Ast.Literal _ as l -> incr symbols; l
 259     | Ast.Layout l -> Ast.Layout (aux_layout l)
 260     | Ast.Magic m -> Ast.Magic (aux_magic m)
 261     | Ast.Variable v -> (aux_variable v)
 262     | t -> assert false
 263   and aux_layout = function
 264     | Ast.Sub (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sub (p1, p2)
 265     | Ast.Sup (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sup (p1, p2)
 266     | Ast.Below (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Below (p1, p2)
 267     | Ast.Above (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Above (p1, p2)
 268     | Ast.Frac (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Frac (p1, p2)
 269     | Ast.InfRule (p1, p2, p3)  -> let p1 = aux p1 in let p2 = aux p2 in let p3 = aux p3 in Ast.InfRule (p1, p2, p3)
 270     | Ast.Atop (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Atop (p1, p2)
 271     | Ast.Over (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Over (p1, p2)
 272     | Ast.Root (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Root (p1, p2)
 273     | Ast.Sqrt p -> Ast.Sqrt (aux p)
 274     | Ast.Break as t -> t
 275     | Ast.Box (b, pl) -> Ast.Box(b, List.map aux pl)
 276     | Ast.Group pl -> Ast.Group (List.map aux pl)
 277     | Ast.Mstyle (l,pl) -> Ast.Mstyle (l, List.map aux pl)
 278     | Ast.Mpadded (l,pl) -> Ast.Mpadded (l, List.map aux pl)
 279     | Ast.Maction l as t ->
 280         if not pponly then
 281         raise(Parse_error("Maction can be used only in output notations"))
 282         else t
 283   and aux_magic magic =
 284     match magic with
 285     | Ast.Opt p -> Ast.Opt (aux p)
 286     | Ast.List0 (p, x) -> Ast.List0 (aux p, x)
 287     | Ast.List1 (p, x) -> Ast.List1 (aux p, x)
 288     | _ -> assert false
 289   and aux_variable =
 290     function
 291     | Ast.NumVar _ as t -> Ast.Variable t
 292     | Ast.TermVar (s,Ast.Self _) when associativity <> Gramext.NonA ->
 293         incr variables;
 294         if !variables > 2 then
 295           raise (Parse_error ("Exactly 2 variables must be specified in an "^
 296           "associative notation"));
 297         (match !variables, associativity with
 298         | 1,Gramext.LeftA ->
 299              Ast.Variable (Ast.TermVar (s, Ast.Self level))
 300         | 1,Gramext.RightA ->
 301              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 302         | 2,Gramext.LeftA ->
 303              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 304         | 2,Gramext.RightA ->
 305              Ast.Variable (Ast.TermVar (s, Ast.Level (level-1)))
 306         | _ -> assert false)
 307     | Ast.TermVar (s,Ast.Level _) when associativity <> Gramext.NonA ->
 308           raise (Parse_error ("Variables can not be declared with a " ^
 309             "precedence in an associative notation"))
 310        (*avoid camlp5 divergence due to non-Sself recursion at the same level *)
 311     | Ast.TermVar (s,Ast.Level l) when l<=level && !variables=0 && !symbols=0->
 312        raise(Parse_error("Left recursive rule with precedence not greater " ^
 313         "than " ^ string_of_int level ^ " is not allowed to avoid divergence"))
 314     | Ast.TermVar _ as t -> incr variables; Ast.Variable t
 315     | Ast.IdentVar _ as t -> Ast.Variable t
 316     | Ast.Ascription _ -> assert false (* TODO *)
 317     | Ast.FreshVar _ -> assert false
 318   in
 319   if associativity <> Gramext.NonA && level = min_precedence then
 320     raise (Parse_error ("You can not specify an associative notation " ^
 321     "at level "^string_of_int min_precedence ^ "; increase it"));
 322   let cp = aux level1_pattern in
 323 (*   prerr_endline ("checked_pattern: " ^ NotationPp.pp_term cp); *)
 324   if !variables <> 2 && associativity <> Gramext.NonA then
 325     raise (Parse_error ("Exactly 2 variables must be specified in an "^
 326      "associative notation"));
 327   CL1P (cp,level)
 328 ;;
 329
 330 (** {2 Grammar} *)
 331
 332 let fold_cluster binder terms ty body =
 333   List.fold_right
 334     (fun term body -> Ast.Binder (binder, (term, ty), body))
 335     terms body  (* terms are names: either Ident or FreshVar *)
 336
 337 let fold_exists terms ty body =
 338   List.fold_right
 339     (fun term body ->
 340       let lambda = Ast.Binder (`Lambda, (term, ty), body) in
 341       Ast.Appl [ Ast.Symbol ("exists", 0); lambda ])
 342     terms body
 343
 344 let fold_binder binder pt_names body =
 345   List.fold_right
 346     (fun (names, ty) body -> fold_cluster binder names ty body)
 347     pt_names body
 348
 349 let return_term loc term = Ast.AttributedTerm (`Loc loc, term)
 350 let return_term_of_level loc term l =
 351   Ast.AttributedTerm (`Loc loc, term l)
 352
 353 (** {2 API implementation} *)
 354
 355 let exc_located_wrapper f =
 356   try
 357     f ()
 358   with
 359   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 360       raise (HExtlib.Localized (floc, Parse_error msg))
 361   | Stdpp.Exc_located (floc, HExtlib.Localized (_,exn)) ->
 362       raise (HExtlib.Localized (floc, (Parse_error (Printexc.to_string exn))))
 363   | Stdpp.Exc_located (floc, exn) ->
 364       raise (HExtlib.Localized (floc, (Parse_error (Printexc.to_string exn))))
 365
 366 let parse_level1_pattern grammars precedence lexbuf =
 367   exc_located_wrapper
 368     (fun () -> Grammar.Entry.parse grammars.level1_pattern (Obj.magic lexbuf) precedence)
 369
 370 let parse_level2_ast grammars lexbuf =
 371   exc_located_wrapper
 372     (fun () -> Grammar.Entry.parse grammars.level2_ast (Obj.magic lexbuf))
 373
 374 let parse_level2_meta grammars lexbuf =
 375   exc_located_wrapper
 376     (fun () -> Grammar.Entry.parse grammars.level2_meta (Obj.magic lexbuf))
 377
 378   (* create empty precedence level for "term" *)
 379 let initialize_grammars grammars =
 380   let dummy_action =
 381     Gramext.action (fun _ ->
 382       failwith "internal error, lexer generated a dummy token")
 383   in
 384   (* Needed since campl4 on "delete_rule" remove the precedence level if it gets
 385    * empty after the deletion. The lexer never generate the Stoken below. *)
 386   let dummy_prod = [ [ Gramext.Stoken ("DUMMY", "") ], dummy_action ] in
 387   let mk_level_list first last =
 388     let rec aux acc = function
 389       | i when i < first -> acc
 390       | i ->
 391           aux
 392             ((Some (level_of i), Some Gramext.NonA, dummy_prod)
 393              :: acc)
 394             (i - 1)
 395     in
 396     aux [] last
 397   in
 398   Grammar.extend
 399     [ Grammar.Entry.obj (grammars.term: 'a Grammar.Entry.e),
 400       None,
 401       mk_level_list min_precedence max_precedence ];
 402 (* {{{ Grammar for concrete syntax patterns, notation level 1 *)
 403   begin
 404   let level1_pattern = grammars.level1_pattern in
 405 EXTEND
 406   GLOBAL: level1_pattern;
 407
 408   level1_pattern: [
 409     [ p = l1_pattern; EOI -> fun l -> NotationUtil.boxify (p l) ]
 410   ];
 411   l1_pattern: [
 412     [ p = LIST1 l1_simple_pattern ->
 413         fun l -> List.map (fun x -> x l) p ]
 414   ];
 415   literal: [
 416     [ s = SYMBOL -> `Symbol s
 417     | k = QKEYWORD -> `Keyword k
 418     | n = NUMBER -> `Number n
 419     ]
 420   ];
 421   sep:       [ [ "sep";      sep = literal -> sep ] ];
 422   l1_magic_pattern: [
 423     [ "list0"; p = l1_simple_pattern; sep = OPT sep ->
 424             fun l -> Ast.List0 (p l, sep)
 425     | "list1"; p = l1_simple_pattern; sep = OPT sep ->
 426             fun l -> Ast.List1 (p l, sep)
 427     | "opt";   p = l1_simple_pattern -> fun l -> Ast.Opt (p l)
 428     ]
 429   ];
 430   l1_pattern_variable: [
 431     [ "term"; precedence = NUMBER; id = IDENT ->
 432         Ast.TermVar (id, Ast.Level (int_of_string precedence))
 433     | "number"; id = IDENT -> Ast.NumVar id
 434     | "ident"; id = IDENT -> Ast.IdentVar id
 435     ]
 436   ];
 437   mstyle: [
 438     [ id = IDENT;
 439       v = [ IDENT | NUMBER | COLOR | FLOATWITHUNIT ] -> id, v]];
 440   mpadded: [
 441     [ id = IDENT;
 442       v = [ PERCENTAGE ] -> id, v]];
 443   l1_simple_pattern:
 444     [ "layout" LEFTA
 445       [ p1 = SELF; SYMBOL "\\sub "; p2 = SELF ->
 446           return_term_of_level loc
 447             (fun l -> Ast.Layout (Ast.Sub (p1 l, p2 l)))
 448       | p1 = SELF; SYMBOL "\\sup "; p2 = SELF ->
 449           return_term_of_level loc
 450             (fun l -> Ast.Layout (Ast.Sup (p1 l, p2 l)))
 451       | p1 = SELF; SYMBOL "\\below "; p2 = SELF ->
 452           return_term_of_level loc
 453             (fun l -> Ast.Layout (Ast.Below (p1 l, p2 l)))
 454       | p1 = SELF; SYMBOL "\\above "; p2 = SELF ->
 455           return_term_of_level loc
 456             (fun l -> Ast.Layout (Ast.Above (p1 l, p2 l)))
 457       | p1 = SELF; SYMBOL "\\over "; p2 = SELF ->
 458           return_term_of_level loc
 459             (fun l -> Ast.Layout (Ast.Over (p1 l, p2 l)))
 460       | p1 = SELF; SYMBOL "\\atop "; p2 = SELF ->
 461           return_term_of_level loc
 462             (fun l -> Ast.Layout (Ast.Atop (p1 l, p2 l)))
 463       | p1 = SELF; SYMBOL "\\frac "; p2 = SELF ->
 464           return_term_of_level loc
 465             (fun l -> Ast.Layout (Ast.Frac (p1 l, p2 l)))
 466       | SYMBOL "\\infrule "; p1 = SELF; p2 = SELF; p3 = SELF ->
 467           return_term_of_level loc
 468             (fun l -> Ast.Layout (Ast.InfRule (p1 l, p2 l, p3 l)))
 469       | SYMBOL "\\sqrt "; p = SELF ->
 470           return_term_of_level loc (fun l -> Ast.Layout (Ast.Sqrt p l))
 471       | SYMBOL "\\root "; index = SELF; SYMBOL "\\of "; arg = SELF ->
 472           return_term_of_level loc
 473             (fun l -> Ast.Layout (Ast.Root (arg l, index l)))
 474       | "hbox"; LPAREN; p = l1_pattern; RPAREN ->
 475           return_term_of_level loc
 476             (fun l -> Ast.Layout (Ast.Box ((Ast.H, false, false), p l)))
 477       | "vbox"; LPAREN; p = l1_pattern; RPAREN ->
 478           return_term_of_level loc
 479             (fun l -> Ast.Layout (Ast.Box ((Ast.V, false, false), p l)))
 480       | "hvbox"; LPAREN; p = l1_pattern; RPAREN ->
 481           return_term_of_level loc
 482             (fun l -> Ast.Layout (Ast.Box ((Ast.HV, false, false), p l)))
 483       | "hovbox"; LPAREN; p = l1_pattern; RPAREN ->
 484           return_term_of_level loc
 485             (fun l -> Ast.Layout (Ast.Box ((Ast.HOV, false, false), p l)))
 486       | "break" -> return_term_of_level loc (fun _ -> Ast.Layout Ast.Break)
 487       | "mstyle"; m = LIST1 mstyle ; LPAREN; t = l1_pattern; RPAREN ->
 488           return_term_of_level loc
 489             (fun l ->
 490                Ast.Layout (Ast.Mstyle (m, t l)))
 491       | "mpadded"; m = LIST1 mpadded ; LPAREN; t = l1_pattern; RPAREN ->
 492           return_term_of_level loc
 493             (fun l ->
 494                Ast.Layout (Ast.Mpadded (m, t l)))
 495       | "maction"; m = LIST1 [ LPAREN; l = l1_pattern; RPAREN -> l ] ->
 496            return_term_of_level loc
 497             (fun l -> Ast.Layout (Ast.Maction (List.map (fun x ->
 498               NotationUtil.group (x l)) m)))
 499       | LPAREN; p = l1_pattern; RPAREN ->
 500           return_term_of_level loc (fun l -> NotationUtil.group (p l))
 501       ]
 502     | "simple" NONA
 503       [ i = IDENT ->
 504          return_term_of_level loc
 505            (fun l -> Ast.Variable (Ast.TermVar (i,Ast.Self l)))
 506       | m = l1_magic_pattern ->
 507              return_term_of_level loc (fun l -> Ast.Magic (m l))
 508       | v = l1_pattern_variable ->
 509              return_term_of_level loc (fun _ -> Ast.Variable v)
 510       | l = literal -> return_term_of_level loc (fun _ -> Ast.Literal l)
 511       ]
 512     ];
 513   END
 514   end;
 515 (* }}} *)
 516 (* {{{ Grammar for ast magics, notation level 2 *)
 517   begin
 518   let level2_meta = grammars.level2_meta in
 519 EXTEND
 520   GLOBAL: level2_meta;
 521   l2_variable: [
 522     [ "term"; precedence = NUMBER; id = IDENT ->
 523         Ast.TermVar (id,Ast.Level (int_of_string precedence))
 524     | "number"; id = IDENT -> Ast.NumVar id
 525     | "ident"; id = IDENT -> Ast.IdentVar id
 526     | "fresh"; id = IDENT -> Ast.FreshVar id
 527     | "anonymous" -> Ast.TermVar ("_",Ast.Self 0) (* is the level relevant?*)
 528     | id = IDENT -> Ast.TermVar (id,Ast.Self 0)
 529     ]
 530   ];
 531   l2_magic: [
 532     [ "fold"; kind = [ "left" -> `Left | "right" -> `Right ];
 533       base = level2_meta; "rec"; id = IDENT; recursive = level2_meta ->
 534         Ast.Fold (kind, base, [id], recursive)
 535     | "default"; some = level2_meta; none = level2_meta ->
 536         Ast.Default (some, none)
 537     | "if"; p_test = level2_meta;
 538       "then"; p_true = level2_meta;
 539       "else"; p_false = level2_meta ->
 540         Ast.If (p_test, p_true, p_false)
 541     | "fail" -> Ast.Fail
 542     ]
 543   ];
 544   level2_meta: [
 545     [ magic = l2_magic -> Ast.Magic magic
 546     | var = l2_variable -> Ast.Variable var
 547     | blob = UNPARSED_AST ->
 548         parse_level2_ast grammars (Ulexing.from_utf8_string blob)
 549     ]
 550   ];
 551 END
 552   end;
 553 (* }}} *)
 554 (* {{{ Grammar for ast patterns, notation level 2 *)
 555   begin
 556   let level2_ast = grammars.level2_ast in
 557   let term = grammars.term in
 558   let let_defs = grammars.let_defs in
 559   let ident = grammars.ident in
 560   let protected_binder_vars = grammars.protected_binder_vars in
 561 EXTEND
 562   GLOBAL: level2_ast term let_defs protected_binder_vars ident;
 563   level2_ast: [ [ p = term -> p ] ];
 564   sort: [
 565     [ "Prop" -> `Prop
 566     | "Set" -> `Set
 567     | "Type"; SYMBOL "["; n = [ NUMBER| IDENT ]; SYMBOL "]" -> `NType n
 568     | "CProp"; SYMBOL "["; n = [ NUMBER| IDENT ]; SYMBOL "]" -> `NCProp n
 569     ]
 570   ];
 571   explicit_subst: [
 572     [ SYMBOL "\\subst ";  (* to avoid catching frequent "a [1]" cases *)
 573       SYMBOL "[";
 574       substs = LIST1 [
 575         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 576       ] SEP SYMBOL ";";
 577       SYMBOL "]" ->
 578         substs
 579     ]
 580   ];
 581   meta_subst: [
 582     [ s = SYMBOL "_" -> None
 583     | p = term -> Some p ]
 584   ];
 585   meta_substs: [
 586     [ SYMBOL "["; substs = LIST0 meta_subst; SYMBOL "]" -> substs ]
 587   ];
 588   possibly_typed_name: [
 589     [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 590         id, Some typ
 591     | arg = single_arg -> arg, None
 592     | id = PIDENT -> Ast.Ident (id, None), None
 593     | SYMBOL "_" -> Ast.Ident ("_", None), None
 594     | LPAREN; id = PIDENT; SYMBOL ":"; typ = term; RPAREN ->
 595         Ast.Ident (id, None), Some typ
 596     | LPAREN; SYMBOL "_"; SYMBOL ":"; typ = term; RPAREN ->
 597         Ast.Ident ("_", None), Some typ
 598     ]
 599   ];
 600   match_pattern: [
 601     [ SYMBOL "_" -> Ast.Wildcard
 602     | id = IDENT -> Ast.Pattern (id, None, [])
 603     | LPAREN; id = IDENT; vars = LIST1 possibly_typed_name; RPAREN ->
 604        Ast.Pattern (id, None, vars)
 605     | id = IDENT; vars = LIST1 possibly_typed_name ->
 606        Ast.Pattern (id, None, vars)
 607     ]
 608   ];
 609   binder: [
 610     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 611     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
 612     | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
 613     ]
 614   ];
 615   arg: [
 616     [ LPAREN; names = LIST1 IDENT SEP SYMBOL ",";
 617       SYMBOL ":"; ty = term; RPAREN ->
 618         List.map (fun n -> Ast.Ident (n, None)) names, Some ty
 619     | name = IDENT -> [Ast.Ident (name, None)], None
 620     | blob = UNPARSED_META ->
 621         let meta = parse_level2_meta grammars (Ulexing.from_utf8_string blob) in
 622         match meta with
 623         | Ast.Variable (Ast.FreshVar _) -> [meta], None
 624         | Ast.Variable (Ast.TermVar ("_",_)) -> [Ast.Ident ("_", None)], None
 625         | _ -> failwith "Invalid bound name."
 626    ]
 627   ];
 628   single_arg: [
 629     [ name = IDENT -> Ast.Ident (name, None)
 630     | blob = UNPARSED_META ->
 631         let meta = parse_level2_meta grammars (Ulexing.from_utf8_string blob) in
 632         match meta with
 633         | Ast.Variable (Ast.FreshVar _)
 634         | Ast.Variable (Ast.IdentVar _) -> meta
 635         | Ast.Variable (Ast.TermVar ("_",_)) -> Ast.Ident ("_", None)
 636         | _ -> failwith "Invalid index name."
 637     ]
 638   ];
 639   ident: [
 640     [ name = IDENT -> Env.Ident name
 641     | blob = UNPARSED_META ->
 642         let meta = parse_level2_meta grammars (Ulexing.from_utf8_string blob) in
 643         match meta with
 644         | Ast.Variable (Ast.FreshVar _) ->
 645            (* it makes sense: extend Env.ident_or_var *)
 646             assert false
 647         | Ast.Variable (Ast.IdentVar name) -> Env.Var name
 648         | Ast.Variable (Ast.TermVar ("_",_)) -> Env.Var "_"
 649         | _ -> failwith ("Invalid index name: " ^ blob)
 650     ]
 651   ];
 652   let_defs: [
 653     [ defs = LIST1 [
 654         name = single_arg;
 655         args = LIST1 arg;
 656         index_name = OPT [ "on"; id = single_arg -> id ];
 657         ty = OPT [ SYMBOL ":" ; p = term -> p ];
 658         SYMBOL <:unicode<def>> (* ≝ *); body = term ->
 659           let rec position_of name p = function
 660             | [] -> None, p
 661             | n :: _ when n = name -> Some p, p
 662             | _ :: tl -> position_of name (p + 1) tl
 663           in
 664           let rec find_arg name n = function
 665             | [] ->
 666                 (* CSC: new NCicPp.status is the best I can do here
 667                    without changing the return type *)
 668                 Ast.fail loc (sprintf "Argument %s not found"
 669                   (NotationPp.pp_term (new NCicPp.status) name))
 670             | (l,_) :: tl ->
 671                 (match position_of name 0 l with
 672                 | None, len -> find_arg name (n + len) tl
 673                 | Some where, len -> n + where)
 674           in
 675           let index =
 676             match index_name with
 677             | None -> 0
 678             | Some index_name -> find_arg index_name 0 args
 679           in
 680           let args =
 681            List.concat
 682             (List.map
 683              (function (names,ty) -> List.map (function x -> x,ty) names
 684              ) args)
 685           in
 686            args, (name, ty), body, index
 687       ] SEP "and" ->
 688         defs
 689     ]
 690   ];
 691   binder_vars: [
 692     [ vars = [ l =
 693         [ l = LIST1 single_arg SEP SYMBOL "," -> l
 694         | l = LIST1 [ PIDENT | SYMBOL "_" ] SEP SYMBOL "," ->
 695             List.map (fun x -> Ast.Ident(x,None)) l
 696       ] -> l ];
 697       typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 698     ]
 699   ];
 700   protected_binder_vars: [
 701     [ LPAREN; vars = binder_vars; RPAREN -> vars
 702     ]
 703   ];
 704   maybe_protected_binder_vars: [
 705     [ vars = binder_vars -> vars
 706     | vars = protected_binder_vars -> vars
 707     ]
 708   ];
 709   term: LEVEL "10"
 710   [
 711     [ "let";
 712      var =
 713       [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 714           id, Some typ
 715       | id = IDENT; ty = OPT [ SYMBOL ":"; typ = term -> typ] ->
 716           Ast.Ident(id,None), ty ];
 717       SYMBOL <:unicode<def>> (* ≝ *);
 718       p1 = term; "in"; p2 = term ->
 719         return_term loc (Ast.LetIn (var, p1, p2))
 720     | LETCOREC; defs = let_defs; "in";
 721       body = term ->
 722         return_term loc (Ast.LetRec (`CoInductive, defs, body))
 723     | LETREC; defs = let_defs; "in";
 724       body = term ->
 725         return_term loc (Ast.LetRec (`Inductive, defs, body))
 726     ]
 727   ];
 728   term: LEVEL "20"
 729     [
 730       [ b = binder; (vars, typ) = maybe_protected_binder_vars; SYMBOL "."; body = term LEVEL "19" ->
 731           return_term loc (fold_cluster b vars typ body)
 732       ]
 733     ];
 734   term: LEVEL "70"
 735     [
 736       [ p1 = term; p2 = term LEVEL "71" ->
 737           let rec aux = function
 738             | Ast.Appl (hd :: tl)
 739             | Ast.AttributedTerm (_, Ast.Appl (hd :: tl)) ->
 740                 aux hd @ tl
 741             | term -> [term]
 742           in
 743           return_term loc (Ast.Appl (aux p1 @ [p2]))
 744       ]
 745     ];
 746   term: LEVEL "90"
 747     [
 748       [ id = IDENT -> return_term loc (Ast.Ident (id, None))
 749       | id = IDENT; s = explicit_subst ->
 750           return_term loc (Ast.Ident (id, Some s))
 751       | s = CSYMBOL -> return_term loc (Ast.Symbol (s, 0))
 752       | u = URI -> return_term loc (Ast.Uri (u, None))
 753       | r = NREF -> return_term loc (Ast.NRef (NReference.reference_of_string r))
 754       | n = NUMBER -> return_term loc (Ast.Num (n, 0))
 755       | IMPLICIT -> return_term loc (Ast.Implicit `JustOne)
 756       | SYMBOL <:unicode<ldots>> -> return_term loc (Ast.Implicit `Vector)
 757       | PLACEHOLDER -> return_term loc Ast.UserInput
 758       | m = META -> return_term loc (Ast.Meta (int_of_string m, []))
 759       | m = META; s = meta_substs ->
 760           return_term loc (Ast.Meta (int_of_string m, s))
 761       | s = sort -> return_term loc (Ast.Sort s)
 762       | "match"; t = term;
 763         indty_ident = OPT [ "in"; id = IDENT -> id, None ];
 764         outtyp = OPT [ "return"; ty = term -> ty ];
 765         "with"; SYMBOL "[";
 766         patterns = LIST0 [
 767           lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
 768           rhs = term ->
 769             lhs, rhs
 770         ] SEP SYMBOL "|";
 771         SYMBOL "]" ->
 772           return_term loc (Ast.Case (t, indty_ident, outtyp, patterns))
 773       | LPAREN; p1 = term; SYMBOL ":"; p2 = term; RPAREN ->
 774           return_term loc (Ast.Cast (p1, p2))
 775       | LPAREN; p = term; RPAREN -> p
 776       | blob = UNPARSED_META ->
 777           parse_level2_meta grammars (Ulexing.from_utf8_string blob)
 778       ]
 779     ];
 780 END
 781   end;
 782 (* }}} *)
 783   grammars
 784 ;;
 785
 786 let initial_grammars keywords =
 787   let lexers = CicNotationLexer.mk_lexers keywords in
 788   let level1_pattern_grammar =
 789     Grammar.gcreate lexers.CicNotationLexer.level1_pattern_lexer in
 790   let level2_ast_grammar =
 791     Grammar.gcreate lexers.CicNotationLexer.level2_ast_lexer in
 792   let level2_meta_grammar =
 793     Grammar.gcreate lexers.CicNotationLexer.level2_meta_lexer in
 794   let level1_pattern =
 795     Grammar.Entry.create level1_pattern_grammar "level1_pattern" in
 796   let level2_ast = Grammar.Entry.create level2_ast_grammar "level2_ast" in
 797   let term = Grammar.Entry.create level2_ast_grammar "term" in
 798   let ident = Grammar.Entry.create level2_ast_grammar "ident" in
 799   let let_defs = Grammar.Entry.create level2_ast_grammar "let_defs" in
 800   let protected_binder_vars =
 801     Grammar.Entry.create level2_ast_grammar "protected_binder_vars" in
 802   let level2_meta = Grammar.Entry.create level2_meta_grammar "level2_meta" in
 803   initialize_grammars { level1_pattern=level1_pattern;
 804     level2_ast=level2_ast;
 805     term=term;
 806     ident=ident;
 807     let_defs=let_defs;
 808     protected_binder_vars=protected_binder_vars;
 809     level2_meta=level2_meta;
 810     level2_ast_grammar=level2_ast_grammar;
 811   }
 812 ;;
 813
 814 class type g_status =
 815  object
 816   method notation_parser_db: db
 817  end
 818
 819 class status0 ~keywords:kwds =
 820  object
 821   val db = { grammars = initial_grammars kwds; keywords = kwds; items = [] }
 822   method notation_parser_db = db
 823   method set_notation_parser_db v = {< db = v >}
 824   method set_notation_parser_status
 825    : 'status. #g_status as 'status -> 'self
 826    = fun o -> {< db = o#notation_parser_db >}
 827  end
 828
 829 class virtual status ~keywords:kwds =
 830  object
 831   inherit NCic.status
 832   inherit status0 kwds
 833  end
 834
 835 let extend (status : #status) (CL1P (level1_pattern,precedence)) action =
 836         (* move inside constructor XXX *)
 837   let add1item status (level, level1_pattern, action) =
 838     let p_bindings, p_atoms =
 839       List.split (extract_term_production status level1_pattern) in
 840     Grammar.extend
 841       [ Grammar.Entry.obj
 842         (status#notation_parser_db.grammars.term : 'a Grammar.Entry.e),
 843         Some (Gramext.Level level),
 844         [ None,
 845           Some (*Gramext.NonA*) Gramext.NonA,
 846           [ p_atoms,
 847             (make_action
 848               (fun (env: NotationEnv.t) (loc: Ast.location) ->
 849                 (action env loc))
 850               p_bindings) ]]];
 851     status
 852   in
 853   let current_item =
 854     let level = level_of precedence in
 855     level, level1_pattern, action in
 856   let keywords = NotationUtil.keywords_of_term level1_pattern @
 857     status#notation_parser_db.keywords in
 858   let items = current_item :: status#notation_parser_db.items in
 859   let status = status#set_notation_parser_status (new status0 ~keywords) in
 860   let status = status#set_notation_parser_db
 861     {status#notation_parser_db with items = items} in
 862   List.fold_left add1item status items
 863 ;;
 864
 865
 866 let parse_level1_pattern status =
 867   parse_level1_pattern status#notation_parser_db.grammars
 868 let parse_level2_ast status =
 869   parse_level2_ast status#notation_parser_db.grammars
 870 let parse_level2_meta status =
 871   parse_level2_meta status#notation_parser_db.grammars
 872
 873 let level2_ast_grammar status =
 874   status#notation_parser_db.grammars.level2_ast_grammar
 875 let term status = status#notation_parser_db.grammars.term
 876 let let_defs status = status#notation_parser_db.grammars.let_defs
 877 let protected_binder_vars status =
 878   status#notation_parser_db.grammars.protected_binder_vars
 879
 880 (** {2 Debugging} *)
 881
 882 let print_l2_pattern status =
 883   Grammar.print_entry Format.std_formatter
 884     (Grammar.Entry.obj status#notation_parser_db.grammars.term);
 885   Format.pp_print_flush Format.std_formatter ();
 886   flush stdout
 887
 888 (* vim:set encoding=utf8 foldmethod=marker: *)