matita/components/registry/helm_registry.ml

   1 (* Copyright (C) 2004-2005, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 let debug = false
  31 let debug_print s =
  32   if debug then prerr_endline ("Helm_registry debugging: " ^ (Lazy.force s))
  33
  34   (** <helpers> *)
  35
  36 let list_uniq l =
  37   let rec aux last_element = function
  38     | [] -> []
  39     | hd :: tl ->
  40         (match last_element with
  41         | Some elt when elt = hd -> aux last_element tl
  42         | _ -> hd :: aux (Some hd) tl)
  43   in
  44   aux None l
  45
  46 let starts_with prefix =
  47 (*
  48   let rex = Str.regexp (Str.quote prefix) in
  49   fun s -> Str.string_match rex s 0
  50 *)
  51   let prefix_len = String.length prefix in
  52   fun s ->
  53     try
  54       String.sub s 0 prefix_len = prefix
  55     with Invalid_argument _ -> false
  56
  57 let hashtbl_keys tbl = Hashtbl.fold (fun k _ acc -> k :: acc) tbl []
  58 let hashtbl_pairs tbl = Hashtbl.fold (fun k v acc -> (k,v) :: acc) tbl []
  59
  60   (** </helpers> *)
  61
  62 exception Malformed_key of string
  63 exception Key_not_found of string
  64 exception Cyclic_definition of string
  65 exception Type_error of string (* expected type, value, msg *)
  66 exception Parse_error of string * int * int * string  (* file, line, col, msg *)
  67
  68   (* root XML tag: used by save_to, ignored by load_from *)
  69 let root_tag = "helm_registry"
  70
  71 let magic_size = 127
  72
  73 let backup_registry registry = Hashtbl.copy registry
  74 let restore_registry backup registry =
  75   Hashtbl.clear registry;
  76   Hashtbl.iter (fun key value -> Hashtbl.add registry key value) backup
  77
  78   (* as \\w but:
  79    * - no sequences of '_' longer than 1 are permitted
  80    *)
  81 let valid_step_rex_raw = "[a-zA-Z0-9]+\\(_[a-z0A-Z-9]+\\)*"
  82 let valid_key_rex_raw =
  83   sprintf "%s\\(\\.%s\\)*" valid_step_rex_raw valid_step_rex_raw
  84 let valid_key_rex = Str.regexp ("^" ^ valid_key_rex_raw ^ "$")
  85 let interpolated_key_rex = Str.regexp ("\\$(" ^ valid_key_rex_raw ^ ")")
  86 let dot_rex = Str.regexp "\\."
  87 let spaces_rex = Str.regexp "[ \t\n\r]+"
  88 let heading_spaces_rex = Str.regexp "^[ \t\n\r]+"
  89 let margin_blanks_rex =
  90   Str.regexp "^\\([ \t\n\r]*\\)\\([^ \t\n\r]*\\)\\([ \t\n\r]*\\)$"
  91
  92 let strip_blanks s = Str.global_replace margin_blanks_rex "\\2" s
  93
  94 let split s =
  95   (* trailing blanks are removed per default by split *)
  96   Str.split spaces_rex (Str.global_replace heading_spaces_rex "" s)
  97 let merge l = String.concat " " l
  98
  99 let handle_type_error f x =
 100   try f x with exn -> raise (Type_error (Printexc.to_string exn))
 101
 102   (** marshallers/unmarshallers *)
 103 let string x = x
 104 let int = handle_type_error int_of_string
 105 let float = handle_type_error float_of_string
 106 let bool = handle_type_error bool_of_string
 107 let of_string x = x
 108 let of_int = handle_type_error string_of_int
 109 let of_float = handle_type_error string_of_float
 110 let of_bool = handle_type_error string_of_bool
 111
 112 (* FG *)
 113 let pair fst_unmarshaller snd_unmarshaller v =
 114   match Str.split spaces_rex v with
 115   | [fst; snd] -> fst_unmarshaller fst, snd_unmarshaller snd
 116   | _ -> raise (Type_error "not a pair")
 117
 118 (* FG *)
 119 let triple fst_unmarshaller snd_unmarshaller trd_unmarshaller v =
 120   match Str.split spaces_rex v with
 121   | [fst; snd; trd] -> fst_unmarshaller fst, snd_unmarshaller snd, trd_unmarshaller trd
 122   | _ -> raise (Type_error "not a triple")
 123
 124   (* escapes for xml configuration file *)
 125 let (escape, unescape) =
 126   let (in_enc, out_enc) = (`Enc_utf8, `Enc_utf8) in
 127   (Netencoding.Html.encode ~in_enc ~out_enc (),
 128    Netencoding.Html.decode ~in_enc ~out_enc ~entity_base:`Xml ())
 129
 130 let key_is_valid key =
 131   if not (Str.string_match valid_key_rex key 0) then
 132     raise (Malformed_key key)
 133
 134 let set' ?(replace=false) registry ~key ~value =
 135   debug_print (lazy(sprintf "Setting (replace: %b) %s = %s" replace key value));
 136   key_is_valid key;
 137   let add_fun = if replace then Hashtbl.replace else Hashtbl.add in
 138   add_fun registry key value
 139
 140 let unset registry = Hashtbl.remove registry
 141
 142 let env_var_of_key s = String.uppercase (Str.global_replace dot_rex "_" s)
 143
 144 let singleton = function
 145   | [] ->
 146       raise (Type_error ("empty list value found where singleton was expected"))
 147   | hd :: _ -> hd
 148
 149 let get registry key =
 150   let rec aux stack key =
 151     key_is_valid key;
 152     if List.mem key stack then begin
 153       let msg = (String.concat " -> " (List.rev stack)) ^ " -> " ^ key in
 154       raise (Cyclic_definition msg)
 155     end;
 156       (* internal value *)
 157     let registry_values = List.rev (Hashtbl.find_all registry key) in
 158     let env_value = (* environment value *)
 159       try
 160         Some (Sys.getenv (env_var_of_key key))
 161       with Not_found -> None
 162     in
 163     let values = (* resulting value *)
 164       match registry_values, env_value with
 165       | _, Some env -> [env]
 166       | [], None ->
 167           (try
 168             [ Sys.getenv key ]
 169           with Not_found -> raise (Key_not_found key))
 170       | values, None -> values
 171     in
 172     List.map (interpolate (key :: stack)) values
 173   and interpolate stack value =
 174     Str.global_substitute interpolated_key_rex
 175       (fun s ->
 176         let matched = Str.matched_string s in
 177           (* "$(var)" -> "var" *)
 178         let key = String.sub matched 2 (String.length matched - 3) in
 179         singleton (aux stack key))
 180       value
 181   in
 182   List.map strip_blanks (aux [] key)
 183
 184 let has registry key = Hashtbl.mem registry key
 185
 186 let get_typed registry unmarshaller key =
 187   let value = singleton (get registry key) in
 188   unmarshaller value
 189
 190 let set_typed registry marshaller ~key ~value =
 191   set' ~replace:true registry ~key ~value:(marshaller value)
 192
 193 let get_opt registry unmarshaller key =
 194   try
 195     Some (unmarshaller (singleton (get registry key)))
 196   with Key_not_found _ -> None
 197
 198 let get_opt_default registry unmarshaller ~default key =
 199   match get_opt registry unmarshaller key with
 200   | None -> default
 201   | Some v -> v
 202
 203 let set_opt registry marshaller ~key ~value =
 204   match value with
 205   | None -> unset registry key
 206   | Some value -> set' ~replace:true registry ~key ~value:(marshaller value)
 207
 208 let get_list registry unmarshaller key =
 209   try
 210     let tmp = get registry key in
 211     let rc = List.map unmarshaller tmp in
 212     rc
 213   with Key_not_found _ -> []
 214
 215 (* FG *)
 216 let get_pair registry fst_unmarshaller snd_unmarshaller =
 217   get_typed registry (pair fst_unmarshaller snd_unmarshaller)
 218
 219 (* FG *)
 220 let get_triple registry fst_unmarshaller snd_unmarshaller trd_unmarshaller =
 221   get_typed registry (triple fst_unmarshaller snd_unmarshaller trd_unmarshaller)
 222
 223 let set_list registry marshaller ~key ~value =
 224   (* since ocaml hash table are crazy... *)
 225   while Hashtbl.mem registry key do
 226     Hashtbl.remove registry key
 227   done;
 228   List.iter (fun v -> set' registry ~key ~value:(marshaller v)) value
 229
 230 type xml_tree =
 231   | Cdata of string
 232   | Element of string * (string * string) list * xml_tree list
 233
 234 let dot_RE = Str.regexp "\\."
 235
 236 let xml_tree_of_registry registry =
 237   let has_child name elements =
 238     List.exists
 239       (function
 240         | Element (_, ["name", name'], _) when name = name' -> true
 241         | _ -> false)
 242       elements
 243   in
 244   let rec get_child name = function
 245     | [] -> assert false
 246     | (Element (_, ["name", name'], _) as child) :: tl when name = name' ->
 247         child, tl
 248     | hd :: tl ->
 249         let child, rest = get_child name tl in
 250         child, hd :: rest
 251   in
 252   let rec add_key path value tree =
 253     match path, tree with
 254     | [key], Element (name, attrs, children) ->
 255         Element (name, attrs,
 256           Element ("key", ["name", key],
 257             [Cdata (strip_blanks value)]) :: children)
 258     | dir :: path, Element (name, attrs, children) ->
 259         if has_child dir children then
 260           let child, rest = get_child dir children in
 261           Element (name, attrs, add_key path value child :: rest)
 262         else
 263           Element (name, attrs,
 264             ((add_key path value (Element ("section", ["name", dir], [])))
 265               :: children))
 266     | _ -> assert false
 267   in
 268   Hashtbl.fold
 269     (fun k v tree -> add_key ((Str.split dot_RE k)) v tree)
 270     registry
 271     (Element (root_tag, [], []))
 272
 273 let rec stream_of_xml_tree = function
 274   | Cdata s -> Xml.xml_cdata s
 275   | Element (name, attrs, children) ->
 276       Xml.xml_nempty name
 277         (List.map (fun (n, v) -> (None, n, v)) attrs)
 278         (stream_of_xml_trees children)
 279 and stream_of_xml_trees = function
 280   | [] -> [< >]
 281   | hd :: tl -> [< stream_of_xml_tree hd; stream_of_xml_trees tl >]
 282
 283 let save_to registry fname =
 284   let token_stream = stream_of_xml_tree (xml_tree_of_registry registry) in
 285   let oc = open_out fname in
 286   Xml.pp_to_outchan token_stream oc;
 287   close_out oc
 288
 289 let rec load_from_absolute ?path registry fname =
 290   let _path = ref (match path with None -> [] | Some p -> p)in
 291     (* <section> elements entered so far *)
 292   let in_key = ref false in (* have we entered a <key> element? *)
 293   let cdata = ref "" in     (* collected cdata (inside <key> *)
 294   let push_path name = _path := name :: !_path in
 295   let pop_path () = _path := List.tl !_path in
 296   let start_element tag attrs =
 297     match tag, attrs with
 298     | "section", ["name", name] -> push_path name
 299     | "key", ["name", name] -> in_key := true; push_path name
 300     | "helm_registry", _ -> ()
 301     | "include", ["href", fname] ->
 302         debug_print (lazy ("including file " ^ fname));
 303         load_from_absolute ~path:!_path registry fname
 304     | tag, _ ->
 305         raise (Parse_error (fname, ~-1, ~-1,
 306           (sprintf "unexpected element <%s> or wrong attribute set" tag)))
 307   in
 308   let end_element tag =
 309     match tag with
 310     | "section" -> pop_path ()
 311     | "key" ->
 312         let key = String.concat "." (List.rev !_path) in
 313         set' registry ~key ~value:!cdata;
 314         cdata := "";
 315         in_key := false;
 316         pop_path ()
 317     | "include" | "helm_registry" -> ()
 318     | _ -> assert false
 319   in
 320   let character_data text =
 321     if !in_key then cdata := !cdata ^ text
 322   in
 323   let callbacks = {
 324     XmlPushParser.default_callbacks with
 325       XmlPushParser.start_element = Some start_element;
 326       XmlPushParser.end_element = Some end_element;
 327       XmlPushParser.character_data = Some character_data;
 328   } in
 329   let xml_parser = XmlPushParser.create_parser callbacks in
 330   let backup = backup_registry registry in
 331 (*   if path = None then Hashtbl.clear registry; *)
 332   try
 333     XmlPushParser.parse xml_parser (`File fname)
 334   with exn ->
 335     restore_registry backup registry;
 336     raise exn
 337
 338 let load_from registry ?path fname =
 339   if Filename.is_relative fname then begin
 340     let no_file_found = ref true in
 341     let path =
 342       match path with
 343       | Some path -> path (* path given as argument *)
 344       | None -> [ Sys.getcwd () ] (* no path given, try with cwd *)
 345     in
 346     List.iter
 347       (fun dir ->
 348         let conffile = dir ^ "/" ^ fname in
 349         if Sys.file_exists conffile then begin
 350           no_file_found := false;
 351           load_from_absolute registry conffile
 352         end)
 353        path;
 354     if !no_file_found then
 355       failwith (sprintf
 356         "Helm_registry.init: no configuration file named %s in [ %s ]"
 357         fname (String.concat "; " path))
 358   end else
 359     load_from_absolute registry fname
 360
 361 let fold registry ?prefix ?(interpolate = true) f init =
 362   let value_of k v =
 363     if interpolate then singleton (get registry k) else strip_blanks v
 364   in
 365   match prefix with
 366   | None -> Hashtbl.fold (fun k v acc -> f acc k (value_of k v)) registry init
 367   | Some s ->
 368       let key_matches = starts_with (s ^ ".") in
 369       let rec fold_filter acc = function
 370         | [] -> acc
 371         | (k,v) :: tl when key_matches k ->
 372             fold_filter (f acc k (value_of k v)) tl
 373         | _ :: tl -> fold_filter acc tl
 374       in
 375       fold_filter init (hashtbl_pairs registry)
 376
 377 let iter registry ?prefix ?interpolate f =
 378   fold registry ?prefix ?interpolate (fun _ k v -> f k v) ()
 379 let to_list registry ?prefix ?interpolate () =
 380   fold registry ?prefix ?interpolate (fun acc k v -> (k, v) :: acc) []
 381
 382 let ls registry prefix =
 383   let prefix = prefix ^ "." in
 384   let prefix_len = String.length prefix in
 385   let key_matches = starts_with prefix in
 386   let matching_keys = (* collect matching keys' _postfixes_ *)
 387     fold registry
 388       (fun acc key _ ->
 389         if key_matches key then
 390           String.sub key prefix_len (String.length key - prefix_len) :: acc
 391         else
 392           acc)
 393       []
 394   in
 395   let (sections, keys) =
 396     List.fold_left
 397       (fun (sections, keys) postfix ->
 398         match Str.split dot_rex postfix with
 399         | [key] -> (sections, key :: keys)
 400         | hd_key :: _ ->  (* length > 1 => nested section found *)
 401             (hd_key :: sections, keys)
 402         | _ -> assert false)
 403       ([], []) matching_keys
 404   in
 405   (list_uniq (List.sort Pervasives.compare sections), keys)
 406
 407 (** {2 API implementation}
 408  * functional methods above are wrapped so that they work on a default
 409  * (imperative) registry*)
 410
 411 let default_registry = Hashtbl.create magic_size
 412
 413 let get key = singleton (get default_registry key)
 414 let set = set' ~replace:true default_registry
 415 let has = has default_registry
 416 let fold ?prefix ?interpolate f init =
 417   fold default_registry ?prefix ?interpolate f init
 418 let iter = iter default_registry
 419 let to_list = to_list default_registry
 420 let ls = ls default_registry
 421 let get_typed unmarshaller = get_typed default_registry unmarshaller
 422 let get_opt unmarshaller = get_opt default_registry unmarshaller
 423 let get_opt_default unmarshaller = get_opt_default default_registry unmarshaller
 424 let get_list unmarshaller = get_list default_registry unmarshaller
 425 let get_pair unmarshaller = get_pair default_registry unmarshaller
 426 let get_triple unmarshaller = get_triple default_registry unmarshaller
 427 let set_typed marshaller = set_typed default_registry marshaller
 428 let set_opt unmarshaller = set_opt default_registry unmarshaller
 429 let set_list marshaller = set_list default_registry marshaller
 430 let unset = unset default_registry
 431 let save_to = save_to default_registry
 432 let load_from = load_from default_registry
 433 let clear () = Hashtbl.clear default_registry
 434
 435 let get_string = get_typed string
 436 let get_int = get_typed int
 437 let get_float = get_typed float
 438 let get_bool = get_typed bool
 439 let set_string = set_typed of_string
 440 let set_int = set_typed of_int
 441 let set_float = set_typed of_float
 442 let set_bool = set_typed of_bool
 443