matita/lablGraphviz.ml

   1 (* Copyright (C) 2006, HELM Team.
   2  *
   3  * This file is part of HELM, an Hypertextual, Electronic
   4  * Library of Mathematics, developed at the Computer Science
   5  * Department, University of Bologna, Italy.
   6  *
   7  * HELM is free software; you can redistribute it and/or
   8  * modify it under the terms of the GNU General Public License
   9  * as published by the Free Software Foundation; either version 2
  10  * of the License, or (at your option) any later version.
  11  *
  12  * HELM is distributed in the hope that it will be useful,
  13  * but WITHOUT ANY WARRANTY; without even the implied warranty of
  14  * MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15  * GNU General Public License for more details.
  16  *
  17  * You should have received a copy of the GNU General Public License
  18  * along with HELM; if not, write to the Free Software
  19  * Foundation, Inc., 59 Temple Place - Suite 330, Boston,
  20  * MA  02111-1307, USA.
  21  *
  22  * For details, see the HELM World-Wide-Web page,
  23  * http://helm.cs.unibo.it/
  24  *)
  25
  26 (* $Id$ *)
  27
  28 open Printf
  29
  30 type attribute = string * string  (* <key, value> pair *)
  31
  32 let png_flags = "-Tpng"
  33 let map_flags = "-Tcmapx"
  34
  35 let tempfile () = Filename.temp_file "matita_" ""
  36
  37 class type graphviz_widget =
  38   object
  39     method load_graph_from_file: ?gviz_cmd:string -> string -> unit
  40     method connect_href:
  41       (GdkEvent.Button.t -> (string * string) list -> unit) -> unit
  42     method center_on_href: string -> unit
  43     method as_image: GMisc.image
  44     method as_viewport: GBin.viewport
  45   end
  46
  47 class graphviz_impl ?packing () =
  48   let viewport = GBin.viewport ?packing () in
  49   let mk_gviz_cmd gviz_cmd flags src_fname dest_fname =
  50     sprintf "cat %s | %s %s > %s" src_fname gviz_cmd flags
  51       dest_fname in
  52   let image =
  53     GMisc.image ~packing:viewport#add ~xalign:0. ~yalign:0. ~xpad:0 ~ypad:0 ()
  54   in
  55   let parse_coords s =
  56     match List.map float_of_string (HExtlib.split ~sep:',' s) with
  57     | [x1; y1; x2; y2 ] -> x1, y1, x2, y2
  58     | _ -> assert false in
  59   object (self)
  60     val mutable href_cb = fun _ _ -> ()
  61     val mutable map = []  (* list of associative list attr name -> attr value *)
  62
  63     initializer
  64       ignore (viewport#event#connect#button_press (fun button ->
  65         (*eprintf "x: %f; y: %f;\n%!" (GdkEvent.Button.x button +. viewport#hadjustment#value) (GdkEvent.Button.y button +. viewport#vadjustment#value);*)
  66         (* compute coordinates relative to image origin *)
  67         let x = GdkEvent.Button.x button +. viewport#hadjustment#value in
  68         let y = GdkEvent.Button.y button +. viewport#vadjustment#value in
  69         (try href_cb button (self#find_href x y) with Not_found -> ());
  70         false))
  71
  72     method load_graph_from_file ?(gviz_cmd = "dot") fname =
  73       let tmp_png = tempfile () in
  74       let rc = Sys.command (mk_gviz_cmd gviz_cmd png_flags fname tmp_png) in
  75       if rc <> 0 then
  76         eprintf
  77           ("Graphviz command failed (exit code: %d) on the following graph:\n"
  78            ^^ "%s\n%!")
  79           rc (HExtlib.input_file fname);
  80       image#set_file tmp_png;
  81       HExtlib.safe_remove tmp_png;
  82       let tmp_map = tempfile () in
  83       ignore (Sys.command (mk_gviz_cmd gviz_cmd map_flags fname tmp_map));
  84       self#load_map tmp_map;
  85       HExtlib.safe_remove tmp_map
  86
  87     method private load_map fname =
  88       let areas = ref [] in
  89       let p =
  90         XmlPushParser.create_parser
  91           { XmlPushParser.default_callbacks with
  92             XmlPushParser.start_element =
  93               Some (fun elt attrs ->
  94                 match elt with
  95                 | "area" -> areas := attrs :: !areas
  96                 | _ -> ()) } in
  97       XmlPushParser.parse p (`File fname);
  98       map <- !areas
  99
 100     method private find_href x y =
 101       List.find
 102         (fun attrs ->
 103           let x1, y1, x2, y2 = parse_coords (List.assoc "coords" attrs) in
 104           x1 <= x && x <= x2 && y1 <= y && y <= y2)
 105         map
 106
 107     method connect_href
 108       (cb: GdkEvent.Button.t -> (string * string) list -> unit)
 109     =
 110       href_cb <- cb
 111
 112     method center_on_href href =
 113       (*eprintf "Centering viewport on uri %s\n%!" href;*)
 114       let attrs =
 115         List.find
 116           (fun attrs ->
 117             try List.assoc "href" attrs = href with Not_found -> false)
 118           map in
 119       try
 120         let x1, y1, x2, y2 = parse_coords (List.assoc "coords" attrs) in
 121         viewport#hadjustment#clamp_page ~lower:x1 ~upper:x2;
 122         viewport#vadjustment#clamp_page ~lower:y1 ~upper:y2;
 123       with Not_found -> ()
 124
 125     method as_image = image
 126     method as_viewport = viewport
 127
 128   end
 129
 130 let graphviz ?packing () =
 131   (new graphviz_impl ?packing () :> graphviz_widget)
 132