matita/components/content_pres/cicNotationParser.ml

   1 (* Copyright (C) 2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = NotationPt
  31 module Env = NotationEnv
  32
  33 exception Parse_error of string
  34 exception Level_not_found of int
  35
  36 let min_precedence = 0
  37 let max_precedence = 100
  38
  39 type ('a,'b,'c,'d) grammars = {
  40   level1_pattern: 'a Grammar.Entry.e;
  41   level2_ast: 'b Grammar.Entry.e;
  42   level2_ast_grammar : Grammar.g;
  43   term: 'b Grammar.Entry.e;
  44   let_defs: 'c Grammar.Entry.e;
  45   protected_binder_vars: 'd Grammar.Entry.e;
  46   level2_meta: 'b Grammar.Entry.e;
  47 }
  48
  49 type checked_l1_pattern = CL1P of NotationPt.term * int
  50
  51 let refresh_uri_in_checked_l1_pattern ~refresh_uri_in_term
  52      ~refresh_uri_in_reference (CL1P (t,n))
  53 =
  54  CL1P (NotationUtil.refresh_uri_in_term ~refresh_uri_in_term
  55  ~refresh_uri_in_reference t, n)
  56
  57 type binding =
  58   | NoBinding
  59   | Binding of string * Env.value_type
  60   | Env of (string * Env.value_type) list
  61
  62 type db = {
  63   grammars:
  64     (int -> NotationPt.term,
  65     Ast.term,
  66     (Ast.term Ast.capture_variable list *
  67       Ast.term Ast.capture_variable * Ast.term * int) list,
  68     Ast.term list * Ast.term option) grammars;
  69   keywords: string list;
  70   items: (string * Ast.term * (NotationEnv.t -> Ast.location -> Ast.term)) list
  71 }
  72
  73 let int_of_string s =
  74   try
  75     Pervasives.int_of_string s
  76   with Failure _ ->
  77     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
  78
  79 (** {2 Grammar extension} *)
  80
  81 let level_of precedence =
  82   if precedence < min_precedence || precedence > max_precedence then
  83     raise (Level_not_found precedence);
  84   string_of_int precedence
  85
  86 let gram_symbol s = Gramext.Stoken ("SYMBOL", s)
  87 let gram_ident s = Gramext.Stoken ("IDENT", s)
  88 let gram_number s = Gramext.Stoken ("NUMBER", s)
  89 let gram_keyword s = Gramext.Stoken ("", s)
  90 let gram_term status = function
  91   | Ast.Self _ -> Gramext.Sself
  92   | Ast.Level precedence ->
  93       Gramext.Snterml
  94         (Grammar.Entry.obj
  95           (status#notation_parser_db.grammars.term : 'a Grammar.Entry.e),
  96          level_of precedence)
  97 ;;
  98
  99 let gram_of_literal =
 100   function
 101   | `Symbol s -> gram_symbol s
 102   | `Keyword s -> gram_keyword s
 103   | `Number s -> gram_number s
 104
 105 let make_action action bindings =
 106   let rec aux (vl : NotationEnv.t) =
 107     function
 108       [] -> Gramext.action (fun (loc: Ast.location) -> action vl loc)
 109     | NoBinding :: tl -> Gramext.action (fun _ -> aux vl tl)
 110     (* LUCA: DEFCON 3 BEGIN *)
 111     | Binding (name, Env.TermType l) :: tl ->
 112         Gramext.action
 113           (fun (v:Ast.term) ->
 114             aux ((name, (Env.TermType l, Env.TermValue v))::vl) tl)
 115     | Binding (name, Env.StringType) :: tl ->
 116         Gramext.action
 117           (fun (v:string) ->
 118             aux ((name, (Env.StringType, Env.StringValue v)) :: vl) tl)
 119     | Binding (name, Env.NumType) :: tl ->
 120         Gramext.action
 121           (fun (v:string) ->
 122             aux ((name, (Env.NumType, Env.NumValue v)) :: vl) tl)
 123     | Binding (name, Env.OptType t) :: tl ->
 124         Gramext.action
 125           (fun (v:'a option) ->
 126             aux ((name, (Env.OptType t, Env.OptValue v)) :: vl) tl)
 127     | Binding (name, Env.ListType t) :: tl ->
 128         Gramext.action
 129           (fun (v:'a list) ->
 130             aux ((name, (Env.ListType t, Env.ListValue v)) :: vl) tl)
 131     | Env _ :: tl ->
 132         Gramext.action (fun (v:NotationEnv.t) -> aux (v @ vl) tl)
 133     (* LUCA: DEFCON 3 END *)
 134   in
 135     aux [] (List.rev bindings)
 136
 137 let flatten_opt =
 138   let rec aux acc =
 139     function
 140       [] -> List.rev acc
 141     | NoBinding :: tl -> aux acc tl
 142     | Env names :: tl -> aux (List.rev names @ acc) tl
 143     | Binding (name, ty) :: tl -> aux ((name, ty) :: acc) tl
 144   in
 145   aux []
 146
 147   (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
 148 let extract_term_production status pattern =
 149   let rec aux = function
 150     | Ast.AttributedTerm (_, t) -> aux t
 151     | Ast.Literal l -> aux_literal l
 152     | Ast.Layout l -> aux_layout l
 153     | Ast.Magic m -> aux_magic m
 154     | Ast.Variable v -> aux_variable v
 155     | t ->
 156         prerr_endline (NotationPp.pp_term t);
 157         assert false
 158   and aux_literal =
 159     function
 160     | `Symbol s -> [NoBinding, gram_symbol s]
 161     | `Keyword s ->
 162         (* assumption: s will be registered as a keyword with the lexer *)
 163         [NoBinding, gram_keyword s]
 164     | `Number s -> [NoBinding, gram_number s]
 165   and aux_layout = function
 166     | Ast.Sub (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sub "] @ aux p2
 167     | Ast.Sup (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sup "] @ aux p2
 168     | Ast.Below (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\below "] @ aux p2
 169     | Ast.Above (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\above "] @ aux p2
 170     | Ast.Frac (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\frac "] @ aux p2
 171     | Ast.InfRule (p1, p2, p3) -> [NoBinding, gram_symbol "\\infrule "] @ aux p1 @ aux p2 @ aux p3
 172     | Ast.Atop (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\atop "] @ aux p2
 173     | Ast.Over (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\over "] @ aux p2
 174     | Ast.Root (p1, p2) ->
 175         [NoBinding, gram_symbol "\\root "] @ aux p2
 176         @ [NoBinding, gram_symbol "\\of "] @ aux p1
 177     | Ast.Sqrt p -> [NoBinding, gram_symbol "\\sqrt "] @ aux p
 178     | Ast.Break -> []
 179     | Ast.Box (_, pl) -> List.flatten (List.map aux pl)
 180     | Ast.Group pl -> List.flatten (List.map aux pl)
 181     | Ast.Mstyle (_,pl) -> List.flatten (List.map aux pl)
 182     | Ast.Mpadded (_,pl) -> List.flatten (List.map aux pl)
 183     | Ast.Maction l -> List.flatten (List.map aux l)
 184   and aux_magic magic =
 185     match magic with
 186     | Ast.Opt p ->
 187         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 188         let action (env_opt : NotationEnv.t option) (loc : Ast.location) =
 189           match env_opt with
 190           | Some env -> List.map Env.opt_binding_some env
 191           | None -> List.map Env.opt_binding_of_name p_names
 192         in
 193         [ Env (List.map Env.opt_declaration p_names),
 194           Gramext.srules
 195             [ [ Gramext.Sopt (Gramext.srules [ p_atoms, p_action ]) ],
 196               Gramext.action action ] ]
 197     | Ast.List0 (p, _)
 198     | Ast.List1 (p, _) ->
 199         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
 200         let action (env_list : NotationEnv.t list) (loc : Ast.location) =
 201           NotationEnv.coalesce_env p_names env_list
 202         in
 203         let gram_of_list s =
 204           match magic with
 205           | Ast.List0 (_, None) -> Gramext.Slist0 s
 206           | Ast.List1 (_, None) -> Gramext.Slist1 s
 207           | Ast.List0 (_, Some l) -> Gramext.Slist0sep (s, gram_of_literal l)
 208           | Ast.List1 (_, Some l) -> Gramext.Slist1sep (s, gram_of_literal l)
 209           | _ -> assert false
 210         in
 211         [ Env (List.map Env.list_declaration p_names),
 212           Gramext.srules
 213             [ [ gram_of_list (Gramext.srules [ p_atoms, p_action ]) ],
 214               Gramext.action action ] ]
 215     | _ -> assert false
 216   and aux_variable =
 217     function
 218     | Ast.NumVar s -> [Binding (s, Env.NumType), gram_number ""]
 219     | Ast.TermVar (s,(Ast.Self level|Ast.Level level as lv)) ->
 220         [Binding (s, Env.TermType level), gram_term status lv]
 221     | Ast.IdentVar s -> [Binding (s, Env.StringType), gram_ident ""]
 222     | Ast.Ascription (p, s) -> assert false (* TODO *)
 223     | Ast.FreshVar _ -> assert false
 224   and inner_pattern p =
 225     let p_bindings, p_atoms = List.split (aux p) in
 226     let p_names = flatten_opt p_bindings in
 227     let action =
 228       make_action (fun (env : NotationEnv.t) (loc : Ast.location) -> env)
 229         p_bindings
 230     in
 231     p_bindings, p_atoms, p_names, action
 232   in
 233   aux pattern
 234
 235 type rule_id = Grammar.token Gramext.g_symbol list
 236
 237 let compare_rule_id x y =
 238   let rec aux = function
 239     | [],[] -> 0
 240     | [],_ -> ~-1
 241     | _,[] -> 1
 242     | ((s1::tl1) as x),((s2::tl2) as y) ->
 243         if Gramext.eq_symbol s1 s2 then aux (tl1,tl2)
 244         else Pervasives.compare x y
 245   in
 246     aux (x,y)
 247
 248
 249 let check_l1_pattern level1_pattern pponly level associativity =
 250   let variables = ref 0 in
 251   let symbols = ref 0 in
 252   let rec aux = function
 253     | Ast.AttributedTerm (att, t) -> Ast.AttributedTerm (att,aux t)
 254     | Ast.Literal _ as l -> incr symbols; l
 255     | Ast.Layout l -> Ast.Layout (aux_layout l)
 256     | Ast.Magic m -> Ast.Magic (aux_magic m)
 257     | Ast.Variable v -> (aux_variable v)
 258     | t -> assert false
 259   and aux_layout = function
 260     | Ast.Sub (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sub (p1, p2)
 261     | Ast.Sup (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sup (p1, p2)
 262     | Ast.Below (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Below (p1, p2)
 263     | Ast.Above (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Above (p1, p2)
 264     | Ast.Frac (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Frac (p1, p2)
 265     | Ast.InfRule (p1, p2, p3)  -> let p1 = aux p1 in let p2 = aux p2 in let p3 = aux p3 in Ast.InfRule (p1, p2, p3)
 266     | Ast.Atop (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Atop (p1, p2)
 267     | Ast.Over (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Over (p1, p2)
 268     | Ast.Root (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Root (p1, p2)
 269     | Ast.Sqrt p -> Ast.Sqrt (aux p)
 270     | Ast.Break as t -> t
 271     | Ast.Box (b, pl) -> Ast.Box(b, List.map aux pl)
 272     | Ast.Group pl -> Ast.Group (List.map aux pl)
 273     | Ast.Mstyle (l,pl) -> Ast.Mstyle (l, List.map aux pl)
 274     | Ast.Mpadded (l,pl) -> Ast.Mpadded (l, List.map aux pl)
 275     | Ast.Maction l as t ->
 276         if not pponly then
 277         raise(Parse_error("Maction can be used only in output notations"))
 278         else t
 279   and aux_magic magic =
 280     match magic with
 281     | Ast.Opt p -> Ast.Opt (aux p)
 282     | Ast.List0 (p, x) -> Ast.List0 (aux p, x)
 283     | Ast.List1 (p, x) -> Ast.List1 (aux p, x)
 284     | _ -> assert false
 285   and aux_variable =
 286     function
 287     | Ast.NumVar _ as t -> Ast.Variable t
 288     | Ast.TermVar (s,Ast.Self _) when associativity <> Gramext.NonA ->
 289         incr variables;
 290         if !variables > 2 then
 291           raise (Parse_error ("Exactly 2 variables must be specified in an "^
 292           "associative notation"));
 293         (match !variables, associativity with
 294         | 1,Gramext.LeftA ->
 295              Ast.Variable (Ast.TermVar (s, Ast.Self level))
 296         | 1,Gramext.RightA ->
 297              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 298         | 2,Gramext.LeftA ->
 299              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
 300         | 2,Gramext.RightA ->
 301              Ast.Variable (Ast.TermVar (s, Ast.Level (level-1)))
 302         | _ -> assert false)
 303     | Ast.TermVar (s,Ast.Level _) when associativity <> Gramext.NonA ->
 304           raise (Parse_error ("Variables can not be declared with a " ^
 305             "precedence in an associative notation"))
 306        (*avoid camlp5 divergence due to non-Sself recursion at the same level *)
 307     | Ast.TermVar (s,Ast.Level l) when l<=level && !variables=0 && !symbols=0->
 308        raise(Parse_error("Left recursive rule with precedence not greater " ^
 309         "than " ^ string_of_int level ^ " is not allowed to avoid divergence"))
 310     | Ast.TermVar _ as t -> incr variables; Ast.Variable t
 311     | Ast.IdentVar _ as t -> Ast.Variable t
 312     | Ast.Ascription _ -> assert false (* TODO *)
 313     | Ast.FreshVar _ -> assert false
 314   in
 315   if associativity <> Gramext.NonA && level = min_precedence then
 316     raise (Parse_error ("You can not specify an associative notation " ^
 317     "at level "^string_of_int min_precedence ^ "; increase it"));
 318   let cp = aux level1_pattern in
 319 (*   prerr_endline ("checked_pattern: " ^ NotationPp.pp_term cp); *)
 320   if !variables <> 2 && associativity <> Gramext.NonA then
 321     raise (Parse_error ("Exactly 2 variables must be specified in an "^
 322      "associative notation"));
 323   CL1P (cp,level)
 324 ;;
 325
 326 (** {2 Grammar} *)
 327
 328 let fold_cluster binder terms ty body =
 329   List.fold_right
 330     (fun term body -> Ast.Binder (binder, (term, ty), body))
 331     terms body  (* terms are names: either Ident or FreshVar *)
 332
 333 let fold_exists terms ty body =
 334   List.fold_right
 335     (fun term body ->
 336       let lambda = Ast.Binder (`Lambda, (term, ty), body) in
 337       Ast.Appl [ Ast.Symbol ("exists", 0); lambda ])
 338     terms body
 339
 340 let fold_binder binder pt_names body =
 341   List.fold_right
 342     (fun (names, ty) body -> fold_cluster binder names ty body)
 343     pt_names body
 344
 345 let return_term loc term = Ast.AttributedTerm (`Loc loc, term)
 346 let return_term_of_level loc term l =
 347   Ast.AttributedTerm (`Loc loc, term l)
 348
 349 (** {2 API implementation} *)
 350
 351 let exc_located_wrapper f =
 352   try
 353     f ()
 354   with
 355   | Stdpp.Exc_located (floc, Stream.Error msg) ->
 356       raise (HExtlib.Localized (floc, Parse_error msg))
 357   | Stdpp.Exc_located (floc, HExtlib.Localized (_,exn)) ->
 358       raise (HExtlib.Localized (floc, (Parse_error (Printexc.to_string exn))))
 359   | Stdpp.Exc_located (floc, exn) ->
 360       raise (HExtlib.Localized (floc, (Parse_error (Printexc.to_string exn))))
 361
 362 let parse_level1_pattern grammars precedence lexbuf =
 363   exc_located_wrapper
 364     (fun () -> Grammar.Entry.parse grammars.level1_pattern (Obj.magic lexbuf) precedence)
 365
 366 let parse_level2_ast grammars lexbuf =
 367   exc_located_wrapper
 368     (fun () -> Grammar.Entry.parse grammars.level2_ast (Obj.magic lexbuf))
 369
 370 let parse_level2_meta grammars lexbuf =
 371   exc_located_wrapper
 372     (fun () -> Grammar.Entry.parse grammars.level2_meta (Obj.magic lexbuf))
 373
 374 let parse_term grammars lexbuf =
 375   exc_located_wrapper
 376     (fun () -> (Grammar.Entry.parse grammars.term (Obj.magic lexbuf)))
 377
 378   (* create empty precedence level for "term" *)
 379 let initialize_grammars grammars =
 380   let dummy_action =
 381     Gramext.action (fun _ ->
 382       failwith "internal error, lexer generated a dummy token")
 383   in
 384   (* Needed since campl4 on "delete_rule" remove the precedence level if it gets
 385    * empty after the deletion. The lexer never generate the Stoken below. *)
 386   let dummy_prod = [ [ Gramext.Stoken ("DUMMY", "") ], dummy_action ] in
 387   let mk_level_list first last =
 388     let rec aux acc = function
 389       | i when i < first -> acc
 390       | i ->
 391           aux
 392             ((Some (level_of i), Some Gramext.NonA, dummy_prod)
 393              :: acc)
 394             (i - 1)
 395     in
 396     aux [] last
 397   in
 398   Grammar.extend
 399     [ Grammar.Entry.obj (grammars.term: 'a Grammar.Entry.e),
 400       None,
 401       mk_level_list min_precedence max_precedence ];
 402 (* {{{ Grammar for concrete syntax patterns, notation level 1 *)
 403   begin
 404   let level1_pattern = grammars.level1_pattern in
 405 EXTEND
 406   GLOBAL: level1_pattern;
 407
 408   level1_pattern: [
 409     [ p = l1_pattern; EOI -> fun l -> NotationUtil.boxify (p l) ]
 410   ];
 411   l1_pattern: [
 412     [ p = LIST1 l1_simple_pattern ->
 413         fun l -> List.map (fun x -> x l) p ]
 414   ];
 415   literal: [
 416     [ s = SYMBOL -> `Symbol s
 417     | k = QKEYWORD -> `Keyword k
 418     | n = NUMBER -> `Number n
 419     ]
 420   ];
 421   sep:       [ [ "sep";      sep = literal -> sep ] ];
 422   l1_magic_pattern: [
 423     [ "list0"; p = l1_simple_pattern; sep = OPT sep ->
 424             fun l -> Ast.List0 (p l, sep)
 425     | "list1"; p = l1_simple_pattern; sep = OPT sep ->
 426             fun l -> Ast.List1 (p l, sep)
 427     | "opt";   p = l1_simple_pattern -> fun l -> Ast.Opt (p l)
 428     ]
 429   ];
 430   l1_pattern_variable: [
 431     [ "term"; precedence = NUMBER; id = IDENT ->
 432         Ast.TermVar (id, Ast.Level (int_of_string precedence))
 433     | "number"; id = IDENT -> Ast.NumVar id
 434     | "ident"; id = IDENT -> Ast.IdentVar id
 435     ]
 436   ];
 437   mstyle: [
 438     [ id = IDENT;
 439       v = [ IDENT | NUMBER | COLOR | FLOATWITHUNIT ] -> id, v]];
 440   mpadded: [
 441     [ id = IDENT;
 442       v = [ PERCENTAGE ] -> id, v]];
 443   l1_simple_pattern:
 444     [ "layout" LEFTA
 445       [ p1 = SELF; SYMBOL "\\sub "; p2 = SELF ->
 446           return_term_of_level loc
 447             (fun l -> Ast.Layout (Ast.Sub (p1 l, p2 l)))
 448       | p1 = SELF; SYMBOL "\\sup "; p2 = SELF ->
 449           return_term_of_level loc
 450             (fun l -> Ast.Layout (Ast.Sup (p1 l, p2 l)))
 451       | p1 = SELF; SYMBOL "\\below "; p2 = SELF ->
 452           return_term_of_level loc
 453             (fun l -> Ast.Layout (Ast.Below (p1 l, p2 l)))
 454       | p1 = SELF; SYMBOL "\\above "; p2 = SELF ->
 455           return_term_of_level loc
 456             (fun l -> Ast.Layout (Ast.Above (p1 l, p2 l)))
 457       | p1 = SELF; SYMBOL "\\over "; p2 = SELF ->
 458           return_term_of_level loc
 459             (fun l -> Ast.Layout (Ast.Over (p1 l, p2 l)))
 460       | p1 = SELF; SYMBOL "\\atop "; p2 = SELF ->
 461           return_term_of_level loc
 462             (fun l -> Ast.Layout (Ast.Atop (p1 l, p2 l)))
 463       | p1 = SELF; SYMBOL "\\frac "; p2 = SELF ->
 464           return_term_of_level loc
 465             (fun l -> Ast.Layout (Ast.Frac (p1 l, p2 l)))
 466       | SYMBOL "\\infrule "; p1 = SELF; p2 = SELF; p3 = SELF ->
 467           return_term_of_level loc
 468             (fun l -> Ast.Layout (Ast.InfRule (p1 l, p2 l, p3 l)))
 469       | SYMBOL "\\sqrt "; p = SELF ->
 470           return_term_of_level loc (fun l -> Ast.Layout (Ast.Sqrt p l))
 471       | SYMBOL "\\root "; index = SELF; SYMBOL "\\of "; arg = SELF ->
 472           return_term_of_level loc
 473             (fun l -> Ast.Layout (Ast.Root (arg l, index l)))
 474       | "hbox"; LPAREN; p = l1_pattern; RPAREN ->
 475           return_term_of_level loc
 476             (fun l -> Ast.Layout (Ast.Box ((Ast.H, false, false), p l)))
 477       | "vbox"; LPAREN; p = l1_pattern; RPAREN ->
 478           return_term_of_level loc
 479             (fun l -> Ast.Layout (Ast.Box ((Ast.V, false, false), p l)))
 480       | "hvbox"; LPAREN; p = l1_pattern; RPAREN ->
 481           return_term_of_level loc
 482             (fun l -> Ast.Layout (Ast.Box ((Ast.HV, false, false), p l)))
 483       | "hovbox"; LPAREN; p = l1_pattern; RPAREN ->
 484           return_term_of_level loc
 485             (fun l -> Ast.Layout (Ast.Box ((Ast.HOV, false, false), p l)))
 486       | "break" -> return_term_of_level loc (fun _ -> Ast.Layout Ast.Break)
 487       | "mstyle"; m = LIST1 mstyle ; LPAREN; t = l1_pattern; RPAREN ->
 488           return_term_of_level loc
 489             (fun l ->
 490                Ast.Layout (Ast.Mstyle (m, t l)))
 491       | "mpadded"; m = LIST1 mpadded ; LPAREN; t = l1_pattern; RPAREN ->
 492           return_term_of_level loc
 493             (fun l ->
 494                Ast.Layout (Ast.Mpadded (m, t l)))
 495       | "maction"; m = LIST1 [ LPAREN; l = l1_pattern; RPAREN -> l ] ->
 496            return_term_of_level loc
 497             (fun l -> Ast.Layout (Ast.Maction (List.map (fun x ->
 498               NotationUtil.group (x l)) m)))
 499       | LPAREN; p = l1_pattern; RPAREN ->
 500           return_term_of_level loc (fun l -> NotationUtil.group (p l))
 501       ]
 502     | "simple" NONA
 503       [ i = IDENT ->
 504          return_term_of_level loc
 505            (fun l -> Ast.Variable (Ast.TermVar (i,Ast.Self l)))
 506       | m = l1_magic_pattern ->
 507              return_term_of_level loc (fun l -> Ast.Magic (m l))
 508       | v = l1_pattern_variable ->
 509              return_term_of_level loc (fun _ -> Ast.Variable v)
 510       | l = literal -> return_term_of_level loc (fun _ -> Ast.Literal l)
 511       ]
 512     ];
 513   END
 514   end;
 515 (* }}} *)
 516 (* {{{ Grammar for ast magics, notation level 2 *)
 517   begin
 518   let level2_meta = grammars.level2_meta in
 519 EXTEND
 520   GLOBAL: level2_meta;
 521   l2_variable: [
 522     [ "term"; precedence = NUMBER; id = IDENT ->
 523         Ast.TermVar (id,Ast.Level (int_of_string precedence))
 524     | "number"; id = IDENT -> Ast.NumVar id
 525     | "ident"; id = IDENT -> Ast.IdentVar id
 526     | "fresh"; id = IDENT -> Ast.FreshVar id
 527     | "anonymous" -> Ast.TermVar ("_",Ast.Self 0) (* is the level relevant?*)
 528     | id = IDENT -> Ast.TermVar (id,Ast.Self 0)
 529     ]
 530   ];
 531   l2_magic: [
 532     [ "fold"; kind = [ "left" -> `Left | "right" -> `Right ];
 533       base = level2_meta; "rec"; id = IDENT; recursive = level2_meta ->
 534         Ast.Fold (kind, base, [id], recursive)
 535     | "default"; some = level2_meta; none = level2_meta ->
 536         Ast.Default (some, none)
 537     | "if"; p_test = level2_meta;
 538       "then"; p_true = level2_meta;
 539       "else"; p_false = level2_meta ->
 540         Ast.If (p_test, p_true, p_false)
 541     | "fail" -> Ast.Fail
 542     ]
 543   ];
 544   level2_meta: [
 545     [ magic = l2_magic -> Ast.Magic magic
 546     | var = l2_variable -> Ast.Variable var
 547     | blob = UNPARSED_AST ->
 548         parse_level2_ast grammars (Ulexing.from_utf8_string blob)
 549     ]
 550   ];
 551 END
 552   end;
 553 (* }}} *)
 554 (* {{{ Grammar for ast patterns, notation level 2 *)
 555   begin
 556   let level2_ast = grammars.level2_ast in
 557   let term = grammars.term in
 558   let let_defs = grammars.let_defs in
 559   let protected_binder_vars = grammars.protected_binder_vars in
 560 EXTEND
 561   GLOBAL: level2_ast term let_defs protected_binder_vars;
 562   level2_ast: [ [ p = term -> p ] ];
 563   sort: [
 564     [ "Prop" -> `Prop
 565     | "Set" -> `Set
 566     | "Type"; SYMBOL "["; n = [ NUMBER| IDENT ]; SYMBOL "]" -> `NType n
 567     | "CProp"; SYMBOL "["; n = [ NUMBER| IDENT ]; SYMBOL "]" -> `NCProp n
 568     ]
 569   ];
 570   explicit_subst: [
 571     [ SYMBOL "\\subst ";  (* to avoid catching frequent "a [1]" cases *)
 572       SYMBOL "[";
 573       substs = LIST1 [
 574         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
 575       ] SEP SYMBOL ";";
 576       SYMBOL "]" ->
 577         substs
 578     ]
 579   ];
 580   meta_subst: [
 581     [ s = SYMBOL "_" -> None
 582     | p = term -> Some p ]
 583   ];
 584   meta_substs: [
 585     [ SYMBOL "["; substs = LIST0 meta_subst; SYMBOL "]" -> substs ]
 586   ];
 587   possibly_typed_name: [
 588     [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 589         id, Some typ
 590     | arg = single_arg -> arg, None
 591     | id = PIDENT -> Ast.Ident (id, None), None
 592     | SYMBOL "_" -> Ast.Ident ("_", None), None
 593     | LPAREN; id = PIDENT; SYMBOL ":"; typ = term; RPAREN ->
 594         Ast.Ident (id, None), Some typ
 595     | LPAREN; SYMBOL "_"; SYMBOL ":"; typ = term; RPAREN ->
 596         Ast.Ident ("_", None), Some typ
 597     ]
 598   ];
 599   match_pattern: [
 600     [ SYMBOL "_" -> Ast.Wildcard
 601     | id = IDENT -> Ast.Pattern (id, None, [])
 602     | LPAREN; id = IDENT; vars = LIST1 possibly_typed_name; RPAREN ->
 603        Ast.Pattern (id, None, vars)
 604     | id = IDENT; vars = LIST1 possibly_typed_name ->
 605        Ast.Pattern (id, None, vars)
 606     ]
 607   ];
 608   binder: [
 609     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
 610     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
 611     | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
 612     ]
 613   ];
 614   arg: [
 615     [ LPAREN; names = LIST1 IDENT SEP SYMBOL ",";
 616       SYMBOL ":"; ty = term; RPAREN ->
 617         List.map (fun n -> Ast.Ident (n, None)) names, Some ty
 618     | name = IDENT -> [Ast.Ident (name, None)], None
 619     | blob = UNPARSED_META ->
 620         let meta = parse_level2_meta grammars (Ulexing.from_utf8_string blob) in
 621         match meta with
 622         | Ast.Variable (Ast.FreshVar _) -> [meta], None
 623         | Ast.Variable (Ast.TermVar ("_",_)) -> [Ast.Ident ("_", None)], None
 624         | _ -> failwith "Invalid bound name."
 625    ]
 626   ];
 627   single_arg: [
 628     [ name = IDENT -> Ast.Ident (name, None)
 629     | blob = UNPARSED_META ->
 630         let meta = parse_level2_meta grammars (Ulexing.from_utf8_string blob) in
 631         match meta with
 632         | Ast.Variable (Ast.FreshVar _)
 633         | Ast.Variable (Ast.IdentVar _) -> meta
 634         | Ast.Variable (Ast.TermVar ("_",_)) -> Ast.Ident ("_", None)
 635         | _ -> failwith "Invalid index name."
 636     ]
 637   ];
 638   let_defs: [
 639     [ defs = LIST1 [
 640         name = single_arg;
 641         args = LIST1 arg;
 642         index_name = OPT [ "on"; id = single_arg -> id ];
 643         ty = OPT [ SYMBOL ":" ; p = term -> p ];
 644         SYMBOL <:unicode<def>> (* ≝ *); body = term ->
 645           let rec position_of name p = function
 646             | [] -> None, p
 647             | n :: _ when n = name -> Some p, p
 648             | _ :: tl -> position_of name (p + 1) tl
 649           in
 650           let rec find_arg name n = function
 651             | [] ->
 652                 Ast.fail loc (sprintf "Argument %s not found"
 653                   (NotationPp.pp_term name))
 654             | (l,_) :: tl ->
 655                 (match position_of name 0 l with
 656                 | None, len -> find_arg name (n + len) tl
 657                 | Some where, len -> n + where)
 658           in
 659           let index =
 660             match index_name with
 661             | None -> 0
 662             | Some index_name -> find_arg index_name 0 args
 663           in
 664           let args =
 665            List.concat
 666             (List.map
 667              (function (names,ty) -> List.map (function x -> x,ty) names
 668              ) args)
 669           in
 670            args, (name, ty), body, index
 671       ] SEP "and" ->
 672         defs
 673     ]
 674   ];
 675   binder_vars: [
 676     [ vars = [ l =
 677         [ l = LIST1 single_arg SEP SYMBOL "," -> l
 678         | l = LIST1 [ PIDENT | SYMBOL "_" ] SEP SYMBOL "," ->
 679             List.map (fun x -> Ast.Ident(x,None)) l
 680       ] -> l ];
 681       typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
 682     ]
 683   ];
 684   protected_binder_vars: [
 685     [ LPAREN; vars = binder_vars; RPAREN -> vars
 686     ]
 687   ];
 688   maybe_protected_binder_vars: [
 689     [ vars = binder_vars -> vars
 690     | vars = protected_binder_vars -> vars
 691     ]
 692   ];
 693   term: LEVEL "10"
 694   [
 695     [ "let";
 696      var =
 697       [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
 698           id, Some typ
 699       | id = IDENT; ty = OPT [ SYMBOL ":"; typ = term -> typ] ->
 700           Ast.Ident(id,None), ty ];
 701       SYMBOL <:unicode<def>> (* ≝ *);
 702       p1 = term; "in"; p2 = term ->
 703         return_term loc (Ast.LetIn (var, p1, p2))
 704     | LETCOREC; defs = let_defs; "in";
 705       body = term ->
 706         return_term loc (Ast.LetRec (`CoInductive, defs, body))
 707     | LETREC; defs = let_defs; "in";
 708       body = term ->
 709         return_term loc (Ast.LetRec (`Inductive, defs, body))
 710     ]
 711   ];
 712   term: LEVEL "20"
 713     [
 714       [ b = binder; (vars, typ) = maybe_protected_binder_vars; SYMBOL "."; body = term LEVEL "19" ->
 715           return_term loc (fold_cluster b vars typ body)
 716       ]
 717     ];
 718   term: LEVEL "70"
 719     [
 720       [ p1 = term; p2 = term LEVEL "71" ->
 721           let rec aux = function
 722             | Ast.Appl (hd :: tl)
 723             | Ast.AttributedTerm (_, Ast.Appl (hd :: tl)) ->
 724                 aux hd @ tl
 725             | term -> [term]
 726           in
 727           return_term loc (Ast.Appl (aux p1 @ [p2]))
 728       ]
 729     ];
 730   term: LEVEL "90"
 731     [
 732       [ id = IDENT -> return_term loc (Ast.Ident (id, None))
 733       | id = IDENT; s = explicit_subst ->
 734           return_term loc (Ast.Ident (id, Some s))
 735       | s = CSYMBOL -> return_term loc (Ast.Symbol (s, 0))
 736       | u = URI -> return_term loc (Ast.Uri (u, None))
 737       | r = NREF -> return_term loc (Ast.NRef (NReference.reference_of_string r))
 738       | n = NUMBER -> return_term loc (Ast.Num (n, 0))
 739       | IMPLICIT -> return_term loc (Ast.Implicit `JustOne)
 740       | SYMBOL <:unicode<ldots>> -> return_term loc (Ast.Implicit `Vector)
 741       | PLACEHOLDER -> return_term loc Ast.UserInput
 742       | m = META -> return_term loc (Ast.Meta (int_of_string m, []))
 743       | m = META; s = meta_substs ->
 744           return_term loc (Ast.Meta (int_of_string m, s))
 745       | s = sort -> return_term loc (Ast.Sort s)
 746       | "match"; t = term;
 747         indty_ident = OPT [ "in"; id = IDENT -> id, None ];
 748         outtyp = OPT [ "return"; ty = term -> ty ];
 749         "with"; SYMBOL "[";
 750         patterns = LIST0 [
 751           lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
 752           rhs = term ->
 753             lhs, rhs
 754         ] SEP SYMBOL "|";
 755         SYMBOL "]" ->
 756           return_term loc (Ast.Case (t, indty_ident, outtyp, patterns))
 757       | LPAREN; p1 = term; SYMBOL ":"; p2 = term; RPAREN ->
 758           return_term loc (Ast.Cast (p1, p2))
 759       | LPAREN; p = term; RPAREN -> p
 760       | blob = UNPARSED_META ->
 761           parse_level2_meta grammars (Ulexing.from_utf8_string blob)
 762       ]
 763     ];
 764 END
 765   end;
 766 (* }}} *)
 767   grammars
 768 ;;
 769
 770 let initial_grammars keywords =
 771   let lexers = CicNotationLexer.mk_lexers keywords in
 772   let level1_pattern_grammar =
 773     Grammar.gcreate lexers.CicNotationLexer.level1_pattern_lexer in
 774   let level2_ast_grammar =
 775     Grammar.gcreate lexers.CicNotationLexer.level2_ast_lexer in
 776   let level2_meta_grammar =
 777     Grammar.gcreate lexers.CicNotationLexer.level2_meta_lexer in
 778   let level1_pattern =
 779     Grammar.Entry.create level1_pattern_grammar "level1_pattern" in
 780   let level2_ast = Grammar.Entry.create level2_ast_grammar "level2_ast" in
 781   let term = Grammar.Entry.create level2_ast_grammar "term" in
 782   let let_defs = Grammar.Entry.create level2_ast_grammar "let_defs" in
 783   let protected_binder_vars =
 784     Grammar.Entry.create level2_ast_grammar "protected_binder_vars" in
 785   let level2_meta = Grammar.Entry.create level2_meta_grammar "level2_meta" in
 786   initialize_grammars { level1_pattern=level1_pattern;
 787     level2_ast=level2_ast;
 788     term=term;
 789     let_defs=let_defs;
 790     protected_binder_vars=protected_binder_vars;
 791     level2_meta=level2_meta;
 792     level2_ast_grammar=level2_ast_grammar;
 793   }
 794 ;;
 795
 796 class type g_status =
 797  object
 798   method notation_parser_db: db
 799  end
 800
 801 class status ~keywords:kwds =
 802  object
 803   val db = { grammars = initial_grammars kwds; keywords = kwds; items = [] }
 804   method notation_parser_db = db
 805   method set_notation_parser_db v = {< db = v >}
 806   method set_notation_parser_status
 807    : 'status. #g_status as 'status -> 'self
 808    = fun o -> {< db = o#notation_parser_db >}
 809  end
 810
 811 let extend (status : #status) (CL1P (level1_pattern,precedence)) action =
 812         (* move inside constructor XXX *)
 813   let add1item status (level, level1_pattern, action) =
 814     let p_bindings, p_atoms =
 815       List.split (extract_term_production status level1_pattern) in
 816     Grammar.extend
 817       [ Grammar.Entry.obj
 818         (status#notation_parser_db.grammars.term : 'a Grammar.Entry.e),
 819         Some (Gramext.Level level),
 820         [ None,
 821           Some (*Gramext.NonA*) Gramext.NonA,
 822           [ p_atoms,
 823             (make_action
 824               (fun (env: NotationEnv.t) (loc: Ast.location) ->
 825                 (action env loc))
 826             p_bindings) ]]];
 827     status
 828   in
 829   let current_item =
 830     let level = level_of precedence in
 831     level, level1_pattern, action in
 832   let keywords = NotationUtil.keywords_of_term level1_pattern @
 833     status#notation_parser_db.keywords in
 834   let items = current_item :: status#notation_parser_db.items in
 835   let status = status#set_notation_parser_status (new status ~keywords) in
 836   let status = status#set_notation_parser_db
 837     {status#notation_parser_db with items = items} in
 838   List.fold_left add1item status items
 839 ;;
 840
 841
 842 let parse_level1_pattern status =
 843   parse_level1_pattern status#notation_parser_db.grammars
 844 let parse_level2_ast status =
 845   parse_level2_ast status#notation_parser_db.grammars
 846 let parse_level2_meta status =
 847   parse_level2_meta status#notation_parser_db.grammars
 848 let parse_term status =
 849   parse_term status#notation_parser_db.grammars
 850
 851 let level2_ast_grammar status =
 852   status#notation_parser_db.grammars.level2_ast_grammar
 853 let term status = status#notation_parser_db.grammars.term
 854 let let_defs status = status#notation_parser_db.grammars.let_defs
 855 let protected_binder_vars status =
 856   status#notation_parser_db.grammars.protected_binder_vars
 857
 858 (** {2 Debugging} *)
 859
 860 let print_l2_pattern status =
 861   Grammar.print_entry Format.std_formatter
 862     (Grammar.Entry.obj status#notation_parser_db.grammars.term);
 863   Format.pp_print_flush Format.std_formatter ();
 864   flush stdout
 865
 866 (* vim:set encoding=utf8 foldmethod=marker: *)