]> matita.cs.unibo.it Git - helm.git/blob - matita/components/content_pres/cicNotationParser.ml
It is now possible to pass a ${ident x} to another previously defined
[helm.git] / matita / components / content_pres / cicNotationParser.ml
1 (* Copyright (C) 2005, HELM Team.
2  * 
3  * This file is part of HELM, an Hypertextual, Electronic
4  * Library of Mathematics, developed at the Computer Science
5  * Department, University of Bologna, Italy.
6  * 
7  * HELM is free software; you can redistribute it and/or
8  * modify it under the terms of the GNU General Public License
9  * as published by the Free Software Foundation; either version 2
10  * of the License, or (at your option) any later version.
11  * 
12  * HELM is distributed in the hope that it will be useful,
13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
15  * GNU General Public License for more details.
16  *
17  * You should have received a copy of the GNU General Public License
18  * along with HELM; if not, write to the Free Software
19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
20  * MA  02111-1307, USA.
21  * 
22  * For details, see the HELM World-Wide-Web page,
23  * http://helm.cs.unibo.it/
24  *)
25
26 (* $Id$ *)
27
28 open Printf
29
30 module Ast = NotationPt
31 module Env = NotationEnv
32
33 exception Parse_error of string
34 exception Level_not_found of int
35
36 let min_precedence = 0
37 let max_precedence = 100
38
39 type ('a,'b,'c,'d,'e) grammars = {
40   level1_pattern: 'a Grammar.Entry.e;
41   level2_ast: 'b Grammar.Entry.e;
42   level2_ast_grammar : Grammar.g;
43   term: 'b Grammar.Entry.e;
44   ident: 'e Grammar.Entry.e;
45   let_defs: 'c Grammar.Entry.e;
46   protected_binder_vars: 'd Grammar.Entry.e;
47   level2_meta: 'b Grammar.Entry.e;
48 }
49
50 type checked_l1_pattern = CL1P of NotationPt.term * int
51
52 let refresh_uri_in_checked_l1_pattern ~refresh_uri_in_term
53      ~refresh_uri_in_reference (CL1P (t,n))
54 =
55  CL1P (NotationUtil.refresh_uri_in_term ~refresh_uri_in_term
56  ~refresh_uri_in_reference t, n)
57
58 type binding =
59   | NoBinding
60   | Binding of string * Env.value_type
61   | Env of (string * Env.value_type) list
62
63 type db = {
64   grammars: 
65     (int -> NotationPt.term, 
66     Ast.term,
67     (Ast.term Ast.capture_variable list *
68       Ast.term Ast.capture_variable * Ast.term * int) list, 
69     Ast.term list * Ast.term option, Env.ident_or_var) grammars;
70   keywords: string list;
71   items: (string * Ast.term * (NotationEnv.t -> Ast.location -> Ast.term)) list
72 }
73
74 let int_of_string s =
75   try
76     Pervasives.int_of_string s
77   with Failure _ ->
78     failwith (sprintf "Lexer failure: string_of_int \"%s\" failed" s)
79
80 (** {2 Grammar extension} *)
81
82 let level_of precedence =
83   if precedence < min_precedence || precedence > max_precedence then
84     raise (Level_not_found precedence);
85   string_of_int precedence 
86
87 let gram_symbol s = Gramext.Stoken ("SYMBOL", s)
88 let gram_ident status =
89  Gramext.Snterm (Grammar.Entry.obj
90   (status#notation_parser_db.grammars.ident : 'a Grammar.Entry.e))
91   (*Gramext.Stoken ("IDENT", s)*)
92 let gram_number s = Gramext.Stoken ("NUMBER", s)
93 let gram_keyword s = Gramext.Stoken ("", s)
94 let gram_term status = function
95   | Ast.Self _ -> Gramext.Sself
96   | Ast.Level precedence ->
97       Gramext.Snterml 
98         (Grammar.Entry.obj 
99           (status#notation_parser_db.grammars.term : 'a Grammar.Entry.e), 
100          level_of precedence)
101 ;;
102
103 let gram_of_literal =
104   function
105   | `Symbol s -> gram_symbol s
106   | `Keyword s -> gram_keyword s
107   | `Number s -> gram_number s
108
109 let make_action action bindings =
110   let rec aux (vl : NotationEnv.t) =
111     function
112       [] -> Gramext.action (fun (loc: Ast.location) -> action vl loc)
113     | NoBinding :: tl -> Gramext.action (fun _ -> aux vl tl)
114     (* LUCA: DEFCON 3 BEGIN *)
115     | Binding (name, Env.TermType l) :: tl ->
116         Gramext.action
117           (fun (v:Ast.term) ->
118             aux ((name, (Env.TermType l, Env.TermValue v))::vl) tl)
119     | Binding (name, Env.StringType) :: tl ->
120         Gramext.action
121           (fun (v:Env.ident_or_var) ->
122             aux ((name, (Env.StringType, Env.StringValue v)) :: vl) tl)
123     | Binding (name, Env.NumType) :: tl ->
124         Gramext.action
125           (fun (v:string) ->
126             aux ((name, (Env.NumType, Env.NumValue v)) :: vl) tl)
127     | Binding (name, Env.OptType t) :: tl ->
128         Gramext.action
129           (fun (v:'a option) ->
130             aux ((name, (Env.OptType t, Env.OptValue v)) :: vl) tl)
131     | Binding (name, Env.ListType t) :: tl ->
132         Gramext.action
133           (fun (v:'a list) ->
134             aux ((name, (Env.ListType t, Env.ListValue v)) :: vl) tl)
135     | Env _ :: tl ->
136         Gramext.action (fun (v:NotationEnv.t) -> aux (v @ vl) tl)
137     (* LUCA: DEFCON 3 END *)
138   in
139     aux [] (List.rev bindings)
140
141 let flatten_opt =
142   let rec aux acc =
143     function
144       [] -> List.rev acc
145     | NoBinding :: tl -> aux acc tl
146     | Env names :: tl -> aux (List.rev names @ acc) tl
147     | Binding (name, ty) :: tl -> aux ((name, ty) :: acc) tl
148   in
149   aux []
150
151   (* given a level 1 pattern computes the new RHS of "term" grammar entry *)
152 let extract_term_production status pattern =
153   let rec aux = function
154     | Ast.AttributedTerm (_, t) -> aux t
155     | Ast.Literal l -> aux_literal l
156     | Ast.Layout l -> aux_layout l
157     | Ast.Magic m -> aux_magic m
158     | Ast.Variable v -> aux_variable v
159     | t ->
160         prerr_endline (NotationPp.pp_term t);
161         assert false
162   and aux_literal =
163     function
164     | `Symbol s -> [NoBinding, gram_symbol s]
165     | `Keyword s ->
166         (* assumption: s will be registered as a keyword with the lexer *)
167         [NoBinding, gram_keyword s]
168     | `Number s -> [NoBinding, gram_number s]
169   and aux_layout = function
170     | Ast.Sub (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sub "] @ aux p2
171     | Ast.Sup (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\sup "] @ aux p2
172     | Ast.Below (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\below "] @ aux p2
173     | Ast.Above (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\above "] @ aux p2
174     | Ast.Frac (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\frac "] @ aux p2
175     | Ast.InfRule (p1, p2, p3) -> [NoBinding, gram_symbol "\\infrule "] @ aux p1 @ aux p2 @ aux p3
176     | Ast.Atop (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\atop "] @ aux p2
177     | Ast.Over (p1, p2) -> aux p1 @ [NoBinding, gram_symbol "\\over "] @ aux p2
178     | Ast.Root (p1, p2) ->
179         [NoBinding, gram_symbol "\\root "] @ aux p2
180         @ [NoBinding, gram_symbol "\\of "] @ aux p1
181     | Ast.Sqrt p -> [NoBinding, gram_symbol "\\sqrt "] @ aux p
182     | Ast.Break -> []
183     | Ast.Box (_, pl) -> List.flatten (List.map aux pl)
184     | Ast.Group pl -> List.flatten (List.map aux pl)
185     | Ast.Mstyle (_,pl) -> List.flatten (List.map aux pl)
186     | Ast.Mpadded (_,pl) -> List.flatten (List.map aux pl)
187     | Ast.Maction l -> List.flatten (List.map aux l)
188   and aux_magic magic =
189     match magic with
190     | Ast.Opt p ->
191         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
192         let action (env_opt : NotationEnv.t option) (loc : Ast.location) =
193           match env_opt with
194           | Some env -> List.map Env.opt_binding_some env
195           | None -> List.map Env.opt_binding_of_name p_names
196         in
197         [ Env (List.map Env.opt_declaration p_names),
198           Gramext.srules
199             [ [ Gramext.Sopt (Gramext.srules [ p_atoms, p_action ]) ],
200               Gramext.action action ] ]
201     | Ast.List0 (p, _)
202     | Ast.List1 (p, _) ->
203         let p_bindings, p_atoms, p_names, p_action = inner_pattern p in
204         let action (env_list : NotationEnv.t list) (loc : Ast.location) =
205           NotationEnv.coalesce_env p_names env_list
206         in
207         let gram_of_list s =
208           match magic with
209           | Ast.List0 (_, None) -> Gramext.Slist0 s
210           | Ast.List1 (_, None) -> Gramext.Slist1 s
211           | Ast.List0 (_, Some l) -> Gramext.Slist0sep (s, gram_of_literal l)
212           | Ast.List1 (_, Some l) -> Gramext.Slist1sep (s, gram_of_literal l)
213           | _ -> assert false
214         in
215         [ Env (List.map Env.list_declaration p_names),
216           Gramext.srules
217             [ [ gram_of_list (Gramext.srules [ p_atoms, p_action ]) ],
218               Gramext.action action ] ]
219     | _ -> assert false
220   and aux_variable =
221     function
222     | Ast.NumVar s -> [Binding (s, Env.NumType), gram_number ""]
223     | Ast.TermVar (s,(Ast.Self level|Ast.Level level as lv)) -> 
224         [Binding (s, Env.TermType level), gram_term status lv]
225     | Ast.IdentVar s -> [Binding (s, Env.StringType), gram_ident status]
226     | Ast.Ascription (p, s) -> assert false (* TODO *)
227     | Ast.FreshVar _ -> assert false
228   and inner_pattern p =
229     let p_bindings, p_atoms = List.split (aux p) in
230     let p_names = flatten_opt p_bindings in
231     let action =
232       make_action (fun (env : NotationEnv.t) (loc : Ast.location) -> env)
233         p_bindings
234     in
235     p_bindings, p_atoms, p_names, action
236   in
237   aux pattern
238
239 type rule_id = Grammar.token Gramext.g_symbol list
240
241 let compare_rule_id x y =
242   let rec aux = function
243     | [],[] -> 0
244     | [],_ -> ~-1
245     | _,[] -> 1
246     | ((s1::tl1) as x),((s2::tl2) as y) ->
247         if Gramext.eq_symbol s1 s2 then aux (tl1,tl2)
248         else Pervasives.compare x y 
249   in
250     aux (x,y)
251
252
253 let check_l1_pattern level1_pattern pponly level associativity =
254   let variables = ref 0 in
255   let symbols = ref 0 in
256   let rec aux = function
257     | Ast.AttributedTerm (att, t) -> Ast.AttributedTerm (att,aux t)
258     | Ast.Literal _ as l -> incr symbols; l
259     | Ast.Layout l -> Ast.Layout (aux_layout l)
260     | Ast.Magic m -> Ast.Magic (aux_magic m)
261     | Ast.Variable v -> (aux_variable v)
262     | t -> assert false
263   and aux_layout = function
264     | Ast.Sub (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sub (p1, p2)
265     | Ast.Sup (p1, p2)   -> let p1 = aux p1 in let p2 = aux p2 in Ast.Sup (p1, p2)
266     | Ast.Below (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Below (p1, p2)
267     | Ast.Above (p1, p2) -> let p1 = aux p1 in let p2 = aux p2 in Ast.Above (p1, p2)
268     | Ast.Frac (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Frac (p1, p2)
269     | Ast.InfRule (p1, p2, p3)  -> let p1 = aux p1 in let p2 = aux p2 in let p3 = aux p3 in Ast.InfRule (p1, p2, p3)
270     | Ast.Atop (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Atop (p1, p2)
271     | Ast.Over (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Over (p1, p2)
272     | Ast.Root (p1, p2)  -> let p1 = aux p1 in let p2 = aux p2 in Ast.Root (p1, p2)
273     | Ast.Sqrt p -> Ast.Sqrt (aux p)
274     | Ast.Break as t -> t 
275     | Ast.Box (b, pl) -> Ast.Box(b, List.map aux pl)
276     | Ast.Group pl -> Ast.Group (List.map aux pl)
277     | Ast.Mstyle (l,pl) -> Ast.Mstyle (l, List.map aux pl)
278     | Ast.Mpadded (l,pl) -> Ast.Mpadded (l, List.map aux pl)
279     | Ast.Maction l as t -> 
280         if not pponly then 
281         raise(Parse_error("Maction can be used only in output notations")) 
282         else t
283   and aux_magic magic =
284     match magic with
285     | Ast.Opt p -> Ast.Opt (aux p)
286     | Ast.List0 (p, x) -> Ast.List0 (aux p, x)
287     | Ast.List1 (p, x) -> Ast.List1 (aux p, x)
288     | _ -> assert false
289   and aux_variable =
290     function
291     | Ast.NumVar _ as t -> Ast.Variable t
292     | Ast.TermVar (s,Ast.Self _) when associativity <> Gramext.NonA -> 
293         incr variables; 
294         if !variables > 2 then
295           raise (Parse_error ("Exactly 2 variables must be specified in an "^
296           "associative notation"));
297         (match !variables, associativity with
298         | 1,Gramext.LeftA -> 
299              Ast.Variable (Ast.TermVar (s, Ast.Self level))
300         | 1,Gramext.RightA -> 
301              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
302         | 2,Gramext.LeftA ->
303              Ast.Variable (Ast.TermVar (s, Ast.Self (level+1)))
304         | 2,Gramext.RightA -> 
305              Ast.Variable (Ast.TermVar (s, Ast.Level (level-1)))
306         | _ -> assert false)
307     | Ast.TermVar (s,Ast.Level _) when associativity <> Gramext.NonA -> 
308           raise (Parse_error ("Variables can not be declared with a " ^ 
309             "precedence in an associative notation"))
310        (*avoid camlp5 divergence due to non-Sself recursion at the same level *)
311     | Ast.TermVar (s,Ast.Level l) when l<=level && !variables=0 && !symbols=0-> 
312        raise(Parse_error("Left recursive rule with precedence not greater " ^
313         "than " ^ string_of_int level ^ " is not allowed to avoid divergence"))
314     | Ast.TermVar _ as t -> incr variables; Ast.Variable t
315     | Ast.IdentVar _ as t -> Ast.Variable t
316     | Ast.Ascription _ -> assert false (* TODO *)
317     | Ast.FreshVar _ -> assert false
318   in
319   if associativity <> Gramext.NonA && level = min_precedence then
320     raise (Parse_error ("You can not specify an associative notation " ^
321     "at level "^string_of_int min_precedence ^ "; increase it"));
322   let cp = aux level1_pattern in
323 (*   prerr_endline ("checked_pattern: " ^ NotationPp.pp_term cp); *)
324   if !variables <> 2 && associativity <> Gramext.NonA then
325     raise (Parse_error ("Exactly 2 variables must be specified in an "^
326      "associative notation"));
327   CL1P (cp,level)
328 ;;
329
330 (** {2 Grammar} *)
331
332 let fold_cluster binder terms ty body =
333   List.fold_right
334     (fun term body -> Ast.Binder (binder, (term, ty), body))
335     terms body  (* terms are names: either Ident or FreshVar *)
336
337 let fold_exists terms ty body =
338   List.fold_right
339     (fun term body ->
340       let lambda = Ast.Binder (`Lambda, (term, ty), body) in
341       Ast.Appl [ Ast.Symbol ("exists", 0); lambda ])
342     terms body
343
344 let fold_binder binder pt_names body =
345   List.fold_right
346     (fun (names, ty) body -> fold_cluster binder names ty body)
347     pt_names body
348
349 let return_term loc term = Ast.AttributedTerm (`Loc loc, term)
350 let return_term_of_level loc term l = 
351   Ast.AttributedTerm (`Loc loc, term l)
352
353 (** {2 API implementation} *)
354
355 let exc_located_wrapper f =
356   try
357     f ()
358   with
359   | Stdpp.Exc_located (floc, Stream.Error msg) ->
360       raise (HExtlib.Localized (floc, Parse_error msg))
361   | Stdpp.Exc_located (floc, HExtlib.Localized (_,exn)) ->
362       raise (HExtlib.Localized (floc, (Parse_error (Printexc.to_string exn))))
363   | Stdpp.Exc_located (floc, exn) ->
364       raise (HExtlib.Localized (floc, (Parse_error (Printexc.to_string exn))))
365
366 let parse_level1_pattern grammars precedence lexbuf =
367   exc_located_wrapper
368     (fun () -> Grammar.Entry.parse grammars.level1_pattern (Obj.magic lexbuf) precedence)
369
370 let parse_level2_ast grammars lexbuf =
371   exc_located_wrapper
372     (fun () -> Grammar.Entry.parse grammars.level2_ast (Obj.magic lexbuf))
373
374 let parse_level2_meta grammars lexbuf =
375   exc_located_wrapper
376     (fun () -> Grammar.Entry.parse grammars.level2_meta (Obj.magic lexbuf))
377
378 let parse_term grammars lexbuf =
379   exc_located_wrapper
380     (fun () -> (Grammar.Entry.parse grammars.term (Obj.magic lexbuf)))
381
382   (* create empty precedence level for "term" *)
383 let initialize_grammars grammars =
384   let dummy_action =
385     Gramext.action (fun _ ->
386       failwith "internal error, lexer generated a dummy token")
387   in
388   (* Needed since campl4 on "delete_rule" remove the precedence level if it gets
389    * empty after the deletion. The lexer never generate the Stoken below. *)
390   let dummy_prod = [ [ Gramext.Stoken ("DUMMY", "") ], dummy_action ] in
391   let mk_level_list first last =
392     let rec aux acc = function
393       | i when i < first -> acc
394       | i ->
395           aux
396             ((Some (level_of i), Some Gramext.NonA, dummy_prod)
397              :: acc)
398             (i - 1)
399     in
400     aux [] last
401   in
402   Grammar.extend
403     [ Grammar.Entry.obj (grammars.term: 'a Grammar.Entry.e),
404       None,
405       mk_level_list min_precedence max_precedence ];
406 (* {{{ Grammar for concrete syntax patterns, notation level 1 *)
407   begin
408   let level1_pattern = grammars.level1_pattern in
409 EXTEND
410   GLOBAL: level1_pattern;
411
412   level1_pattern: [ 
413     [ p = l1_pattern; EOI -> fun l -> NotationUtil.boxify (p l) ] 
414   ];
415   l1_pattern: [ 
416     [ p = LIST1 l1_simple_pattern -> 
417         fun l -> List.map (fun x -> x l) p ] 
418   ];
419   literal: [
420     [ s = SYMBOL -> `Symbol s
421     | k = QKEYWORD -> `Keyword k
422     | n = NUMBER -> `Number n
423     ]
424   ];
425   sep:       [ [ "sep";      sep = literal -> sep ] ];
426   l1_magic_pattern: [
427     [ "list0"; p = l1_simple_pattern; sep = OPT sep -> 
428             fun l -> Ast.List0 (p l, sep)
429     | "list1"; p = l1_simple_pattern; sep = OPT sep -> 
430             fun l -> Ast.List1 (p l, sep)
431     | "opt";   p = l1_simple_pattern -> fun l -> Ast.Opt (p l)
432     ]
433   ];
434   l1_pattern_variable: [
435     [ "term"; precedence = NUMBER; id = IDENT -> 
436         Ast.TermVar (id, Ast.Level (int_of_string precedence))
437     | "number"; id = IDENT -> Ast.NumVar id
438     | "ident"; id = IDENT -> Ast.IdentVar id
439     ]
440   ];
441   mstyle: [ 
442     [ id = IDENT; 
443       v = [ IDENT | NUMBER | COLOR | FLOATWITHUNIT ] -> id, v]];
444   mpadded: [ 
445     [ id = IDENT; 
446       v = [ PERCENTAGE ] -> id, v]];
447   l1_simple_pattern:
448     [ "layout" LEFTA
449       [ p1 = SELF; SYMBOL "\\sub "; p2 = SELF ->
450           return_term_of_level loc 
451             (fun l -> Ast.Layout (Ast.Sub (p1 l, p2 l)))
452       | p1 = SELF; SYMBOL "\\sup "; p2 = SELF ->
453           return_term_of_level loc 
454             (fun l -> Ast.Layout (Ast.Sup (p1 l, p2 l)))
455       | p1 = SELF; SYMBOL "\\below "; p2 = SELF ->
456           return_term_of_level loc 
457             (fun l -> Ast.Layout (Ast.Below (p1 l, p2 l)))
458       | p1 = SELF; SYMBOL "\\above "; p2 = SELF ->
459           return_term_of_level loc 
460             (fun l -> Ast.Layout (Ast.Above (p1 l, p2 l)))
461       | p1 = SELF; SYMBOL "\\over "; p2 = SELF ->
462           return_term_of_level loc 
463             (fun l -> Ast.Layout (Ast.Over (p1 l, p2 l)))
464       | p1 = SELF; SYMBOL "\\atop "; p2 = SELF ->
465           return_term_of_level loc 
466             (fun l -> Ast.Layout (Ast.Atop (p1 l, p2 l)))
467       | p1 = SELF; SYMBOL "\\frac "; p2 = SELF ->
468           return_term_of_level loc 
469             (fun l -> Ast.Layout (Ast.Frac (p1 l, p2 l)))
470       | SYMBOL "\\infrule "; p1 = SELF; p2 = SELF; p3 = SELF ->
471           return_term_of_level loc 
472             (fun l -> Ast.Layout (Ast.InfRule (p1 l, p2 l, p3 l)))
473       | SYMBOL "\\sqrt "; p = SELF -> 
474           return_term_of_level loc (fun l -> Ast.Layout (Ast.Sqrt p l))
475       | SYMBOL "\\root "; index = SELF; SYMBOL "\\of "; arg = SELF ->
476           return_term_of_level loc 
477             (fun l -> Ast.Layout (Ast.Root (arg l, index l)))
478       | "hbox"; LPAREN; p = l1_pattern; RPAREN ->
479           return_term_of_level loc 
480             (fun l -> Ast.Layout (Ast.Box ((Ast.H, false, false), p l)))
481       | "vbox"; LPAREN; p = l1_pattern; RPAREN ->
482           return_term_of_level loc 
483             (fun l -> Ast.Layout (Ast.Box ((Ast.V, false, false), p l)))
484       | "hvbox"; LPAREN; p = l1_pattern; RPAREN ->
485           return_term_of_level loc 
486             (fun l -> Ast.Layout (Ast.Box ((Ast.HV, false, false), p l)))
487       | "hovbox"; LPAREN; p = l1_pattern; RPAREN ->
488           return_term_of_level loc 
489             (fun l -> Ast.Layout (Ast.Box ((Ast.HOV, false, false), p l)))
490       | "break" -> return_term_of_level loc (fun _ -> Ast.Layout Ast.Break)
491       | "mstyle"; m = LIST1 mstyle ; LPAREN; t = l1_pattern; RPAREN ->
492           return_term_of_level loc 
493             (fun l -> 
494                Ast.Layout (Ast.Mstyle (m, t l)))
495       | "mpadded"; m = LIST1 mpadded ; LPAREN; t = l1_pattern; RPAREN ->
496           return_term_of_level loc 
497             (fun l -> 
498                Ast.Layout (Ast.Mpadded (m, t l)))
499       | "maction"; m = LIST1 [ LPAREN; l = l1_pattern; RPAREN -> l ] ->
500            return_term_of_level loc 
501             (fun l -> Ast.Layout (Ast.Maction (List.map (fun x ->
502               NotationUtil.group (x l)) m)))
503       | LPAREN; p = l1_pattern; RPAREN ->
504           return_term_of_level loc (fun l -> NotationUtil.group (p l))
505       ]
506     | "simple" NONA
507       [ i = IDENT -> 
508          return_term_of_level loc 
509            (fun l -> Ast.Variable (Ast.TermVar (i,Ast.Self l)))
510       | m = l1_magic_pattern -> 
511              return_term_of_level loc (fun l -> Ast.Magic (m l))
512       | v = l1_pattern_variable -> 
513              return_term_of_level loc (fun _ -> Ast.Variable v)
514       | l = literal -> return_term_of_level loc (fun _ -> Ast.Literal l)
515       ]
516     ];
517   END
518   end;
519 (* }}} *)
520 (* {{{ Grammar for ast magics, notation level 2 *)
521   begin
522   let level2_meta = grammars.level2_meta in
523 EXTEND
524   GLOBAL: level2_meta;
525   l2_variable: [
526     [ "term"; precedence = NUMBER; id = IDENT -> 
527         Ast.TermVar (id,Ast.Level (int_of_string precedence))
528     | "number"; id = IDENT -> Ast.NumVar id
529     | "ident"; id = IDENT -> Ast.IdentVar id
530     | "fresh"; id = IDENT -> Ast.FreshVar id
531     | "anonymous" -> Ast.TermVar ("_",Ast.Self 0) (* is the level relevant?*)
532     | id = IDENT -> Ast.TermVar (id,Ast.Self 0)
533     ]
534   ];
535   l2_magic: [
536     [ "fold"; kind = [ "left" -> `Left | "right" -> `Right ];
537       base = level2_meta; "rec"; id = IDENT; recursive = level2_meta ->
538         Ast.Fold (kind, base, [id], recursive)
539     | "default"; some = level2_meta; none = level2_meta ->
540         Ast.Default (some, none)
541     | "if"; p_test = level2_meta;
542       "then"; p_true = level2_meta;
543       "else"; p_false = level2_meta ->
544         Ast.If (p_test, p_true, p_false)
545     | "fail" -> Ast.Fail
546     ]
547   ];
548   level2_meta: [
549     [ magic = l2_magic -> Ast.Magic magic
550     | var = l2_variable -> Ast.Variable var
551     | blob = UNPARSED_AST ->
552         parse_level2_ast grammars (Ulexing.from_utf8_string blob)
553     ]
554   ];
555 END
556   end;
557 (* }}} *)
558 (* {{{ Grammar for ast patterns, notation level 2 *)
559   begin
560   let level2_ast = grammars.level2_ast in
561   let term = grammars.term in
562   let let_defs = grammars.let_defs in
563   let ident = grammars.ident in
564   let protected_binder_vars = grammars.protected_binder_vars in
565 EXTEND
566   GLOBAL: level2_ast term let_defs protected_binder_vars ident;
567   level2_ast: [ [ p = term -> p ] ];
568   sort: [
569     [ "Prop" -> `Prop
570     | "Set" -> `Set
571     | "Type"; SYMBOL "["; n = [ NUMBER| IDENT ]; SYMBOL "]" -> `NType n
572     | "CProp"; SYMBOL "["; n = [ NUMBER| IDENT ]; SYMBOL "]" -> `NCProp n
573     ]
574   ];
575   explicit_subst: [
576     [ SYMBOL "\\subst ";  (* to avoid catching frequent "a [1]" cases *)
577       SYMBOL "[";
578       substs = LIST1 [
579         i = IDENT; SYMBOL <:unicode<Assign>> (* ≔ *); t = term -> (i, t)
580       ] SEP SYMBOL ";";
581       SYMBOL "]" ->
582         substs
583     ]
584   ];
585   meta_subst: [
586     [ s = SYMBOL "_" -> None
587     | p = term -> Some p ]
588   ];
589   meta_substs: [
590     [ SYMBOL "["; substs = LIST0 meta_subst; SYMBOL "]" -> substs ]
591   ];
592   possibly_typed_name: [
593     [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
594         id, Some typ
595     | arg = single_arg -> arg, None
596     | id = PIDENT -> Ast.Ident (id, None), None
597     | SYMBOL "_" -> Ast.Ident ("_", None), None
598     | LPAREN; id = PIDENT; SYMBOL ":"; typ = term; RPAREN ->
599         Ast.Ident (id, None), Some typ
600     | LPAREN; SYMBOL "_"; SYMBOL ":"; typ = term; RPAREN ->
601         Ast.Ident ("_", None), Some typ
602     ]
603   ];
604   match_pattern: [
605     [ SYMBOL "_" -> Ast.Wildcard
606     | id = IDENT -> Ast.Pattern (id, None, [])
607     | LPAREN; id = IDENT; vars = LIST1 possibly_typed_name; RPAREN ->
608        Ast.Pattern (id, None, vars)
609     | id = IDENT; vars = LIST1 possibly_typed_name ->
610        Ast.Pattern (id, None, vars)
611     ]
612   ];
613   binder: [
614     [ SYMBOL <:unicode<Pi>>     (* Π *) -> `Pi
615     | SYMBOL <:unicode<forall>> (* ∀ *) -> `Forall
616     | SYMBOL <:unicode<lambda>> (* λ *) -> `Lambda
617     ]
618   ];
619   arg: [
620     [ LPAREN; names = LIST1 IDENT SEP SYMBOL ",";
621       SYMBOL ":"; ty = term; RPAREN ->
622         List.map (fun n -> Ast.Ident (n, None)) names, Some ty
623     | name = IDENT -> [Ast.Ident (name, None)], None
624     | blob = UNPARSED_META ->
625         let meta = parse_level2_meta grammars (Ulexing.from_utf8_string blob) in
626         match meta with
627         | Ast.Variable (Ast.FreshVar _) -> [meta], None
628         | Ast.Variable (Ast.TermVar ("_",_)) -> [Ast.Ident ("_", None)], None
629         | _ -> failwith "Invalid bound name."
630    ]
631   ];
632   single_arg: [
633     [ name = IDENT -> Ast.Ident (name, None)
634     | blob = UNPARSED_META ->
635         let meta = parse_level2_meta grammars (Ulexing.from_utf8_string blob) in
636         match meta with
637         | Ast.Variable (Ast.FreshVar _)
638         | Ast.Variable (Ast.IdentVar _) -> meta
639         | Ast.Variable (Ast.TermVar ("_",_)) -> Ast.Ident ("_", None)
640         | _ -> failwith "Invalid index name."
641     ]
642   ];
643   ident: [
644     [ name = IDENT -> Env.Ident name
645     | blob = UNPARSED_META ->
646         let meta = parse_level2_meta grammars (Ulexing.from_utf8_string blob) in
647         match meta with
648         | Ast.Variable (Ast.FreshVar _) ->
649            (* it makes sense: extend Env.ident_or_var *)
650             assert false
651         | Ast.Variable (Ast.IdentVar name) -> Env.Var name
652         | Ast.Variable (Ast.TermVar ("_",_)) -> Env.Var "_"
653         | _ -> failwith ("Invalid index name: " ^ blob)
654     ]
655   ];
656   let_defs: [
657     [ defs = LIST1 [
658         name = single_arg;
659         args = LIST1 arg;
660         index_name = OPT [ "on"; id = single_arg -> id ];
661         ty = OPT [ SYMBOL ":" ; p = term -> p ];
662         SYMBOL <:unicode<def>> (* ≝ *); body = term ->
663           let rec position_of name p = function 
664             | [] -> None, p
665             | n :: _ when n = name -> Some p, p
666             | _ :: tl -> position_of name (p + 1) tl
667           in
668           let rec find_arg name n = function 
669             | [] ->
670                 Ast.fail loc (sprintf "Argument %s not found"
671                   (NotationPp.pp_term name))
672             | (l,_) :: tl -> 
673                 (match position_of name 0 l with
674                 | None, len -> find_arg name (n + len) tl
675                 | Some where, len -> n + where)
676           in
677           let index = 
678             match index_name with 
679             | None -> 0 
680             | Some index_name -> find_arg index_name 0 args
681           in
682           let args =
683            List.concat
684             (List.map
685              (function (names,ty) -> List.map (function x -> x,ty) names
686              ) args)
687           in
688            args, (name, ty), body, index
689       ] SEP "and" ->
690         defs
691     ]
692   ];
693   binder_vars: [
694     [ vars = [ l =
695         [ l = LIST1 single_arg SEP SYMBOL "," -> l
696         | l = LIST1 [ PIDENT | SYMBOL "_" ] SEP SYMBOL "," -> 
697             List.map (fun x -> Ast.Ident(x,None)) l
698       ] -> l ];
699       typ = OPT [ SYMBOL ":"; t = term -> t ] -> (vars, typ)
700     ]
701   ];
702   protected_binder_vars: [
703     [ LPAREN; vars = binder_vars; RPAREN -> vars 
704     ]
705   ];
706   maybe_protected_binder_vars: [
707     [ vars = binder_vars -> vars
708     | vars = protected_binder_vars -> vars
709     ]
710   ];
711   term: LEVEL "10"
712   [
713     [ "let"; 
714      var = 
715       [ LPAREN; id = single_arg; SYMBOL ":"; typ = term; RPAREN ->
716           id, Some typ
717       | id = IDENT; ty = OPT [ SYMBOL ":"; typ = term -> typ] ->
718           Ast.Ident(id,None), ty ];
719       SYMBOL <:unicode<def>> (* ≝ *);
720       p1 = term; "in"; p2 = term ->
721         return_term loc (Ast.LetIn (var, p1, p2))
722     | LETCOREC; defs = let_defs; "in";
723       body = term ->
724         return_term loc (Ast.LetRec (`CoInductive, defs, body))
725     | LETREC; defs = let_defs; "in";
726       body = term ->
727         return_term loc (Ast.LetRec (`Inductive, defs, body))
728     ]
729   ];
730   term: LEVEL "20"
731     [
732       [ b = binder; (vars, typ) = maybe_protected_binder_vars; SYMBOL "."; body = term LEVEL "19" ->
733           return_term loc (fold_cluster b vars typ body)
734       ]
735     ];
736   term: LEVEL "70"
737     [
738       [ p1 = term; p2 = term LEVEL "71" ->
739           let rec aux = function
740             | Ast.Appl (hd :: tl)
741             | Ast.AttributedTerm (_, Ast.Appl (hd :: tl)) ->
742                 aux hd @ tl
743             | term -> [term]
744           in
745           return_term loc (Ast.Appl (aux p1 @ [p2]))
746       ]
747     ];
748   term: LEVEL "90"
749     [
750       [ id = IDENT -> return_term loc (Ast.Ident (id, None))
751       | id = IDENT; s = explicit_subst ->
752           return_term loc (Ast.Ident (id, Some s))
753       | s = CSYMBOL -> return_term loc (Ast.Symbol (s, 0))
754       | u = URI -> return_term loc (Ast.Uri (u, None))
755       | r = NREF -> return_term loc (Ast.NRef (NReference.reference_of_string r))
756       | n = NUMBER -> return_term loc (Ast.Num (n, 0))
757       | IMPLICIT -> return_term loc (Ast.Implicit `JustOne)
758       | SYMBOL <:unicode<ldots>> -> return_term loc (Ast.Implicit `Vector)
759       | PLACEHOLDER -> return_term loc Ast.UserInput
760       | m = META -> return_term loc (Ast.Meta (int_of_string m, []))
761       | m = META; s = meta_substs ->
762           return_term loc (Ast.Meta (int_of_string m, s))
763       | s = sort -> return_term loc (Ast.Sort s)
764       | "match"; t = term;
765         indty_ident = OPT [ "in"; id = IDENT -> id, None ];
766         outtyp = OPT [ "return"; ty = term -> ty ];
767         "with"; SYMBOL "[";
768         patterns = LIST0 [
769           lhs = match_pattern; SYMBOL <:unicode<Rightarrow>> (* ⇒ *);
770           rhs = term ->
771             lhs, rhs
772         ] SEP SYMBOL "|";
773         SYMBOL "]" ->
774           return_term loc (Ast.Case (t, indty_ident, outtyp, patterns))
775       | LPAREN; p1 = term; SYMBOL ":"; p2 = term; RPAREN ->
776           return_term loc (Ast.Cast (p1, p2))
777       | LPAREN; p = term; RPAREN -> p
778       | blob = UNPARSED_META ->
779           parse_level2_meta grammars (Ulexing.from_utf8_string blob)
780       ]
781     ];
782 END
783   end;
784 (* }}} *)
785   grammars
786 ;;
787
788 let initial_grammars keywords =
789   let lexers = CicNotationLexer.mk_lexers keywords in
790   let level1_pattern_grammar = 
791     Grammar.gcreate lexers.CicNotationLexer.level1_pattern_lexer in
792   let level2_ast_grammar = 
793     Grammar.gcreate lexers.CicNotationLexer.level2_ast_lexer in
794   let level2_meta_grammar = 
795     Grammar.gcreate lexers.CicNotationLexer.level2_meta_lexer in
796   let level1_pattern =
797     Grammar.Entry.create level1_pattern_grammar "level1_pattern" in
798   let level2_ast = Grammar.Entry.create level2_ast_grammar "level2_ast" in
799   let term = Grammar.Entry.create level2_ast_grammar "term" in
800   let ident = Grammar.Entry.create level2_ast_grammar "ident" in
801   let let_defs = Grammar.Entry.create level2_ast_grammar "let_defs" in
802   let protected_binder_vars = 
803     Grammar.Entry.create level2_ast_grammar "protected_binder_vars" in
804   let level2_meta = Grammar.Entry.create level2_meta_grammar "level2_meta" in
805   initialize_grammars { level1_pattern=level1_pattern;
806     level2_ast=level2_ast;
807     term=term;
808     ident=ident;
809     let_defs=let_defs;
810     protected_binder_vars=protected_binder_vars;
811     level2_meta=level2_meta;
812     level2_ast_grammar=level2_ast_grammar;
813   }
814 ;;
815
816 class type g_status =
817  object
818   method notation_parser_db: db
819  end
820
821 class status ~keywords:kwds =
822  object
823   val db = { grammars = initial_grammars kwds; keywords = kwds; items = [] }
824   method notation_parser_db = db
825   method set_notation_parser_db v = {< db = v >}
826   method set_notation_parser_status
827    : 'status. #g_status as 'status -> 'self
828    = fun o -> {< db = o#notation_parser_db >}
829  end
830
831 let extend (status : #status) (CL1P (level1_pattern,precedence)) action =
832         (* move inside constructor XXX *)
833   let add1item status (level, level1_pattern, action) =
834     let p_bindings, p_atoms =
835       List.split (extract_term_production status level1_pattern) in
836     Grammar.extend
837       [ Grammar.Entry.obj 
838         (status#notation_parser_db.grammars.term : 'a Grammar.Entry.e),
839         Some (Gramext.Level level),
840         [ None,
841           Some (*Gramext.NonA*) Gramext.NonA,
842           [ p_atoms, 
843             (make_action
844               (fun (env: NotationEnv.t) (loc: Ast.location) ->
845                 (action env loc))
846               p_bindings) ]]];
847     status
848   in
849   let current_item = 
850     let level = level_of precedence in
851     level, level1_pattern, action in
852   let keywords = NotationUtil.keywords_of_term level1_pattern @
853     status#notation_parser_db.keywords in
854   let items = current_item :: status#notation_parser_db.items in 
855   let status = status#set_notation_parser_status (new status ~keywords) in
856   let status = status#set_notation_parser_db 
857     {status#notation_parser_db with items = items} in
858   List.fold_left add1item status items
859 ;;
860
861
862 let parse_level1_pattern status =
863   parse_level1_pattern status#notation_parser_db.grammars 
864 let parse_level2_ast status =
865   parse_level2_ast status#notation_parser_db.grammars 
866 let parse_level2_meta status =
867   parse_level2_meta status#notation_parser_db.grammars
868 let parse_term status =
869   parse_term status#notation_parser_db.grammars
870
871 let level2_ast_grammar status = 
872   status#notation_parser_db.grammars.level2_ast_grammar
873 let term status = status#notation_parser_db.grammars.term
874 let let_defs status = status#notation_parser_db.grammars.let_defs
875 let protected_binder_vars status = 
876   status#notation_parser_db.grammars.protected_binder_vars
877
878 (** {2 Debugging} *)
879
880 let print_l2_pattern status =
881   Grammar.print_entry Format.std_formatter 
882     (Grammar.Entry.obj status#notation_parser_db.grammars.term);
883   Format.pp_print_flush Format.std_formatter ();
884   flush stdout  
885
886 (* vim:set encoding=utf8 foldmethod=marker: *)