matita/library/nat/primes.ma

   1 (**************************************************************************)
   2 (*       ___                                                                *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||       A.Asperti, C.Sacerdoti Coen,                          *)
   8 (*      ||A||       E.Tassi, S.Zacchiroli                                 *)
   9 (*      \   /                                                             *)
  10 (*       \ /        Matita is distributed under the terms of the          *)
  11 (*        v         GNU Lesser General Public License Version 2.1         *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 set "baseuri" "cic:/matita/nat/primes".
  16
  17 include "nat/div_and_mod.ma".
  18 include "nat/minimization.ma".
  19 include "nat/sigma_and_pi.ma".
  20 include "nat/factorial.ma".
  21
  22 inductive divides (n,m:nat) : Prop \def
  23 witness : \forall p:nat.m = times n p \to divides n m.
  24
  25 interpretation "divides" 'divides n m = (cic:/matita/nat/primes/divides.ind#xpointer(1/1) n m).
  26 interpretation "not divides" 'ndivides n m =
  27  (cic:/matita/logic/connectives/Not.con (cic:/matita/nat/primes/divides.ind#xpointer(1/1) n m)).
  28
  29 theorem reflexive_divides : reflexive nat divides.
  30 unfold reflexive.
  31 intros.
  32 exact (witness x x (S O) (times_n_SO x)).
  33 qed.
  34
  35 theorem divides_to_div_mod_spec :
  36 \forall n,m. O < n \to n \divides m \to div_mod_spec m n (m / n) O.
  37 intros.elim H1.rewrite > H2.
  38 constructor 1.assumption.
  39 apply (lt_O_n_elim n H).intros.
  40 rewrite < plus_n_O.
  41 rewrite > div_times.apply sym_times.
  42 qed.
  43
  44 theorem div_mod_spec_to_divides :
  45 \forall n,m,p. div_mod_spec m n p O \to n \divides m.
  46 intros.elim H.
  47 apply (witness n m p).
  48 rewrite < sym_times.
  49 rewrite > (plus_n_O (p*n)).assumption.
  50 qed.
  51
  52 theorem divides_to_mod_O:
  53 \forall n,m. O < n \to n \divides m \to (m \mod n) = O.
  54 intros.apply (div_mod_spec_to_eq2 m n (m / n) (m \mod n) (m / n) O).
  55 apply div_mod_spec_div_mod.assumption.
  56 apply divides_to_div_mod_spec.assumption.assumption.
  57 qed.
  58
  59 theorem mod_O_to_divides:
  60 \forall n,m. O< n \to (m \mod n) = O \to  n \divides m.
  61 intros.
  62 apply (witness n m (m / n)).
  63 rewrite > (plus_n_O (n * (m / n))).
  64 rewrite < H1.
  65 rewrite < sym_times.
  66 (* Andrea: perche' hint non lo trova ?*)
  67 apply div_mod.
  68 assumption.
  69 qed.
  70
  71 theorem divides_n_O: \forall n:nat. n \divides O.
  72 intro. apply (witness n O O).apply times_n_O.
  73 qed.
  74
  75 theorem divides_n_n: \forall n:nat. n \divides n.
  76 intro. apply (witness n n (S O)).apply times_n_SO.
  77 qed.
  78
  79 theorem divides_SO_n: \forall n:nat. (S O) \divides n.
  80 intro. apply (witness (S O) n n). simplify.apply plus_n_O.
  81 qed.
  82
  83 theorem divides_plus: \forall n,p,q:nat.
  84 n \divides p \to n \divides q \to n \divides p+q.
  85 intros.
  86 elim H.elim H1. apply (witness n (p+q) (n2+n1)).
  87 rewrite > H2.rewrite > H3.apply sym_eq.apply distr_times_plus.
  88 qed.
  89
  90 theorem divides_minus: \forall n,p,q:nat.
  91 divides n p \to divides n q \to divides n (p-q).
  92 intros.
  93 elim H.elim H1. apply (witness n (p-q) (n2-n1)).
  94 rewrite > H2.rewrite > H3.apply sym_eq.apply distr_times_minus.
  95 qed.
  96
  97 theorem divides_times: \forall n,m,p,q:nat.
  98 n \divides p \to m \divides q \to n*m \divides p*q.
  99 intros.
 100 elim H.elim H1. apply (witness (n*m) (p*q) (n2*n1)).
 101 rewrite > H2.rewrite > H3.
 102 apply (trans_eq nat ? (n*(m*(n2*n1)))).
 103 apply (trans_eq nat ? (n*(n2*(m*n1)))).
 104 apply assoc_times.
 105 apply eq_f.
 106 apply (trans_eq nat ? ((n2*m)*n1)).
 107 apply sym_eq. apply assoc_times.
 108 rewrite > (sym_times n2 m).apply assoc_times.
 109 apply sym_eq. apply assoc_times.
 110 qed.
 111
 112 theorem transitive_divides: transitive ? divides.
 113 unfold.
 114 intros.
 115 elim H.elim H1. apply (witness x z (n2*n)).
 116 rewrite > H3.rewrite > H2.
 117 apply assoc_times.
 118 qed.
 119
 120 variant trans_divides: \forall n,m,p.
 121  n \divides m \to m \divides p \to n \divides p \def transitive_divides.
 122
 123 theorem eq_mod_to_divides:\forall n,m,p. O< p \to
 124 mod n p = mod m p \to divides p (n-m).
 125 intros.
 126 cut (n \le m \or \not n \le m).
 127 elim Hcut.
 128 cut (n-m=O).
 129 rewrite > Hcut1.
 130 apply (witness p O O).
 131 apply times_n_O.
 132 apply eq_minus_n_m_O.
 133 assumption.
 134 apply (witness p (n-m) ((div n p)-(div m p))).
 135 rewrite > distr_times_minus.
 136 rewrite > sym_times.
 137 rewrite > (sym_times p).
 138 cut ((div n p)*p = n - (mod n p)).
 139 rewrite > Hcut1.
 140 rewrite > eq_minus_minus_minus_plus.
 141 rewrite > sym_plus.
 142 rewrite > H1.
 143 rewrite < div_mod.reflexivity.
 144 assumption.
 145 apply sym_eq.
 146 apply plus_to_minus.
 147 rewrite > sym_plus.
 148 apply div_mod.
 149 assumption.
 150 apply (decidable_le n m).
 151 qed.
 152
 153 theorem antisymmetric_divides: antisymmetric nat divides.
 154 unfold antisymmetric.intros.elim H. elim H1.
 155 apply (nat_case1 n2).intro.
 156 rewrite > H3.rewrite > H2.rewrite > H4.
 157 rewrite < times_n_O.reflexivity.
 158 intros.
 159 apply (nat_case1 n).intro.
 160 rewrite > H2.rewrite > H3.rewrite > H5.
 161 rewrite < times_n_O.reflexivity.
 162 intros.
 163 apply antisymmetric_le.
 164 rewrite > H2.rewrite > times_n_SO in \vdash (? % ?).
 165 apply le_times_r.rewrite > H4.apply le_S_S.apply le_O_n.
 166 rewrite > H3.rewrite > times_n_SO in \vdash (? % ?).
 167 apply le_times_r.rewrite > H5.apply le_S_S.apply le_O_n.
 168 qed.
 169
 170 (* divides le *)
 171 theorem divides_to_le : \forall n,m. O < m \to n \divides m \to n \le m.
 172 intros. elim H1.rewrite > H2.cut (O < n2).
 173 apply (lt_O_n_elim n2 Hcut).intro.rewrite < sym_times.
 174 simplify.rewrite < sym_plus.
 175 apply le_plus_n.
 176 elim (le_to_or_lt_eq O n2).
 177 assumption.
 178 absurd (O<m).assumption.
 179 rewrite > H2.rewrite < H3.rewrite < times_n_O.
 180 apply (not_le_Sn_n O).
 181 apply le_O_n.
 182 qed.
 183
 184 theorem divides_to_lt_O : \forall n,m. O < m \to n \divides m \to O < n.
 185 intros.elim H1.
 186 elim (le_to_or_lt_eq O n (le_O_n n)).
 187 assumption.
 188 rewrite < H3.absurd (O < m).assumption.
 189 rewrite > H2.rewrite < H3.
 190 simplify.exact (not_le_Sn_n O).
 191 qed.
 192
 193
 194 (*divides and div*)
 195
 196 theorem divides_to_div: \forall n,m.divides n m \to m/n*n = m.
 197 intro.
 198 elim (le_to_or_lt_eq O n (le_O_n n))
 199   [rewrite > plus_n_O.
 200    rewrite < (divides_to_mod_O ? ? H H1).
 201    apply sym_eq.
 202    apply div_mod.
 203    assumption
 204   |elim H1.
 205    generalize in match H2.
 206    rewrite < H.
 207    simplify.
 208    intro.
 209    rewrite > H3.
 210    reflexivity
 211   ]
 212 qed.
 213
 214 theorem div_div: \forall n,d:nat. O < n \to divides d n \to
 215 n/(n/d) = d.
 216 intros.
 217 apply (inj_times_l1 (n/d))
 218   [apply (lt_times_n_to_lt d)
 219     [apply (divides_to_lt_O ? ? H H1).
 220     |rewrite > divides_to_div;assumption
 221     ]
 222   |rewrite > divides_to_div
 223     [rewrite > sym_times.
 224      rewrite > divides_to_div
 225       [reflexivity
 226       |assumption
 227       ]
 228     |apply (witness ? ? d).
 229      apply sym_eq.
 230      apply divides_to_div.
 231      assumption
 232     ]
 233   ]
 234 qed.
 235
 236 theorem divides_to_eq_times_div_div_times: \forall a,b,c:nat.
 237 O \lt b \to c \divides b \to a * (b /c) = (a*b)/c.
 238 intros.
 239 elim H1.
 240 rewrite > H2.
 241 rewrite > (sym_times c n2).
 242 cut(O \lt c)
 243 [ rewrite > (lt_O_to_div_times n2 c)
 244   [ rewrite < assoc_times.
 245     rewrite > (lt_O_to_div_times (a *n2) c)
 246     [ reflexivity
 247     | assumption
 248     ]
 249   | assumption
 250   ]
 251 | apply (divides_to_lt_O c b);
 252     assumption.
 253 ]
 254 qed.
 255
 256
 257 (* boolean divides *)
 258 definition divides_b : nat \to nat \to bool \def
 259 \lambda n,m :nat. (eqb (m \mod n) O).
 260
 261 theorem divides_b_to_Prop :
 262 \forall n,m:nat. O < n \to
 263 match divides_b n m with
 264 [ true \Rightarrow n \divides m
 265 | false \Rightarrow n \ndivides m].
 266 intros.unfold divides_b.
 267 apply eqb_elim.
 268 intro.simplify.apply mod_O_to_divides.assumption.assumption.
 269 intro.simplify.unfold Not.intro.apply H1.apply divides_to_mod_O.assumption.assumption.
 270 qed.
 271
 272 theorem divides_b_true_to_divides1:
 273 \forall n,m:nat. O < n \to
 274 (divides_b n m = true ) \to n \divides m.
 275 intros.
 276 change with
 277 match true with
 278 [ true \Rightarrow n \divides m
 279 | false \Rightarrow n \ndivides m].
 280 rewrite < H1.apply divides_b_to_Prop.
 281 assumption.
 282 qed.
 283
 284 theorem divides_b_true_to_divides:
 285 \forall n,m:nat. divides_b n m = true \to n \divides m.
 286 intros 2.apply (nat_case n)
 287   [apply (nat_case m)
 288     [intro.apply divides_n_n
 289     |simplify.intros.apply False_ind.
 290      apply not_eq_true_false.apply sym_eq.assumption
 291     ]
 292   |intros.
 293    apply divides_b_true_to_divides1
 294     [apply lt_O_S|assumption]
 295   ]
 296 qed.
 297
 298 theorem divides_b_false_to_not_divides1:
 299 \forall n,m:nat. O < n \to
 300 (divides_b n m = false ) \to n \ndivides m.
 301 intros.
 302 change with
 303 match false with
 304 [ true \Rightarrow n \divides m
 305 | false \Rightarrow n \ndivides m].
 306 rewrite < H1.apply divides_b_to_Prop.
 307 assumption.
 308 qed.
 309
 310 theorem divides_b_false_to_not_divides:
 311 \forall n,m:nat. divides_b n m = false \to n \ndivides m.
 312 intros 2.apply (nat_case n)
 313   [apply (nat_case m)
 314     [simplify.unfold Not.intros.
 315      apply not_eq_true_false.assumption
 316     |unfold Not.intros.elim H1.
 317      apply (not_eq_O_S m1).apply sym_eq.
 318      assumption
 319     ]
 320   |intros.
 321    apply divides_b_false_to_not_divides1
 322     [apply lt_O_S|assumption]
 323   ]
 324 qed.
 325
 326 theorem decidable_divides: \forall n,m:nat.O < n \to
 327 decidable (n \divides m).
 328 intros.unfold decidable.
 329 cut
 330 (match divides_b n m with
 331 [ true \Rightarrow n \divides m
 332 | false \Rightarrow n \ndivides m] \to n \divides m \lor n \ndivides m).
 333 apply Hcut.apply divides_b_to_Prop.assumption.
 334 elim (divides_b n m).left.apply H1.right.apply H1.
 335 qed.
 336
 337 theorem divides_to_divides_b_true : \forall n,m:nat. O < n \to
 338 n \divides m \to divides_b n m = true.
 339 intros.
 340 cut (match (divides_b n m) with
 341 [ true \Rightarrow n \divides m
 342 | false \Rightarrow n \ndivides m] \to ((divides_b n m) = true)).
 343 apply Hcut.apply divides_b_to_Prop.assumption.
 344 elim (divides_b n m).reflexivity.
 345 absurd (n \divides m).assumption.assumption.
 346 qed.
 347
 348 theorem not_divides_to_divides_b_false: \forall n,m:nat. O < n \to
 349 \lnot(n \divides m) \to (divides_b n m) = false.
 350 intros.
 351 cut (match (divides_b n m) with
 352 [ true \Rightarrow n \divides m
 353 | false \Rightarrow n \ndivides m] \to ((divides_b n m) = false)).
 354 apply Hcut.apply divides_b_to_Prop.assumption.
 355 elim (divides_b n m).
 356 absurd (n \divides m).assumption.assumption.
 357 reflexivity.
 358 qed.
 359
 360 theorem divides_b_true_to_lt_O: \forall n,m. O < n \to divides_b m n = true \to O < m.
 361 intros.
 362 elim (le_to_or_lt_eq ? ? (le_O_n m))
 363   [assumption
 364   |apply False_ind.
 365    elim H1.
 366    rewrite < H2 in H1.
 367    simplify in H1.
 368    apply (lt_to_not_eq O n H).
 369    apply sym_eq.
 370    apply eqb_true_to_eq.
 371    assumption
 372   ]
 373 qed.
 374
 375 (* divides and pi *)
 376 theorem divides_f_pi_f : \forall f:nat \to nat.\forall n,m,i:nat.
 377 m \le i \to i \le n+m \to f i \divides pi n f m.
 378 intros 5.elim n.simplify.
 379 cut (i = m).rewrite < Hcut.apply divides_n_n.
 380 apply antisymmetric_le.assumption.assumption.
 381 simplify.
 382 cut (i < S n1+m \lor i = S n1 + m).
 383 elim Hcut.
 384 apply (transitive_divides ? (pi n1 f m)).
 385 apply H1.apply le_S_S_to_le. assumption.
 386 apply (witness ? ? (f (S n1+m))).apply sym_times.
 387 rewrite > H3.
 388 apply (witness ? ? (pi n1 f m)).reflexivity.
 389 apply le_to_or_lt_eq.assumption.
 390 qed.
 391
 392 (*
 393 theorem mod_S_pi: \forall f:nat \to nat.\forall n,i:nat.
 394 i < n \to (S O) < (f i) \to (S (pi n f)) \mod (f i) = (S O).
 395 intros.cut (pi n f) \mod (f i) = O.
 396 rewrite < Hcut.
 397 apply mod_S.apply trans_lt O (S O).apply le_n (S O).assumption.
 398 rewrite > Hcut.assumption.
 399 apply divides_to_mod_O.apply trans_lt O (S O).apply le_n (S O).assumption.
 400 apply divides_f_pi_f.assumption.
 401 qed.
 402 *)
 403
 404 (* divides and fact *)
 405 theorem divides_fact : \forall n,i:nat.
 406 O < i \to i \le n \to i \divides n!.
 407 intros 3.elim n.absurd (O<i).assumption.apply (le_n_O_elim i H1).
 408 apply (not_le_Sn_O O).
 409 change with (i \divides (S n1)*n1!).
 410 apply (le_n_Sm_elim i n1 H2).
 411 intro.
 412 apply (transitive_divides ? n1!).
 413 apply H1.apply le_S_S_to_le. assumption.
 414 apply (witness ? ? (S n1)).apply sym_times.
 415 intro.
 416 rewrite > H3.
 417 apply (witness ? ? n1!).reflexivity.
 418 qed.
 419
 420 theorem mod_S_fact: \forall n,i:nat.
 421 (S O) < i \to i \le n \to (S n!) \mod i = (S O).
 422 intros.cut (n! \mod i = O).
 423 rewrite < Hcut.
 424 apply mod_S.apply (trans_lt O (S O)).apply (le_n (S O)).assumption.
 425 rewrite > Hcut.assumption.
 426 apply divides_to_mod_O.apply (trans_lt O (S O)).apply (le_n (S O)).assumption.
 427 apply divides_fact.apply (trans_lt O (S O)).apply (le_n (S O)).assumption.
 428 assumption.
 429 qed.
 430
 431 theorem not_divides_S_fact: \forall n,i:nat.
 432 (S O) < i \to i \le n \to i \ndivides S n!.
 433 intros.
 434 apply divides_b_false_to_not_divides.
 435 unfold divides_b.
 436 rewrite > mod_S_fact[simplify.reflexivity|assumption|assumption].
 437 qed.
 438
 439 (* prime *)
 440 definition prime : nat \to  Prop \def
 441 \lambda n:nat. (S O) < n \land
 442 (\forall m:nat. m \divides n \to (S O) < m \to  m = n).
 443
 444 theorem not_prime_O: \lnot (prime O).
 445 unfold Not.unfold prime.intro.elim H.apply (not_le_Sn_O (S O) H1).
 446 qed.
 447
 448 theorem not_prime_SO: \lnot (prime (S O)).
 449 unfold Not.unfold prime.intro.elim H.apply (not_le_Sn_n (S O) H1).
 450 qed.
 451
 452 theorem prime_to_lt_O: \forall p. prime p \to O < p.
 453 intros.elim H.apply lt_to_le.assumption.
 454 qed.
 455
 456 (* smallest factor *)
 457 definition smallest_factor : nat \to nat \def
 458 \lambda n:nat.
 459 match n with
 460 [ O \Rightarrow O
 461 | (S p) \Rightarrow
 462   match p with
 463   [ O \Rightarrow (S O)
 464   | (S q) \Rightarrow min_aux q (S (S O)) (\lambda m.(eqb ((S(S q)) \mod m) O))]].
 465
 466 (* it works !
 467 theorem example1 : smallest_factor (S(S(S O))) = (S(S(S O))).
 468 normalize.reflexivity.
 469 qed.
 470
 471 theorem example2: smallest_factor (S(S(S(S O)))) = (S(S O)).
 472 normalize.reflexivity.
 473 qed.
 474
 475 theorem example3 : smallest_factor (S(S(S(S(S(S(S O))))))) = (S(S(S(S(S(S(S O))))))).
 476 simplify.reflexivity.
 477 qed. *)
 478
 479 theorem lt_SO_smallest_factor:
 480 \forall n:nat. (S O) < n \to (S O) < (smallest_factor n).
 481 intro.
 482 apply (nat_case n).intro.apply False_ind.apply (not_le_Sn_O (S O) H).
 483 intro.apply (nat_case m).intro. apply False_ind.apply (not_le_Sn_n (S O) H).
 484 intros.
 485 change with
 486 (S O < min_aux m1 (S (S O)) (\lambda m.(eqb ((S(S m1)) \mod m) O))).
 487 apply (lt_to_le_to_lt ? (S (S O))).
 488 apply (le_n (S(S O))).
 489 cut ((S(S O)) = (S(S m1)) - m1).
 490 rewrite > Hcut.
 491 apply le_min_aux.
 492 apply sym_eq.apply plus_to_minus.
 493 rewrite < sym_plus.simplify.reflexivity.
 494 qed.
 495
 496 theorem lt_O_smallest_factor: \forall n:nat. O < n \to O < (smallest_factor n).
 497 intro.
 498 apply (nat_case n).intro.apply False_ind.apply (not_le_Sn_n O H).
 499 intro.apply (nat_case m).intro.
 500 simplify.unfold lt.apply le_n.
 501 intros.apply (trans_lt ? (S O)).
 502 unfold lt.apply le_n.
 503 apply lt_SO_smallest_factor.unfold lt. apply le_S_S.
 504 apply le_S_S.apply le_O_n.
 505 qed.
 506
 507 theorem divides_smallest_factor_n :
 508 \forall n:nat. O < n \to smallest_factor n \divides n.
 509 intro.
 510 apply (nat_case n).intro.apply False_ind.apply (not_le_Sn_O O H).
 511 intro.apply (nat_case m).intro. simplify.
 512 apply (witness ? ? (S O)). simplify.reflexivity.
 513 intros.
 514 apply divides_b_true_to_divides.
 515 change with
 516 (eqb ((S(S m1)) \mod (min_aux m1 (S (S O))
 517   (\lambda m.(eqb ((S(S m1)) \mod m) O)))) O = true).
 518 apply f_min_aux_true.
 519 apply (ex_intro nat ? (S(S m1))).
 520 split.split.
 521 apply (le_S_S_to_le (S (S O)) (S (S m1)) ?).
 522 apply (minus_le_O_to_le (S (S (S O))) (S (S (S m1))) ?).
 523 apply (le_n O).
 524 rewrite < sym_plus. simplify. apply le_n.
 525 apply (eq_to_eqb_true (mod (S (S m1)) (S (S m1))) O ?).
 526 apply (mod_n_n (S (S m1)) ?).
 527 apply (H).
 528 qed.
 529
 530 theorem le_smallest_factor_n :
 531 \forall n:nat. smallest_factor n \le n.
 532 intro.apply (nat_case n).simplify.apply le_n.
 533 intro.apply (nat_case m).simplify.apply le_n.
 534 intro.apply divides_to_le.
 535 unfold lt.apply le_S_S.apply le_O_n.
 536 apply divides_smallest_factor_n.
 537 unfold lt.apply le_S_S.apply le_O_n.
 538 qed.
 539
 540 theorem lt_smallest_factor_to_not_divides: \forall n,i:nat.
 541 (S O) < n \to (S O) < i \to i < (smallest_factor n) \to i \ndivides n.
 542 intros 2.
 543 apply (nat_case n).intro.apply False_ind.apply (not_le_Sn_O (S O) H).
 544 intro.apply (nat_case m).intro. apply False_ind.apply (not_le_Sn_n (S O) H).
 545 intros.
 546 apply divides_b_false_to_not_divides.
 547 apply (lt_min_aux_to_false
 548 (\lambda i:nat.eqb ((S(S m1)) \mod i) O) (S (S O)) m1 i).
 549 assumption.
 550 assumption.
 551 qed.
 552
 553 theorem prime_smallest_factor_n :
 554 \forall n:nat. (S O) < n \to prime (smallest_factor n).
 555 intro.change with ((S(S O)) \le n \to (S O) < (smallest_factor n) \land
 556 (\forall m:nat. m \divides smallest_factor n \to (S O) < m \to  m = (smallest_factor n))).
 557 intro.split.
 558 apply lt_SO_smallest_factor.assumption.
 559 intros.
 560 cut (le m (smallest_factor n)).
 561 elim (le_to_or_lt_eq m (smallest_factor n) Hcut).
 562 absurd (m \divides n).
 563 apply (transitive_divides m (smallest_factor n)).
 564 assumption.
 565 apply divides_smallest_factor_n.
 566 apply (trans_lt ? (S O)). unfold lt. apply le_n. exact H.
 567 apply lt_smallest_factor_to_not_divides.
 568 exact H.assumption.assumption.assumption.
 569 apply divides_to_le.
 570 apply (trans_lt O (S O)).
 571 apply (le_n (S O)).
 572 apply lt_SO_smallest_factor.
 573 exact H.
 574 assumption.
 575 qed.
 576
 577 theorem prime_to_smallest_factor: \forall n. prime n \to
 578 smallest_factor n = n.
 579 intro.apply (nat_case n).intro.apply False_ind.apply (not_prime_O H).
 580 intro.apply (nat_case m).intro.apply False_ind.apply (not_prime_SO H).
 581 intro.
 582 change with
 583 ((S O) < (S(S m1)) \land
 584 (\forall m:nat. m \divides S(S m1) \to (S O) < m \to  m = (S(S m1))) \to
 585 smallest_factor (S(S m1)) = (S(S m1))).
 586 intro.elim H.apply H2.
 587 apply divides_smallest_factor_n.
 588 apply (trans_lt ? (S O)).unfold lt. apply le_n.assumption.
 589 apply lt_SO_smallest_factor.
 590 assumption.
 591 qed.
 592
 593 (* a number n > O is prime iff its smallest factor is n *)
 594 definition primeb \def \lambda n:nat.
 595 match n with
 596 [ O \Rightarrow false
 597 | (S p) \Rightarrow
 598   match p with
 599   [ O \Rightarrow false
 600   | (S q) \Rightarrow eqb (smallest_factor (S(S q))) (S(S q))]].
 601
 602 (* it works!
 603 theorem example4 : primeb (S(S(S O))) = true.
 604 normalize.reflexivity.
 605 qed.
 606
 607 theorem example5 : primeb (S(S(S(S(S(S O)))))) = false.
 608 normalize.reflexivity.
 609 qed.
 610
 611 theorem example6 : primeb (S(S(S(S((S(S(S(S(S(S(S O)))))))))))) = true.
 612 normalize.reflexivity.
 613 qed.
 614
 615 theorem example7 : primeb (S(S(S(S(S(S((S(S(S(S((S(S(S(S(S(S(S O))))))))))))))))))) = true.
 616 normalize.reflexivity.
 617 qed. *)
 618
 619 theorem primeb_to_Prop: \forall n.
 620 match primeb n with
 621 [ true \Rightarrow prime n
 622 | false \Rightarrow \lnot (prime n)].
 623 intro.
 624 apply (nat_case n).simplify.unfold Not.unfold prime.intro.elim H.apply (not_le_Sn_O (S O) H1).
 625 intro.apply (nat_case m).simplify.unfold Not.unfold prime.intro.elim H.apply (not_le_Sn_n (S O) H1).
 626 intro.
 627 change with
 628 match eqb (smallest_factor (S(S m1))) (S(S m1)) with
 629 [ true \Rightarrow prime (S(S m1))
 630 | false \Rightarrow \lnot (prime (S(S m1)))].
 631 apply (eqb_elim (smallest_factor (S(S m1))) (S(S m1))).
 632 intro.simplify.
 633 rewrite < H.
 634 apply prime_smallest_factor_n.
 635 unfold lt.apply le_S_S.apply le_S_S.apply le_O_n.
 636 intro.simplify.
 637 change with (prime (S(S m1)) \to False).
 638 intro.apply H.
 639 apply prime_to_smallest_factor.
 640 assumption.
 641 qed.
 642
 643 theorem primeb_true_to_prime : \forall n:nat.
 644 primeb n = true \to prime n.
 645 intros.change with
 646 match true with
 647 [ true \Rightarrow prime n
 648 | false \Rightarrow \lnot (prime n)].
 649 rewrite < H.
 650 apply primeb_to_Prop.
 651 qed.
 652
 653 theorem primeb_false_to_not_prime : \forall n:nat.
 654 primeb n = false \to \lnot (prime n).
 655 intros.change with
 656 match false with
 657 [ true \Rightarrow prime n
 658 | false \Rightarrow \lnot (prime n)].
 659 rewrite < H.
 660 apply primeb_to_Prop.
 661 qed.
 662
 663 theorem decidable_prime : \forall n:nat.decidable (prime n).
 664 intro.unfold decidable.
 665 cut
 666 (match primeb n with
 667 [ true \Rightarrow prime n
 668 | false \Rightarrow \lnot (prime n)] \to (prime n) \lor \lnot (prime n)).
 669 apply Hcut.apply primeb_to_Prop.
 670 elim (primeb n).left.apply H.right.apply H.
 671 qed.
 672
 673 theorem prime_to_primeb_true: \forall n:nat.
 674 prime n \to primeb n = true.
 675 intros.
 676 cut (match (primeb n) with
 677 [ true \Rightarrow prime n
 678 | false \Rightarrow \lnot (prime n)] \to ((primeb n) = true)).
 679 apply Hcut.apply primeb_to_Prop.
 680 elim (primeb n).reflexivity.
 681 absurd (prime n).assumption.assumption.
 682 qed.
 683
 684 theorem not_prime_to_primeb_false: \forall n:nat.
 685 \lnot(prime n) \to primeb n = false.
 686 intros.
 687 cut (match (primeb n) with
 688 [ true \Rightarrow prime n
 689 | false \Rightarrow \lnot (prime n)] \to ((primeb n) = false)).
 690 apply Hcut.apply primeb_to_Prop.
 691 elim (primeb n).
 692 absurd (prime n).assumption.assumption.
 693 reflexivity.
 694 qed.
 695