matita/matita/contribs/lambda/labeled_sequential_reduction.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "pointer.ma".
  16 include "multiplicity.ma".
  17
  18 (* LABELED SEQUENTIAL REDUCTION (SINGLE STEP) *******************************)
  19
  20 (* Note: the application "(A B)" is represented by "@B.A" following:
  21          F. Kamareddine and R.P. Nederpelt: "A useful λ-notation".
  22          Theoretical Computer Science 155(1), Elsevier (1996), pp. 85-109.
  23 *)
  24 inductive lsred: ptr → relation term ≝
  25 | lsred_beta   : ∀B,A. lsred (◊) (@B.𝛌.A) ([↙B]A)
  26 | lsred_abst   : ∀p,A1,A2. lsred p A1 A2 → lsred (rc::p) (𝛌.A1) (𝛌.A2)
  27 | lsred_appl_sn: ∀p,B1,B2,A. lsred p B1 B2 → lsred (sn::p) (@B1.A) (@B2.A)
  28 | lsred_appl_dx: ∀p,B,A1,A2. lsred p A1 A2 → lsred (dx::p) (@B.A1) (@B.A2)
  29 .
  30
  31 interpretation "labelled sequential reduction"
  32    'SeqRed M p N = (lsred p M N).
  33
  34 (* Note: we do not use → since it is reserved by CIC *)
  35 notation "hvbox( M break ↦ [ term 46 p ] break term 46 N )"
  36    non associative with precedence 45
  37    for @{ 'SeqRed $M $p $N }.
  38
  39 lemma lsred_inv_vref: ∀p,M,N. M ↦[p] N → ∀i. #i = M → ⊥.
  40 #p #M #N * -p -M -N
  41 [ #B #A #i #H destruct
  42 | #p #A1 #A2 #_ #i #H destruct
  43 | #p #B1 #B2 #A #_ #i #H destruct
  44 | #p #B #A1 #A2 #_ #i #H destruct
  45 ]
  46 qed-.
  47
  48 lemma lsred_inv_nil: ∀p,M,N. M ↦[p] N → ◊ = p →
  49                      ∃∃B,A. @B. 𝛌.A = M & [↙B] A = N.
  50 #p #M #N * -p -M -N
  51 [ #B #A #_ destruct /2 width=4/
  52 | #p #A1 #A2 #_ #H destruct
  53 | #p #B1 #B2 #A #_ #H destruct
  54 | #p #B #A1 #A2 #_ #H destruct
  55 ]
  56 qed-.
  57
  58 lemma lsred_inv_rc: ∀p,M,N. M ↦[p] N → ∀q. rc::q = p →
  59                     ∃∃A1,A2. A1 ↦[q] A2 & 𝛌.A1 = M & 𝛌.A2 = N.
  60 #p #M #N * -p -M -N
  61 [ #B #A #q #H destruct
  62 | #p #A1 #A2 #HA12 #q #H destruct /2 width=5/
  63 | #p #B1 #B2 #A #_ #q #H destruct
  64 | #p #B #A1 #A2 #_ #q #H destruct
  65 ]
  66 qed-.
  67
  68 lemma lsred_inv_sn: ∀p,M,N. M ↦[p] N → ∀q. sn::q = p →
  69                     ∃∃B1,B2,A. B1 ↦[q] B2 & @B1.A = M & @B2.A = N.
  70 #p #M #N * -p -M -N
  71 [ #B #A #q #H destruct
  72 | #p #A1 #A2 #_ #q #H destruct
  73 | #p #B1 #B2 #A #HB12 #q #H destruct /2 width=6/
  74 | #p #B #A1 #A2 #_ #q #H destruct
  75 ]
  76 qed-.
  77
  78 lemma lsred_inv_dx: ∀p,M,N. M ↦[p] N → ∀q. dx::q = p →
  79                     ∃∃B,A1,A2. A1 ↦[q] A2 & @B.A1 = M & @B.A2 = N.
  80 #p #M #N * -p -M -N
  81 [ #B #A #q #H destruct
  82 | #p #A1 #A2 #_ #q #H destruct
  83 | #p #B1 #B2 #A #_ #q #H destruct
  84 | #p #B #A1 #A2 #HA12 #q #H destruct /2 width=6/
  85 ]
  86 qed-.
  87
  88 lemma lsred_fwd_mult: ∀p,M,N. M ↦[p] N → #{N} < #{M} * #{M}.
  89 #p #M #N #H elim H -p -M -N
  90 [ #B #A @(le_to_lt_to_lt … (#{A}*#{B})) //
  91   normalize /3 width=1 by lt_minus_to_plus_r, lt_times/ (**) (* auto: too slow without trace *)
  92 | //
  93 | #p #B #D #A #_ #IHBD
  94   @(lt_to_le_to_lt … (#{B}*#{B}+#{A})) [ /2 width=1/ ] -D -p
  95 | #p #B #A #C #_ #IHAC
  96   @(lt_to_le_to_lt … (#{B}+#{A}*#{A})) [ /2 width=1/ ] -C -p
  97 ]
  98 @(transitive_le … (#{B}*#{B}+#{A}*#{A})) [ /2 width=1/ ]
  99 >distributive_times_plus normalize /2 width=1/
 100 qed-.
 101
 102 lemma lsred_lift: ∀p. liftable (lsred p).
 103 #p #h #M1 #M2 #H elim H -p -M1 -M2 normalize /2 width=1/
 104 #B #A #d <dsubst_lift_le //
 105 qed.
 106
 107 lemma lsred_inv_lift: ∀p. deliftable_sn (lsred p).
 108 #p #h #N1 #N2 #H elim H -p -N1 -N2
 109 [ #D #C #d #M1 #H
 110   elim (lift_inv_appl … H) -H #B #M #H0 #HM #H destruct
 111   elim (lift_inv_abst … HM) -HM #A #H0 #H destruct /3 width=3/
 112 | #p #C1 #C2 #_ #IHC12 #d #M1 #H
 113   elim (lift_inv_abst … H) -H #A1 #HAC1 #H
 114   elim (IHC12 … HAC1) -C1 #A2 #HA12 #HAC2 destruct
 115   @(ex2_intro … (𝛌.A2)) // /2 width=1/
 116 | #p #D1 #D2 #C1 #_ #IHD12 #d #M1 #H
 117   elim (lift_inv_appl … H) -H #B1 #A #HBD1 #H1 #H2
 118   elim (IHD12 … HBD1) -D1 #B2 #HB12 #HBD2 destruct
 119   @(ex2_intro … (@B2.A)) // /2 width=1/
 120 | #p #D1 #C1 #C2 #_ #IHC12 #d #M1 #H
 121   elim (lift_inv_appl … H) -H #B #A1 #H1 #HAC1 #H2
 122   elim (IHC12 … HAC1) -C1 #A2 #HA12 #HAC2 destruct
 123   @(ex2_intro … (@B.A2)) // /2 width=1/
 124 ]
 125 qed-.
 126
 127 lemma lsred_dsubst: ∀p. dsubstable_dx (lsred p).
 128 #p #D1 #M1 #M2 #H elim H -p -M1 -M2 normalize /2 width=1/
 129 #D2 #A #d >dsubst_dsubst_ge //
 130 qed.
 131
 132 theorem lsred_mono: ∀p. singlevalued … (lsred p).
 133 #p #M #N1 #H elim H -p -M -N1
 134 [ #B #A #N2 #H elim (lsred_inv_nil … H ?) -H //
 135   #D #C #H #HN2 destruct //
 136 | #p #A1 #A2 #_ #IHA12 #N2 #H elim (lsred_inv_rc … H ??) -H [3: // |2: skip ] (**) (* simplify line *)
 137   #C1 #C2 #HC12 #H #HN2 destruct /3 width=1/
 138 | #p #B1 #B2 #A #_ #IHB12 #N2 #H elim (lsred_inv_sn … H ??) -H [3: // |2: skip ] (**) (* simplify line *)
 139   #D1 #D2 #C #HD12 #H #HN2 destruct /3 width=1/
 140 | #p #B #A1 #A2 #_ #IHA12 #N2 #H elim (lsred_inv_dx … H ??) -H [3: // |2: skip ] (**) (* simplify line *)
 141   #D #C1 #C2 #HC12 #H #HN2 destruct /3 width=1/
 142 ]
 143 qed-.