matita/components/ng_disambiguation/nCicDisambiguate.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: nCic.ml 9058 2008-10-13 17:42:30Z tassi $ *)
  13
  14 open Printf
  15
  16 open DisambiguateTypes
  17 open UriManager
  18
  19 module Ast = NotationPt
  20 module NRef = NReference
  21
  22 let debug_print s = prerr_endline (Lazy.force s);;
  23 let debug_print _ = ();;
  24
  25 let reference_of_oxuri = ref (fun _ -> assert false);;
  26 let set_reference_of_oxuri f = reference_of_oxuri := f;;
  27
  28 let cic_name_of_name = function
  29   | Ast.Ident (n, None) ->  n
  30   | _ -> assert false
  31 ;;
  32
  33 let rec mk_rels howmany from =
  34   match howmany with
  35   | 0 -> []
  36   | _ -> (NCic.Rel (howmany + from)) :: (mk_rels (howmany-1) from)
  37 ;;
  38
  39 let refine_term
  40  metasenv subst context uri ~rdb ~use_coercions term expty _ ~localization_tbl=
  41   assert (uri=None);
  42   debug_print (lazy (sprintf "TEST_INTERPRETATION: %s"
  43     (NCicPp.ppterm ~metasenv ~subst ~context term)));
  44   try
  45     let localise t =
  46       try NCicUntrusted.NCicHash.find localization_tbl t
  47       with Not_found ->
  48         prerr_endline ("NOT LOCALISED" ^ NCicPp.ppterm ~metasenv ~subst ~context t);
  49         (*assert false*) HExtlib.dummy_floc
  50     in
  51     let metasenv, subst, term, _ =
  52       NCicRefiner.typeof
  53         (rdb#set_coerc_db
  54           (if use_coercions then rdb#coerc_db else NCicCoercion.empty_db))
  55         metasenv subst context term expty ~localise
  56     in
  57      Disambiguate.Ok (term, metasenv, subst, ())
  58   with
  59   | NCicRefiner.Uncertain loc_msg ->
  60       debug_print (lazy ("UNCERTAIN: [" ^ snd (Lazy.force loc_msg) ^ "] " ^
  61         NCicPp.ppterm ~metasenv ~subst ~context term)) ;
  62       Disambiguate.Uncertain loc_msg
  63   | NCicRefiner.RefineFailure loc_msg ->
  64       debug_print (lazy (sprintf "PRUNED:\nterm%s\nmessage:%s"
  65         (NCicPp.ppterm ~metasenv ~subst ~context term) (snd(Lazy.force loc_msg))));
  66       Disambiguate.Ko loc_msg
  67 ;;
  68
  69 let refine_obj
  70   ~rdb metasenv subst _context _uri
  71   ~use_coercions obj _ _ugraph ~localization_tbl
  72 =
  73   assert (metasenv=[]);
  74   assert (subst=[]);
  75   let localise t =
  76     try NCicUntrusted.NCicHash.find localization_tbl t
  77     with Not_found ->
  78       (*assert false*)HExtlib.dummy_floc
  79   in
  80   try
  81     let obj =
  82       NCicRefiner.typeof_obj
  83         (rdb#set_coerc_db
  84            (if use_coercions then rdb#coerc_db
  85             else NCicCoercion.empty_db))
  86         obj ~localise
  87     in
  88       Disambiguate.Ok (obj, [], [], ())
  89   with
  90   | NCicRefiner.Uncertain loc_msg ->
  91       debug_print (lazy ("UNCERTAIN: [" ^ snd (Lazy.force loc_msg) ^ "] " ^
  92         NCicPp.ppobj obj)) ;
  93       Disambiguate.Uncertain loc_msg
  94   | NCicRefiner.RefineFailure loc_msg ->
  95       debug_print (lazy (sprintf "PRUNED:\nobj: %s\nmessage: %s"
  96         (NCicPp.ppobj obj) (snd(Lazy.force loc_msg))));
  97       Disambiguate.Ko loc_msg
  98 ;;
  99
 100
 101   (* TODO move it to Cic *)
 102 let find_in_context name context =
 103   let rec aux acc = function
 104     | [] -> raise Not_found
 105     | hd :: _ when hd = name -> acc
 106     | _ :: tl ->  aux (acc + 1) tl
 107   in
 108   aux 1 context
 109
 110 let interpretate_term_and_interpretate_term_option
 111   ?(create_dummy_ids=false)
 112     ~obj_context ~mk_choice ~env ~uri ~is_path ~localization_tbl
 113 =
 114   (* create_dummy_ids shouldbe used only for interpretating patterns *)
 115   assert (uri = None);
 116
 117   let rec aux ~localize loc context = function
 118     | NotationPt.AttributedTerm (`Loc loc, term) ->
 119         let res = aux ~localize loc context term in
 120         if localize then
 121          NCicUntrusted.NCicHash.add localization_tbl res loc;
 122        res
 123     | NotationPt.AttributedTerm (_, term) -> aux ~localize loc context term
 124     | NotationPt.Appl (NotationPt.Appl inner :: args) ->
 125         aux ~localize loc context (NotationPt.Appl (inner @ args))
 126     | NotationPt.Appl
 127         (NotationPt.AttributedTerm (att,(NotationPt.Appl inner))::args)->
 128         aux ~localize loc context
 129           (NotationPt.AttributedTerm (att,NotationPt.Appl (inner @ args)))
 130     | NotationPt.Appl (NotationPt.Symbol (symb, i) :: args) ->
 131         let cic_args = List.map (aux ~localize loc context) args in
 132         Disambiguate.resolve ~mk_choice ~env (Symbol (symb, i)) (`Args cic_args)
 133     | NotationPt.Appl terms ->
 134        NCic.Appl (List.map (aux ~localize loc context) terms)
 135     | NotationPt.Binder (binder_kind, (var, typ), body) ->
 136         let cic_type = aux_option ~localize loc context `Type typ in
 137         let cic_name = cic_name_of_name var  in
 138         let cic_body = aux ~localize loc (cic_name :: context) body in
 139         (match binder_kind with
 140         | `Lambda -> NCic.Lambda (cic_name, cic_type, cic_body)
 141         | `Pi
 142         | `Forall -> NCic.Prod (cic_name, cic_type, cic_body)
 143         | `Exists ->
 144             Disambiguate.resolve ~env ~mk_choice (Symbol ("exists", 0))
 145               (`Args [ cic_type; NCic.Lambda (cic_name, cic_type, cic_body) ]))
 146     | NotationPt.Case (term, indty_ident, outtype, branches) ->
 147         let cic_term = aux ~localize loc context term in
 148         let cic_outtype = aux_option ~localize loc context `Term outtype in
 149         let do_branch ((_, _, args), term) =
 150          let rec do_branch' context = function
 151            | [] -> aux ~localize loc context term
 152            | (name, typ) :: tl ->
 153                let cic_name = cic_name_of_name name in
 154                let cic_body = do_branch' (cic_name :: context) tl in
 155                let typ =
 156                  match typ with
 157                  | None -> NCic.Implicit `Type
 158                  | Some typ -> aux ~localize loc context typ
 159                in
 160                NCic.Lambda (cic_name, typ, cic_body)
 161          in
 162           do_branch' context args
 163         in
 164         if create_dummy_ids then
 165          let branches =
 166           List.map
 167            (function
 168                Ast.Wildcard,term -> ("wildcard",None,[]), term
 169              | Ast.Pattern _,_ ->
 170                 raise (DisambiguateTypes.Invalid_choice
 171                  (lazy (loc, "Syntax error: the left hand side of a "^
 172                    "branch pattern must be \"_\"")))
 173            ) branches
 174          in
 175          (*
 176           NCic.MutCase (ref, cic_outtype, cic_term,
 177             (List.map do_branch branches))
 178           *) ignore branches; assert false (* patterns not implemented yet *)
 179         else
 180          let indtype_ref =
 181           match indty_ident with
 182           | Some (indty_ident, _) ->
 183              (match Disambiguate.resolve ~env ~mk_choice
 184                 (Id indty_ident) (`Args []) with
 185               | NCic.Const (NReference.Ref (_,NReference.Ind _) as r) -> r
 186               | NCic.Implicit _ ->
 187                  raise (Disambiguate.Try_again
 188                   (lazy "The type of the term to be matched is still unknown"))
 189               | t ->
 190                 raise (DisambiguateTypes.Invalid_choice
 191                   (lazy (loc,"The type of the term to be matched "^
 192                           "is not (co)inductive: " ^ NCicPp.ppterm
 193                           ~metasenv:[] ~subst:[] ~context:[] t))))
 194           | None ->
 195               let rec fst_constructor =
 196                 function
 197                    (Ast.Pattern (head, _, _), _) :: _ -> head
 198                  | (Ast.Wildcard, _) :: tl -> fst_constructor tl
 199                  | [] -> raise (Invalid_choice (lazy (loc,"The type "^
 200                      "of the term to be matched cannot be determined "^
 201                      "because it is an inductive type without constructors "^
 202                      "or because all patterns use wildcards")))
 203               in
 204 (*
 205               DisambiguateTypes.Environment.iter
 206                   (fun k v ->
 207                       prerr_endline
 208                         (DisambiguateTypes.string_of_domain_item k ^ " => " ^
 209                         description_of_alias v)) env;
 210 *)
 211               (match Disambiguate.resolve ~env ~mk_choice
 212                 (Id (fst_constructor branches)) (`Args []) with
 213               | NCic.Const (NReference.Ref (_,NReference.Con _) as r) ->
 214                    let b,_,_,_,_ = NCicEnvironment.get_checked_indtys r in
 215                    NReference.mk_indty b r
 216               | NCic.Implicit _ ->
 217                  raise (Disambiguate.Try_again
 218                   (lazy "The type of the term to be matched is still unknown"))
 219               | t ->
 220                 raise (DisambiguateTypes.Invalid_choice
 221                   (lazy (loc,
 222                   "The type of the term to be matched is not (co)inductive: "
 223                   ^ NCicPp.ppterm ~metasenv:[] ~subst:[] ~context:[] t))))
 224          in
 225          let _,leftsno,itl,_,indtyp_no =
 226           NCicEnvironment.get_checked_indtys indtype_ref in
 227          let _,_,_,cl =
 228           try
 229            List.nth itl indtyp_no
 230           with _ -> assert false in
 231          let rec count_prod t =
 232                  match NCicReduction.whd ~subst:[] [] t with
 233                NCic.Prod (_, _, t) -> 1 + (count_prod t)
 234              | _ -> 0
 235          in
 236          let rec sort branches cl =
 237           match cl with
 238              [] ->
 239               let rec analyze unused unrecognized useless =
 240                function
 241                   [] ->
 242                    if unrecognized != [] then
 243                     raise (DisambiguateTypes.Invalid_choice
 244                      (lazy
 245                        (loc,"Unrecognized constructors: " ^
 246                         String.concat " " unrecognized)))
 247                    else if useless > 0 then
 248                     raise (DisambiguateTypes.Invalid_choice
 249                      (lazy
 250                        (loc,"The last " ^ string_of_int useless ^
 251                         "case" ^ if useless > 1 then "s are" else " is" ^
 252                         " unused")))
 253                    else
 254                     []
 255                 | (Ast.Wildcard,_)::tl when not unused ->
 256                     analyze true unrecognized useless tl
 257                 | (Ast.Pattern (head,_,_),_)::tl when not unused ->
 258                     analyze unused (head::unrecognized) useless tl
 259                 | _::tl -> analyze unused unrecognized (useless + 1) tl
 260               in
 261                analyze false [] 0 branches
 262            | (_,name,ty)::cltl ->
 263               let rec find_and_remove =
 264                function
 265                   [] ->
 266                    raise
 267                     (DisambiguateTypes.Invalid_choice
 268                      (lazy (loc, "Missing case: " ^ name)))
 269                 | ((Ast.Wildcard, _) as branch :: _) as branches ->
 270                     branch, branches
 271                 | (Ast.Pattern (name',_,_),_) as branch :: tl
 272                    when name = name' ->
 273                     branch,tl
 274                 | branch::tl ->
 275                    let found,rest = find_and_remove tl in
 276                     found, branch::rest
 277               in
 278                let branch,tl = find_and_remove branches in
 279                match branch with
 280                   Ast.Pattern (name,y,args),term ->
 281                    if List.length args = count_prod ty - leftsno then
 282                     ((name,y,args),term)::sort tl cltl
 283                    else
 284                     raise
 285                      (DisambiguateTypes.Invalid_choice
 286                       (lazy (loc,"Wrong number of arguments for " ^ name)))
 287                 | Ast.Wildcard,term ->
 288                    let rec mk_lambdas =
 289                     function
 290                        0 -> term
 291                      | n ->
 292                         NotationPt.Binder
 293                          (`Lambda, (NotationPt.Ident ("_", None), None),
 294                            mk_lambdas (n - 1))
 295                    in
 296                     (("wildcard",None,[]),
 297                      mk_lambdas (count_prod ty - leftsno)) :: sort tl cltl
 298          in
 299           let branches = sort branches cl in
 300            NCic.Match (indtype_ref, cic_outtype, cic_term,
 301             (List.map do_branch branches))
 302     | NotationPt.Cast (t1, t2) ->
 303         let cic_t1 = aux ~localize loc context t1 in
 304         let cic_t2 = aux ~localize loc context t2 in
 305         NCic.LetIn ("_",cic_t2,cic_t1, NCic.Rel 1)
 306     | NotationPt.LetIn ((name, typ), def, body) ->
 307         let cic_def = aux ~localize loc context def in
 308         let cic_name = cic_name_of_name name in
 309         let cic_typ =
 310           match typ with
 311           | None -> NCic.Implicit `Type
 312           | Some t -> aux ~localize loc context t
 313         in
 314         let cic_body = aux ~localize loc (cic_name :: context) body in
 315         NCic.LetIn (cic_name, cic_typ, cic_def, cic_body)
 316     | NotationPt.LetRec (_kind, _defs, _body) -> NCic.Implicit `Term
 317     | NotationPt.Ident _
 318     | NotationPt.Uri _
 319     | NotationPt.NRef _ when is_path -> raise Disambiguate.PathNotWellFormed
 320     | NotationPt.Ident (name, subst) ->
 321        assert (subst = None);
 322        (try
 323              NCic.Rel (find_in_context name context)
 324        with Not_found ->
 325          try NCic.Const (List.assoc name obj_context)
 326          with Not_found ->
 327             Disambiguate.resolve ~env ~mk_choice (Id name) (`Args []))
 328     | NotationPt.Uri (uri, subst) ->
 329        assert (subst = None);
 330        (try
 331          NCic.Const (!reference_of_oxuri(UriManager.uri_of_string uri))
 332         with NRef.IllFormedReference _ ->
 333          NotationPt.fail loc "Ill formed reference")
 334     | NotationPt.NRef nref -> NCic.Const nref
 335     | NotationPt.NCic t ->
 336            let context = (* to make metas_of_term happy *)
 337              List.map (fun x -> x,NCic.Decl (NCic.Implicit `Type)) context in
 338            assert(NCicUntrusted.metas_of_term [] context t = []); t
 339     | NotationPt.Implicit `Vector -> NCic.Implicit `Vector
 340     | NotationPt.Implicit `JustOne -> NCic.Implicit `Term
 341     | NotationPt.Implicit (`Tagged s) -> NCic.Implicit (`Tagged s)
 342     | NotationPt.UserInput -> NCic.Implicit `Hole
 343     | NotationPt.Num (num, i) ->
 344         Disambiguate.resolve ~env ~mk_choice (Num i) (`Num_arg num)
 345     | NotationPt.Meta (index, subst) ->
 346         let cic_subst =
 347          List.map
 348           (function None -> assert false| Some t -> aux ~localize loc context t)
 349           subst
 350         in
 351          NCic.Meta (index, (0, NCic.Ctx cic_subst))
 352     | NotationPt.Sort `Prop -> NCic.Sort NCic.Prop
 353     | NotationPt.Sort `Set -> NCic.Sort (NCic.Type
 354        [`Type,NUri.uri_of_string "cic:/matita/pts/Type.univ"])
 355     | NotationPt.Sort (`NType s) -> NCic.Sort (NCic.Type
 356        [`Type,NUri.uri_of_string ("cic:/matita/pts/Type" ^ s ^ ".univ")])
 357     | NotationPt.Sort (`NCProp s) -> NCic.Sort (NCic.Type
 358        [`CProp,NUri.uri_of_string ("cic:/matita/pts/Type" ^ s ^ ".univ")])
 359     | NotationPt.Symbol (symbol, instance) ->
 360         Disambiguate.resolve ~env ~mk_choice
 361          (Symbol (symbol, instance)) (`Args [])
 362     | NotationPt.Variable _
 363     | NotationPt.Magic _
 364     | NotationPt.Layout _
 365     | NotationPt.Literal _ -> assert false (* god bless Bologna *)
 366   and aux_option ~localize loc context annotation = function
 367     | None -> NCic.Implicit annotation
 368     | Some (NotationPt.AttributedTerm (`Loc loc, term)) ->
 369         let res = aux_option ~localize loc context annotation (Some term) in
 370         if localize then
 371           NCicUntrusted.NCicHash.add localization_tbl res loc;
 372         res
 373     | Some (NotationPt.AttributedTerm (_, term)) ->
 374         aux_option ~localize loc context annotation (Some term)
 375     | Some NotationPt.Implicit `JustOne -> NCic.Implicit annotation
 376     | Some NotationPt.Implicit `Vector -> NCic.Implicit `Vector
 377     | Some term -> aux ~localize loc context term
 378   in
 379    (fun ~context -> aux ~localize:true HExtlib.dummy_floc context),
 380    (fun ~context -> aux_option ~localize:true HExtlib.dummy_floc context)
 381 ;;
 382
 383 let interpretate_term ?(create_dummy_ids=false) ~context ~env ~uri ~is_path ast
 384      ~obj_context ~localization_tbl ~mk_choice
 385 =
 386   let context = List.map fst context in
 387   fst
 388     (interpretate_term_and_interpretate_term_option
 389       ~obj_context ~mk_choice ~create_dummy_ids ~env ~uri ~is_path ~localization_tbl)
 390     ~context ast
 391 ;;
 392
 393 let interpretate_term_option
 394   ?(create_dummy_ids=false) ~context ~env ~uri ~is_path
 395   ~localization_tbl ~mk_choice ~obj_context
 396 =
 397   let context = List.map fst context in
 398   snd
 399     (interpretate_term_and_interpretate_term_option
 400       ~obj_context ~mk_choice ~create_dummy_ids ~env ~uri ~is_path ~localization_tbl)
 401     ~context
 402 ;;
 403
 404 let disambiguate_path path =
 405   let localization_tbl = NCicUntrusted.NCicHash.create 23 in
 406   fst
 407     (interpretate_term_and_interpretate_term_option
 408     ~obj_context:[] ~mk_choice:(fun _ -> assert false)
 409     ~create_dummy_ids:true ~env:DisambiguateTypes.Environment.empty
 410     ~uri:None ~is_path:true ~localization_tbl) ~context:[] path
 411 ;;
 412
 413 let ncic_name_of_ident = function
 414   | Ast.Ident (name, None) -> name
 415   | _ -> assert false
 416 ;;
 417
 418 let interpretate_obj
 419 (*      ?(create_dummy_ids=false)  *)
 420      ~context ~env ~uri ~is_path obj ~localization_tbl ~mk_choice
 421 =
 422  assert (context = []);
 423  assert (is_path = false);
 424  let interpretate_term ~obj_context =
 425   interpretate_term ~mk_choice ~localization_tbl ~obj_context in
 426  let interpretate_term_option ~obj_context =
 427    interpretate_term_option ~mk_choice ~localization_tbl ~obj_context in
 428  let uri = match uri with | None -> assert false | Some u -> u in
 429  match obj with
 430  | NotationPt.Theorem (flavour, name, ty, bo, pragma) ->
 431      let ty' =
 432        interpretate_term
 433          ~obj_context:[] ~context:[] ~env ~uri:None ~is_path:false ty
 434      in
 435      let height = (* XXX calculate *) 0 in
 436      uri, height, [], [],
 437      (match bo,flavour with
 438       | None,`Axiom ->
 439           let attrs = `Provided, flavour, pragma in
 440           NCic.Constant ([],name,None,ty',attrs)
 441       | Some _,`Axiom -> assert false
 442       | None,_ ->
 443           let attrs = `Provided, flavour, pragma in
 444           NCic.Constant ([],name,Some (NCic.Implicit `Term),ty',attrs)
 445       | Some bo,_ ->
 446         (match bo with
 447          | NotationPt.LetRec (kind, defs, _) ->
 448              let inductive = kind = `Inductive in
 449              let _,obj_context =
 450                List.fold_left
 451                  (fun (i,acc) (_,(name,_),_,k) ->
 452                   (i+1,
 453                     (ncic_name_of_ident name, NReference.reference_of_spec uri
 454                      (if inductive then NReference.Fix (i,k,0)
 455                       else NReference.CoFix i)) :: acc))
 456                  (0,[]) defs
 457              in
 458              let inductiveFuns =
 459                List.map
 460                  (fun (params, (name, typ), body, decr_idx) ->
 461                    let add_binders kind t =
 462                     List.fold_right
 463                      (fun var t ->
 464                         NotationPt.Binder (kind, var, t)) params t
 465                    in
 466                    let cic_body =
 467                      interpretate_term
 468                        ~obj_context ~context ~env ~uri:None ~is_path:false
 469                        (add_binders `Lambda body)
 470                    in
 471                    let cic_type =
 472                      interpretate_term_option
 473                        ~obj_context:[]
 474                        ~context ~env ~uri:None ~is_path:false `Type
 475                        (HExtlib.map_option (add_binders `Pi) typ)
 476                    in
 477                    ([],ncic_name_of_ident name, decr_idx, cic_type, cic_body))
 478                  defs
 479              in
 480              let attrs = `Provided, flavour, pragma in
 481              NCic.Fixpoint (inductive,inductiveFuns,attrs)
 482          | bo ->
 483              let bo =
 484                interpretate_term
 485                 ~obj_context:[] ~context:[] ~env ~uri:None ~is_path:false bo
 486              in
 487              let attrs = `Provided, flavour, pragma in
 488              NCic.Constant ([],name,Some bo,ty',attrs)))
 489  | NotationPt.Inductive (params,tyl) ->
 490     let context,params =
 491      let context,res =
 492       List.fold_left
 493        (fun (context,res) (name,t) ->
 494          let t =
 495           match t with
 496              None -> NotationPt.Implicit `JustOne
 497            | Some t -> t in
 498          let name = cic_name_of_name name in
 499          let t =
 500           interpretate_term ~obj_context:[] ~context ~env ~uri:None
 501            ~is_path:false t
 502          in
 503           (name,NCic.Decl t)::context,(name,t)::res
 504        ) ([],[]) params
 505      in
 506       context,List.rev res in
 507     let add_params =
 508      List.fold_right (fun (name,ty) t -> NCic.Prod (name,ty,t)) params in
 509     let leftno = List.length params in
 510     let _,inductive,_,_ = try List.hd tyl with Failure _ -> assert false in
 511     let obj_context =
 512      snd (
 513       List.fold_left
 514        (fun (i,res) (name,_,_,_) ->
 515          let nref =
 516           NReference.reference_of_spec uri (NReference.Ind (inductive,i,leftno))
 517          in
 518           i+1,(name,nref)::res)
 519        (0,[]) tyl) in
 520     let tyl =
 521      List.map
 522       (fun (name,_,ty,cl) ->
 523         let ty' =
 524          add_params
 525          (interpretate_term ~obj_context:[] ~context ~env ~uri:None
 526            ~is_path:false ty) in
 527         let cl' =
 528          List.map
 529           (fun (name,ty) ->
 530             let ty' =
 531              add_params
 532               (interpretate_term ~obj_context ~context ~env ~uri:None
 533                 ~is_path:false ty) in
 534             let relevance = [] in
 535              relevance,name,ty'
 536           ) cl in
 537         let relevance = [] in
 538          relevance,name,ty',cl'
 539       ) tyl
 540     in
 541      let height = (* XXX calculate *) 0 in
 542      let attrs = `Provided, `Regular in
 543      uri, height, [], [],
 544      NCic.Inductive (inductive,leftno,tyl,attrs)
 545  | NotationPt.Record (params,name,ty,fields) ->
 546     let context,params =
 547      let context,res =
 548       List.fold_left
 549        (fun (context,res) (name,t) ->
 550          let t =
 551           match t with
 552              None -> NotationPt.Implicit `JustOne
 553            | Some t -> t in
 554          let name = cic_name_of_name name in
 555          let t =
 556           interpretate_term ~obj_context:[] ~context ~env ~uri:None
 557            ~is_path:false t
 558          in
 559           (name,NCic.Decl t)::context,(name,t)::res
 560        ) ([],[]) params
 561      in
 562       context,List.rev res in
 563     let add_params =
 564      List.fold_right (fun (name,ty) t -> NCic.Prod (name,ty,t)) params in
 565     let leftno = List.length params in
 566     let ty' =
 567      add_params
 568       (interpretate_term ~obj_context:[] ~context ~env ~uri:None
 569         ~is_path:false ty) in
 570     let nref =
 571      NReference.reference_of_spec uri (NReference.Ind (true,0,leftno)) in
 572     let obj_context = [name,nref] in
 573     let fields' =
 574      snd (
 575       List.fold_left
 576        (fun (context,res) (name,ty,_coercion,_arity) ->
 577          let ty =
 578           interpretate_term ~obj_context ~context ~env ~uri:None
 579            ~is_path:false ty in
 580          let context' = (name,NCic.Decl ty)::context in
 581           context',(name,ty)::res
 582        ) (context,[]) fields) in
 583     let concl =
 584      let mutind = NCic.Const nref in
 585      if params = [] then mutind
 586      else
 587       NCic.Appl
 588        (mutind::mk_rels (List.length params) (List.length fields)) in
 589     let con =
 590      List.fold_left (fun t (name,ty) -> NCic.Prod (name,ty,t)) concl fields' in
 591     let con' = add_params con in
 592     let relevance = [] in
 593     let tyl = [relevance,name,ty',[relevance,"mk_" ^ name,con']] in
 594     let field_names = List.map (fun (x,_,y,z) -> x,y,z) fields in
 595      let height = (* XXX calculate *) 0 in
 596      let attrs = `Provided, `Record field_names in
 597      uri, height, [], [],
 598      NCic.Inductive (true,leftno,tyl,attrs)
 599 ;;
 600
 601 let disambiguate_term ~context ~metasenv ~subst ~expty
 602    ~mk_implicit ~description_of_alias ~fix_instance ~mk_choice
 603    ~aliases ~universe ~rdb ~lookup_in_library
 604    (text,prefix_len,term)
 605  =
 606   let mk_localization_tbl x = NCicUntrusted.NCicHash.create x in
 607    let res,b =
 608     MultiPassDisambiguator.disambiguate_thing
 609      ~freshen_thing:NotationUtil.freshen_term
 610      ~context ~metasenv ~initial_ugraph:() ~aliases
 611      ~mk_implicit ~description_of_alias ~fix_instance
 612      ~string_context_of_context:(List.map (fun (x,_) -> Some x))
 613      ~universe ~uri:None ~pp_thing:NotationPp.pp_term
 614      ~passes:(MultiPassDisambiguator.passes ())
 615      ~lookup_in_library ~domain_of_thing:Disambiguate.domain_of_term
 616      ~interpretate_thing:(interpretate_term ~obj_context:[] ~mk_choice (?create_dummy_ids:None))
 617      ~refine_thing:(refine_term ~rdb) (text,prefix_len,term)
 618      ~mk_localization_tbl ~expty ~subst
 619    in
 620     List.map (function (a,b,c,d,_) -> a,b,c,d) res, b
 621 ;;
 622
 623 let disambiguate_obj
 624    ~mk_implicit ~description_of_alias ~fix_instance ~mk_choice
 625    ~aliases ~universe ~rdb ~lookup_in_library ~uri
 626    (text,prefix_len,obj)
 627  =
 628   let mk_localization_tbl x = NCicUntrusted.NCicHash.create x in
 629    let res,b =
 630     MultiPassDisambiguator.disambiguate_thing
 631      ~freshen_thing:NotationUtil.freshen_obj
 632      ~context:[] ~metasenv:[] ~subst:[] ~initial_ugraph:() ~aliases
 633      ~mk_implicit ~description_of_alias ~fix_instance
 634      ~string_context_of_context:(List.map (fun (x,_) -> Some x))
 635      ~universe
 636      ~uri:(Some uri)
 637      ~pp_thing:(NotationPp.pp_obj NotationPp.pp_term)
 638      ~passes:(MultiPassDisambiguator.passes ())
 639      ~lookup_in_library ~domain_of_thing:Disambiguate.domain_of_obj
 640      ~interpretate_thing:(interpretate_obj ~mk_choice)
 641      ~refine_thing:(refine_obj ~rdb)
 642      (text,prefix_len,obj)
 643      ~mk_localization_tbl ~expty:None
 644    in
 645     List.map (function (a,b,c,d,_) -> a,b,c,d) res, b
 646 ;;
 647 (*
 648 let _ =
 649 let mk_type n =
 650   if n = 0 then
 651      [false, NUri.uri_of_string ("cic:/matita/pts/Type.univ")]
 652   else
 653      [false, NUri.uri_of_string ("cic:/matita/pts/Type"^string_of_int n^".univ")]
 654 in
 655 let mk_cprop n =
 656   if n = 0 then
 657     [false, NUri.uri_of_string ("cic:/matita/pts/CProp.univ")]
 658   else
 659     [false, NUri.uri_of_string ("cic:/matita/pts/CProp"^string_of_int n^".univ")]
 660 in
 661          NCicEnvironment.add_constraint true (mk_type 0) (mk_type 1);
 662          NCicEnvironment.add_constraint true (mk_cprop 0) (mk_cprop 1);
 663          NCicEnvironment.add_constraint true (mk_cprop 0) (mk_type 1);
 664          NCicEnvironment.add_constraint true (mk_type 0) (mk_cprop 1);
 665          NCicEnvironment.add_constraint false (mk_cprop 0) (mk_type 0);
 666          NCicEnvironment.add_constraint false (mk_type 0) (mk_cprop 0);
 667
 668          NCicEnvironment.add_constraint true (mk_type 1) (mk_type 2);
 669          NCicEnvironment.add_constraint true (mk_cprop 1) (mk_cprop 2);
 670          NCicEnvironment.add_constraint true (mk_cprop 1) (mk_type 2);
 671          NCicEnvironment.add_constraint true (mk_type 1) (mk_cprop 2);
 672          NCicEnvironment.add_constraint false (mk_cprop 1) (mk_type 1);
 673          NCicEnvironment.add_constraint false (mk_type 1) (mk_cprop 1);
 674
 675          NCicEnvironment.add_constraint true (mk_type 2) (mk_type 3);
 676          NCicEnvironment.add_constraint true (mk_cprop 2) (mk_cprop 3);
 677          NCicEnvironment.add_constraint true (mk_cprop 2) (mk_type 3);
 678          NCicEnvironment.add_constraint true (mk_type 2) (mk_cprop 3);
 679          NCicEnvironment.add_constraint false (mk_cprop 2) (mk_type 2);
 680          NCicEnvironment.add_constraint false (mk_type 2) (mk_cprop 2);
 681
 682          NCicEnvironment.add_constraint false (mk_cprop 3) (mk_type 3);
 683          NCicEnvironment.add_constraint false (mk_type 3) (mk_cprop 3);
 684
 685 ;;
 686 *)
 687