matita/components/ng_library/nCicLibrary.ml

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department, University of Bologna, Italy.
   5     ||I||
   6     ||T||  HELM is free software; you can redistribute it and/or
   7     ||A||  modify it under the terms of the GNU General Public License
   8     \   /  version 2 or (at your option) any later version.
   9      \ /   This software is distributed as is, NO WARRANTY.
  10       V_______________________________________________________________ *)
  11
  12 (* $Id$ *)
  13
  14 exception LibraryOutOfSync of string Lazy.t
  15 exception IncludedFileNotCompiled of string * string
  16
  17 let magic = 2;;
  18
  19 let refresh_uri uri = NUri.uri_of_string (NUri.string_of_uri uri);;
  20
  21 let refresh_uri_in_universe =
  22  List.map (fun (x,u) -> x, refresh_uri u)
  23 ;;
  24
  25 let refresh_uri_in_reference (NReference.Ref (uri,spec)) =
  26  NReference.reference_of_spec (refresh_uri uri) spec
  27
  28 let refresh_uri_in_term status =
  29  let rec aux =
  30   function
  31   | NCic.Meta (i,(n,NCic.Ctx l)) ->
  32      NCic.Meta (i,(n,NCic.Ctx (List.map aux l)))
  33   | NCic.Meta _ as t -> t
  34   | NCic.Const ref -> NCic.Const (refresh_uri_in_reference ref)
  35   | NCic.Sort (NCic.Type l) -> NCic.Sort (NCic.Type (refresh_uri_in_universe l))
  36   | NCic.Match (NReference.Ref (uri,spec),outtype,term,pl) ->
  37      let r = NReference.reference_of_spec (refresh_uri uri) spec in
  38      let outtype = aux outtype in
  39      let term = aux term in
  40      let pl = List.map aux pl in
  41       NCic.Match (r,outtype,term,pl)
  42   | t -> NCicUtils.map status (fun _ _ -> ()) () (fun _ -> aux) t
  43 in
  44  aux
  45 ;;
  46
  47 let refresh_uri_in_obj status (uri,height,metasenv,subst,obj_kind) =
  48  assert (metasenv = []);
  49  assert (subst = []);
  50  refresh_uri uri,height,metasenv,subst,
  51   NCicUntrusted.map_obj_kind (refresh_uri_in_term status) obj_kind
  52 ;;
  53
  54 let ng_path_of_baseuri ?(no_suffix=false) baseuri =
  55  let uri = NUri.string_of_uri baseuri in
  56  let path = String.sub uri 4 (String.length uri - 4) in
  57  let path = Helm_registry.get "matita.basedir" ^ path in
  58  let dirname = Filename.dirname path in
  59   HExtlib.mkdir dirname;
  60   if no_suffix then
  61    path
  62   else
  63    path ^ ".ng"
  64 ;;
  65
  66 let require_path path =
  67  let ch = open_in path in
  68  let mmagic,dump = Marshal.from_channel ch in
  69   close_in ch;
  70   if mmagic <> magic then
  71    raise (LibraryOutOfSync (lazy "The library is out of sync with the implementation. Please recompile the library."))
  72   else
  73    dump
  74 ;;
  75
  76 let require0 ~baseuri = require_path (ng_path_of_baseuri baseuri)
  77
  78 let db_path () = Helm_registry.get "matita.basedir" ^ "/ng_db.ng";;
  79
  80 type timestamp =
  81  [ `Obj of NUri.uri * NCic.obj
  82  | `Constr of NCic.universe * NCic.universe] list *
  83  (NUri.uri * string * NReference.reference) list
  84 ;;
  85
  86 let time0 = [],[];;
  87 let storage = ref [];;
  88 let local_aliases = ref [];;
  89
  90 let load_db,set_global_aliases,get_global_aliases,add_deps,get_deps,remove_deps=
  91  let global_aliases = ref [] in
  92  let rev_includes_map = ref NUri.UriMap.empty in
  93  let store_db () =
  94   let ch = open_out (db_path ()) in
  95   Marshal.to_channel ch (magic,(!global_aliases,!rev_includes_map)) [];
  96   close_out ch in
  97  let load_db () =
  98   HExtlib.mkdir (Helm_registry.get "matita.basedir");
  99   try
 100    let ga,im = require_path (db_path ()) in
 101    let ga =
 102     List.map
 103      (fun (uri,name,NReference.Ref (uri2,spec)) ->
 104        refresh_uri uri,name,NReference.reference_of_spec (refresh_uri uri2) spec
 105      ) ga in
 106    let im =
 107     NUri.UriMap.fold
 108      (fun u l im -> NUri.UriMap.add (refresh_uri u) (List.map refresh_uri l) im
 109      ) im NUri.UriMap.empty
 110    in
 111     global_aliases := ga;
 112     rev_includes_map := im
 113   with
 114    Sys_error _ -> () in
 115  let get_deps u =
 116   let get_deps_one_step u =
 117     try NUri.UriMap.find u !rev_includes_map with Not_found -> [] in
 118   let rec aux res =
 119    function
 120       [] -> res
 121     | he::tl ->
 122        if List.mem he res then
 123         aux res tl
 124        else
 125         aux (he::res) (get_deps_one_step he @ tl)
 126   in
 127    aux [] [u] in
 128  let remove_deps u =
 129   rev_includes_map := NUri.UriMap.remove u !rev_includes_map;
 130   rev_includes_map :=
 131    NUri.UriMap.map
 132     (fun l -> List.filter (fun uri -> not (NUri.eq u uri)) l) !rev_includes_map;
 133   store_db ()
 134  in
 135   load_db,
 136   (fun ga -> global_aliases := ga; store_db ()),
 137   (fun () -> !global_aliases),
 138   (fun u l ->
 139     rev_includes_map := NUri.UriMap.add u (l @ get_deps u) !rev_includes_map;
 140     store_db ()),
 141   get_deps,
 142   remove_deps
 143 ;;
 144
 145 let init = load_db;;
 146
 147 class virtual status =
 148  object
 149   inherit NCic.status
 150   val timestamp = (time0 : timestamp)
 151   method timestamp = timestamp
 152   method set_timestamp v = {< timestamp = v >}
 153  end
 154
 155 let time_travel0 (sto,ali) =
 156  let diff_len = List.length !storage - List.length sto in
 157  let to_be_deleted,_ = HExtlib.split_nth diff_len !storage in
 158   if List.length to_be_deleted > 0 then
 159    List.iter NCicEnvironment.invalidate_item to_be_deleted;
 160   storage := sto; local_aliases := ali
 161 ;;
 162
 163 let time_travel status = time_travel0 status#timestamp;;
 164
 165 let replace status =
 166  let sto,ali = status#timestamp in
 167   storage := sto; local_aliases := ali
 168 ;;
 169
 170 type obj = string * Obj.t
 171 (* includes are transitively closed; dependencies are only immediate *)
 172 type dump =
 173  { objs: obj list ; includes: NUri.uri list; dependencies: string list }
 174
 175 class type g_dumpable_status =
 176  object
 177   method dump: dump
 178  end
 179
 180 class dumpable_status =
 181  object
 182   val db = { objs = []; includes = []; dependencies = [] }
 183   method dump = db
 184   method set_dump v = {< db = v >}
 185   method set_dumpable_status
 186    : 'status. #g_dumpable_status as 'status -> 'self
 187    = fun o -> {< db = o#dump >}
 188  end
 189
 190 let get_transitively_included status =
 191  status#dump.includes
 192 ;;
 193
 194 let dump_obj status obj =
 195  status#set_dump {status#dump with objs = obj::status#dump.objs }
 196 ;;
 197
 198 module type SerializerType =
 199  sig
 200   type dumpable_status
 201
 202   type 'a register_type =
 203    'a ->
 204     refresh_uri_in_universe:(NCic.universe -> NCic.universe) ->
 205     refresh_uri_in_term:(NCic.status -> NCic.term -> NCic.term) ->
 206     refresh_uri_in_reference:(NReference.reference -> NReference.reference) ->
 207     alias_only:bool ->
 208      dumpable_status -> dumpable_status
 209
 210   val register: < run: 'a.  string -> 'a register_type -> ('a -> obj) >
 211   val serialize: baseuri:NUri.uri -> dumpable_status -> unit
 212   val require:
 213    baseuri:NUri.uri -> fname:string -> alias_only:bool ->
 214     dumpable_status -> dumpable_status
 215   val dependencies_of: baseuri:NUri.uri -> string list
 216  end
 217
 218 module Serializer(D: sig type dumpable_s val get: dumpable_s -> dumpable_status  val set: dumpable_s -> dumpable_status -> dumpable_s end) =
 219  struct
 220   type dumpable_status = D.dumpable_s
 221   type 'a register_type =
 222    'a ->
 223     refresh_uri_in_universe:(NCic.universe -> NCic.universe) ->
 224     refresh_uri_in_term:(NCic.status -> NCic.term -> NCic.term) ->
 225     refresh_uri_in_reference:(NReference.reference -> NReference.reference) ->
 226     alias_only:bool ->
 227      dumpable_status -> dumpable_status
 228
 229   let require1 = ref (fun ~alias_only:_ _ -> assert false) (* unknown data*)
 230   let already_registered = ref []
 231
 232   let register =
 233    object
 234     method run : 'a.  string -> 'a register_type -> ('a -> obj)
 235     = fun tag require ->
 236      assert (not (List.mem tag !already_registered));
 237      already_registered := tag :: !already_registered;
 238      let old_require1 = !require1 in
 239      require1 :=
 240       (fun ~alias_only ((tag',data) as x) ->
 241         if tag=tag' then
 242          require (Obj.magic data) ~refresh_uri_in_universe ~refresh_uri_in_term
 243           ~refresh_uri_in_reference ~alias_only
 244         else
 245          old_require1 ~alias_only x);
 246      (fun x -> tag,Obj.repr x)
 247    end
 248
 249   let serialize ~baseuri status =
 250    let status = D.get status in
 251    let ch = open_out (ng_path_of_baseuri baseuri) in
 252    Marshal.to_channel ch (magic,(status#dump.dependencies,status#dump.objs)) [];
 253    close_out ch;
 254    List.iter
 255     (function
 256      | `Obj (uri,obj) ->
 257          let ch = open_out (ng_path_of_baseuri uri) in
 258          Marshal.to_channel ch (magic,obj) [];
 259          close_out ch
 260      | `Constr _ -> ()
 261     ) !storage;
 262    set_global_aliases (!local_aliases @ get_global_aliases ());
 263    List.iter (fun u -> add_deps u [baseuri]) status#dump.includes;
 264    time_travel0 time0
 265
 266   let require2 ~baseuri ~alias_only status =
 267    try
 268     let s = D.get status in
 269     let status =
 270      D.set status
 271       (s#set_dump
 272         {s#dump with
 273         includes = baseuri::List.filter ((<>) baseuri) s#dump.includes}) in
 274     let _dependencies,dump = require0 ~baseuri in
 275      List.fold_right (!require1 ~alias_only) dump status
 276    with
 277     Sys_error _ ->
 278      raise (IncludedFileNotCompiled(ng_path_of_baseuri baseuri,NUri.string_of_uri baseuri))
 279
 280   let dependencies_of ~baseuri = fst (require0 ~baseuri)
 281
 282   let record_include =
 283    let aux (baseuri,fname) ~refresh_uri_in_universe:_ ~refresh_uri_in_term:_
 284    ~refresh_uri_in_reference:_ ~alias_only status =
 285      let baseuri = refresh_uri baseuri in
 286      if not alias_only && List.mem baseuri (get_transitively_included (D.get status)) then status
 287      else
 288       (HLog.warn ("include " ^ (if alias_only then "alias " else "") ^ fname);
 289       let status = require2 ~baseuri ~alias_only status in
 290       HLog.warn ("done: include " ^ (if alias_only then "alias " else "") ^ fname);
 291       status)
 292    in
 293     register#run "include" aux
 294
 295   let require ~baseuri ~fname ~alias_only status =
 296    if not alias_only && List.mem baseuri (get_transitively_included (D.get status)) then status
 297    else
 298     (let status =
 299      if not alias_only then
 300       let s = D.get status in
 301        D.set status
 302         (s#set_dump {s#dump with dependencies = fname::s#dump.dependencies})
 303      else
 304       status in
 305     let status = require2 ~baseuri ~alias_only status in
 306     let s = D.get status in
 307      D.set status
 308       (s#set_dump
 309         {s#dump with
 310           objs = record_include (baseuri,fname)::s#dump.objs }))
 311 end
 312
 313 let fetch_obj status uri =
 314  let obj = require0 ~baseuri:uri in
 315   refresh_uri_in_obj status obj
 316 ;;
 317
 318 let resolve name =
 319  try
 320   HExtlib.filter_map
 321    (fun (_,name',nref) -> if name'=name then Some nref else None)
 322    (!local_aliases @ get_global_aliases ())
 323  with
 324   Not_found -> raise (NCicEnvironment.ObjectNotFound (lazy name))
 325 ;;
 326
 327 let aliases_of uri =
 328   HExtlib.filter_map
 329    (fun (uri',_,nref) ->
 330      if NUri.eq uri' uri then Some nref else None) !local_aliases
 331 ;;
 332
 333 let add_obj status ((u,_,_,_,_) as obj) =
 334  NCicEnvironment.check_and_add_obj status obj;
 335  storage := (`Obj (u,obj))::!storage;
 336   let _,height,_,_,obj = obj in
 337   let references =
 338    match obj with
 339       NCic.Constant (_,name,None,_,_) ->
 340        [u,name,NReference.reference_of_spec u NReference.Decl]
 341     | NCic.Constant (_,name,Some _,_,_) ->
 342        [u,name,NReference.reference_of_spec u (NReference.Def height)]
 343     | NCic.Fixpoint (is_ind,fl,_) ->
 344        HExtlib.list_mapi
 345         (fun (_,name,recno,_,_) i ->
 346           if is_ind then
 347            u,name,NReference.reference_of_spec u(NReference.Fix(i,recno,height))
 348           else
 349            u,name,NReference.reference_of_spec u (NReference.CoFix i)) fl
 350     | NCic.Inductive (inductive,leftno,il,_) ->
 351        List.flatten
 352         (HExtlib.list_mapi
 353          (fun (_,iname,_,cl) i ->
 354            HExtlib.list_mapi
 355             (fun (_,cname,_) j->
 356               u,cname,
 357                NReference.reference_of_spec u (NReference.Con (i,j+1,leftno))
 358             ) cl @
 359            [u,iname,
 360              NReference.reference_of_spec u
 361               (NReference.Ind (inductive,i,leftno))]
 362          ) il)
 363   in
 364   local_aliases := references @ !local_aliases;
 365   status#set_timestamp (!storage,!local_aliases)
 366 ;;
 367
 368 let add_constraint status u1 u2 =
 369   if
 370    List.exists
 371     (function `Constr (u1',u2') when u1=u1' && u2=u2' -> true | _ -> false)
 372     !storage
 373   then
 374    (*CSC: raise an exception here! *)
 375    (prerr_endline "CANNOT ADD A CONSTRAINT TWICE"; assert false);
 376   NCicEnvironment.add_lt_constraint u1 u2;
 377   storage := (`Constr (u1,u2)) :: !storage;
 378   status#set_timestamp (!storage,!local_aliases)
 379 ;;
 380
 381 let get_obj status u =
 382  try
 383   List.assq u
 384    (HExtlib.filter_map
 385     (function `Obj (u,o) -> Some (u,o) | _ -> None )
 386     !storage)
 387  with Not_found ->
 388   try fetch_obj status u
 389   with Sys_error _ ->
 390    raise (NCicEnvironment.ObjectNotFound (lazy (NUri.string_of_uri u)))
 391 ;;
 392
 393 NCicEnvironment.set_get_obj get_obj;;