matita/library/nat/primes.ma

   1 (**************************************************************************)
   2 (*       ___                                                                *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||       A.Asperti, C.Sacerdoti Coen,                          *)
   8 (*      ||A||       E.Tassi, S.Zacchiroli                                 *)
   9 (*      \   /                                                             *)
  10 (*       \ /        Matita is distributed under the terms of the          *)
  11 (*        v         GNU Lesser General Public License Version 2.1         *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 set "baseuri" "cic:/matita/nat/primes".
  16
  17 include "nat/div_and_mod.ma".
  18 include "nat/minimization.ma".
  19 include "nat/sigma_and_pi.ma".
  20 include "nat/factorial.ma".
  21
  22 inductive divides (n,m:nat) : Prop \def
  23 witness : \forall p:nat.m = times n p \to divides n m.
  24
  25 interpretation "divides" 'divides n m = (cic:/matita/nat/primes/divides.ind#xpointer(1/1) n m).
  26 interpretation "not divides" 'ndivides n m =
  27  (cic:/matita/logic/connectives/Not.con (cic:/matita/nat/primes/divides.ind#xpointer(1/1) n m)).
  28
  29 theorem reflexive_divides : reflexive nat divides.
  30 unfold reflexive.
  31 intros.
  32 exact (witness x x (S O) (times_n_SO x)).
  33 qed.
  34
  35 theorem divides_to_div_mod_spec :
  36 \forall n,m. O < n \to n \divides m \to div_mod_spec m n (m / n) O.
  37 intros.elim H1.rewrite > H2.
  38 constructor 1.assumption.
  39 apply (lt_O_n_elim n H).intros.
  40 rewrite < plus_n_O.
  41 rewrite > div_times.apply sym_times.
  42 qed.
  43
  44 theorem div_mod_spec_to_divides :
  45 \forall n,m,p. div_mod_spec m n p O \to n \divides m.
  46 intros.elim H.
  47 apply (witness n m p).
  48 rewrite < sym_times.
  49 rewrite > (plus_n_O (p*n)).assumption.
  50 qed.
  51
  52 theorem divides_to_mod_O:
  53 \forall n,m. O < n \to n \divides m \to (m \mod n) = O.
  54 intros.apply (div_mod_spec_to_eq2 m n (m / n) (m \mod n) (m / n) O).
  55 apply div_mod_spec_div_mod.assumption.
  56 apply divides_to_div_mod_spec.assumption.assumption.
  57 qed.
  58
  59 theorem mod_O_to_divides:
  60 \forall n,m. O< n \to (m \mod n) = O \to  n \divides m.
  61 intros.
  62 apply (witness n m (m / n)).
  63 rewrite > (plus_n_O (n * (m / n))).
  64 rewrite < H1.
  65 rewrite < sym_times.
  66 (* Andrea: perche' hint non lo trova ?*)
  67 apply div_mod.
  68 assumption.
  69 qed.
  70
  71 theorem divides_n_O: \forall n:nat. n \divides O.
  72 intro. apply (witness n O O).apply times_n_O.
  73 qed.
  74
  75 theorem divides_n_n: \forall n:nat. n \divides n.
  76 intro. apply (witness n n (S O)).apply times_n_SO.
  77 qed.
  78
  79 theorem divides_SO_n: \forall n:nat. (S O) \divides n.
  80 intro. apply (witness (S O) n n). simplify.apply plus_n_O.
  81 qed.
  82
  83 theorem divides_plus: \forall n,p,q:nat.
  84 n \divides p \to n \divides q \to n \divides p+q.
  85 intros.
  86 elim H.elim H1. apply (witness n (p+q) (n2+n1)).
  87 rewrite > H2.rewrite > H3.apply sym_eq.apply distr_times_plus.
  88 qed.
  89
  90 theorem divides_minus: \forall n,p,q:nat.
  91 divides n p \to divides n q \to divides n (p-q).
  92 intros.
  93 elim H.elim H1. apply (witness n (p-q) (n2-n1)).
  94 rewrite > H2.rewrite > H3.apply sym_eq.apply distr_times_minus.
  95 qed.
  96
  97 theorem divides_times: \forall n,m,p,q:nat.
  98 n \divides p \to m \divides q \to n*m \divides p*q.
  99 intros.
 100 elim H.elim H1. apply (witness (n*m) (p*q) (n2*n1)).
 101 rewrite > H2.rewrite > H3.
 102 apply (trans_eq nat ? (n*(m*(n2*n1)))).
 103 apply (trans_eq nat ? (n*(n2*(m*n1)))).
 104 apply assoc_times.
 105 apply eq_f.
 106 apply (trans_eq nat ? ((n2*m)*n1)).
 107 apply sym_eq. apply assoc_times.
 108 rewrite > (sym_times n2 m).apply assoc_times.
 109 apply sym_eq. apply assoc_times.
 110 qed.
 111
 112 theorem transitive_divides: transitive ? divides.
 113 unfold.
 114 intros.
 115 elim H.elim H1. apply (witness x z (n2*n)).
 116 rewrite > H3.rewrite > H2.
 117 apply assoc_times.
 118 qed.
 119
 120 variant trans_divides: \forall n,m,p.
 121  n \divides m \to m \divides p \to n \divides p \def transitive_divides.
 122
 123 theorem eq_mod_to_divides:\forall n,m,p. O< p \to
 124 mod n p = mod m p \to divides p (n-m).
 125 intros.
 126 cut (n \le m \or \not n \le m).
 127 elim Hcut.
 128 cut (n-m=O).
 129 rewrite > Hcut1.
 130 apply (witness p O O).
 131 apply times_n_O.
 132 apply eq_minus_n_m_O.
 133 assumption.
 134 apply (witness p (n-m) ((div n p)-(div m p))).
 135 rewrite > distr_times_minus.
 136 rewrite > sym_times.
 137 rewrite > (sym_times p).
 138 cut ((div n p)*p = n - (mod n p)).
 139 rewrite > Hcut1.
 140 rewrite > eq_minus_minus_minus_plus.
 141 rewrite > sym_plus.
 142 rewrite > H1.
 143 rewrite < div_mod.reflexivity.
 144 assumption.
 145 apply sym_eq.
 146 apply plus_to_minus.
 147 rewrite > sym_plus.
 148 apply div_mod.
 149 assumption.
 150 apply (decidable_le n m).
 151 qed.
 152
 153 theorem antisymmetric_divides: antisymmetric nat divides.
 154 unfold antisymmetric.intros.elim H. elim H1.
 155 apply (nat_case1 n2).intro.
 156 rewrite > H3.rewrite > H2.rewrite > H4.
 157 rewrite < times_n_O.reflexivity.
 158 intros.
 159 apply (nat_case1 n).intro.
 160 rewrite > H2.rewrite > H3.rewrite > H5.
 161 rewrite < times_n_O.reflexivity.
 162 intros.
 163 apply antisymmetric_le.
 164 rewrite > H2.rewrite > times_n_SO in \vdash (? % ?).
 165 apply le_times_r.rewrite > H4.apply le_S_S.apply le_O_n.
 166 rewrite > H3.rewrite > times_n_SO in \vdash (? % ?).
 167 apply le_times_r.rewrite > H5.apply le_S_S.apply le_O_n.
 168 qed.
 169
 170 (* divides le *)
 171 theorem divides_to_le : \forall n,m. O < m \to n \divides m \to n \le m.
 172 intros. elim H1.rewrite > H2.cut (O < n2).
 173 apply (lt_O_n_elim n2 Hcut).intro.rewrite < sym_times.
 174 simplify.rewrite < sym_plus.
 175 apply le_plus_n.
 176 elim (le_to_or_lt_eq O n2).
 177 assumption.
 178 absurd (O<m).assumption.
 179 rewrite > H2.rewrite < H3.rewrite < times_n_O.
 180 apply (not_le_Sn_n O).
 181 apply le_O_n.
 182 qed.
 183
 184 theorem divides_to_lt_O : \forall n,m. O < m \to n \divides m \to O < n.
 185 intros.elim H1.
 186 elim (le_to_or_lt_eq O n (le_O_n n)).
 187 assumption.
 188 rewrite < H3.absurd (O < m).assumption.
 189 rewrite > H2.rewrite < H3.
 190 simplify.exact (not_le_Sn_n O).
 191 qed.
 192
 193 (*divides and div*)
 194
 195 theorem divides_to_times_div: \forall n,m:nat.
 196 O \lt m \to m \divides n \to (n / m) * m = n.
 197 intros.
 198 rewrite > plus_n_O.
 199 apply sym_eq.
 200 cut (n \mod m = O)
 201 [ rewrite < Hcut.
 202   apply div_mod.
 203   assumption
 204 | apply divides_to_mod_O;
 205     assumption.
 206 ]
 207 qed.
 208
 209 (*to remove hypotesis b > 0*)
 210 theorem divides_to_eq_times_div_div_times: \forall a,b,c:nat.
 211 O \lt b \to c \divides b \to a * (b /c) = (a*b)/c.
 212 (*theorem divides_to_eq_times_div_div_times: \forall a,b,c:nat.
 213 c \divides b \to a * (b /c) = (a*b)/c.*)
 214 intros.
 215 elim H1.
 216 rewrite > H2.
 217 rewrite > (sym_times c n2).
 218 cut(O \lt c)
 219 [ rewrite > (lt_O_to_div_times n2 c)
 220   [ rewrite < assoc_times.
 221     rewrite > (lt_O_to_div_times (a *n2) c)
 222     [ reflexivity
 223     | assumption
 224     ]
 225   | assumption
 226   ]
 227 | apply (divides_to_lt_O c b);
 228     assumption.
 229 ]
 230 qed.
 231
 232 (* boolean divides *)
 233 definition divides_b : nat \to nat \to bool \def
 234 \lambda n,m :nat. (eqb (m \mod n) O).
 235
 236 theorem divides_b_to_Prop :
 237 \forall n,m:nat. O < n \to
 238 match divides_b n m with
 239 [ true \Rightarrow n \divides m
 240 | false \Rightarrow n \ndivides m].
 241 intros.unfold divides_b.
 242 apply eqb_elim.
 243 intro.simplify.apply mod_O_to_divides.assumption.assumption.
 244 intro.simplify.unfold Not.intro.apply H1.apply divides_to_mod_O.assumption.assumption.
 245 qed.
 246
 247 theorem divides_b_true_to_divides1:
 248 \forall n,m:nat. O < n \to
 249 (divides_b n m = true ) \to n \divides m.
 250 intros.
 251 change with
 252 match true with
 253 [ true \Rightarrow n \divides m
 254 | false \Rightarrow n \ndivides m].
 255 rewrite < H1.apply divides_b_to_Prop.
 256 assumption.
 257 qed.
 258
 259 theorem divides_b_true_to_divides:
 260 \forall n,m:nat. divides_b n m = true \to n \divides m.
 261 intros 2.apply (nat_case n)
 262   [apply (nat_case m)
 263     [intro.apply divides_n_n
 264     |simplify.intros.apply False_ind.
 265      apply not_eq_true_false.apply sym_eq.assumption
 266     ]
 267   |intros.
 268    apply divides_b_true_to_divides1
 269     [apply lt_O_S|assumption]
 270   ]
 271 qed.
 272
 273 theorem divides_b_false_to_not_divides1:
 274 \forall n,m:nat. O < n \to
 275 (divides_b n m = false ) \to n \ndivides m.
 276 intros.
 277 change with
 278 match false with
 279 [ true \Rightarrow n \divides m
 280 | false \Rightarrow n \ndivides m].
 281 rewrite < H1.apply divides_b_to_Prop.
 282 assumption.
 283 qed.
 284
 285 theorem divides_b_false_to_not_divides:
 286 \forall n,m:nat. divides_b n m = false \to n \ndivides m.
 287 intros 2.apply (nat_case n)
 288   [apply (nat_case m)
 289     [simplify.unfold Not.intros.
 290      apply not_eq_true_false.assumption
 291     |unfold Not.intros.elim H1.
 292      apply (not_eq_O_S m1).apply sym_eq.
 293      assumption
 294     ]
 295   |intros.
 296    apply divides_b_false_to_not_divides1
 297     [apply lt_O_S|assumption]
 298   ]
 299 qed.
 300
 301 theorem decidable_divides: \forall n,m:nat.O < n \to
 302 decidable (n \divides m).
 303 intros.unfold decidable.
 304 cut
 305 (match divides_b n m with
 306 [ true \Rightarrow n \divides m
 307 | false \Rightarrow n \ndivides m] \to n \divides m \lor n \ndivides m).
 308 apply Hcut.apply divides_b_to_Prop.assumption.
 309 elim (divides_b n m).left.apply H1.right.apply H1.
 310 qed.
 311
 312 theorem divides_to_divides_b_true : \forall n,m:nat. O < n \to
 313 n \divides m \to divides_b n m = true.
 314 intros.
 315 cut (match (divides_b n m) with
 316 [ true \Rightarrow n \divides m
 317 | false \Rightarrow n \ndivides m] \to ((divides_b n m) = true)).
 318 apply Hcut.apply divides_b_to_Prop.assumption.
 319 elim (divides_b n m).reflexivity.
 320 absurd (n \divides m).assumption.assumption.
 321 qed.
 322
 323 theorem not_divides_to_divides_b_false: \forall n,m:nat. O < n \to
 324 \lnot(n \divides m) \to (divides_b n m) = false.
 325 intros.
 326 cut (match (divides_b n m) with
 327 [ true \Rightarrow n \divides m
 328 | false \Rightarrow n \ndivides m] \to ((divides_b n m) = false)).
 329 apply Hcut.apply divides_b_to_Prop.assumption.
 330 elim (divides_b n m).
 331 absurd (n \divides m).assumption.assumption.
 332 reflexivity.
 333 qed.
 334
 335 theorem divides_b_true_to_lt_O: \forall n,m. O < n \to divides_b m n = true \to O < m.
 336 intros.
 337 elim (le_to_or_lt_eq ? ? (le_O_n m))
 338   [assumption
 339   |apply False_ind.
 340    elim H1.
 341    rewrite < H2 in H1.
 342    simplify in H1.
 343    apply (lt_to_not_eq O n H).
 344    apply sym_eq.
 345    apply eqb_true_to_eq.
 346    assumption
 347   ]
 348 qed.
 349
 350 (* divides and pi *)
 351 theorem divides_f_pi_f : \forall f:nat \to nat.\forall n,m,i:nat.
 352 m \le i \to i \le n+m \to f i \divides pi n f m.
 353 intros 5.elim n.simplify.
 354 cut (i = m).rewrite < Hcut.apply divides_n_n.
 355 apply antisymmetric_le.assumption.assumption.
 356 simplify.
 357 cut (i < S n1+m \lor i = S n1 + m).
 358 elim Hcut.
 359 apply (transitive_divides ? (pi n1 f m)).
 360 apply H1.apply le_S_S_to_le. assumption.
 361 apply (witness ? ? (f (S n1+m))).apply sym_times.
 362 rewrite > H3.
 363 apply (witness ? ? (pi n1 f m)).reflexivity.
 364 apply le_to_or_lt_eq.assumption.
 365 qed.
 366
 367 (*
 368 theorem mod_S_pi: \forall f:nat \to nat.\forall n,i:nat.
 369 i < n \to (S O) < (f i) \to (S (pi n f)) \mod (f i) = (S O).
 370 intros.cut (pi n f) \mod (f i) = O.
 371 rewrite < Hcut.
 372 apply mod_S.apply trans_lt O (S O).apply le_n (S O).assumption.
 373 rewrite > Hcut.assumption.
 374 apply divides_to_mod_O.apply trans_lt O (S O).apply le_n (S O).assumption.
 375 apply divides_f_pi_f.assumption.
 376 qed.
 377 *)
 378
 379 (* divides and fact *)
 380 theorem divides_fact : \forall n,i:nat.
 381 O < i \to i \le n \to i \divides n!.
 382 intros 3.elim n.absurd (O<i).assumption.apply (le_n_O_elim i H1).
 383 apply (not_le_Sn_O O).
 384 change with (i \divides (S n1)*n1!).
 385 apply (le_n_Sm_elim i n1 H2).
 386 intro.
 387 apply (transitive_divides ? n1!).
 388 apply H1.apply le_S_S_to_le. assumption.
 389 apply (witness ? ? (S n1)).apply sym_times.
 390 intro.
 391 rewrite > H3.
 392 apply (witness ? ? n1!).reflexivity.
 393 qed.
 394
 395 theorem mod_S_fact: \forall n,i:nat.
 396 (S O) < i \to i \le n \to (S n!) \mod i = (S O).
 397 intros.cut (n! \mod i = O).
 398 rewrite < Hcut.
 399 apply mod_S.apply (trans_lt O (S O)).apply (le_n (S O)).assumption.
 400 rewrite > Hcut.assumption.
 401 apply divides_to_mod_O.apply (trans_lt O (S O)).apply (le_n (S O)).assumption.
 402 apply divides_fact.apply (trans_lt O (S O)).apply (le_n (S O)).assumption.
 403 assumption.
 404 qed.
 405
 406 theorem not_divides_S_fact: \forall n,i:nat.
 407 (S O) < i \to i \le n \to i \ndivides S n!.
 408 intros.
 409 apply divides_b_false_to_not_divides.
 410 unfold divides_b.
 411 rewrite > mod_S_fact[simplify.reflexivity|assumption|assumption].
 412 qed.
 413
 414 (* prime *)
 415 definition prime : nat \to  Prop \def
 416 \lambda n:nat. (S O) < n \land
 417 (\forall m:nat. m \divides n \to (S O) < m \to  m = n).
 418
 419 theorem not_prime_O: \lnot (prime O).
 420 unfold Not.unfold prime.intro.elim H.apply (not_le_Sn_O (S O) H1).
 421 qed.
 422
 423 theorem not_prime_SO: \lnot (prime (S O)).
 424 unfold Not.unfold prime.intro.elim H.apply (not_le_Sn_n (S O) H1).
 425 qed.
 426
 427 theorem prime_to_lt_O: \forall p. prime p \to O < p.
 428 intros.elim H.apply lt_to_le.assumption.
 429 qed.
 430
 431 (* smallest factor *)
 432 definition smallest_factor : nat \to nat \def
 433 \lambda n:nat.
 434 match n with
 435 [ O \Rightarrow O
 436 | (S p) \Rightarrow
 437   match p with
 438   [ O \Rightarrow (S O)
 439   | (S q) \Rightarrow min_aux q (S (S O)) (\lambda m.(eqb ((S(S q)) \mod m) O))]].
 440
 441 (* it works !
 442 theorem example1 : smallest_factor (S(S(S O))) = (S(S(S O))).
 443 normalize.reflexivity.
 444 qed.
 445
 446 theorem example2: smallest_factor (S(S(S(S O)))) = (S(S O)).
 447 normalize.reflexivity.
 448 qed.
 449
 450 theorem example3 : smallest_factor (S(S(S(S(S(S(S O))))))) = (S(S(S(S(S(S(S O))))))).
 451 simplify.reflexivity.
 452 qed. *)
 453
 454 theorem lt_SO_smallest_factor:
 455 \forall n:nat. (S O) < n \to (S O) < (smallest_factor n).
 456 intro.
 457 apply (nat_case n).intro.apply False_ind.apply (not_le_Sn_O (S O) H).
 458 intro.apply (nat_case m).intro. apply False_ind.apply (not_le_Sn_n (S O) H).
 459 intros.
 460 change with
 461 (S O < min_aux m1 (S (S O)) (\lambda m.(eqb ((S(S m1)) \mod m) O))).
 462 apply (lt_to_le_to_lt ? (S (S O))).
 463 apply (le_n (S(S O))).
 464 cut ((S(S O)) = (S(S m1)) - m1).
 465 rewrite > Hcut.
 466 apply le_min_aux.
 467 apply sym_eq.apply plus_to_minus.
 468 rewrite < sym_plus.simplify.reflexivity.
 469 qed.
 470
 471 theorem lt_O_smallest_factor: \forall n:nat. O < n \to O < (smallest_factor n).
 472 intro.
 473 apply (nat_case n).intro.apply False_ind.apply (not_le_Sn_n O H).
 474 intro.apply (nat_case m).intro.
 475 simplify.unfold lt.apply le_n.
 476 intros.apply (trans_lt ? (S O)).
 477 unfold lt.apply le_n.
 478 apply lt_SO_smallest_factor.unfold lt. apply le_S_S.
 479 apply le_S_S.apply le_O_n.
 480 qed.
 481
 482 theorem divides_smallest_factor_n :
 483 \forall n:nat. O < n \to smallest_factor n \divides n.
 484 intro.
 485 apply (nat_case n).intro.apply False_ind.apply (not_le_Sn_O O H).
 486 intro.apply (nat_case m).intro. simplify.
 487 apply (witness ? ? (S O)). simplify.reflexivity.
 488 intros.
 489 apply divides_b_true_to_divides.
 490 change with
 491 (eqb ((S(S m1)) \mod (min_aux m1 (S (S O))
 492   (\lambda m.(eqb ((S(S m1)) \mod m) O)))) O = true).
 493 apply f_min_aux_true.
 494 apply (ex_intro nat ? (S(S m1))).
 495 split.split.
 496 apply (le_S_S_to_le (S (S O)) (S (S m1)) ?).
 497 apply (minus_le_O_to_le (S (S (S O))) (S (S (S m1))) ?).
 498 apply (le_n O).
 499 rewrite < sym_plus. simplify. apply le_n.
 500 apply (eq_to_eqb_true (mod (S (S m1)) (S (S m1))) O ?).
 501 apply (mod_n_n (S (S m1)) ?).
 502 apply (H).
 503 qed.
 504
 505 theorem le_smallest_factor_n :
 506 \forall n:nat. smallest_factor n \le n.
 507 intro.apply (nat_case n).simplify.apply le_n.
 508 intro.apply (nat_case m).simplify.apply le_n.
 509 intro.apply divides_to_le.
 510 unfold lt.apply le_S_S.apply le_O_n.
 511 apply divides_smallest_factor_n.
 512 unfold lt.apply le_S_S.apply le_O_n.
 513 qed.
 514
 515 theorem lt_smallest_factor_to_not_divides: \forall n,i:nat.
 516 (S O) < n \to (S O) < i \to i < (smallest_factor n) \to i \ndivides n.
 517 intros 2.
 518 apply (nat_case n).intro.apply False_ind.apply (not_le_Sn_O (S O) H).
 519 intro.apply (nat_case m).intro. apply False_ind.apply (not_le_Sn_n (S O) H).
 520 intros.
 521 apply divides_b_false_to_not_divides.
 522 apply (lt_min_aux_to_false
 523 (\lambda i:nat.eqb ((S(S m1)) \mod i) O) (S (S O)) m1 i).
 524 assumption.
 525 assumption.
 526 qed.
 527
 528 theorem prime_smallest_factor_n :
 529 \forall n:nat. (S O) < n \to prime (smallest_factor n).
 530 intro.change with ((S(S O)) \le n \to (S O) < (smallest_factor n) \land
 531 (\forall m:nat. m \divides smallest_factor n \to (S O) < m \to  m = (smallest_factor n))).
 532 intro.split.
 533 apply lt_SO_smallest_factor.assumption.
 534 intros.
 535 cut (le m (smallest_factor n)).
 536 elim (le_to_or_lt_eq m (smallest_factor n) Hcut).
 537 absurd (m \divides n).
 538 apply (transitive_divides m (smallest_factor n)).
 539 assumption.
 540 apply divides_smallest_factor_n.
 541 apply (trans_lt ? (S O)). unfold lt. apply le_n. exact H.
 542 apply lt_smallest_factor_to_not_divides.
 543 exact H.assumption.assumption.assumption.
 544 apply divides_to_le.
 545 apply (trans_lt O (S O)).
 546 apply (le_n (S O)).
 547 apply lt_SO_smallest_factor.
 548 exact H.
 549 assumption.
 550 qed.
 551
 552 theorem prime_to_smallest_factor: \forall n. prime n \to
 553 smallest_factor n = n.
 554 intro.apply (nat_case n).intro.apply False_ind.apply (not_prime_O H).
 555 intro.apply (nat_case m).intro.apply False_ind.apply (not_prime_SO H).
 556 intro.
 557 change with
 558 ((S O) < (S(S m1)) \land
 559 (\forall m:nat. m \divides S(S m1) \to (S O) < m \to  m = (S(S m1))) \to
 560 smallest_factor (S(S m1)) = (S(S m1))).
 561 intro.elim H.apply H2.
 562 apply divides_smallest_factor_n.
 563 apply (trans_lt ? (S O)).unfold lt. apply le_n.assumption.
 564 apply lt_SO_smallest_factor.
 565 assumption.
 566 qed.
 567
 568 (* a number n > O is prime iff its smallest factor is n *)
 569 definition primeb \def \lambda n:nat.
 570 match n with
 571 [ O \Rightarrow false
 572 | (S p) \Rightarrow
 573   match p with
 574   [ O \Rightarrow false
 575   | (S q) \Rightarrow eqb (smallest_factor (S(S q))) (S(S q))]].
 576
 577 (* it works!
 578 theorem example4 : primeb (S(S(S O))) = true.
 579 normalize.reflexivity.
 580 qed.
 581
 582 theorem example5 : primeb (S(S(S(S(S(S O)))))) = false.
 583 normalize.reflexivity.
 584 qed.
 585
 586 theorem example6 : primeb (S(S(S(S((S(S(S(S(S(S(S O)))))))))))) = true.
 587 normalize.reflexivity.
 588 qed.
 589
 590 theorem example7 : primeb (S(S(S(S(S(S((S(S(S(S((S(S(S(S(S(S(S O))))))))))))))))))) = true.
 591 normalize.reflexivity.
 592 qed. *)
 593
 594 theorem primeb_to_Prop: \forall n.
 595 match primeb n with
 596 [ true \Rightarrow prime n
 597 | false \Rightarrow \lnot (prime n)].
 598 intro.
 599 apply (nat_case n).simplify.unfold Not.unfold prime.intro.elim H.apply (not_le_Sn_O (S O) H1).
 600 intro.apply (nat_case m).simplify.unfold Not.unfold prime.intro.elim H.apply (not_le_Sn_n (S O) H1).
 601 intro.
 602 change with
 603 match eqb (smallest_factor (S(S m1))) (S(S m1)) with
 604 [ true \Rightarrow prime (S(S m1))
 605 | false \Rightarrow \lnot (prime (S(S m1)))].
 606 apply (eqb_elim (smallest_factor (S(S m1))) (S(S m1))).
 607 intro.simplify.
 608 rewrite < H.
 609 apply prime_smallest_factor_n.
 610 unfold lt.apply le_S_S.apply le_S_S.apply le_O_n.
 611 intro.simplify.
 612 change with (prime (S(S m1)) \to False).
 613 intro.apply H.
 614 apply prime_to_smallest_factor.
 615 assumption.
 616 qed.
 617
 618 theorem primeb_true_to_prime : \forall n:nat.
 619 primeb n = true \to prime n.
 620 intros.change with
 621 match true with
 622 [ true \Rightarrow prime n
 623 | false \Rightarrow \lnot (prime n)].
 624 rewrite < H.
 625 apply primeb_to_Prop.
 626 qed.
 627
 628 theorem primeb_false_to_not_prime : \forall n:nat.
 629 primeb n = false \to \lnot (prime n).
 630 intros.change with
 631 match false with
 632 [ true \Rightarrow prime n
 633 | false \Rightarrow \lnot (prime n)].
 634 rewrite < H.
 635 apply primeb_to_Prop.
 636 qed.
 637
 638 theorem decidable_prime : \forall n:nat.decidable (prime n).
 639 intro.unfold decidable.
 640 cut
 641 (match primeb n with
 642 [ true \Rightarrow prime n
 643 | false \Rightarrow \lnot (prime n)] \to (prime n) \lor \lnot (prime n)).
 644 apply Hcut.apply primeb_to_Prop.
 645 elim (primeb n).left.apply H.right.apply H.
 646 qed.
 647
 648 theorem prime_to_primeb_true: \forall n:nat.
 649 prime n \to primeb n = true.
 650 intros.
 651 cut (match (primeb n) with
 652 [ true \Rightarrow prime n
 653 | false \Rightarrow \lnot (prime n)] \to ((primeb n) = true)).
 654 apply Hcut.apply primeb_to_Prop.
 655 elim (primeb n).reflexivity.
 656 absurd (prime n).assumption.assumption.
 657 qed.
 658
 659 theorem not_prime_to_primeb_false: \forall n:nat.
 660 \lnot(prime n) \to primeb n = false.
 661 intros.
 662 cut (match (primeb n) with
 663 [ true \Rightarrow prime n
 664 | false \Rightarrow \lnot (prime n)] \to ((primeb n) = false)).
 665 apply Hcut.apply primeb_to_Prop.
 666 elim (primeb n).
 667 absurd (prime n).assumption.assumption.
 668 reflexivity.
 669 qed.
 670