matita/library/nat/gcd.ma

   1 (**************************************************************************)
   2 (*       ___                                                                *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||       A.Asperti, C.Sacerdoti Coen,                          *)
   8 (*      ||A||       E.Tassi, S.Zacchiroli                                 *)
   9 (*      \   /                                                             *)
  10 (*       \ /        Matita is distributed under the terms of the          *)
  11 (*        v         GNU Lesser General Public License Version 2.1         *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 set "baseuri" "cic:/matita/nat/gcd".
  16
  17 include "nat/primes.ma".
  18
  19 let rec gcd_aux p m n: nat \def
  20 match divides_b n m with
  21 [ true \Rightarrow n
  22 | false \Rightarrow
  23   match p with
  24   [O \Rightarrow n
  25   |(S q) \Rightarrow gcd_aux q n (m \mod n)]].
  26
  27 definition gcd : nat \to nat \to nat \def
  28 \lambda n,m:nat.
  29   match leb n m with
  30   [ true \Rightarrow
  31     match n with
  32     [ O \Rightarrow m
  33     | (S p) \Rightarrow gcd_aux (S p) m (S p) ]
  34   | false \Rightarrow
  35     match m with
  36     [ O \Rightarrow n
  37     | (S p) \Rightarrow gcd_aux (S p) n (S p) ]].
  38
  39 theorem divides_mod: \forall p,m,n:nat. O < n \to p \divides m \to p \divides n \to
  40 p \divides (m \mod n).
  41 intros.elim H1.elim H2.
  42 (* apply (witness ? ? (n2 - n1*(m / n))). *)
  43 apply witness[|
  44 rewrite > distr_times_minus.
  45 rewrite < H3 in \vdash (? ? ? (? % ?)).
  46 rewrite < assoc_times.
  47 rewrite < H4 in \vdash (? ? ? (? ? (? % ?))).
  48 apply sym_eq.apply plus_to_minus.
  49 rewrite > sym_times.
  50 letin x \def div.
  51 rewrite < (div_mod ? ? H).
  52 reflexivity.
  53 ]
  54 qed.
  55
  56 theorem divides_mod_to_divides: \forall p,m,n:nat. O < n \to
  57 p \divides (m \mod n) \to p \divides n \to p \divides m.
  58 intros.elim H1.elim H2.
  59 apply (witness p m ((n1*(m / n))+n2)).
  60 rewrite > distr_times_plus.
  61 rewrite < H3.
  62 rewrite < assoc_times.
  63 rewrite < H4.rewrite < sym_times.
  64 apply div_mod.assumption.
  65 qed.
  66
  67 theorem divides_gcd_aux_mn: \forall p,m,n. O < n \to n \le m \to n \le p \to
  68 gcd_aux p m n \divides m \land gcd_aux p m n \divides n.
  69 intro.elim p.
  70 absurd (O < n).assumption.apply le_to_not_lt.assumption.
  71 cut ((n1 \divides m) \lor (n1 \ndivides m)).
  72 simplify.
  73 elim Hcut.rewrite > divides_to_divides_b_true.
  74 simplify.
  75 split.assumption.apply (witness n1 n1 (S O)).apply times_n_SO.
  76 assumption.assumption.
  77 rewrite > not_divides_to_divides_b_false.
  78 simplify.
  79 cut (gcd_aux n n1 (m \mod n1) \divides n1 \land
  80 gcd_aux n n1 (m \mod n1) \divides mod m n1).
  81 elim Hcut1.
  82 split.apply (divides_mod_to_divides ? ? n1).
  83 assumption.assumption.assumption.assumption.
  84 apply H.
  85 cut (O \lt m \mod n1 \lor O = mod m n1).
  86 elim Hcut1.assumption.
  87 apply False_ind.apply H4.apply mod_O_to_divides.
  88 assumption.apply sym_eq.assumption.
  89 apply le_to_or_lt_eq.apply le_O_n.
  90 apply lt_to_le.
  91 apply lt_mod_m_m.assumption.
  92 apply le_S_S_to_le.
  93 apply (trans_le ? n1).
  94 change with (m \mod n1 < n1).
  95 apply lt_mod_m_m.assumption.assumption.
  96 assumption.assumption.
  97 apply (decidable_divides n1 m).assumption.
  98 qed.
  99
 100 theorem divides_gcd_nm: \forall n,m.
 101 gcd n m \divides m \land gcd n m \divides n.
 102 intros.
 103 (*CSC: simplify simplifies too much because of a redex in gcd *)
 104 change with
 105 (match leb n m with
 106   [ true \Rightarrow
 107     match n with
 108     [ O \Rightarrow m
 109     | (S p) \Rightarrow gcd_aux (S p) m (S p) ]
 110   | false \Rightarrow
 111     match m with
 112     [ O \Rightarrow n
 113     | (S p) \Rightarrow gcd_aux (S p) n (S p) ] ] \divides m
 114 \land
 115 match leb n m with
 116   [ true \Rightarrow
 117     match n with
 118     [ O \Rightarrow m
 119     | (S p) \Rightarrow gcd_aux (S p) m (S p) ]
 120   | false \Rightarrow
 121     match m with
 122     [ O \Rightarrow n
 123     | (S p) \Rightarrow gcd_aux (S p) n (S p) ] ] \divides n).
 124 apply (leb_elim n m).
 125 apply (nat_case1 n).
 126 simplify.intros.split.
 127 apply (witness m m (S O)).apply times_n_SO.
 128 apply (witness m O O).apply times_n_O.
 129 intros.change with
 130 (gcd_aux (S m1) m (S m1) \divides m
 131 \land
 132 gcd_aux (S m1) m (S m1) \divides (S m1)).
 133 apply divides_gcd_aux_mn.
 134 unfold lt.apply le_S_S.apply le_O_n.
 135 assumption.apply le_n.
 136 simplify.intro.
 137 apply (nat_case1 m).
 138 simplify.intros.split.
 139 apply (witness n O O).apply times_n_O.
 140 apply (witness n n (S O)).apply times_n_SO.
 141 intros.change with
 142 (gcd_aux (S m1) n (S m1) \divides (S m1)
 143 \land
 144 gcd_aux (S m1) n (S m1) \divides n).
 145 cut (gcd_aux (S m1) n (S m1) \divides n
 146 \land
 147 gcd_aux (S m1) n (S m1) \divides S m1).
 148 elim Hcut.split.assumption.assumption.
 149 apply divides_gcd_aux_mn.
 150 unfold lt.apply le_S_S.apply le_O_n.
 151 apply not_lt_to_le.unfold Not. unfold lt.intro.apply H.
 152 rewrite > H1.apply (trans_le ? (S n)).
 153 apply le_n_Sn.assumption.apply le_n.
 154 qed.
 155
 156 theorem divides_gcd_n: \forall n,m. gcd n m \divides n.
 157 intros.
 158 exact (proj2  ? ? (divides_gcd_nm n m)).
 159 qed.
 160
 161 theorem divides_gcd_m: \forall n,m. gcd n m \divides m.
 162 intros.
 163 exact (proj1 ? ? (divides_gcd_nm n m)).
 164 qed.
 165
 166 theorem divides_gcd_aux: \forall p,m,n,d. O < n \to n \le m \to n \le p \to
 167 d \divides m \to d \divides n \to d \divides gcd_aux p m n.
 168 intro.elim p.
 169 absurd (O < n).assumption.apply le_to_not_lt.assumption.
 170 simplify.
 171 cut (n1 \divides m \lor n1 \ndivides m).
 172 elim Hcut.
 173 rewrite > divides_to_divides_b_true.
 174 simplify.assumption.
 175 assumption.assumption.
 176 rewrite > not_divides_to_divides_b_false.
 177 simplify.
 178 apply H.
 179 cut (O \lt m \mod n1 \lor O = m \mod n1).
 180 elim Hcut1.assumption.
 181 absurd (n1 \divides m).apply mod_O_to_divides.
 182 assumption.apply sym_eq.assumption.assumption.
 183 apply le_to_or_lt_eq.apply le_O_n.
 184 apply lt_to_le.
 185 apply lt_mod_m_m.assumption.
 186 apply le_S_S_to_le.
 187 apply (trans_le ? n1).
 188 change with (m \mod n1 < n1).
 189 apply lt_mod_m_m.assumption.assumption.
 190 assumption.
 191 apply divides_mod.assumption.assumption.assumption.
 192 assumption.assumption.
 193 apply (decidable_divides n1 m).assumption.
 194 qed.
 195
 196 theorem divides_d_gcd: \forall m,n,d.
 197 d \divides m \to d \divides n \to d \divides gcd n m.
 198 intros.
 199 (*CSC: here simplify simplifies too much because of a redex in gcd *)
 200 change with
 201 (d \divides
 202 match leb n m with
 203   [ true \Rightarrow
 204     match n with
 205     [ O \Rightarrow m
 206     | (S p) \Rightarrow gcd_aux (S p) m (S p) ]
 207   | false \Rightarrow
 208     match m with
 209     [ O \Rightarrow n
 210     | (S p) \Rightarrow gcd_aux (S p) n (S p) ]]).
 211 apply (leb_elim n m).
 212 apply (nat_case1 n).simplify.intros.assumption.
 213 intros.
 214 change with (d \divides gcd_aux (S m1) m (S m1)).
 215 apply divides_gcd_aux.
 216 unfold lt.apply le_S_S.apply le_O_n.assumption.apply le_n.assumption.
 217 rewrite < H2.assumption.
 218 apply (nat_case1 m).simplify.intros.assumption.
 219 intros.
 220 change with (d \divides gcd_aux (S m1) n (S m1)).
 221 apply divides_gcd_aux.
 222 unfold lt.apply le_S_S.apply le_O_n.
 223 apply lt_to_le.apply not_le_to_lt.assumption.apply le_n.assumption.
 224 rewrite < H2.assumption.
 225 qed.
 226
 227 theorem eq_minus_gcd_aux: \forall p,m,n.O < n \to n \le m \to n \le p \to
 228 \exists a,b. a*n - b*m = gcd_aux p m n \lor b*m - a*n = gcd_aux p m n.
 229 intro.
 230 elim p.
 231 absurd (O < n).assumption.apply le_to_not_lt.assumption.
 232 cut (O < m).
 233 cut (n1 \divides m \lor  n1 \ndivides m).
 234 simplify.
 235 elim Hcut1.
 236 rewrite > divides_to_divides_b_true.
 237 simplify.
 238 apply (ex_intro ? ? (S O)).
 239 apply (ex_intro ? ? O).
 240 left.simplify.rewrite < plus_n_O.
 241 apply sym_eq.apply minus_n_O.
 242 assumption.assumption.
 243 rewrite > not_divides_to_divides_b_false.
 244 change with
 245 (\exists a,b.
 246 a*n1 - b*m = gcd_aux n n1 (m \mod n1)
 247 \lor
 248 b*m - a*n1 = gcd_aux n n1 (m \mod n1)).
 249 cut
 250 (\exists a,b.
 251 a*(m \mod n1) - b*n1= gcd_aux n n1 (m \mod n1)
 252 \lor
 253 b*n1 - a*(m \mod n1) = gcd_aux n n1 (m \mod n1)).
 254 elim Hcut2.elim H5.elim H6.
 255 (* first case *)
 256 rewrite < H7.
 257 apply (ex_intro ? ? (a1+a*(m / n1))).
 258 apply (ex_intro ? ? a).
 259 right.
 260 rewrite < sym_plus.
 261 rewrite < (sym_times n1).
 262 rewrite > distr_times_plus.
 263 rewrite > (sym_times n1).
 264 rewrite > (sym_times n1).
 265 rewrite > (div_mod m n1) in \vdash (? ? (? % ?) ?).
 266 rewrite > assoc_times.
 267 rewrite < sym_plus.
 268 rewrite > distr_times_plus.
 269 rewrite < eq_minus_minus_minus_plus.
 270 rewrite < sym_plus.
 271 rewrite < plus_minus.
 272 rewrite < minus_n_n.reflexivity.
 273 apply le_n.
 274 assumption.
 275 (* second case *)
 276 rewrite < H7.
 277 apply (ex_intro ? ? (a1+a*(m / n1))).
 278 apply (ex_intro ? ? a).
 279 left.
 280 (* clear Hcut2.clear H5.clear H6.clear H. *)
 281 rewrite > sym_times.
 282 rewrite > distr_times_plus.
 283 rewrite > sym_times.
 284 rewrite > (sym_times n1).
 285 rewrite > (div_mod m n1) in \vdash (? ? (? ? %) ?).
 286 rewrite > distr_times_plus.
 287 rewrite > assoc_times.
 288 rewrite < eq_minus_minus_minus_plus.
 289 rewrite < sym_plus.
 290 rewrite < plus_minus.
 291 rewrite < minus_n_n.reflexivity.
 292 apply le_n.
 293 assumption.
 294 apply (H n1 (m \mod n1)).
 295 cut (O \lt m \mod n1 \lor O = m \mod n1).
 296 elim Hcut2.assumption.
 297 absurd (n1 \divides m).apply mod_O_to_divides.
 298 assumption.
 299 symmetry.assumption.assumption.
 300 apply le_to_or_lt_eq.apply le_O_n.
 301 apply lt_to_le.
 302 apply lt_mod_m_m.assumption.
 303 apply le_S_S_to_le.
 304 apply (trans_le ? n1).
 305 change with (m \mod n1 < n1).
 306 apply lt_mod_m_m.
 307 assumption.assumption.assumption.assumption.
 308 apply (decidable_divides n1 m).assumption.
 309 apply (lt_to_le_to_lt ? n1).assumption.assumption.
 310 qed.
 311
 312 theorem eq_minus_gcd:
 313  \forall m,n.\exists a,b.a*n - b*m = (gcd n m) \lor b*m - a*n = (gcd n m).
 314 intros.
 315 unfold gcd.
 316 apply (leb_elim n m).
 317 apply (nat_case1 n).
 318 simplify.intros.
 319 apply (ex_intro ? ? O).
 320 apply (ex_intro ? ? (S O)).
 321 right.simplify.
 322 rewrite < plus_n_O.
 323 apply sym_eq.apply minus_n_O.
 324 intros.
 325 change with
 326 (\exists a,b.
 327 a*(S m1) - b*m = (gcd_aux (S m1) m (S m1))
 328 \lor b*m - a*(S m1) = (gcd_aux (S m1) m (S m1))).
 329 apply eq_minus_gcd_aux.
 330 unfold lt. apply le_S_S.apply le_O_n.
 331 assumption.apply le_n.
 332 apply (nat_case1 m).
 333 simplify.intros.
 334 apply (ex_intro ? ? (S O)).
 335 apply (ex_intro ? ? O).
 336 left.simplify.
 337 rewrite < plus_n_O.
 338 apply sym_eq.apply minus_n_O.
 339 intros.
 340 change with
 341 (\exists a,b.
 342 a*n - b*(S m1) = (gcd_aux (S m1) n (S m1))
 343 \lor b*(S m1) - a*n = (gcd_aux (S m1) n (S m1))).
 344 cut
 345 (\exists a,b.
 346 a*(S m1) - b*n = (gcd_aux (S m1) n (S m1))
 347 \lor
 348 b*n - a*(S m1) = (gcd_aux (S m1) n (S m1))).
 349 elim Hcut.elim H2.elim H3.
 350 apply (ex_intro ? ? a1).
 351 apply (ex_intro ? ? a).
 352 right.assumption.
 353 apply (ex_intro ? ? a1).
 354 apply (ex_intro ? ? a).
 355 left.assumption.
 356 apply eq_minus_gcd_aux.
 357 unfold lt. apply le_S_S.apply le_O_n.
 358 apply lt_to_le.apply not_le_to_lt.assumption.
 359 apply le_n.
 360 qed.
 361
 362 (* some properties of gcd *)
 363
 364 theorem gcd_O_n: \forall n:nat. gcd O n = n.
 365 intro.simplify.reflexivity.
 366 qed.
 367
 368 theorem gcd_O_to_eq_O:\forall m,n:nat. (gcd m n) = O \to
 369 m = O \land n = O.
 370 intros.cut (O \divides n \land O \divides m).
 371 elim Hcut.elim H2.split.
 372 assumption.elim H1.assumption.
 373 rewrite < H.
 374 apply divides_gcd_nm.
 375 qed.
 376
 377 theorem lt_O_gcd:\forall m,n:nat. O < n \to O < gcd m n.
 378 intros.
 379 apply (nat_case1 (gcd m n)).
 380 intros.
 381 generalize in match (gcd_O_to_eq_O m n H1).
 382 intros.elim H2.
 383 rewrite < H4 in \vdash (? ? %).assumption.
 384 intros.unfold lt.apply le_S_S.apply le_O_n.
 385 qed.
 386
 387 theorem symmetric_gcd: symmetric nat gcd.
 388 (*CSC: bug here: unfold symmetric does not work *)
 389 change with
 390 (\forall n,m:nat. gcd n m = gcd m n).
 391 intros.
 392 cut (O < (gcd n m) \lor O = (gcd n m)).
 393 elim Hcut.
 394 cut (O < (gcd m n) \lor O = (gcd m n)).
 395 elim Hcut1.
 396 apply antisym_le.
 397 apply divides_to_le.assumption.
 398 apply divides_d_gcd.apply divides_gcd_n.apply divides_gcd_m.
 399 apply divides_to_le.assumption.
 400 apply divides_d_gcd.apply divides_gcd_n.apply divides_gcd_m.
 401 rewrite < H1.
 402 cut (m=O \land n=O).
 403 elim Hcut2.rewrite > H2.rewrite > H3.reflexivity.
 404 apply gcd_O_to_eq_O.apply sym_eq.assumption.
 405 apply le_to_or_lt_eq.apply le_O_n.
 406 rewrite < H.
 407 cut (n=O \land m=O).
 408 elim Hcut1.rewrite > H1.rewrite > H2.reflexivity.
 409 apply gcd_O_to_eq_O.apply sym_eq.assumption.
 410 apply le_to_or_lt_eq.apply le_O_n.
 411 qed.
 412
 413 variant sym_gcd: \forall n,m:nat. gcd n m = gcd m n \def
 414 symmetric_gcd.
 415
 416 theorem le_gcd_times: \forall m,n,p:nat. O< p \to gcd m n \le gcd m (n*p).
 417 intros.
 418 apply (nat_case n).apply le_n.
 419 intro.
 420 apply divides_to_le.
 421 apply lt_O_gcd.
 422 rewrite > (times_n_O O).
 423 apply lt_times.unfold lt.apply le_S_S.apply le_O_n.assumption.
 424 apply divides_d_gcd.
 425 apply (transitive_divides ? (S m1)).
 426 apply divides_gcd_m.
 427 apply (witness ? ? p).reflexivity.
 428 apply divides_gcd_n.
 429 qed.
 430
 431 theorem gcd_times_SO_to_gcd_SO: \forall m,n,p:nat. O < n \to O < p \to
 432 gcd m (n*p) = (S O) \to gcd m n = (S O).
 433 intros.
 434 apply antisymmetric_le.
 435 rewrite < H2.
 436 apply le_gcd_times.assumption.
 437 change with (O < gcd m n).
 438 apply lt_O_gcd.assumption.
 439 qed.
 440
 441 (* for the "converse" of the previous result see the end  of this development *)
 442
 443 theorem gcd_SO_n: \forall n:nat. gcd (S O) n = (S O).
 444 intro.
 445 apply antisym_le.apply divides_to_le.unfold lt.apply le_n.
 446 apply divides_gcd_n.
 447 cut (O < gcd (S O) n \lor O = gcd (S O) n).
 448 elim Hcut.assumption.
 449 apply False_ind.
 450 apply (not_eq_O_S O).
 451 cut ((S O)=O \land n=O).
 452 elim Hcut1.apply sym_eq.assumption.
 453 apply gcd_O_to_eq_O.apply sym_eq.assumption.
 454 apply le_to_or_lt_eq.apply le_O_n.
 455 qed.
 456
 457 theorem divides_gcd_mod: \forall m,n:nat. O < n \to
 458 divides (gcd m n) (gcd n (m \mod n)).
 459 intros.
 460 apply divides_d_gcd.
 461 apply divides_mod.assumption.
 462 apply divides_gcd_n.
 463 apply divides_gcd_m.
 464 apply divides_gcd_m.
 465 qed.
 466
 467 theorem divides_mod_gcd: \forall m,n:nat. O < n \to
 468 divides (gcd n (m \mod n)) (gcd m n) .
 469 intros.
 470 apply divides_d_gcd.
 471 apply divides_gcd_n.
 472 apply (divides_mod_to_divides ? ? n).
 473 assumption.
 474 apply divides_gcd_m.
 475 apply divides_gcd_n.
 476 qed.
 477
 478 theorem gcd_mod: \forall m,n:nat. O < n \to
 479 (gcd n (m \mod n)) = (gcd m n) .
 480 intros.
 481 apply antisymmetric_divides.
 482 apply divides_mod_gcd.assumption.
 483 apply divides_gcd_mod.assumption.
 484 qed.
 485
 486 (* gcd and primes *)
 487
 488 theorem prime_to_gcd_SO: \forall n,m:nat. prime n \to n \ndivides m \to
 489 gcd n m = (S O).
 490 intros.unfold prime in H.
 491 elim H.
 492 apply antisym_le.
 493 apply not_lt_to_le.unfold Not.unfold lt.
 494 intro.
 495 apply H1.rewrite < (H3 (gcd n m)).
 496 apply divides_gcd_m.
 497 apply divides_gcd_n.assumption.
 498 cut (O < gcd n m \lor O = gcd n m).
 499 elim Hcut.assumption.
 500 apply False_ind.
 501 apply (not_le_Sn_O (S O)).
 502 cut (n=O \land m=O).
 503 elim Hcut1.rewrite < H5 in \vdash (? ? %).assumption.
 504 apply gcd_O_to_eq_O.apply sym_eq.assumption.
 505 apply le_to_or_lt_eq.apply le_O_n.
 506 qed.
 507
 508 theorem divides_times_to_divides: \forall n,p,q:nat.prime n \to n \divides p*q \to
 509 n \divides p \lor n \divides q.
 510 intros.
 511 cut (n \divides p \lor n \ndivides p)
 512   [elim Hcut
 513     [left.assumption
 514     |right.
 515      cut (\exists a,b. a*n - b*p = (S O) \lor b*p - a*n = (S O))
 516        [elim Hcut1.elim H3.elim H4
 517          [(* first case *)
 518           rewrite > (times_n_SO q).rewrite < H5.
 519           rewrite > distr_times_minus.
 520           rewrite > (sym_times q (a1*p)).
 521           rewrite > (assoc_times a1).
 522           elim H1.
 523           (*
 524              rewrite > H6.
 525              applyS (witness n (n*(q*a-a1*n2)) (q*a-a1*n2))
 526              reflexivity. *);
 527           applyS (witness n ? ? (refl_eq ? ?)) (* timeout=50 *).
 528           (*
 529           rewrite < (sym_times n).rewrite < assoc_times.
 530           rewrite > (sym_times q).rewrite > assoc_times.
 531           rewrite < (assoc_times a1).rewrite < (sym_times n).
 532           rewrite > (assoc_times n).
 533           rewrite < distr_times_minus.
 534           apply (witness ? ? (q*a-a1*n2)).reflexivity
 535           *)
 536          |(* second case *)
 537           rewrite > (times_n_SO q).rewrite < H5.
 538           rewrite > distr_times_minus.
 539           rewrite > (sym_times q (a1*p)).
 540           rewrite > (assoc_times a1).
 541           elim H1.rewrite > H6.
 542           rewrite < sym_times.rewrite > assoc_times.
 543           rewrite < (assoc_times q).
 544           rewrite < (sym_times n).
 545           rewrite < distr_times_minus.
 546           apply (witness ? ? (n2*a1-q*a)).reflexivity
 547         ](* end second case *)
 548      |rewrite < (prime_to_gcd_SO n p)
 549        [apply eq_minus_gcd|assumption|assumption
 550        ]
 551      ]
 552    ]
 553  |apply (decidable_divides n p).
 554   apply (trans_lt ? (S O))
 555     [unfold lt.apply le_n
 556     |unfold prime in H.elim H. assumption
 557     ]
 558   ]
 559 qed.
 560
 561 theorem eq_gcd_times_SO: \forall m,n,p:nat. O < n \to O < p \to
 562 gcd m n = (S O) \to gcd m p = (S O) \to gcd m (n*p) = (S O).
 563 intros.
 564 apply antisymmetric_le.
 565 apply not_lt_to_le.
 566 unfold Not.intro.
 567 cut (divides (smallest_factor (gcd m (n*p))) n \lor
 568      divides (smallest_factor (gcd m (n*p))) p).
 569 elim Hcut.
 570 apply (not_le_Sn_n (S O)).
 571 change with ((S O) < (S O)).
 572 rewrite < H2 in \vdash (? ? %).
 573 apply (lt_to_le_to_lt ? (smallest_factor (gcd m (n*p)))).
 574 apply lt_SO_smallest_factor.assumption.
 575 apply divides_to_le.
 576 rewrite > H2.unfold lt.apply le_n.
 577 apply divides_d_gcd.assumption.
 578 apply (transitive_divides ? (gcd m (n*p))).
 579 apply divides_smallest_factor_n.
 580 apply (trans_lt ? (S O)). unfold lt. apply le_n. assumption.
 581 apply divides_gcd_n.
 582 apply (not_le_Sn_n (S O)).
 583 change with ((S O) < (S O)).
 584 rewrite < H3 in \vdash (? ? %).
 585 apply (lt_to_le_to_lt ? (smallest_factor (gcd m (n*p)))).
 586 apply lt_SO_smallest_factor.assumption.
 587 apply divides_to_le.
 588 rewrite > H3.unfold lt.apply le_n.
 589 apply divides_d_gcd.assumption.
 590 apply (transitive_divides ? (gcd m (n*p))).
 591 apply divides_smallest_factor_n.
 592 apply (trans_lt ? (S O)). unfold lt. apply le_n. assumption.
 593 apply divides_gcd_n.
 594 apply divides_times_to_divides.
 595 apply prime_smallest_factor_n.
 596 assumption.
 597 apply (transitive_divides ? (gcd m (n*p))).
 598 apply divides_smallest_factor_n.
 599 apply (trans_lt ? (S O)).unfold lt. apply le_n. assumption.
 600 apply divides_gcd_m.
 601 change with (O < gcd m (n*p)).
 602 apply lt_O_gcd.
 603 rewrite > (times_n_O O).
 604 apply lt_times.assumption.assumption.
 605 qed.
 606
 607 theorem gcd_SO_to_divides_times_to_divides: \forall m,n,p:nat. O < n \to
 608 gcd n m = (S O) \to n \divides (m*p) \to n \divides p.
 609 intros.
 610 cut (n \divides p \lor n \ndivides p)
 611   [elim Hcut
 612     [assumption
 613     |cut (\exists a,b. a*n - b*m = (S O) \lor b*m - a*n = (S O))
 614       [elim Hcut1.elim H4.elim H5
 615         [(* first case *)
 616           rewrite > (times_n_SO p).rewrite < H6.
 617           rewrite > distr_times_minus.
 618           rewrite > (sym_times p (a1*m)).
 619           rewrite > (assoc_times a1).
 620           elim H2.
 621           applyS (witness n ? ? (refl_eq ? ?)) (* timeout=50 *).
 622          |(* second case *)
 623           rewrite > (times_n_SO p).rewrite < H6.
 624           rewrite > distr_times_minus.
 625           rewrite > (sym_times p (a1*m)).
 626           rewrite > (assoc_times a1).
 627           elim H2.
 628           applyS (witness n ? ? (refl_eq ? ?)).
 629         ](* end second case *)
 630      |rewrite < H1.apply eq_minus_gcd.
 631      ]
 632    ]
 633  |apply (decidable_divides n p).
 634   assumption.
 635  ]
 636 qed.