matita/components/ng_kernel/nReference.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 exception IllFormedReference of string Lazy.t
  15
  16 type spec =
  17  | Decl
  18  | Def of int (* height *)
  19  | Fix of int * int * int (* fixno, recparamno, height *)
  20  | CoFix of int
  21  | Ind of bool * int * int (* inductive, indtyno, leftno *)
  22  | Con of int * int * int  (* indtyno, constrno, leftno  *)
  23
  24 type reference = Ref of NUri.uri * spec
  25
  26 let eq = (==);;
  27
  28 let compare (Ref (u1,s1)) (Ref (u2,s2)) =
  29  let res = NUri.compare u1 u2 in
  30   if res = 0 then compare s1 s2 else res
  31 ;;
  32
  33 module OrderedStrings =
  34  struct
  35   type t = string
  36   let compare (s1 : t) (s2 : t) = Pervasives.compare s1 s2
  37  end
  38 ;;
  39
  40 module MapStringsToReference = Map.Make(OrderedStrings);;
  41
  42 let set_of_reference = ref MapStringsToReference.empty;;
  43
  44 (* '.' not allowed in path and foo
  45  *
  46  * Decl                   cic:/path/foo.dec
  47  * Def                    cic:/path/foo.def
  48  * Fix of int * int       cic:/path/foo.fix(i,j)
  49  * CoFix of int           cic:/path/foo.cfx(i)
  50  * Ind of int             cic:/path/foo.ind(i)
  51  * Con of int * int       cic:/path/foo.con(i,j)
  52  *)
  53
  54 let uri_suffix_of_ref_suffix = function
  55     | "dec" | "fix" | "cfx" | "def" -> "con"
  56     | "ind" | "con" -> "ind"
  57     | x -> prerr_endline (x ^ " not a valid suffix"); assert false
  58 ;;
  59
  60 let reference_of_string =
  61   let get3 s dot =
  62     let comma2 = String.rindex s ',' in
  63     let comma = String.rindex_from s (comma2-1) ',' in
  64     let s_i = String.sub s (dot+5) (comma-dot-5) in
  65     let s_j = String.sub s (comma+1) (comma2-comma-1) in
  66     let s_h = String.sub s (comma2+1) (String.length s-comma2-2) in
  67     let i = int_of_string s_i in
  68     let j = int_of_string s_j in
  69     let h = int_of_string s_h in
  70     i,j,h
  71   in
  72 (*
  73   let get2 s dot =
  74     let comma = String.rindex s ',' in
  75     let i = int_of_string (String.sub s (dot+5) (comma-dot-5)) in
  76     let j = int_of_string (String.sub s (comma+1) (String.length s-comma-2)) in
  77     i,j
  78   in
  79 *)
  80   let get1 s dot =
  81     let i = int_of_string (String.sub s (dot+5) (String.length s-1-dot-5)) in
  82     i
  83   in
  84 fun s ->
  85   try MapStringsToReference.find s !set_of_reference
  86   with Not_found ->
  87     let new_reference =
  88       try
  89         let dot = String.rindex s '.' in
  90         let prefix = String.sub s 0 (dot+1) in
  91         let suffix = String.sub s (dot+1) 3 in
  92         let u = NUri.uri_of_string (prefix ^ uri_suffix_of_ref_suffix suffix) in
  93         match suffix with
  94         | "dec" -> Ref (u, Decl)
  95         | "def" -> let i = get1 s dot in Ref (u, Def i)
  96         | "fix" -> let i,j,h = get3 s dot in Ref (u, Fix (i,j,h))
  97         | "cfx" -> let i = get1 s dot in Ref (u, CoFix (i))
  98         | "ind" -> let b,i,l = get3 s dot in Ref (u, Ind (b=1,i,l))
  99         | "con" -> let i,j,l = get3 s dot in Ref (u, Con (i,j,l))
 100         | _ -> raise Not_found
 101       with Not_found -> raise (IllFormedReference (lazy s))
 102     in
 103     set_of_reference := MapStringsToReference.add s new_reference !set_of_reference;
 104     new_reference
 105 ;;
 106
 107 let string_of_reference (Ref (u,indinfo)) =
 108   let s = NUri.string_of_uri u in
 109   let dot = String.rindex s '.' in
 110   let s2 = String.sub s 0 dot in
 111   match indinfo with
 112   | Decl ->  s2 ^ ".dec"
 113   | Def h -> s2 ^ ".def(" ^ string_of_int h ^ ")"
 114   | Fix (i,j,h)  ->
 115       s2 ^ ".fix(" ^ string_of_int i ^ "," ^
 116       string_of_int j ^ "," ^ string_of_int h ^ ")"
 117   | CoFix i -> s2 ^ ".cfx(" ^ string_of_int i ^ ")"
 118   | Ind (b,i,l)->s2 ^".ind(" ^(if b then "1" else "0")^ "," ^ string_of_int i ^
 119       "," ^ string_of_int l ^ ")"
 120   | Con (i,j,l) -> s2 ^ ".con(" ^ string_of_int i ^ "," ^ string_of_int j ^
 121       "," ^ string_of_int l ^ ")"
 122 ;;
 123
 124 let mk_constructor j = function
 125   | Ref (u, Ind (_,i,l)) ->
 126       reference_of_string (string_of_reference (Ref (u, Con (i,j,l))))
 127   | r ->
 128       raise (IllFormedReference (lazy ("NON INDUCTIVE TYPE REFERENCE: " ^
 129         string_of_reference r)));
 130 ;;
 131 let mk_indty b = function
 132   | Ref (u, Con (i,_,l)) ->
 133       reference_of_string (string_of_reference (Ref (u, Ind (b,i,l))))
 134   | r ->
 135       raise (IllFormedReference (lazy
 136         ("NON INDUCTIVE TYPE CONSTRUCTOR REFERENCE: " ^ string_of_reference r)));
 137 ;;
 138
 139 let mk_fix i j = function
 140   | Ref (u, Fix (_,_,h)) ->
 141       reference_of_string (string_of_reference (Ref (u, Fix (i,j,h))))
 142   | _ -> assert false
 143 ;;
 144
 145 let mk_cofix i = function
 146   | Ref (u, CoFix _) ->
 147       reference_of_string (string_of_reference (Ref (u, CoFix i)))
 148   | _ -> assert false
 149 ;;
 150
 151 let reference_of_spec u spec =
 152   reference_of_string (string_of_reference (Ref (u, spec)))
 153 ;;
 154
 155
 156
 157