matita/components/ng_disambiguation/nCicDisambiguate.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id: nCic.ml 9058 2008-10-13 17:42:30Z tassi $ *)
  13
  14 open Printf
  15
  16 open DisambiguateTypes
  17
  18 module Ast = NotationPt
  19 module NRef = NReference
  20
  21 let debug_print s = prerr_endline (Lazy.force s);;
  22 let debug_print _ = ();;
  23
  24 let cic_name_of_name = function
  25   | Ast.Ident (n, None) ->  n
  26   | _ -> assert false
  27 ;;
  28
  29 let rec mk_rels howmany from =
  30   match howmany with
  31   | 0 -> []
  32   | _ -> (NCic.Rel (howmany + from)) :: (mk_rels (howmany-1) from)
  33 ;;
  34
  35 let refine_term
  36  metasenv subst context uri ~rdb ~use_coercions term expty _ ~localization_tbl=
  37   assert (uri=None);
  38   debug_print (lazy (sprintf "TEST_INTERPRETATION: %s"
  39     (NCicPp.ppterm ~metasenv ~subst ~context term)));
  40   try
  41     let localise t =
  42       try NCicUntrusted.NCicHash.find localization_tbl t
  43       with Not_found ->
  44         prerr_endline ("NOT LOCALISED" ^ NCicPp.ppterm ~metasenv ~subst ~context t);
  45         (*assert false*) HExtlib.dummy_floc
  46     in
  47     let metasenv, subst, term, _ =
  48       NCicRefiner.typeof
  49         (rdb#set_coerc_db
  50           (if use_coercions then rdb#coerc_db else NCicCoercion.empty_db))
  51         metasenv subst context term expty ~localise
  52     in
  53      Disambiguate.Ok (term, metasenv, subst, ())
  54   with
  55   | NCicRefiner.Uncertain loc_msg ->
  56       debug_print (lazy ("UNCERTAIN: [" ^ snd (Lazy.force loc_msg) ^ "] " ^
  57         NCicPp.ppterm ~metasenv ~subst ~context term)) ;
  58       Disambiguate.Uncertain loc_msg
  59   | NCicRefiner.RefineFailure loc_msg ->
  60       debug_print (lazy (sprintf "PRUNED:\nterm%s\nmessage:%s"
  61         (NCicPp.ppterm ~metasenv ~subst ~context term) (snd(Lazy.force loc_msg))));
  62       Disambiguate.Ko loc_msg
  63 ;;
  64
  65 let refine_obj
  66   ~rdb metasenv subst _context _uri
  67   ~use_coercions obj _ _ugraph ~localization_tbl
  68 =
  69   assert (metasenv=[]);
  70   assert (subst=[]);
  71   let localise t =
  72     try NCicUntrusted.NCicHash.find localization_tbl t
  73     with Not_found ->
  74       (*assert false*)HExtlib.dummy_floc
  75   in
  76   try
  77     let obj =
  78       NCicRefiner.typeof_obj
  79         (rdb#set_coerc_db
  80            (if use_coercions then rdb#coerc_db
  81             else NCicCoercion.empty_db))
  82         obj ~localise
  83     in
  84       Disambiguate.Ok (obj, [], [], ())
  85   with
  86   | NCicRefiner.Uncertain loc_msg ->
  87       debug_print (lazy ("UNCERTAIN: [" ^ snd (Lazy.force loc_msg) ^ "] " ^
  88         NCicPp.ppobj obj)) ;
  89       Disambiguate.Uncertain loc_msg
  90   | NCicRefiner.RefineFailure loc_msg ->
  91       debug_print (lazy (sprintf "PRUNED:\nobj: %s\nmessage: %s"
  92         (NCicPp.ppobj obj) (snd(Lazy.force loc_msg))));
  93       Disambiguate.Ko loc_msg
  94 ;;
  95
  96
  97   (* TODO move it to Cic *)
  98 let find_in_context name context =
  99   let rec aux acc = function
 100     | [] -> raise Not_found
 101     | hd :: _ when hd = name -> acc
 102     | _ :: tl ->  aux (acc + 1) tl
 103   in
 104   aux 1 context
 105
 106 let interpretate_term_and_interpretate_term_option
 107   ?(create_dummy_ids=false)
 108     ~obj_context ~mk_choice ~env ~uri ~is_path ~localization_tbl
 109 =
 110   (* create_dummy_ids shouldbe used only for interpretating patterns *)
 111   assert (uri = None);
 112
 113   let rec aux ~localize loc context = function
 114     | NotationPt.AttributedTerm (`Loc loc, term) ->
 115         let res = aux ~localize loc context term in
 116         if localize then
 117          NCicUntrusted.NCicHash.add localization_tbl res loc;
 118        res
 119     | NotationPt.AttributedTerm (_, term) -> aux ~localize loc context term
 120     | NotationPt.Appl (NotationPt.Appl inner :: args) ->
 121         aux ~localize loc context (NotationPt.Appl (inner @ args))
 122     | NotationPt.Appl
 123         (NotationPt.AttributedTerm (att,(NotationPt.Appl inner))::args)->
 124         aux ~localize loc context
 125           (NotationPt.AttributedTerm (att,NotationPt.Appl (inner @ args)))
 126     | NotationPt.Appl (NotationPt.Symbol (symb, i) :: args) ->
 127         let cic_args = List.map (aux ~localize loc context) args in
 128         Disambiguate.resolve ~mk_choice ~env (Symbol (symb, i)) (`Args cic_args)
 129     | NotationPt.Appl terms ->
 130        NCic.Appl (List.map (aux ~localize loc context) terms)
 131     | NotationPt.Binder (binder_kind, (var, typ), body) ->
 132         let cic_type = aux_option ~localize loc context `Type typ in
 133         let cic_name = cic_name_of_name var  in
 134         let cic_body = aux ~localize loc (cic_name :: context) body in
 135         (match binder_kind with
 136         | `Lambda -> NCic.Lambda (cic_name, cic_type, cic_body)
 137         | `Pi
 138         | `Forall -> NCic.Prod (cic_name, cic_type, cic_body)
 139         | `Exists ->
 140             Disambiguate.resolve ~env ~mk_choice (Symbol ("exists", 0))
 141               (`Args [ cic_type; NCic.Lambda (cic_name, cic_type, cic_body) ]))
 142     | NotationPt.Case (term, indty_ident, outtype, branches) ->
 143         let cic_term = aux ~localize loc context term in
 144         let cic_outtype = aux_option ~localize loc context `Term outtype in
 145         let do_branch ((_, _, args), term) =
 146          let rec do_branch' context = function
 147            | [] -> aux ~localize loc context term
 148            | (name, typ) :: tl ->
 149                let cic_name = cic_name_of_name name in
 150                let cic_body = do_branch' (cic_name :: context) tl in
 151                let typ =
 152                  match typ with
 153                  | None -> NCic.Implicit `Type
 154                  | Some typ -> aux ~localize loc context typ
 155                in
 156                NCic.Lambda (cic_name, typ, cic_body)
 157          in
 158           do_branch' context args
 159         in
 160         if create_dummy_ids then
 161          let branches =
 162           List.map
 163            (function
 164                Ast.Wildcard,term -> ("wildcard",None,[]), term
 165              | Ast.Pattern _,_ ->
 166                 raise (DisambiguateTypes.Invalid_choice
 167                  (lazy (loc, "Syntax error: the left hand side of a "^
 168                    "branch pattern must be \"_\"")))
 169            ) branches
 170          in
 171          (*
 172           NCic.MutCase (ref, cic_outtype, cic_term,
 173             (List.map do_branch branches))
 174           *) ignore branches; assert false (* patterns not implemented yet *)
 175         else
 176          let indtype_ref =
 177           match indty_ident with
 178           | Some (indty_ident, _) ->
 179              (match Disambiguate.resolve ~env ~mk_choice
 180                 (Id indty_ident) (`Args []) with
 181               | NCic.Const (NReference.Ref (_,NReference.Ind _) as r) -> r
 182               | NCic.Implicit _ ->
 183                  raise (Disambiguate.Try_again
 184                   (lazy "The type of the term to be matched is still unknown"))
 185               | t ->
 186                 raise (DisambiguateTypes.Invalid_choice
 187                   (lazy (loc,"The type of the term to be matched "^
 188                           "is not (co)inductive: " ^ NCicPp.ppterm
 189                           ~metasenv:[] ~subst:[] ~context:[] t))))
 190           | None ->
 191               let rec fst_constructor =
 192                 function
 193                    (Ast.Pattern (head, _, _), _) :: _ -> head
 194                  | (Ast.Wildcard, _) :: tl -> fst_constructor tl
 195                  | [] -> raise (Invalid_choice (lazy (loc,"The type "^
 196                      "of the term to be matched cannot be determined "^
 197                      "because it is an inductive type without constructors "^
 198                      "or because all patterns use wildcards")))
 199               in
 200 (*
 201               DisambiguateTypes.Environment.iter
 202                   (fun k v ->
 203                       prerr_endline
 204                         (DisambiguateTypes.string_of_domain_item k ^ " => " ^
 205                         description_of_alias v)) env;
 206 *)
 207               (match Disambiguate.resolve ~env ~mk_choice
 208                 (Id (fst_constructor branches)) (`Args []) with
 209               | NCic.Const (NReference.Ref (_,NReference.Con _) as r) ->
 210                    let b,_,_,_,_ = NCicEnvironment.get_checked_indtys r in
 211                    NReference.mk_indty b r
 212               | NCic.Implicit _ ->
 213                  raise (Disambiguate.Try_again
 214                   (lazy "The type of the term to be matched is still unknown"))
 215               | t ->
 216                 raise (DisambiguateTypes.Invalid_choice
 217                   (lazy (loc,
 218                   "The type of the term to be matched is not (co)inductive: "
 219                   ^ NCicPp.ppterm ~metasenv:[] ~subst:[] ~context:[] t))))
 220          in
 221          let _,leftsno,itl,_,indtyp_no =
 222           NCicEnvironment.get_checked_indtys indtype_ref in
 223          let _,_,_,cl =
 224           try
 225            List.nth itl indtyp_no
 226           with _ -> assert false in
 227          let rec count_prod t =
 228                  match NCicReduction.whd ~subst:[] [] t with
 229                NCic.Prod (_, _, t) -> 1 + (count_prod t)
 230              | _ -> 0
 231          in
 232          let rec sort branches cl =
 233           match cl with
 234              [] ->
 235               let rec analyze unused unrecognized useless =
 236                function
 237                   [] ->
 238                    if unrecognized != [] then
 239                     raise (DisambiguateTypes.Invalid_choice
 240                      (lazy
 241                        (loc,"Unrecognized constructors: " ^
 242                         String.concat " " unrecognized)))
 243                    else if useless > 0 then
 244                     raise (DisambiguateTypes.Invalid_choice
 245                      (lazy
 246                        (loc,"The last " ^ string_of_int useless ^
 247                         "case" ^ if useless > 1 then "s are" else " is" ^
 248                         " unused")))
 249                    else
 250                     []
 251                 | (Ast.Wildcard,_)::tl when not unused ->
 252                     analyze true unrecognized useless tl
 253                 | (Ast.Pattern (head,_,_),_)::tl when not unused ->
 254                     analyze unused (head::unrecognized) useless tl
 255                 | _::tl -> analyze unused unrecognized (useless + 1) tl
 256               in
 257                analyze false [] 0 branches
 258            | (_,name,ty)::cltl ->
 259               let rec find_and_remove =
 260                function
 261                   [] ->
 262                    raise
 263                     (DisambiguateTypes.Invalid_choice
 264                      (lazy (loc, "Missing case: " ^ name)))
 265                 | ((Ast.Wildcard, _) as branch :: _) as branches ->
 266                     branch, branches
 267                 | (Ast.Pattern (name',_,_),_) as branch :: tl
 268                    when name = name' ->
 269                     branch,tl
 270                 | branch::tl ->
 271                    let found,rest = find_and_remove tl in
 272                     found, branch::rest
 273               in
 274                let branch,tl = find_and_remove branches in
 275                match branch with
 276                   Ast.Pattern (name,y,args),term ->
 277                    if List.length args = count_prod ty - leftsno then
 278                     ((name,y,args),term)::sort tl cltl
 279                    else
 280                     raise
 281                      (DisambiguateTypes.Invalid_choice
 282                       (lazy (loc,"Wrong number of arguments for " ^ name)))
 283                 | Ast.Wildcard,term ->
 284                    let rec mk_lambdas =
 285                     function
 286                        0 -> term
 287                      | n ->
 288                         NotationPt.Binder
 289                          (`Lambda, (NotationPt.Ident ("_", None), None),
 290                            mk_lambdas (n - 1))
 291                    in
 292                     (("wildcard",None,[]),
 293                      mk_lambdas (count_prod ty - leftsno)) :: sort tl cltl
 294          in
 295           let branches = sort branches cl in
 296            NCic.Match (indtype_ref, cic_outtype, cic_term,
 297             (List.map do_branch branches))
 298     | NotationPt.Cast (t1, t2) ->
 299         let cic_t1 = aux ~localize loc context t1 in
 300         let cic_t2 = aux ~localize loc context t2 in
 301         NCic.LetIn ("_",cic_t2,cic_t1, NCic.Rel 1)
 302     | NotationPt.LetIn ((name, typ), def, body) ->
 303         let cic_def = aux ~localize loc context def in
 304         let cic_name = cic_name_of_name name in
 305         let cic_typ =
 306           match typ with
 307           | None -> NCic.Implicit `Type
 308           | Some t -> aux ~localize loc context t
 309         in
 310         let cic_body = aux ~localize loc (cic_name :: context) body in
 311         NCic.LetIn (cic_name, cic_typ, cic_def, cic_body)
 312     | NotationPt.LetRec (_kind, _defs, _body) -> NCic.Implicit `Term
 313     | NotationPt.Ident _
 314     | NotationPt.Uri _
 315     | NotationPt.NRef _ when is_path -> raise Disambiguate.PathNotWellFormed
 316     | NotationPt.Ident (name, subst) ->
 317        assert (subst = None);
 318        (try
 319              NCic.Rel (find_in_context name context)
 320        with Not_found ->
 321          try NCic.Const (List.assoc name obj_context)
 322          with Not_found ->
 323             Disambiguate.resolve ~env ~mk_choice (Id name) (`Args []))
 324     | NotationPt.Uri (uri, subst) ->
 325        assert (subst = None);
 326        (try
 327          NCic.Const (NReference.reference_of_string uri)
 328         with NRef.IllFormedReference _ ->
 329          NotationPt.fail loc "Ill formed reference")
 330     | NotationPt.NRef nref -> NCic.Const nref
 331     | NotationPt.NCic t ->
 332            let context = (* to make metas_of_term happy *)
 333              List.map (fun x -> x,NCic.Decl (NCic.Implicit `Type)) context in
 334            assert(NCicUntrusted.metas_of_term [] context t = []); t
 335     | NotationPt.Implicit `Vector -> NCic.Implicit `Vector
 336     | NotationPt.Implicit `JustOne -> NCic.Implicit `Term
 337     | NotationPt.Implicit (`Tagged s) -> NCic.Implicit (`Tagged s)
 338     | NotationPt.UserInput -> NCic.Implicit `Hole
 339     | NotationPt.Num (num, i) ->
 340         Disambiguate.resolve ~env ~mk_choice (Num i) (`Num_arg num)
 341     | NotationPt.Meta (index, subst) ->
 342         let cic_subst =
 343          List.map
 344           (function None -> assert false| Some t -> aux ~localize loc context t)
 345           subst
 346         in
 347          NCic.Meta (index, (0, NCic.Ctx cic_subst))
 348     | NotationPt.Sort `Prop -> NCic.Sort NCic.Prop
 349     | NotationPt.Sort `Set -> NCic.Sort (NCic.Type
 350        [`Type,NUri.uri_of_string "cic:/matita/pts/Type.univ"])
 351     | NotationPt.Sort (`NType s) -> NCic.Sort (NCic.Type
 352        [`Type,NUri.uri_of_string ("cic:/matita/pts/Type" ^ s ^ ".univ")])
 353     | NotationPt.Sort (`NCProp s) -> NCic.Sort (NCic.Type
 354        [`CProp,NUri.uri_of_string ("cic:/matita/pts/Type" ^ s ^ ".univ")])
 355     | NotationPt.Symbol (symbol, instance) ->
 356         Disambiguate.resolve ~env ~mk_choice
 357          (Symbol (symbol, instance)) (`Args [])
 358     | NotationPt.Variable _
 359     | NotationPt.Magic _
 360     | NotationPt.Layout _
 361     | NotationPt.Literal _ -> assert false (* god bless Bologna *)
 362   and aux_option ~localize loc context annotation = function
 363     | None -> NCic.Implicit annotation
 364     | Some (NotationPt.AttributedTerm (`Loc loc, term)) ->
 365         let res = aux_option ~localize loc context annotation (Some term) in
 366         if localize then
 367           NCicUntrusted.NCicHash.add localization_tbl res loc;
 368         res
 369     | Some (NotationPt.AttributedTerm (_, term)) ->
 370         aux_option ~localize loc context annotation (Some term)
 371     | Some NotationPt.Implicit `JustOne -> NCic.Implicit annotation
 372     | Some NotationPt.Implicit `Vector -> NCic.Implicit `Vector
 373     | Some term -> aux ~localize loc context term
 374   in
 375    (fun ~context -> aux ~localize:true HExtlib.dummy_floc context),
 376    (fun ~context -> aux_option ~localize:true HExtlib.dummy_floc context)
 377 ;;
 378
 379 let interpretate_term ?(create_dummy_ids=false) ~context ~env ~uri ~is_path ast
 380      ~obj_context ~localization_tbl ~mk_choice
 381 =
 382   let context = List.map fst context in
 383   fst
 384     (interpretate_term_and_interpretate_term_option
 385       ~obj_context ~mk_choice ~create_dummy_ids ~env ~uri ~is_path ~localization_tbl)
 386     ~context ast
 387 ;;
 388
 389 let interpretate_term_option
 390   ?(create_dummy_ids=false) ~context ~env ~uri ~is_path
 391   ~localization_tbl ~mk_choice ~obj_context
 392 =
 393   let context = List.map fst context in
 394   snd
 395     (interpretate_term_and_interpretate_term_option
 396       ~obj_context ~mk_choice ~create_dummy_ids ~env ~uri ~is_path ~localization_tbl)
 397     ~context
 398 ;;
 399
 400 let disambiguate_path path =
 401   let localization_tbl = NCicUntrusted.NCicHash.create 23 in
 402   fst
 403     (interpretate_term_and_interpretate_term_option
 404     ~obj_context:[] ~mk_choice:(fun _ -> assert false)
 405     ~create_dummy_ids:true ~env:DisambiguateTypes.Environment.empty
 406     ~uri:None ~is_path:true ~localization_tbl) ~context:[] path
 407 ;;
 408
 409 let ncic_name_of_ident = function
 410   | Ast.Ident (name, None) -> name
 411   | _ -> assert false
 412 ;;
 413
 414 let interpretate_obj
 415 (*      ?(create_dummy_ids=false)  *)
 416      ~context ~env ~uri ~is_path obj ~localization_tbl ~mk_choice
 417 =
 418  assert (context = []);
 419  assert (is_path = false);
 420  let interpretate_term ~obj_context =
 421   interpretate_term ~mk_choice ~localization_tbl ~obj_context in
 422  let interpretate_term_option ~obj_context =
 423    interpretate_term_option ~mk_choice ~localization_tbl ~obj_context in
 424  let uri = match uri with | None -> assert false | Some u -> u in
 425  match obj with
 426  | NotationPt.Theorem (flavour, name, ty, bo, pragma) ->
 427      let ty' =
 428        interpretate_term
 429          ~obj_context:[] ~context:[] ~env ~uri:None ~is_path:false ty
 430      in
 431      let height = (* XXX calculate *) 0 in
 432      uri, height, [], [],
 433      (match bo,flavour with
 434       | None,`Axiom ->
 435           let attrs = `Provided, flavour, pragma in
 436           NCic.Constant ([],name,None,ty',attrs)
 437       | Some _,`Axiom -> assert false
 438       | None,_ ->
 439           let attrs = `Provided, flavour, pragma in
 440           NCic.Constant ([],name,Some (NCic.Implicit `Term),ty',attrs)
 441       | Some bo,_ ->
 442         (match bo with
 443          | NotationPt.LetRec (kind, defs, _) ->
 444              let inductive = kind = `Inductive in
 445              let _,obj_context =
 446                List.fold_left
 447                  (fun (i,acc) (_,(name,_),_,k) ->
 448                   (i+1,
 449                     (ncic_name_of_ident name, NReference.reference_of_spec uri
 450                      (if inductive then NReference.Fix (i,k,0)
 451                       else NReference.CoFix i)) :: acc))
 452                  (0,[]) defs
 453              in
 454              let inductiveFuns =
 455                List.map
 456                  (fun (params, (name, typ), body, decr_idx) ->
 457                    let add_binders kind t =
 458                     List.fold_right
 459                      (fun var t ->
 460                         NotationPt.Binder (kind, var, t)) params t
 461                    in
 462                    let cic_body =
 463                      interpretate_term
 464                        ~obj_context ~context ~env ~uri:None ~is_path:false
 465                        (add_binders `Lambda body)
 466                    in
 467                    let cic_type =
 468                      interpretate_term_option
 469                        ~obj_context:[]
 470                        ~context ~env ~uri:None ~is_path:false `Type
 471                        (HExtlib.map_option (add_binders `Pi) typ)
 472                    in
 473                    ([],ncic_name_of_ident name, decr_idx, cic_type, cic_body))
 474                  defs
 475              in
 476              let attrs = `Provided, flavour, pragma in
 477              NCic.Fixpoint (inductive,inductiveFuns,attrs)
 478          | bo ->
 479              let bo =
 480                interpretate_term
 481                 ~obj_context:[] ~context:[] ~env ~uri:None ~is_path:false bo
 482              in
 483              let attrs = `Provided, flavour, pragma in
 484              NCic.Constant ([],name,Some bo,ty',attrs)))
 485  | NotationPt.Inductive (params,tyl) ->
 486     let context,params =
 487      let context,res =
 488       List.fold_left
 489        (fun (context,res) (name,t) ->
 490          let t =
 491           match t with
 492              None -> NotationPt.Implicit `JustOne
 493            | Some t -> t in
 494          let name = cic_name_of_name name in
 495          let t =
 496           interpretate_term ~obj_context:[] ~context ~env ~uri:None
 497            ~is_path:false t
 498          in
 499           (name,NCic.Decl t)::context,(name,t)::res
 500        ) ([],[]) params
 501      in
 502       context,List.rev res in
 503     let add_params =
 504      List.fold_right (fun (name,ty) t -> NCic.Prod (name,ty,t)) params in
 505     let leftno = List.length params in
 506     let _,inductive,_,_ = try List.hd tyl with Failure _ -> assert false in
 507     let obj_context =
 508      snd (
 509       List.fold_left
 510        (fun (i,res) (name,_,_,_) ->
 511          let nref =
 512           NReference.reference_of_spec uri (NReference.Ind (inductive,i,leftno))
 513          in
 514           i+1,(name,nref)::res)
 515        (0,[]) tyl) in
 516     let tyl =
 517      List.map
 518       (fun (name,_,ty,cl) ->
 519         let ty' =
 520          add_params
 521          (interpretate_term ~obj_context:[] ~context ~env ~uri:None
 522            ~is_path:false ty) in
 523         let cl' =
 524          List.map
 525           (fun (name,ty) ->
 526             let ty' =
 527              add_params
 528               (interpretate_term ~obj_context ~context ~env ~uri:None
 529                 ~is_path:false ty) in
 530             let relevance = [] in
 531              relevance,name,ty'
 532           ) cl in
 533         let relevance = [] in
 534          relevance,name,ty',cl'
 535       ) tyl
 536     in
 537      let height = (* XXX calculate *) 0 in
 538      let attrs = `Provided, `Regular in
 539      uri, height, [], [],
 540      NCic.Inductive (inductive,leftno,tyl,attrs)
 541  | NotationPt.Record (params,name,ty,fields) ->
 542     let context,params =
 543      let context,res =
 544       List.fold_left
 545        (fun (context,res) (name,t) ->
 546          let t =
 547           match t with
 548              None -> NotationPt.Implicit `JustOne
 549            | Some t -> t in
 550          let name = cic_name_of_name name in
 551          let t =
 552           interpretate_term ~obj_context:[] ~context ~env ~uri:None
 553            ~is_path:false t
 554          in
 555           (name,NCic.Decl t)::context,(name,t)::res
 556        ) ([],[]) params
 557      in
 558       context,List.rev res in
 559     let add_params =
 560      List.fold_right (fun (name,ty) t -> NCic.Prod (name,ty,t)) params in
 561     let leftno = List.length params in
 562     let ty' =
 563      add_params
 564       (interpretate_term ~obj_context:[] ~context ~env ~uri:None
 565         ~is_path:false ty) in
 566     let nref =
 567      NReference.reference_of_spec uri (NReference.Ind (true,0,leftno)) in
 568     let obj_context = [name,nref] in
 569     let fields' =
 570      snd (
 571       List.fold_left
 572        (fun (context,res) (name,ty,_coercion,_arity) ->
 573          let ty =
 574           interpretate_term ~obj_context ~context ~env ~uri:None
 575            ~is_path:false ty in
 576          let context' = (name,NCic.Decl ty)::context in
 577           context',(name,ty)::res
 578        ) (context,[]) fields) in
 579     let concl =
 580      let mutind = NCic.Const nref in
 581      if params = [] then mutind
 582      else
 583       NCic.Appl
 584        (mutind::mk_rels (List.length params) (List.length fields)) in
 585     let con =
 586      List.fold_left (fun t (name,ty) -> NCic.Prod (name,ty,t)) concl fields' in
 587     let con' = add_params con in
 588     let relevance = [] in
 589     let tyl = [relevance,name,ty',[relevance,"mk_" ^ name,con']] in
 590     let field_names = List.map (fun (x,_,y,z) -> x,y,z) fields in
 591      let height = (* XXX calculate *) 0 in
 592      let attrs = `Provided, `Record field_names in
 593      uri, height, [], [],
 594      NCic.Inductive (true,leftno,tyl,attrs)
 595 ;;
 596
 597 let disambiguate_term ~context ~metasenv ~subst ~expty
 598    ~mk_implicit ~description_of_alias ~fix_instance ~mk_choice
 599    ~aliases ~universe ~rdb ~lookup_in_library
 600    (text,prefix_len,term)
 601  =
 602   let mk_localization_tbl x = NCicUntrusted.NCicHash.create x in
 603    let res,b =
 604     MultiPassDisambiguator.disambiguate_thing
 605      ~freshen_thing:NotationUtil.freshen_term
 606      ~context ~metasenv ~initial_ugraph:() ~aliases
 607      ~mk_implicit ~description_of_alias ~fix_instance
 608      ~string_context_of_context:(List.map (fun (x,_) -> Some x))
 609      ~universe ~uri:None ~pp_thing:NotationPp.pp_term
 610      ~passes:(MultiPassDisambiguator.passes ())
 611      ~lookup_in_library ~domain_of_thing:Disambiguate.domain_of_term
 612      ~interpretate_thing:(interpretate_term ~obj_context:[] ~mk_choice (?create_dummy_ids:None))
 613      ~refine_thing:(refine_term ~rdb) (text,prefix_len,term)
 614      ~mk_localization_tbl ~expty ~subst
 615    in
 616     List.map (function (a,b,c,d,_) -> a,b,c,d) res, b
 617 ;;
 618
 619 let disambiguate_obj
 620    ~mk_implicit ~description_of_alias ~fix_instance ~mk_choice
 621    ~aliases ~universe ~rdb ~lookup_in_library ~uri
 622    (text,prefix_len,obj)
 623  =
 624   let mk_localization_tbl x = NCicUntrusted.NCicHash.create x in
 625    let res,b =
 626     MultiPassDisambiguator.disambiguate_thing
 627      ~freshen_thing:NotationUtil.freshen_obj
 628      ~context:[] ~metasenv:[] ~subst:[] ~initial_ugraph:() ~aliases
 629      ~mk_implicit ~description_of_alias ~fix_instance
 630      ~string_context_of_context:(List.map (fun (x,_) -> Some x))
 631      ~universe
 632      ~uri:(Some uri)
 633      ~pp_thing:(NotationPp.pp_obj NotationPp.pp_term)
 634      ~passes:(MultiPassDisambiguator.passes ())
 635      ~lookup_in_library ~domain_of_thing:Disambiguate.domain_of_obj
 636      ~interpretate_thing:(interpretate_obj ~mk_choice)
 637      ~refine_thing:(refine_obj ~rdb)
 638      (text,prefix_len,obj)
 639      ~mk_localization_tbl ~expty:None
 640    in
 641     List.map (function (a,b,c,d,_) -> a,b,c,d) res, b
 642 ;;
 643 (*
 644 let _ =
 645 let mk_type n =
 646   if n = 0 then
 647      [false, NUri.uri_of_string ("cic:/matita/pts/Type.univ")]
 648   else
 649      [false, NUri.uri_of_string ("cic:/matita/pts/Type"^string_of_int n^".univ")]
 650 in
 651 let mk_cprop n =
 652   if n = 0 then
 653     [false, NUri.uri_of_string ("cic:/matita/pts/CProp.univ")]
 654   else
 655     [false, NUri.uri_of_string ("cic:/matita/pts/CProp"^string_of_int n^".univ")]
 656 in
 657          NCicEnvironment.add_constraint true (mk_type 0) (mk_type 1);
 658          NCicEnvironment.add_constraint true (mk_cprop 0) (mk_cprop 1);
 659          NCicEnvironment.add_constraint true (mk_cprop 0) (mk_type 1);
 660          NCicEnvironment.add_constraint true (mk_type 0) (mk_cprop 1);
 661          NCicEnvironment.add_constraint false (mk_cprop 0) (mk_type 0);
 662          NCicEnvironment.add_constraint false (mk_type 0) (mk_cprop 0);
 663
 664          NCicEnvironment.add_constraint true (mk_type 1) (mk_type 2);
 665          NCicEnvironment.add_constraint true (mk_cprop 1) (mk_cprop 2);
 666          NCicEnvironment.add_constraint true (mk_cprop 1) (mk_type 2);
 667          NCicEnvironment.add_constraint true (mk_type 1) (mk_cprop 2);
 668          NCicEnvironment.add_constraint false (mk_cprop 1) (mk_type 1);
 669          NCicEnvironment.add_constraint false (mk_type 1) (mk_cprop 1);
 670
 671          NCicEnvironment.add_constraint true (mk_type 2) (mk_type 3);
 672          NCicEnvironment.add_constraint true (mk_cprop 2) (mk_cprop 3);
 673          NCicEnvironment.add_constraint true (mk_cprop 2) (mk_type 3);
 674          NCicEnvironment.add_constraint true (mk_type 2) (mk_cprop 3);
 675          NCicEnvironment.add_constraint false (mk_cprop 2) (mk_type 2);
 676          NCicEnvironment.add_constraint false (mk_type 2) (mk_cprop 2);
 677
 678          NCicEnvironment.add_constraint false (mk_cprop 3) (mk_type 3);
 679          NCicEnvironment.add_constraint false (mk_type 3) (mk_cprop 3);
 680
 681 ;;
 682 *)
 683