matita/help/C/matita-xhtml.xsl

   1 <?xml version="1.0" encoding="utf-8"?>
   2
   3 <xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
   4
   5   <xsl:import href="http://docbook.sourceforge.net/release/xsl/current/xhtml/chunk.xsl"/>
   6   <xsl:output method="xml" encoding="utf-8" indent="yes"/>
   7
   8   <xsl:param name="use.id.as.filename" select="1" />
   9   <xsl:param name="html.stylesheet">docbook.css</xsl:param>
  10   <!--
  11   <xsl:param name="header.rule" select="0" />
  12   <xsl:param name="footer.rule" select="0" />
  13   -->
  14
  15   <!-- more quiet output of author information -->
  16
  17   <xsl:template match="authorgroup" mode="titlepage.mode">
  18     <ul class="authorgroup">
  19       <xsl:apply-templates mode="matita.manual.mode" />
  20     </ul>
  21   </xsl:template>
  22   <xsl:template match="author" mode="matita.manual.mode">
  23     <li class="author">
  24       <xsl:value-of select="firstname" />
  25       <xsl:text> </xsl:text>
  26       <xsl:value-of select="surname" />
  27       <xsl:text> &lt;</xsl:text>
  28       <xsl:element name="a">
  29         <xsl:attribute name="href">
  30           <xsl:text>mailto:</xsl:text>
  31           <xsl:value-of select="affiliation/address/email" />
  32         </xsl:attribute>
  33         <xsl:value-of select="affiliation/address/email" />
  34       </xsl:element>
  35       <xsl:text>&gt;</xsl:text>
  36     </li>
  37   </xsl:template>
  38
  39   <!-- only print the latest revision instead of all of them -->
  40   <!-- XXX ZACK: right now it just assumes that only one revision does exist -->
  41
  42   <xsl:template match="revhistory" mode="titlepage.mode">
  43     <div class="revhistory">
  44       <xsl:apply-templates mode="matita.manual.mode" />
  45     </div>
  46   </xsl:template>
  47   <xsl:template match="revision" mode="matita.manual.mode">
  48     <span class="revision">
  49       <xsl:text>Revision: </xsl:text>
  50       <span class="revnumber">
  51         <xsl:value-of select="revnumber" />
  52       </span>
  53       <xsl:text>, </xsl:text>
  54       <span class="date">
  55         <xsl:value-of select="date" />
  56       </span>
  57     </span>
  58   </xsl:template>
  59
  60   <!-- Matita logo on the top left corner -->
  61
  62   <xsl:template name="user.header.navigation">
  63     <a href="../../">
  64       <div class="matita_logo">
  65         <img src="../../images/matita-tiny.png" alt="Tiny Matita logo" />
  66         <span>Matita Home</span>
  67       </div>
  68     </a>
  69   </xsl:template>
  70
  71 </xsl:stylesheet>
  72