matita/components/content_pres/termContentPres.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 module Ast = NotationPt
  31 module Env = NotationEnv
  32
  33 let debug = false
  34 let debug_print s = if debug then prerr_endline (Lazy.force s) else ()
  35
  36 type pattern_id = int
  37 type pretty_printer_id = pattern_id
  38
  39 let resolve_binder = function
  40   | `Lambda -> "\\lambda"
  41   | `Pi -> "\\Pi"
  42   | `Forall -> "\\forall"
  43   | `Exists -> "\\exists"
  44
  45 let add_level_info prec t = Ast.AttributedTerm (`Level prec, t)
  46
  47 let rec top_pos t = add_level_info ~-1 t
  48
  49 let rec remove_level_info =
  50   function
  51   | Ast.AttributedTerm (`Level _, t) -> remove_level_info t
  52   | Ast.AttributedTerm (a, t) -> Ast.AttributedTerm (a, remove_level_info t)
  53   | t -> t
  54
  55 let add_xml_attrs attrs t =
  56   if attrs = [] then t else Ast.AttributedTerm (`XmlAttrs attrs, t)
  57
  58 let add_keyword_attrs =
  59   add_xml_attrs (RenderingAttrs.keyword_attributes `MathML)
  60
  61 let box kind spacing indent content =
  62   Ast.Layout (Ast.Box ((kind, spacing, indent), content))
  63
  64 let hbox = box Ast.H
  65 let vbox = box Ast.V
  66 let hvbox = box Ast.HV
  67 let hovbox = box Ast.HOV
  68 let break = Ast.Layout Ast.Break
  69 let space = Ast.Literal (`Symbol " ")
  70 let builtin_symbol s = Ast.Literal (`Symbol s)
  71 let keyword k = add_keyword_attrs (Ast.Literal (`Keyword k))
  72
  73 let number s =
  74   add_xml_attrs (RenderingAttrs.number_attributes `MathML)
  75     (Ast.Literal (`Number s))
  76
  77 let ident i =
  78   add_xml_attrs (RenderingAttrs.ident_attributes `MathML) (Ast.Ident (i, None))
  79
  80 let ident_w_href href i =
  81   match href with
  82   | None -> ident i
  83   | Some href ->
  84       let href = NReference.string_of_reference href in
  85       add_xml_attrs [Some "xlink", "href", href] (ident i)
  86
  87 let binder_symbol s =
  88   add_xml_attrs (RenderingAttrs.builtin_symbol_attributes `MathML)
  89     (builtin_symbol s)
  90
  91 let xml_of_sort x =
  92   let to_string x = Ast.Ident (x, None) in
  93   let identify x =
  94     add_xml_attrs (RenderingAttrs.keyword_attributes `MathML) (to_string x)
  95   in
  96   let lvl t = Ast.AttributedTerm (`Level 90,t) in
  97   match x with
  98   | `Prop -> identify "Prop"
  99   | `Set -> identify "Set"
 100   | `CProp _ -> identify "CProp"
 101   | `Type _ -> identify "Type"
 102   | `NType s -> lvl(Ast.Layout (Ast.Sub (identify "Type",to_string s)))
 103   | `NCProp s -> lvl(Ast.Layout (Ast.Sub (identify "CProp",to_string s)))
 104 ;;
 105
 106
 107 let map_space f l =
 108  HExtlib.list_concat
 109   ~sep:[space] (List.map (fun x -> [f x]) l)
 110 ;;
 111
 112 let pp_ast0 t k =
 113   let rec aux =
 114     function
 115     | Ast.Appl ts ->
 116         let rec aux_args level =
 117           function
 118           | [] -> []
 119           | [ last ] ->
 120               [ Ast.AttributedTerm (`Level level,k last) ]
 121           | hd :: tl ->
 122               (Ast.AttributedTerm (`Level level, k hd)) :: aux_args 71 tl
 123         in
 124         add_level_info Ast.apply_prec
 125           (hovbox true true (NotationUtil.dress break (aux_args 70 ts)))
 126     | Ast.Binder (binder_kind, (id, ty), body) ->
 127         add_level_info Ast.binder_prec
 128           (hvbox false true
 129             [ binder_symbol (resolve_binder binder_kind);
 130               k id; builtin_symbol ":"; aux_ty ty; break;
 131               builtin_symbol "."; k body ])
 132     | Ast.Case (what, indty_opt, outty_opt, patterns) ->
 133         let outty_box =
 134           match outty_opt with
 135           | None -> []
 136           | Some outty ->
 137               [ space; keyword "return"; space; break; remove_level_info (k outty)]
 138         in
 139         let indty_box =
 140           match indty_opt with
 141           | None -> []
 142           | Some (indty, href) -> [ space; keyword "in"; space; break; ident_w_href href indty ]
 143         in
 144         let match_box =
 145           hvbox false false [
 146            hvbox false true [
 147             hvbox false true [keyword "match"; space; break; top_pos (k what)];
 148             break;
 149             hvbox false true indty_box;
 150             break;
 151             hvbox false true outty_box
 152            ];
 153            break;
 154            space;
 155            keyword "with";
 156            space
 157          ]
 158         in
 159         let mk_case_pattern =
 160          function
 161             Ast.Pattern (head, href, vars) ->
 162              hvbox true true (ident_w_href href head ::
 163                List.flatten (List.map (fun x -> [break;x]) (map_space aux_var vars)))
 164           | Ast.Wildcard -> builtin_symbol "_"
 165         in
 166         let patterns' =
 167           List.map
 168             (fun (lhs, rhs) ->
 169               remove_level_info
 170                 (hovbox false true [
 171                   mk_case_pattern lhs; break; builtin_symbol "\\Rightarrow";
 172                   break; top_pos (k rhs) ]))
 173             patterns
 174         in
 175         let patterns'' =
 176           let rec aux_patterns = function
 177             | [] -> assert false
 178             | [ last ] ->
 179                 [ break;
 180                   hbox false false [
 181                     builtin_symbol "|";
 182                     last; builtin_symbol "]" ] ]
 183             | hd :: tl ->
 184                 [ break; hbox false false [ builtin_symbol "|"; hd ] ]
 185                 @ aux_patterns tl
 186           in
 187           match patterns' with
 188           | [] ->
 189               [ hbox false false [ builtin_symbol "["; builtin_symbol "]" ] ]
 190           | [ one ] ->
 191               [ hbox false false [
 192                 builtin_symbol "["; one; builtin_symbol "]" ] ]
 193           | hd :: tl ->
 194               hbox false false [ builtin_symbol "["; hd ]
 195               :: aux_patterns tl
 196         in
 197         add_level_info Ast.simple_prec
 198           (hvbox false false [
 199             hvbox false false ([match_box]); break;
 200             hbox false false [ hvbox false false patterns'' ] ])
 201     | Ast.Cast (bo, ty) ->
 202         add_level_info Ast.simple_prec
 203           (hvbox false true [
 204             builtin_symbol "("; top_pos (k bo); break; builtin_symbol ":";
 205             top_pos (k ty); builtin_symbol ")"])
 206     | Ast.LetIn (var, s, t) ->
 207         add_level_info Ast.let_in_prec
 208           (hvbox false true [
 209             hvbox false true [
 210               keyword "let"; space;
 211               hvbox false true [
 212                 aux_var var; space;
 213                 builtin_symbol "\\def"; break; top_pos (k s) ];
 214               break; space; keyword "in"; space ];
 215             break;
 216             k t ])
 217     | Ast.LetRec (rec_kind, funs, where) ->
 218         let rec_op =
 219           match rec_kind with `Inductive -> "rec" | `CoInductive -> "corec"
 220         in
 221         let mk_fun (args, (name,ty), body, rec_param) =
 222          List.flatten (List.map (fun x -> [aux_var x; space]) args),
 223           k name, HExtlib.map_option k ty, k body, fst (List.nth args rec_param)
 224         in
 225         let mk_funs = List.map mk_fun in
 226         let fst_fun, tl_funs =
 227           match mk_funs funs with hd :: tl -> hd, tl | [] -> assert false
 228         in
 229         let fst_row =
 230           let (params, name, ty, body, rec_param) = fst_fun in
 231           hvbox false true ([
 232             keyword "let";
 233             space;
 234             keyword rec_op;
 235             space;
 236             name;
 237             space] @
 238             params @
 239             [keyword "on" ; space ; rec_param ;space ] @
 240             (match ty with None -> [] | Some ty -> [builtin_symbol ":"; ty]) @
 241             [ builtin_symbol "\\def";
 242             break;
 243             top_pos body ])
 244         in
 245         let tl_rows =
 246           List.map
 247             (fun (params, name, ty, body, rec_param) ->
 248               [ break;
 249                 hvbox false true ([
 250                   keyword "and"; space;
 251                   name] @
 252                   params @
 253                   [space; keyword "on" ; space; rec_param ;space ] @
 254                   (match ty with
 255                       None -> []
 256                     | Some ty -> [builtin_symbol ":"; ty]) @
 257                   [ builtin_symbol "\\def"; break; body ])])
 258             tl_funs
 259         in
 260         add_level_info Ast.let_in_prec
 261           ((hvbox false false
 262             (fst_row :: List.flatten tl_rows
 263              @ [ break; keyword "in"; break; k where ])))
 264     | Ast.Implicit `JustOne -> builtin_symbol "?"
 265     | Ast.Implicit `Vector -> builtin_symbol "…"
 266     | Ast.Meta (n, l) ->
 267         let local_context l =
 268             List.map (function None -> None | Some t -> Some (k t)) l
 269         in
 270         Ast.Meta(n, local_context l)
 271     | Ast.Sort sort -> aux_sort sort
 272     | Ast.Num _
 273     | Ast.Symbol _
 274     | Ast.Ident (_, None) | Ast.Ident (_, Some [])
 275     | Ast.Uri (_, None) | Ast.Uri (_, Some [])
 276     | Ast.Literal _
 277     | Ast.UserInput as leaf -> leaf
 278     | t -> NotationUtil.visit_ast ~special_k k t
 279   and aux_sort sort_kind = xml_of_sort sort_kind
 280   and aux_ty = function
 281     | None -> builtin_symbol "?"
 282     | Some ty -> k ty
 283   and aux_var = function
 284     | name, Some ty ->
 285         hvbox false true [
 286           builtin_symbol "("; name; builtin_symbol ":"; break; k ty;
 287           builtin_symbol ")" ]
 288     | name, None -> name
 289   and special_k = function
 290     | Ast.AttributedTerm (attrs, t) -> Ast.AttributedTerm (attrs, k t)
 291     | t ->
 292         prerr_endline ("unexpected special: " ^ NotationPp.pp_term t);
 293         assert false
 294   in
 295   aux t
 296
 297   (* persistent state *)
 298
 299 module IntMap = Map.Make(struct type t = int let compare = compare end);;
 300
 301 type db = {
 302  level1_patterns21: NotationPt.term IntMap.t;
 303  compiled21: ((NotationPt.term -> (NotationEnv.t * NotationPt.term list * int) option)) Lazy.t option;
 304  pattern21_matrix: (NotationPt.term * pattern_id) list;
 305  counter: pattern_id
 306 }
 307
 308 let initial_db = {
 309  level1_patterns21 = IntMap.empty;
 310  compiled21 = None;
 311  pattern21_matrix = [];
 312  counter = ~-1
 313 }
 314
 315 class type g_status =
 316   object
 317     method content_pres_db: db
 318   end
 319
 320 class status =
 321  object
 322    val content_pres_db = initial_db
 323    method content_pres_db = content_pres_db
 324    method set_content_pres_db v = {< content_pres_db = v >}
 325    method set_content_pres_status
 326     : 'status. #g_status as 'status -> 'self
 327     = fun o -> {< content_pres_db = o#content_pres_db >}
 328  end
 329
 330 let get_compiled21 status =
 331   match status#content_pres_db.compiled21 with
 332   | None -> assert false
 333   | Some f -> Lazy.force f
 334
 335 let set_compiled21 status f =
 336  status#set_content_pres_db
 337   { status#content_pres_db with compiled21 = Some f }
 338
 339 let add_idrefs =
 340   List.fold_right (fun idref t -> Ast.AttributedTerm (`IdRef idref, t))
 341
 342 let instantiate21 idrefs env l1 =
 343   let rec subst_singleton pos env =
 344     function
 345       Ast.AttributedTerm (attr, t) ->
 346         Ast.AttributedTerm (attr, subst_singleton pos env t)
 347     | t -> NotationUtil.group (subst pos env t)
 348   and subst pos env = function
 349     | Ast.AttributedTerm (attr, t) ->
 350 (*         prerr_endline ("loosing attribute " ^ NotationPp.pp_attribute attr); *)
 351         subst pos env t
 352     | Ast.Variable var ->
 353         let name, expected_ty = NotationEnv.declaration_of_var var in
 354         let ty, value =
 355           try
 356             List.assoc name env
 357           with Not_found ->
 358             prerr_endline ("name " ^ name ^ " not found in environment");
 359             assert false
 360         in
 361         assert (NotationEnv.well_typed ty value); (* INVARIANT *)
 362         (* following assertion should be a conditional that makes this
 363          * instantiation fail *)
 364         if not (NotationEnv.well_typed expected_ty value) then
 365          begin
 366           prerr_endline ("The variable " ^ name ^ " is used with the wrong type in the notation declaration");
 367           assert false
 368          end;
 369         let value = NotationEnv.term_of_value value in
 370         let value =
 371           match expected_ty with
 372           | Env.TermType l -> Ast.AttributedTerm (`Level l,value)
 373           | _ -> value
 374         in
 375         [ value ]
 376     | Ast.Magic m -> subst_magic pos env m
 377     | Ast.Literal l as t ->
 378         let t = add_idrefs idrefs t in
 379         (match l with
 380         | `Keyword k -> [ add_keyword_attrs t ]
 381         | _ -> [ t ])
 382     | Ast.Layout l -> [ Ast.Layout (subst_layout pos env l) ]
 383     | t -> [ NotationUtil.visit_ast (subst_singleton pos env) t ]
 384   and subst_magic pos env = function
 385     | Ast.List0 (p, sep_opt)
 386     | Ast.List1 (p, sep_opt) ->
 387         let rec_decls = NotationEnv.declarations_of_term p in
 388         let rec_values =
 389           List.map (fun (n, _) -> NotationEnv.lookup_list env n) rec_decls
 390         in
 391         let values = NotationUtil.ncombine rec_values in
 392         let sep =
 393           match sep_opt with
 394             | None -> []
 395             | Some l -> [ Ast.Literal l; break; space ]
 396         in
 397         let rec instantiate_list acc = function
 398           | [] -> List.rev acc
 399           | value_set :: [] ->
 400               let env = NotationEnv.combine rec_decls value_set in
 401               instantiate_list (NotationUtil.group (subst pos env p) :: acc)
 402                 []
 403           | value_set :: tl ->
 404               let env = NotationEnv.combine rec_decls value_set in
 405               let terms = subst pos env p in
 406               instantiate_list (NotationUtil.group (terms @ sep) :: acc) tl
 407         in
 408         if values = [] then []
 409         else [hovbox false false (instantiate_list [] values)]
 410     | Ast.Opt p ->
 411         let opt_decls = NotationEnv.declarations_of_term p in
 412         let env =
 413           let rec build_env = function
 414             | [] -> []
 415             | (name, ty) :: tl ->
 416                   (* assumption: if one of the value is None then all are *)
 417                 (match NotationEnv.lookup_opt env name with
 418                 | None -> raise Exit
 419                 | Some v -> (name, (ty, v)) :: build_env tl)
 420           in
 421           try build_env opt_decls with Exit -> []
 422         in
 423           begin
 424             match env with
 425               | [] -> []
 426               | _ -> subst pos env p
 427           end
 428     | _ -> assert false (* impossible *)
 429   and subst_layout pos env = function
 430     | Ast.Box (kind, tl) ->
 431         let tl' = subst_children pos env tl in
 432         Ast.Box (kind, List.concat tl')
 433     | l -> NotationUtil.visit_layout (subst_singleton pos env) l
 434   and subst_children pos env =
 435     function
 436     | [] -> []
 437     | [ child ] ->
 438         let pos' =
 439           match pos with
 440           | `Inner -> `Right
 441           | `Left -> `Left
 442 (*           | `None -> assert false *)
 443           | `Right -> `Right
 444         in
 445         [ subst pos' env child ]
 446     | hd :: tl ->
 447         let pos' =
 448           match pos with
 449           | `Inner -> `Inner
 450           | `Left -> `Inner
 451 (*           | `None -> assert false *)
 452           | `Right -> `Right
 453         in
 454         (subst pos env hd) :: subst_children pos' env tl
 455   in
 456     subst_singleton `Left env l1
 457
 458 let rec pp_ast1 status term =
 459   let rec pp_value = function
 460     | NotationEnv.NumValue _ as v -> v
 461     | NotationEnv.StringValue _ as v -> v
 462 (*     | NotationEnv.TermValue t when t == term -> NotationEnv.TermValue (pp_ast0 t pp_ast1) *)
 463     | NotationEnv.TermValue t -> NotationEnv.TermValue (pp_ast1 status t)
 464     | NotationEnv.OptValue None as v -> v
 465     | NotationEnv.OptValue (Some v) ->
 466         NotationEnv.OptValue (Some (pp_value v))
 467     | NotationEnv.ListValue vl ->
 468         NotationEnv.ListValue (List.map pp_value vl)
 469   in
 470   let ast_env_of_env env =
 471     List.map (fun (var, (ty, value)) -> (var, (ty, pp_value value))) env
 472   in
 473 (* prerr_endline ("pattern matching from 2 to 1 on term " ^ NotationPp.pp_term term); *)
 474   match term with
 475   | Ast.AttributedTerm (attrs, term') ->
 476       Ast.AttributedTerm (attrs, pp_ast1 status term')
 477   | _ ->
 478       (match get_compiled21 status term with
 479       | None -> pp_ast0 term (pp_ast1 status)
 480       | Some (env, ctors, pid) ->
 481           let idrefs =
 482             List.flatten (List.map NotationUtil.get_idrefs ctors)
 483           in
 484           let l1 =
 485             try
 486               IntMap.find pid status#content_pres_db.level1_patterns21
 487             with Not_found -> assert false
 488           in
 489           instantiate21 idrefs (ast_env_of_env env) l1)
 490
 491 let load_patterns21 status t =
 492   set_compiled21 status (lazy (Content2presMatcher.Matcher21.compiler t))
 493
 494 let pp_ast status ast =
 495   debug_print (lazy "pp_ast <-");
 496   let ast' = pp_ast1 status ast in
 497   debug_print (lazy ("pp_ast -> " ^ NotationPp.pp_term ast'));
 498   ast'
 499
 500 let fill_pos_info l1_pattern = l1_pattern
 501 (*   let rec aux toplevel pos =
 502     function
 503     | Ast.Layout l ->
 504         (match l
 505
 506     | Ast.Magic m ->
 507         Ast.Box (
 508     | Ast.Variable _ as t -> add_pos_info pos t
 509     | t -> t
 510   in
 511   aux true l1_pattern *)
 512
 513 let fresh_id status =
 514   let counter = status#content_pres_db.counter+1 in
 515    status#set_content_pres_db ({ status#content_pres_db with counter = counter  }), counter
 516
 517 let add_pretty_printer status l2 (CicNotationParser.CL1P (l1,precedence)) =
 518   let status,id = fresh_id status in
 519   let l1' = add_level_info precedence (fill_pos_info l1) in
 520   let l2' = NotationUtil.strip_attributes l2 in
 521   let status =
 522    status#set_content_pres_db
 523     { status#content_pres_db with
 524        level1_patterns21 =
 525         IntMap.add id l1' status#content_pres_db.level1_patterns21;
 526        pattern21_matrix = (l2',id)::status#content_pres_db.pattern21_matrix } in
 527   load_patterns21 status status#content_pres_db.pattern21_matrix
 528
 529   (* presentation -> content *)
 530
 531 let unopt_names names env =
 532   let rec aux acc = function
 533     | (name, (ty, v)) :: tl when List.mem name names ->
 534         (match ty, v with
 535         | Env.OptType ty, Env.OptValue (Some v) ->
 536             aux ((name, (ty, v)) :: acc) tl
 537         | _ -> assert false)
 538     | hd :: tl -> aux (hd :: acc) tl
 539     | [] -> acc
 540   in
 541   aux [] env
 542
 543 let head_names names env =
 544   let rec aux acc = function
 545     | (name, (ty, v)) :: tl when List.mem name names ->
 546         (match ty, v with
 547         | Env.ListType ty, Env.ListValue (v :: _) ->
 548             aux ((name, (ty, v)) :: acc) tl
 549         | Env.TermType _, Env.TermValue _  ->
 550             aux ((name, (ty, v)) :: acc) tl
 551         | Env.OptType _, Env.OptValue _ ->
 552             aux ((name, (ty, v)) :: acc) tl
 553         | _ -> assert false)
 554     | _ :: tl -> aux acc tl
 555       (* base pattern may contain only meta names, thus we trash all others *)
 556     | [] -> acc
 557   in
 558   aux [] env
 559
 560 let tail_names names env =
 561   let rec aux acc = function
 562     | (name, (ty, v)) :: tl when List.mem name names ->
 563         (match ty, v with
 564         | Env.ListType ty, Env.ListValue (_ :: vtl) ->
 565             aux ((name, (Env.ListType ty, Env.ListValue vtl)) :: acc) tl
 566         | Env.TermType _, Env.TermValue _  ->
 567             aux ((name, (ty, v)) :: acc) tl
 568         | Env.OptType _, Env.OptValue _ ->
 569             aux ((name, (ty, v)) :: acc) tl
 570         | _ -> assert false)
 571     | binding :: tl -> aux (binding :: acc) tl
 572     | [] -> acc
 573   in
 574   aux [] env
 575
 576 let instantiate_level2 env term =
 577 (*   prerr_endline ("istanzio: " ^ NotationPp.pp_term term); *)
 578   let fresh_env = ref [] in
 579   let lookup_fresh_name n =
 580     try
 581       List.assoc n !fresh_env
 582     with Not_found ->
 583       let new_name = NotationUtil.fresh_name () in
 584       fresh_env := (n, new_name) :: !fresh_env;
 585       new_name
 586   in
 587   let rec aux env term =
 588 (*    prerr_endline ("ENV " ^ NotationPp.pp_env env); *)
 589     match term with
 590     | Ast.AttributedTerm (a, term) -> (*Ast.AttributedTerm (a, *)aux env term
 591     | Ast.Appl terms -> Ast.Appl (List.map (aux env) terms)
 592     | Ast.Binder (binder, var, body) ->
 593         Ast.Binder (binder, aux_capture_var env var, aux env body)
 594     | Ast.Case (term, indty, outty_opt, patterns) ->
 595         Ast.Case (aux env term, indty, aux_opt env outty_opt,
 596           List.map (aux_branch env) patterns)
 597     | Ast.LetIn (var, t1, t3) ->
 598         Ast.LetIn (aux_capture_var env var, aux env t1, aux env t3)
 599     | Ast.LetRec (kind, definitions, body) ->
 600         Ast.LetRec (kind, List.map (aux_definition env) definitions,
 601           aux env body)
 602     | Ast.Uri (name, None) -> Ast.Uri (name, None)
 603     | Ast.Uri (name, Some substs) ->
 604         Ast.Uri (name, Some (aux_substs env substs))
 605     | Ast.Ident (name, Some substs) ->
 606         Ast.Ident (name, Some (aux_substs env substs))
 607     | Ast.Meta (index, substs) -> Ast.Meta (index, aux_meta_substs env substs)
 608
 609     | Ast.Implicit _
 610     | Ast.Ident _
 611     | Ast.Num _
 612     | Ast.Sort _
 613     | Ast.Symbol _
 614     | Ast.UserInput -> term
 615
 616     | Ast.Magic magic -> aux_magic env magic
 617     | Ast.Variable var -> aux_variable env var
 618
 619     | Ast.Cast (t, ty) -> Ast.Cast (aux env t, aux env ty)
 620
 621     | _ -> assert false
 622   and aux_opt env = function
 623     | Some term -> Some (aux env term)
 624     | None -> None
 625   and aux_capture_var env (name, ty_opt) = (aux env name, aux_opt env ty_opt)
 626   and aux_branch env (pattern, term) =
 627     (aux_pattern env pattern, aux env term)
 628   and aux_pattern env =
 629    function
 630       Ast.Pattern (head, hrefs, vars) ->
 631        Ast.Pattern (head, hrefs, List.map (aux_capture_var env) vars)
 632     | Ast.Wildcard -> Ast.Wildcard
 633   and aux_definition env (params, var, term, i) =
 634     (List.map (aux_capture_var env) params, aux_capture_var env var, aux env term, i)
 635   and aux_substs env substs =
 636     List.map (fun (name, term) -> (name, aux env term)) substs
 637   and aux_meta_substs env meta_substs = List.map (aux_opt env) meta_substs
 638   and aux_variable env = function
 639     | Ast.NumVar name -> Ast.Num (Env.lookup_num env name, 0)
 640     | Ast.IdentVar name -> Ast.Ident (Env.lookup_string env name, None)
 641     | Ast.TermVar (name,(Ast.Level l|Ast.Self l)) ->
 642         Ast.AttributedTerm (`Level l,Env.lookup_term env name)
 643     | Ast.FreshVar name -> Ast.Ident (lookup_fresh_name name, None)
 644     | Ast.Ascription (term, name) -> assert false
 645   and aux_magic env = function
 646     | Ast.Default (some_pattern, none_pattern) ->
 647         let some_pattern_names = NotationUtil.names_of_term some_pattern in
 648         let none_pattern_names = NotationUtil.names_of_term none_pattern in
 649         let opt_names =
 650           List.filter
 651             (fun name -> not (List.mem name none_pattern_names))
 652             some_pattern_names
 653         in
 654         (match opt_names with
 655         | [] -> assert false (* some pattern must contain at least 1 name *)
 656         | (name :: _) as names ->
 657             (match Env.lookup_value env name with
 658             | Env.OptValue (Some _) ->
 659                 (* assumption: if "name" above is bound to Some _, then all
 660                  * names returned by "meta_names_of" are bound to Some _ as well
 661                  *)
 662                 aux (unopt_names names env) some_pattern
 663             | Env.OptValue None -> aux env none_pattern
 664             | _ ->
 665                 prerr_endline (sprintf
 666                   "lookup of %s in env %s did not return an optional value"
 667                   name (NotationPp.pp_env env));
 668                 assert false))
 669     | Ast.Fold (`Left, base_pattern, names, rec_pattern) ->
 670         let acc_name = List.hd names in (* names can't be empty, cfr. parser *)
 671         let meta_names =
 672           List.filter ((<>) acc_name)
 673             (NotationUtil.names_of_term rec_pattern)
 674         in
 675         (match meta_names with
 676         | [] -> assert false (* as above *)
 677         | (name :: _) as names ->
 678             let rec instantiate_fold_left acc env' =
 679               match Env.lookup_value env' name with
 680               | Env.ListValue (_ :: _) ->
 681                   instantiate_fold_left
 682                     (let acc_binding =
 683                       acc_name, (Env.TermType 0, Env.TermValue acc)
 684                      in
 685                      aux (acc_binding :: head_names names env') rec_pattern)
 686                     (tail_names names env')
 687               | Env.ListValue [] -> acc
 688               | _ -> assert false
 689             in
 690             instantiate_fold_left (aux env base_pattern) env)
 691     | Ast.Fold (`Right, base_pattern, names, rec_pattern) ->
 692         let acc_name = List.hd names in (* names can't be empty, cfr. parser *)
 693         let meta_names =
 694           List.filter ((<>) acc_name)
 695             (NotationUtil.names_of_term rec_pattern)
 696         in
 697         (match meta_names with
 698         | [] -> assert false (* as above *)
 699         | (name :: _) as names ->
 700             let rec instantiate_fold_right env' =
 701               match Env.lookup_value env' name with
 702               | Env.ListValue (_ :: _) ->
 703                   let acc = instantiate_fold_right (tail_names names env') in
 704                   let acc_binding =
 705                     acc_name, (Env.TermType 0, Env.TermValue acc)
 706                   in
 707                   aux (acc_binding :: head_names names env') rec_pattern
 708               | Env.ListValue [] -> aux env base_pattern
 709               | _ -> assert false
 710             in
 711             instantiate_fold_right env)
 712     | Ast.If (_, p_true, p_false) as t ->
 713         aux env (NotationUtil.find_branch (Ast.Magic t))
 714     | Ast.Fail -> assert false
 715     | _ -> assert false
 716   in
 717   aux env term