matita/components/ng_kernel/nCicSubstitution.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 module C = NCic
  15 module Ref = NReference
  16
  17 let debug_print = fun _ -> ();;
  18
  19 let lift_from status ?(no_implicit=true) k n =
  20  let rec liftaux k = function
  21     | C.Rel m as t -> if m < k then t else C.Rel (m + n)
  22     | C.Meta (i,(m,(C.Irl 0 as l))) when k <= m+1 -> C.Meta (i,(m,l))
  23     | C.Meta (i,(m,l)) when k <= m+1 -> C.Meta (i,(m+n,l))
  24     | C.Meta (_,(m,C.Irl l)) as t when k > l + m -> t
  25     | C.Meta (i,(m,l)) ->
  26        let lctx = NCicUtils.expand_local_context l in
  27        C.Meta (i, (m, C.Ctx (HExtlib.sharing_map (liftaux (k-m)) lctx)))
  28     | C.Implicit _ as t -> (* was the identity *)
  29         if no_implicit then assert false
  30         else t
  31     | t -> NCicUtils.map status (fun _ k -> k + 1) k liftaux t
  32  in
  33  liftaux k
  34 ;;
  35
  36 let lift status ?(from=1) ?(no_implicit=true) n t =
  37   if n = 0 then t else lift_from status ~no_implicit from n t
  38 ;;
  39
  40
  41 (* subst t1 t2                                                          *)
  42 (*  substitutes [t1] for [Rel 1] in [t2]                                *)
  43 (*  if avoid_beta_redexes is true (default: false) no new beta redexes  *)
  44 (*  are generated. WARNING: the substitution can diverge when t2 is not *)
  45 (*  well typed and avoid_beta_redexes is true.                          *)
  46 (*  map_arg is ReductionStrategy.from_env_for_unwind when psubst is     *)
  47 (*  used to implement nCicReduction.unwind'                             *)
  48 let rec psubst status ?(avoid_beta_redexes=false) ?(no_implicit=true) map_arg args =
  49  let nargs = List.length args in
  50  let rec substaux k = function
  51    | C.Rel n as t ->
  52       (match n with
  53       | n when n >= (k+nargs) ->
  54          if nargs <> 0 then C.Rel (n - nargs) else t
  55       | n when n < k -> t
  56       | n (* k <= n < k+nargs *) ->
  57        (try lift status ~no_implicit (k-1) (map_arg (List.nth args (n-k)))
  58         with Failure _ | Invalid_argument _ -> assert false))
  59    | C.Meta (i,(m,l)) as t when m >= k + nargs - 1 ->
  60        if nargs <> 0 then C.Meta (i,(m-nargs,l)) else t
  61    | C.Meta (_,(m,(C.Irl l))) as t when k > l + m -> t
  62    | C.Meta (i,(m,l)) ->
  63       let lctx = NCicUtils.expand_local_context l in
  64        C.Meta (i,(0,
  65          C.Ctx (HExtlib.sharing_map
  66                   (fun x -> substaux k (lift status ~no_implicit m x)) lctx)))
  67    | C.Implicit _ as t ->
  68        if no_implicit then assert false (* was identity *)
  69        else t
  70    | C.Appl (he::tl) as t ->
  71       (* Invariant: no Appl applied to another Appl *)
  72       let rec avoid he' = function
  73         | [] -> he'
  74         | arg::tl' as args->
  75             (match he' with
  76             | C.Appl l -> C.Appl (l@args)
  77             | C.Lambda (_,_,bo) when avoid_beta_redexes ->
  78                 (* map_arg is here \x.x, Obj magic is needed because
  79                  * we don't have polymorphic recursion w/o records *)
  80                 avoid (psubst status
  81                   ~avoid_beta_redexes ~no_implicit
  82                   Obj.magic [Obj.magic arg] bo) tl'
  83             | _ -> if he == he' && args == tl then t else C.Appl (he'::args))
  84       in
  85       let tl = HExtlib.sharing_map (substaux k) tl in
  86       avoid (substaux k he) tl
  87    | t -> NCicUtils.map status (fun _ k -> k + 1) k substaux t
  88  in
  89   substaux 1
  90 ;;
  91
  92 let subst status ?avoid_beta_redexes ?no_implicit arg =
  93   psubst status ?avoid_beta_redexes ?no_implicit(fun x -> x)[arg];;
  94
  95 (* subst_meta (n, C.Ctx [t_1 ; ... ; t_n]) t                                 *)
  96 (*  returns the term [t] where [Rel i] is substituted with [t_i] lifted by n *)
  97 (*  [t_i] is lifted as usual when it crosses an abstraction                  *)
  98 (* subst_meta (n, (C.Irl _ | C.Ctx [])) t | -> lift status n t               *)
  99 let subst_meta status = function
 100   | m, C.Irl _
 101   | m, C.Ctx [] -> lift status m
 102   | m, C.Ctx l  -> psubst status (lift status m) l
 103 ;;