matita/components/content_pres/cicNotationParser.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = NotationPt
  31 module Env = NotationEnv
  32
  33 exception Parse_error of string
  34 exception Level_not_found of int
  35
  36 let min_precedence = 0
  37 let max_precedence = 100
  38
  39 type ('a,'b,'c,'d) grammars = {
  40   level1_pattern: 'a Grammar.Entry.e;
  41   level2_ast: 'b Grammar.Entry.e;
  42   level2_ast_grammar : Grammar.g;
  43   term: 'b Grammar.Entry.e;
  44   let_defs: 'c Grammar.Entry.e;
  45   protected_binder_vars: 'd Grammar.Entry.e;
  46   level2_meta: 'b Grammar.Entry.e;
  47 }
  48
  49 type checked_l1_pattern = CL1P of NotationPt.term * int
  50
  51 type binding =
  52   | NoBinding
  53   | Binding of string * Env.value_type
  54   | Env of (string * Env.value_type) list
  55
  56 type db = {
  57   grammars:
  58     (int -> NotationPt.term,
  59     Ast.term,
  60     (Ast.term Ast.capture_variable list *
  61       Ast.term Ast.capture_variable * Ast.term * int) list,
  62     Ast.term list * Ast.term option) grammars;
  63   keywords: string list;
  64   items: (string * Ast.term * (NotationEnv.t -> Ast.location -> Ast.term)) list
  65 }
  66
  67 let int_of_string s =
  68   try
  69     Pervasives.int_of_string s
  70   with Failure _ ->
  71     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  72
  73 (** {2 Grammar extension} *)
  74
  75 let level_of precedence =
  76   if precedence < min_precedence || precedence > max_precedence then
  77     raise (Level_not_found precedence);
  78   string_of_int precedence
  79
  80 let gram_symbol s = Gramext.Stoken ("SYMBOL", s)
  81 let gram_ident s = Gramext.Stoken ("IDENT", s)
  82 let gram_number s = Gramext.Stoken ("NUMBER", s)
  83 let gram_keyword s = Gramext.Stoken ("", s)
  84 let gram_term status = function
  85   | Ast.Self _ -> Gramext.Sself
  86   | Ast.Level precedence ->
  87       Gramext.Snterml
  88         (Grammar.Entry.obj
  89           (status#notation_parser_db.grammars.term : 'a Grammar.Entry.e),
  90          level_of precedence)
  91 ;;
  92
  93 let gram_of_literal =
  94   function
  95   | `Symbol s -> gram_symbol s
  96   | `Keyword s -> gram_keyword s
  97   | `Number s -> gram_number s
  98
  99 let make_action action bindings =
 100   let rec aux (vl : NotationEnv.t) =
 101     function
 102       [] -> Gramext.action (fun (loc: Ast.location) -> action vl loc)
 103     | NoBinding :: tl -> Gramext.action (fun _ -> aux vl tl)
 104     (* LUCA: DEFCON 3 BEGIN *)
 105     | Binding (name, Env.TermType l) :: tl ->
 106         Gramext.action
 107           (fun (v:Ast.term) ->
 108             aux ((name, (Env.TermType l, Env.TermValue v))::vl) tl)
 109     | Binding (name, Env.StringType) :: tl ->
 110         Gramext.action
 111           (fun (v:string) ->
 112             aux ((name, (Env.StringType, Env.StringValue v)) :: vl) tl)
 113     | Binding (name, Env.NumType) :: tl ->
 114         Gramext.action
 115           (fun (v:string) ->
 116             aux ((name, (Env.NumType, Env.NumValue v)) :: vl) tl)
 117     | Binding (name, Env.OptType t) :: tl ->
 118         Gramext.action
 119           (fun (v:'a option) ->
 120             aux ((name, (Env.OptType t, Env.OptValue v)) :: vl) tl)
 121     | Binding (name, Env.ListType t) :: tl ->
 122         Gramext.action
 123           (fun (v:'a list) ->
 124             aux ((name, (Env.ListType t, Env.ListValue v)) :: vl) tl)
 125     | Env _ :: tl ->
 126         Gramext.action (fun (v:NotationEnv.t) -> aux (v @ vl) tl)
 127     (* LUCA: DEFCON 3 END *)
 128   in
 129     aux [] (List.rev bindings)
 130
 131 let flatten_opt =
 132   let rec aux acc =
 133     function
 134       [] -> List.rev acc
 135     | NoBinding :: tl -> aux acc tl
 136     | Env names :: tl -> aux (List.rev names @ acc) tl
 137     | Binding (name, ty) :: tl -> aux ((name, ty) :: acc) tl
 138   in
 139   aux []
 140
 141   (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
 142 let extract_term_production status pattern =
 143   let rec aux = function
 144     | Ast.AttributedTerm (_, t) -> aux t
 145     | Ast.Literal l -> aux_literal l
 146     | Ast.Layout l -> aux_layout l
 147     | Ast.Magic m -> aux_magic m
 148     | Ast.Variable v -> aux_variable v
 149     | t ->
 150         prerr_endline (NotationPp.pp_term t);
 151         assert false
 152   and aux_literal =
 153     function
 154     | `Symbol s -> [NoBinding, gram_symbol s]
 155     | `Keyword s ->
 156         (* assumption: s will be registered as a keyword with the lexer *)
 157         [NoBinding, gram_keyword s]
 158     | `Number s -> [NoBinding, gram_number s]
 159   and aux_layout = function
 160     | Ast.Sub (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sub "] @ aux p2
 161     | Ast.Sup (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sup "] @ aux p2
 162     | Ast.Below (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\below "] @ aux p2
 163     | Ast.Above (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\above "] @ aux p2
 164     | Ast.Frac (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\frac "] @ aux p2
 165     | Ast.InfRule (p1, p2, p3) -> [NoBinding, gram_symbol "\\infrule "] @ aux p1 @ aux p2 @ aux p3
 166     | Ast.Atop (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\atop "] @ aux p2
 167     | Ast.Over (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\over "] @ aux p2
 168     | Ast.Root (p1, p2) ->
 169         [NoBinding, gram_symbol "\\root "] @ aux p2
 170         @ [NoBinding, gram_symbol "\\of "] @ aux p1
 171     | Ast.Sqrt p -> [NoBinding, gram_symbol "\\sqrt "] @ aux p
 172     | Ast.Break -> []
 173     | Ast.Box (_, pl) -> List.flatten (List.map aux pl)
 174     | Ast.Group pl -> List.flatten (List.map aux pl)
 175     | Ast.Mstyle (_,pl) -> List.flatten (List.map aux pl)
 176     | Ast.Mpadded (_,pl) -> List.flatten (List.map aux pl)
 177     | Ast.Maction l -> List.flatten (List.map aux l)
 178   and aux_magic magic =
 179     match magic with
 180     | Ast.Opt p ->
 181         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 182         let action (env_opt : NotationEnv.t option) (loc : Ast.location) =
 183           match env_opt with
 184           | Some env -> List.map Env.opt_binding_some env
 185           | None -> List.map Env.opt_binding_of_name p_names
 186         in
 187         [ Env (List.map Env.opt_declaration p_names),
 188           Gramext.srules
 189             [ [ Gramext.Sopt (Gramext.srules [ p_atoms, p_action ]) ],
 190               Gramext.action action ] ]
 191     | Ast.List0 (p, _)
 192     | Ast.List1 (p, _) ->
 193         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 194         let action (env_list : NotationEnv.t list) (loc : Ast.location) =
 195           NotationEnv.coalesce_env p_names env_list
 196         in
 197         let gram_of_list s =
 198           match magic with
 199           | Ast.List0 (_, None) -> Gramext.Slist0 s
 200           | Ast.List1 (_, None) -> Gramext.Slist1 s
 201           | Ast.List0 (_, Some l) -> Gramext.Slist0sep (s, gram_of_literal l)
 202           | Ast.List1 (_, Some l) -> Gramext.Slist1sep (s, gram_of_literal l)
 203           | _ -> assert false
 204         in
 205         [ Env (List.map Env.list_declaration p_names),
 206           Gramext.srules
 207             [ [ gram_of_list (Gramext.srules [ p_atoms, p_action ]) ],
 208               Gramext.action action ] ]
 209     | _ -> assert false
 210   and aux_variable =
 211     function
 212     | Ast.NumVar s -> [Binding (s, Env.NumType), gram_number ""]
 213     | Ast.TermVar (s,(Ast.Self level|Ast.Level level as lv)) ->
 214         [Binding (s, Env.TermType level), gram_term status lv]
 215     | Ast.IdentVar s -> [Binding (s, Env.StringType), gram_ident ""]
 216     | Ast.Ascription (p, s) -> assert false (* TODO *)
 217     | Ast.FreshVar _ -> assert false
 218   and inner_pattern p =
 219     let p_bindings, p_atoms = List.split (aux p) in
 220     let p_names = flatten_opt p_bindings in
 221     let action =
 222       make_action (fun (env : NotationEnv.t) (loc : Ast.location) -> env)
 223         p_bindings
 224     in
 225     p_bindings, p_atoms, p_names, action
 226   in
 227   aux pattern
 228
 229 type rule_id = Grammar.token Gramext.g_symbol list
 230
 231 let compare_rule_id x y =
 232   let rec aux = function
 233     | [],[] -> 0
 234     | [],_ -> ~-1
 235     | _,[] -> 1
 236     | ((s1::tl1) as x),((s2::tl2) as y) ->
 237         if Gramext.eq_symbol s1 s2 then aux (tl1,tl2)
 238         else Pervasives.compare x y
 239   in
 240     aux (x,y)
 241
 242
 243 let check_l1_pattern level1_pattern pponly level associativity =
 244   let variables = ref 0 in
 245   let symbols = ref 0 in
 246   let rec aux = function
 247     | Ast.AttributedTerm (att, t) -> Ast.AttributedTerm (att,aux t)
 248     | Ast.Literal _ as l -> incr symbols; l
 249     | Ast.Layout l -> Ast.Layout (aux_layout l)
 250     | Ast.Magic m -> Ast.Magic (aux_magic m)
 251     | Ast.Variable v -> (aux_variable v)
 252     | t -> assert false
 253   and aux_layout = function
 254     | Ast.Sub (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sub (p1, p2)
 255     | Ast.Sup (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sup (p1, p2)
 256     | Ast.Below (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Below (p1, p2)
 257     | Ast.Above (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Above (p1, p2)
 258     | Ast.Frac (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Frac (p1, p2)
 259     | Ast.InfRule (p1, p2, p3)  -> let p1 = aux p1 in let p2 = aux p2 in let p3 = aux p3 in Ast.InfRule (p1, p2, p3)
 260     | Ast.Atop (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Atop (p1, p2)
 261     | Ast.Over (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Over (p1, p2)
 262     | Ast.Root (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Root (p1, p2)
 263     | Ast.Sqrt p -> Ast.Sqrt (aux p)
 264     | Ast.Break as t -> t
 265     | Ast.Box (b, pl) -> Ast.Box(b, List.map aux pl)
 266     | Ast.Group pl -> Ast.Group (List.map aux pl)
 267     | Ast.Mstyle (l,pl) -> Ast.Mstyle (l, List.map aux pl)
 268     | Ast.Mpadded (l,pl) -> Ast.Mpadded (l, List.map aux pl)
 269     | Ast.Maction l as t ->
 270         if not pponly then
 271         raise(Parse_error("Maction can be used only in output notations"))
 272         else t
 273   and aux_magic magic =
 274     match magic with
 275     | Ast.Opt p -> Ast.Opt (aux p)
 276     | Ast.List0 (p, x) -> Ast.List0 (aux p, x)
 277     | Ast.List1 (p, x) -> Ast.List1 (aux p, x)
 278     | _ -> assert false
 279   and aux_variable =
 280     function
 281     | Ast.NumVar _ as t -> Ast.Variable t
 282     | Ast.TermVar (s,Ast.Self _) when associativity <> Gramext.NonA ->
 283         incr variables;
 284         if !variables > 2 then
 285           raise (Parse_error ("Exactly 2 variables must be specified in an "^
 286           "associative notation"));
 287         (match !variables, associativity with
 288         | 1,Gramext.LeftA ->
 289              Ast.Variable (Ast.TermVar (s, Ast.Self level))
 290         | 1,Gramext.RightA ->
 291              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 292         | 2,Gramext.LeftA ->
 293              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 294         | 2,Gramext.RightA ->
 295              Ast.Variable (Ast.TermVar (s, Ast.Level (level-1)))
 296         | _ -> assert false)
 297     | Ast.TermVar (s,Ast.Level _) when associativity <> Gramext.NonA ->
 298           raise (Parse_error ("Variables can not be declared with a " ^
 299             "precedence in an associative notation"))
 300        (*avoid camlp5 divergence due to non-Sself recursion at the same level *)
 301     | Ast.TermVar (s,Ast.Level l) when l<=level && !variables=0 && !symbols=0->
 302        raise(Parse_error("Left recursive rule with precedence not greater " ^
 303         "than " ^ string_of_int level ^ " is not allowed to avoid divergence"))
 304     | Ast.TermVar _ as t -> incr variables; Ast.Variable t
 305     | Ast.IdentVar _ as t -> Ast.Variable t
 306     | Ast.Ascription _ -> assert false (* TODO *)
 307     | Ast.FreshVar _ -> assert false
 308   in
 309   if associativity <> Gramext.NonA && level = min_precedence then
 310     raise (Parse_error ("You can not specify an associative notation " ^
 311     "at level "^string_of_int min_precedence ^ "; increase it"));
 312   let cp = aux level1_pattern in
 313 (*   prerr_endline ("checked_pattern: " ^ NotationPp.pp_term cp); *)
 314   if !variables <> 2 && associativity <> Gramext.NonA then
 315     raise (Parse_error ("Exactly 2 variables must be specified in an "^
 316      "associative notation"));
 317   CL1P (cp,level)
 318 ;;
 319
 320 (** {2 Grammar} *)
 321
 322 let fold_cluster binder terms ty body =
 323   List.fold_right
 324     (fun term body -> Ast.Binder (binder, (term, ty), body))
 325     terms body  (* terms are names: either Ident or FreshVar *)
 326
 327 let fold_exists terms ty body =
 328   List.fold_right
 329     (fun term body ->
 330       let lambda = Ast.Binder (`Lambda, (term, ty), body) in
 331       Ast.Appl [ Ast.Symbol ("exists", 0); lambda ])
 332     terms body
 333
 334 let fold_binder binder pt_names body =
 335   List.fold_right
 336     (fun (names, ty) body -> fold_cluster binder names ty body)
 337     pt_names body
 338
 339 let return_term loc term = Ast.AttributedTerm (`Loc loc, term)
 340 let return_term_of_level loc term l =
 341   Ast.AttributedTerm (`Loc loc, term l)
 342
 343 (** {2 API implementation} *)
 344
 345 let exc_located_wrapper f =
 346   try
 347     f ()
 348   with
 349   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 350       raise (HExtlib.Localized (floc, Parse_error msg))
 351   | Stdpp.Exc_located (floc, HExtlib.Localized (_,exn)) ->
 352       raise (HExtlib.Localized (floc, (Parse_error (Printexc.to_string exn))))
 353   | Stdpp.Exc_located (floc, exn) ->
 354       raise (HExtlib.Localized (floc, (Parse_error (Printexc.to_string exn))))
 355
 356 let parse_level1_pattern grammars precedence lexbuf =
 357   exc_located_wrapper
 358     (fun () -> Grammar.Entry.parse grammars.level1_pattern (Obj.magic lexbuf) precedence)
 359
 360 let parse_level2_ast grammars lexbuf =
 361   exc_located_wrapper
 362     (fun () -> Grammar.Entry.parse grammars.level2_ast (Obj.magic lexbuf))
 363
 364 let parse_level2_meta grammars lexbuf =
 365   exc_located_wrapper
 366     (fun () -> Grammar.Entry.parse grammars.level2_meta (Obj.magic lexbuf))
 367
 368 let parse_term grammars lexbuf =
 369   exc_located_wrapper
 370     (fun () -> (Grammar.Entry.parse grammars.term (Obj.magic lexbuf)))
 371
 372   (* create empty precedence level for "term" *)
 373 let initialize_grammars grammars =
 374   let dummy_action =
 375     Gramext.action (fun _ ->
 376       failwith "internal error, lexer generated a dummy token")
 377   in
 378   (* Needed since campl4 on "delete_rule" remove the precedence level if it gets
 379    * empty after the deletion. The lexer never generate the Stoken below. *)
 380   let dummy_prod = [ [ Gramext.Stoken ("DUMMY", "") ], dummy_action ] in
 381   let mk_level_list first last =
 382     let rec aux acc = function
 383       | i when i < first -> acc
 384       | i ->
 385           aux
 386             ((Some (level_of i), Some Gramext.NonA, dummy_prod)
 387              :: acc)
 388             (i - 1)
 389     in
 390     aux [] last
 391   in
 392   Grammar.extend
 393     [ Grammar.Entry.obj (grammars.term: 'a Grammar.Entry.e),
 394       None,
 395       mk_level_list min_precedence max_precedence ];
 396 (* {{{ Grammar for concrete syntax patterns, notation level 1 *)
 397   begin
 398   let level1_pattern = grammars.level1_pattern in
 399 EXTEND
 400   GLOBAL: level1_pattern;
 401
 402   level1_pattern: [
 403     [ p = l1_pattern; EOI -> fun l -> NotationUtil.boxify (p l) ]
 404   ];
 405   l1_pattern: [
 406     [ p = LIST1 l1_simple_pattern ->
 407         fun l -> List.map (fun x -> x l) p ]
 408   ];
 409   literal: [
 410     [ s = SYMBOL -> `Symbol s
 411     | k = QKEYWORD -> `Keyword k
 412     | n = NUMBER -> `Number n
 413     ]
 414   ];
 415   sep:       [ [ "sep";      sep = literal -> sep ] ];
 416   l1_magic_pattern: [
 417     [ "list0"; p = l1_simple_pattern; sep = OPT sep ->
 418             fun l -> Ast.List0 (p l, sep)
 419     | "list1"; p = l1_simple_pattern; sep = OPT sep ->
 420             fun l -> Ast.List1 (p l, sep)
 421     | "opt";   p = l1_simple_pattern -> fun l -> Ast.Opt (p l)
 422     ]
 423   ];
 424   l1_pattern_variable: [
 425     [ "term"; precedence = NUMBER; id = IDENT ->
 426         Ast.TermVar (id, Ast.Level (int_of_string precedence))
 427     | "number"; id = IDENT -> Ast.NumVar id
 428     | "ident"; id = IDENT -> Ast.IdentVar id
 429     ]
 430   ];
 431   mstyle: [
 432     [ id = IDENT;
 433       v = [ IDENT | NUMBER | COLOR | FLOATWITHUNIT ] -> id, v]];
 434   mpadded: [
 435     [ id = IDENT;
 436       v = [ PERCENTAGE ] -> id, v]];
 437   l1_simple_pattern:
 438     [ "layout" LEFTA
 439       [ p1 = SELF; SYMBOL "\\sub "; p2 = SELF ->
 440           return_term_of_level loc
 441             (fun l -> Ast.Layout (Ast.Sub (p1 l, p2 l)))
 442       | p1 = SELF; SYMBOL "\\sup "; p2 = SELF ->
 443           return_term_of_level loc
 444             (fun l -> Ast.Layout (Ast.Sup (p1 l, p2 l)))
 445       | p1 = SELF; SYMBOL "\\below "; p2 = SELF ->
 446           return_term_of_level loc
 447             (fun l -> Ast.Layout (Ast.Below (p1 l, p2 l)))
 448       | p1 = SELF; SYMBOL "\\above "; p2 = SELF ->
 449           return_term_of_level loc
 450             (fun l -> Ast.Layout (Ast.Above (p1 l, p2 l)))
 451       | p1 = SELF; SYMBOL "\\over "; p2 = SELF ->
 452           return_term_of_level loc
 453             (fun l -> Ast.Layout (Ast.Over (p1 l, p2 l)))
 454       | p1 = SELF; SYMBOL "\\atop "; p2 = SELF ->
 455           return_term_of_level loc
 456             (fun l -> Ast.Layout (Ast.Atop (p1 l, p2 l)))
 457       | p1 = SELF; SYMBOL "\\frac "; p2 = SELF ->
 458           return_term_of_level loc
 459             (fun l -> Ast.Layout (Ast.Frac (p1 l, p2 l)))
 460       | SYMBOL "\\infrule "; p1 = SELF; p2 = SELF; p3 = SELF ->
 461           return_term_of_level loc
 462             (fun l -> Ast.Layout (Ast.InfRule (p1 l, p2 l, p3 l)))
 463       | SYMBOL "\\sqrt "; p = SELF ->
 464           return_term_of_level loc (fun l -> Ast.Layout (Ast.Sqrt p l))
 465       | SYMBOL "\\root "; index = SELF; SYMBOL "\\of "; arg = SELF ->
 466           return_term_of_level loc
 467             (fun l -> Ast.Layout (Ast.Root (arg l, index l)))
 468       | "hbox"; LPAREN; p = l1_pattern; RPAREN ->
 469           return_term_of_level loc
 470             (fun l -> Ast.Layout (Ast.Box ((Ast.H, false, false), p l)))
 471       | "vbox"; LPAREN; p = l1_pattern; RPAREN ->
 472           return_term_of_level loc
 473             (fun l -> Ast.Layout (Ast.Box ((Ast.V, false, false), p l)))
 474       | "hvbox"; LPAREN; p = l1_pattern; RPAREN ->
 475           return_term_of_level loc
 476             (fun l -> Ast.Layout (Ast.Box ((Ast.HV, false, false), p l)))
 477       | "hovbox"; LPAREN; p = l1_pattern; RPAREN ->
 478           return_term_of_level loc
 479             (fun l -> Ast.Layout (Ast.Box ((Ast.HOV, false, false), p l)))
 480       | "break" -> return_term_of_level loc (fun _ -> Ast.Layout Ast.Break)
 481       | "mstyle"; m = LIST1 mstyle ; LPAREN; t = l1_pattern; RPAREN ->
 482           return_term_of_level loc
 483             (fun l ->
 484                Ast.Layout (Ast.Mstyle (m, t l)))
 485       | "mpadded"; m = LIST1 mpadded ; LPAREN; t = l1_pattern; RPAREN ->
 486           return_term_of_level loc
 487             (fun l ->
 488                Ast.Layout (Ast.Mpadded (m, t l)))
 489       | "maction"; m = LIST1 [ LPAREN; l = l1_pattern; RPAREN -> l ] ->
 490            return_term_of_level loc
 491             (fun l -> Ast.Layout (Ast.Maction (List.map (fun x ->
 492               NotationUtil.group (x l)) m)))
 493       | LPAREN; p = l1_pattern; RPAREN ->
 494           return_term_of_level loc (fun l -> NotationUtil.group (p l))
 495       ]
 496     | "simple" NONA
 497       [ i = IDENT ->
 498          return_term_of_level loc
 499            (fun l -> Ast.Variable (Ast.TermVar (i,Ast.Self l)))
 500       | m = l1_magic_pattern ->
 501              return_term_of_level loc (fun l -> Ast.Magic (m l))
 502       | v = l1_pattern_variable ->
 503              return_term_of_level loc (fun _ -> Ast.Variable v)
 504       | l = literal -> return_term_of_level loc (fun _ -> Ast.Literal l)
 505       ]
 506     ];
 507   END
 508   end;
 509 (* }}} *)
 510 (* {{{ Grammar for ast magics, notation level 2 *)
 511   begin
 512   let level2_meta = grammars.level2_meta in
 513 EXTEND
 514   GLOBAL: level2_meta;
 515   l2_variable: [
 516     [ "term"; precedence = NUMBER; id = IDENT ->
 517         Ast.TermVar (id,Ast.Level (int_of_string precedence))
 518     | "number"; id = IDENT -> Ast.NumVar id
 519     | "ident"; id = IDENT -> Ast.IdentVar id
 520     | "fresh"; id = IDENT -> Ast.FreshVar id
 521     | "anonymous" -> Ast.TermVar ("_",Ast.Self 0) (* is the level relevant?*)
 522     | id = IDENT -> Ast.TermVar (id,Ast.Self 0)
 523     ]
 524   ];
 525   l2_magic: [
 526     [ "fold"; kind = [ "left" -> `Left | "right" -> `Right ];
 527       base = level2_meta; "rec"; id = IDENT; recursive = level2_meta ->
 528         Ast.Fold (kind, base, [id], recursive)
 529     | "default"; some = level2_meta; none = level2_meta ->
 530         Ast.Default (some, none)
 531     | "if"; p_test = level2_meta;
 532       "then"; p_true = level2_meta;
 533       "else"; p_false = level2_meta ->
 534         Ast.If (p_test, p_true, p_false)
 535     | "fail" -> Ast.Fail
 536     ]
 537   ];
 538   level2_meta: [
 539     [ magic = l2_magic -> Ast.Magic magic
 540     | var = l2_variable -> Ast.Variable var
 541     | blob = UNPARSED_AST ->
 542         parse_level2_ast grammars (Ulexing.from_utf8_string blob)
 543     ]
 544   ];
 545 END
 546   end;
 547 (* }}} *)
 548 (* {{{ Grammar for ast patterns, notation level 2 *)
 549   begin
 550   let level2_ast = grammars.level2_ast in
 551   let term = grammars.term in
 552   let let_defs = grammars.let_defs in
 553   let protected_binder_vars = grammars.protected_binder_vars in
 554 EXTEND
 555   GLOBAL: level2_ast term let_defs protected_binder_vars;
 556   level2_ast: [ [ p = term -> p ] ];
 557   sort: [
 558     [ "Prop" -> `Prop
 559     | "Set" -> `Set
 560     | "Type"; SYMBOL "["; n = [ NUMBER| IDENT ]; SYMBOL "]" -> `NType n
 561     | "CProp"; SYMBOL "["; n = [ NUMBER| IDENT ]; SYMBOL "]" -> `NCProp n
 562     ]
 563   ];
 564   explicit_subst: [
 565     [ SYMBOL "\\subst ";  (* to avoid catching frequent "a [1]" cases *)
 566       SYMBOL "[";
 567       substs = LIST1 [
 568         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 569       ] SEP SYMBOL ";";
 570       SYMBOL "]" ->
 571         substs
 572     ]
 573   ];
 574   meta_subst: [
 575     [ s = SYMBOL "_" -> None
 576     | p = term -> Some p ]
 577   ];
 578   meta_substs: [
 579     [ SYMBOL "["; substs = LIST0 meta_subst; SYMBOL "]" -> substs ]
 580   ];
 581   possibly_typed_name: [
 582     [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 583         id, Some typ
 584     | arg = single_arg -> arg, None
 585     | id = PIDENT -> Ast.Ident (id, None), None
 586     | SYMBOL "_" -> Ast.Ident ("_", None), None
 587     | LPAREN; id = PIDENT; SYMBOL ":"; typ = term; RPAREN ->
 588         Ast.Ident (id, None), Some typ
 589     | LPAREN; SYMBOL "_"; SYMBOL ":"; typ = term; RPAREN ->
 590         Ast.Ident ("_", None), Some typ
 591     ]
 592   ];
 593   match_pattern: [
 594     [ SYMBOL "_" -> Ast.Wildcard
 595     | id = IDENT -> Ast.Pattern (id, None, [])
 596     | LPAREN; id = IDENT; vars = LIST1 possibly_typed_name; RPAREN ->
 597        Ast.Pattern (id, None, vars)
 598     | id = IDENT; vars = LIST1 possibly_typed_name ->
 599        Ast.Pattern (id, None, vars)
 600     ]
 601   ];
 602   binder: [
 603     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 604     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
 605     | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
 606     ]
 607   ];
 608   arg: [
 609     [ LPAREN; names = LIST1 IDENT SEP SYMBOL ",";
 610       SYMBOL ":"; ty = term; RPAREN ->
 611         List.map (fun n -> Ast.Ident (n, None)) names, Some ty
 612     | name = IDENT -> [Ast.Ident (name, None)], None
 613     | blob = UNPARSED_META ->
 614         let meta = parse_level2_meta grammars (Ulexing.from_utf8_string blob) in
 615         match meta with
 616         | Ast.Variable (Ast.FreshVar _) -> [meta], None
 617         | Ast.Variable (Ast.TermVar ("_",_)) -> [Ast.Ident ("_", None)], None
 618         | _ -> failwith "Invalid bound name."
 619    ]
 620   ];
 621   single_arg: [
 622     [ name = IDENT -> Ast.Ident (name, None)
 623     | blob = UNPARSED_META ->
 624         let meta = parse_level2_meta grammars (Ulexing.from_utf8_string blob) in
 625         match meta with
 626         | Ast.Variable (Ast.FreshVar _)
 627         | Ast.Variable (Ast.IdentVar _) -> meta
 628         | Ast.Variable (Ast.TermVar ("_",_)) -> Ast.Ident ("_", None)
 629         | _ -> failwith "Invalid index name."
 630     ]
 631   ];
 632   let_defs: [
 633     [ defs = LIST1 [
 634         name = single_arg;
 635         args = LIST1 arg;
 636         index_name = OPT [ "on"; id = single_arg -> id ];
 637         ty = OPT [ SYMBOL ":" ; p = term -> p ];
 638         SYMBOL <:unicode<def>> (* ≝ *); body = term ->
 639           let rec position_of name p = function
 640             | [] -> None, p
 641             | n :: _ when n = name -> Some p, p
 642             | _ :: tl -> position_of name (p + 1) tl
 643           in
 644           let rec find_arg name n = function
 645             | [] ->
 646                 Ast.fail loc (sprintf "Argument %s not found"
 647                   (NotationPp.pp_term name))
 648             | (l,_) :: tl ->
 649                 (match position_of name 0 l with
 650                 | None, len -> find_arg name (n + len) tl
 651                 | Some where, len -> n + where)
 652           in
 653           let index =
 654             match index_name with
 655             | None -> 0
 656             | Some index_name -> find_arg index_name 0 args
 657           in
 658           let args =
 659            List.concat
 660             (List.map
 661              (function (names,ty) -> List.map (function x -> x,ty) names
 662              ) args)
 663           in
 664            args, (name, ty), body, index
 665       ] SEP "and" ->
 666         defs
 667     ]
 668   ];
 669   binder_vars: [
 670     [ vars = [ l =
 671         [ l = LIST1 single_arg SEP SYMBOL "," -> l
 672         | l = LIST1 [ PIDENT | SYMBOL "_" ] SEP SYMBOL "," ->
 673             List.map (fun x -> Ast.Ident(x,None)) l
 674       ] -> l ];
 675       typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 676     ]
 677   ];
 678   protected_binder_vars: [
 679     [ LPAREN; vars = binder_vars; RPAREN -> vars
 680     ]
 681   ];
 682   maybe_protected_binder_vars: [
 683     [ vars = binder_vars -> vars
 684     | vars = protected_binder_vars -> vars
 685     ]
 686   ];
 687   term: LEVEL "10"
 688   [
 689     [ "let";
 690      var =
 691       [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 692           id, Some typ
 693       | id = IDENT; ty = OPT [ SYMBOL ":"; typ = term -> typ] ->
 694           Ast.Ident(id,None), ty ];
 695       SYMBOL <:unicode<def>> (* ≝ *);
 696       p1 = term; "in"; p2 = term ->
 697         return_term loc (Ast.LetIn (var, p1, p2))
 698     | LETCOREC; defs = let_defs; "in";
 699       body = term ->
 700         return_term loc (Ast.LetRec (`CoInductive, defs, body))
 701     | LETREC; defs = let_defs; "in";
 702       body = term ->
 703         return_term loc (Ast.LetRec (`Inductive, defs, body))
 704     ]
 705   ];
 706   term: LEVEL "20"
 707     [
 708       [ b = binder; (vars, typ) = maybe_protected_binder_vars; SYMBOL "."; body = term LEVEL "19" ->
 709           return_term loc (fold_cluster b vars typ body)
 710       ]
 711     ];
 712   term: LEVEL "70"
 713     [
 714       [ p1 = term; p2 = term LEVEL "71" ->
 715           let rec aux = function
 716             | Ast.Appl (hd :: tl)
 717             | Ast.AttributedTerm (_, Ast.Appl (hd :: tl)) ->
 718                 aux hd @ tl
 719             | term -> [term]
 720           in
 721           return_term loc (Ast.Appl (aux p1 @ [p2]))
 722       ]
 723     ];
 724   term: LEVEL "90"
 725     [
 726       [ id = IDENT -> return_term loc (Ast.Ident (id, None))
 727       | id = IDENT; s = explicit_subst ->
 728           return_term loc (Ast.Ident (id, Some s))
 729       | s = CSYMBOL -> return_term loc (Ast.Symbol (s, 0))
 730       | u = URI -> return_term loc (Ast.Uri (u, None))
 731       | r = NREF -> return_term loc (Ast.NRef (NReference.reference_of_string r))
 732       | n = NUMBER -> return_term loc (Ast.Num (n, 0))
 733       | IMPLICIT -> return_term loc (Ast.Implicit `JustOne)
 734       | SYMBOL <:unicode<ldots>> -> return_term loc (Ast.Implicit `Vector)
 735       | PLACEHOLDER -> return_term loc Ast.UserInput
 736       | m = META -> return_term loc (Ast.Meta (int_of_string m, []))
 737       | m = META; s = meta_substs ->
 738           return_term loc (Ast.Meta (int_of_string m, s))
 739       | s = sort -> return_term loc (Ast.Sort s)
 740       | "match"; t = term;
 741         indty_ident = OPT [ "in"; id = IDENT -> id, None ];
 742         outtyp = OPT [ "return"; ty = term -> ty ];
 743         "with"; SYMBOL "[";
 744         patterns = LIST0 [
 745           lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
 746           rhs = term ->
 747             lhs, rhs
 748         ] SEP SYMBOL "|";
 749         SYMBOL "]" ->
 750           return_term loc (Ast.Case (t, indty_ident, outtyp, patterns))
 751       | LPAREN; p1 = term; SYMBOL ":"; p2 = term; RPAREN ->
 752           return_term loc (Ast.Cast (p1, p2))
 753       | LPAREN; p = term; RPAREN -> p
 754       | blob = UNPARSED_META ->
 755           parse_level2_meta grammars (Ulexing.from_utf8_string blob)
 756       ]
 757     ];
 758 END
 759   end;
 760 (* }}} *)
 761   grammars
 762 ;;
 763
 764 let initial_grammars keywords =
 765   let lexers = CicNotationLexer.mk_lexers keywords in
 766   let level1_pattern_grammar =
 767     Grammar.gcreate lexers.CicNotationLexer.level1_pattern_lexer in
 768   let level2_ast_grammar =
 769     Grammar.gcreate lexers.CicNotationLexer.level2_ast_lexer in
 770   let level2_meta_grammar =
 771     Grammar.gcreate lexers.CicNotationLexer.level2_meta_lexer in
 772   let level1_pattern =
 773     Grammar.Entry.create level1_pattern_grammar "level1_pattern" in
 774   let level2_ast = Grammar.Entry.create level2_ast_grammar "level2_ast" in
 775   let term = Grammar.Entry.create level2_ast_grammar "term" in
 776   let let_defs = Grammar.Entry.create level2_ast_grammar "let_defs" in
 777   let protected_binder_vars =
 778     Grammar.Entry.create level2_ast_grammar "protected_binder_vars" in
 779   let level2_meta = Grammar.Entry.create level2_meta_grammar "level2_meta" in
 780   initialize_grammars { level1_pattern=level1_pattern;
 781     level2_ast=level2_ast;
 782     term=term;
 783     let_defs=let_defs;
 784     protected_binder_vars=protected_binder_vars;
 785     level2_meta=level2_meta;
 786     level2_ast_grammar=level2_ast_grammar;
 787   }
 788 ;;
 789
 790 class type g_status =
 791  object
 792   method notation_parser_db: db
 793  end
 794
 795 class status ~keywords:kwds =
 796  object
 797   val db = { grammars = initial_grammars kwds; keywords = kwds; items = [] }
 798   method notation_parser_db = db
 799   method set_notation_parser_db v = {< db = v >}
 800   method set_notation_parser_status
 801    : 'status. #g_status as 'status -> 'self
 802    = fun o -> {< db = o#notation_parser_db >}
 803  end
 804
 805 let extend (status : #status) (CL1P (level1_pattern,precedence)) action =
 806         (* move inside constructor XXX *)
 807   let add1item status (level, level1_pattern, action) =
 808     let p_bindings, p_atoms =
 809       List.split (extract_term_production status level1_pattern) in
 810     Grammar.extend
 811       [ Grammar.Entry.obj
 812         (status#notation_parser_db.grammars.term : 'a Grammar.Entry.e),
 813         Some (Gramext.Level level),
 814         [ None,
 815           Some (*Gramext.NonA*) Gramext.NonA,
 816           [ p_atoms,
 817             (make_action
 818               (fun (env: NotationEnv.t) (loc: Ast.location) ->
 819                 (action env loc))
 820             p_bindings) ]]];
 821     status
 822   in
 823   let current_item =
 824     let level = level_of precedence in
 825     level, level1_pattern, action in
 826   let keywords = NotationUtil.keywords_of_term level1_pattern @
 827     status#notation_parser_db.keywords in
 828   let items = current_item :: status#notation_parser_db.items in
 829   let status = status#set_notation_parser_status (new status ~keywords) in
 830   let status = status#set_notation_parser_db
 831     {status#notation_parser_db with items = items} in
 832   List.fold_left add1item status items
 833 ;;
 834
 835
 836 let parse_level1_pattern status =
 837   parse_level1_pattern status#notation_parser_db.grammars
 838 let parse_level2_ast status =
 839   parse_level2_ast status#notation_parser_db.grammars
 840 let parse_level2_meta status =
 841   parse_level2_meta status#notation_parser_db.grammars
 842 let parse_term status =
 843   parse_term status#notation_parser_db.grammars
 844
 845 let level2_ast_grammar status =
 846   status#notation_parser_db.grammars.level2_ast_grammar
 847 let term status = status#notation_parser_db.grammars.term
 848 let let_defs status = status#notation_parser_db.grammars.let_defs
 849 let protected_binder_vars status =
 850   status#notation_parser_db.grammars.protected_binder_vars
 851
 852 (** {2 Debugging} *)
 853
 854 let print_l2_pattern status =
 855   Grammar.print_entry Format.std_formatter
 856     (Grammar.Entry.obj status#notation_parser_db.grammars.term);
 857   Format.pp_print_flush Format.std_formatter ();
 858   flush stdout
 859
 860 (* vim:set encoding=utf8 foldmethod=marker: *)