matita/matita/contribs/lambda/paths/labeled_st_reduction.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "subterms/delifting_substitution.ma".
  16 include "subterms/projections.ma".
  17 include "paths/standard_order.ma".
  18
  19 (* PATH-LABELED STANDARD REDUCTION ON SUBTERMS (SINGLE STEP) ****************)
  20
  21 (* Note: this is standard reduction on marked redexes,
  22          left residuals are unmarked in the reductum
  23 *)
  24 inductive pl_st: path → relation subterms ≝
  25 | pl_st_beta   : ∀V,T. pl_st (◊) ({⊤}@V.{⊤}𝛌.T) ([↙V]T)
  26 | pl_st_abst   : ∀b,p,T1,T2. pl_st p T1 T2 → pl_st (rc::p) ({b}𝛌.T1) ({⊥}𝛌.T2)
  27 | pl_st_appl_sn: ∀b,p,V1,V2,T. pl_st p V1 V2 → pl_st (sn::p) ({b}@V1.T) ({⊥}@V2.{⊥}⇕T)
  28 | pl_st_appl_dx: ∀b,p,V,T1,T2. pl_st p T1 T2 → pl_st (dx::p) ({b}@V.T1) ({b}@V.T2)
  29 .
  30
  31 interpretation "path-labeled standard reduction"
  32     'Std F p G = (pl_st p F G).
  33
  34 notation "hvbox( F break Ⓡ ↦ [ term 46 p ] break term 46 G )"
  35    non associative with precedence 45
  36    for @{ 'Std $F $p $G }.
  37 (*
  38 lemma pl_st_inv_pl_sred: ∀p,F,G. F Ⓡ↦[p] G → ⇓F ↦[p] ⇓G.
  39 #p #F #G #H elim H -p -F -G // /2 width=1/
  40 qed-.
  41
  42 lemma pl_st_inv_vref: ∀p,F,G. F Ⓡ↦[p] G → ∀b,i. {b}#i = F → ⊥.
  43 /3 width=5 by pl_st_inv_st, st_inv_vref/
  44 qed-.
  45 *)
  46 lemma pl_st_inv_abst: ∀p,F,G. F Ⓡ↦[p] G → ∀b0,U1. {b0}𝛌.U1 = F →
  47                       ∃∃q,U2. U1 Ⓡ↦[q] U2 & rc::q = p & {⊥}𝛌.U2 = G.
  48 #p #F #G * -p -F -G
  49 [ #V #T #b0 #U1 #H destruct
  50 | #b #p #T1 #T2 #HT12 #b0 #U1 #H destruct /2 width=5/
  51 | #b #p #V1 #V2 #T #_ #b0 #U1 #H destruct
  52 | #b #p #V #T1 #T2 #_ #b0 #U1 #H destruct
  53 ]
  54 qed-.
  55
  56 lemma pl_st_inv_appl: ∀p,F,G. F Ⓡ↦[p] G → ∀b0,W,U. {b0}@W.U = F →
  57                       ∨∨ (∃∃U0. ⊤ = b0 & ◊ = p & {⊤}𝛌.U0 = U & [↙W] U0 = G)
  58                        | (∃∃q,W0. sn::q = p & W Ⓡ↦[q] W0 & {⊥}@W0.{⊥}⇕U = G)
  59                        | (∃∃q,U0. dx::q = p & U Ⓡ↦[q] U0 & {b0}@W.U0 = G).
  60 #p #F #G * -p -F -G
  61 [ #V #T #b0 #W #U #H destruct /3 width=3/
  62 | #b #p #T1 #T2 #_ #b0 #W #U #H destruct
  63 | #b #p #V1 #V2 #T #HV12 #b0 #W #U #H destruct /3 width=5/
  64 | #b #p #V #T1 #T2 #HT12 #b0 #W #U #H destruct /3 width=5/
  65 ]
  66 qed-.
  67
  68 lemma pl_st_fwd_abst: ∀p,F,G. F Ⓡ↦[p] G → ∀b0,U2. {b0}𝛌.U2 = G →
  69                       ◊ = p ∨ ∃q. rc::q = p.
  70 #p #F #G * -p -F -G
  71 [ /2 width=1/
  72 | /3 width=2/
  73 | #b #p #V1 #V2 #T #_ #b0 #U2 #H destruct
  74 | #b #p #V #T1 #T2 #_ #b0 #U2 #H destruct
  75 ]
  76 qed-.
  77
  78 lemma pl_st_inv_nil: ∀p,F,G. F Ⓡ↦[p] G → ◊ = p →
  79                      ∃∃V,T. {⊤}@V.{⊤} 𝛌.T = F & [↙V] T = G.
  80 #p #F #G * -p -F -G
  81 [ #V #T #_ destruct /2 width=4/
  82 | #b #p #T1 #T2 #_ #H destruct
  83 | #b #p #V1 #V2 #T #_ #H destruct
  84 | #b #p #V #T1 #T2 #_ #H destruct
  85 ]
  86 qed-.
  87
  88 lemma pl_st_inv_rc: ∀p,F,G. F Ⓡ↦[p] G → ∀q. rc::q = p →
  89                     ∃∃b,T1,T2. T1 Ⓡ↦[q] T2 & {b}𝛌.T1 = F & {⊥}𝛌.T2 = G.
  90 #p #F #G * -p -F -G
  91 [ #V #T #q #H destruct
  92 | #b #p #T1 #T2 #HT12 #q #H destruct /2 width=6/
  93 | #b #p #V1 #V2 #T #_ #q #H destruct
  94 | #b #p #V #T1 #T2 #_ #q #H destruct
  95 ]
  96 qed-.
  97
  98 lemma pl_st_inv_sn: ∀p,F,G. F Ⓡ↦[p] G → ∀q. sn::q = p →
  99                     ∃∃b,V1,V2,T. V1 Ⓡ↦[q] V2 & {b}@V1.T = F & {⊥}@V2.{⊥}⇕T = G.
 100 #p #F #G * -p -F -G
 101 [ #V #T #q #H destruct
 102 | #b #p #T1 #T2 #_ #q #H destruct
 103 | #b #p #V1 #V2 #T #HV12 #q #H destruct /2 width=7/
 104 | #b #p #V #T1 #T2 #_ #q #H destruct
 105 ]
 106 qed-.
 107
 108 lemma pl_st_inv_dx: ∀p,F,G. F Ⓡ↦[p] G → ∀q. dx::q = p →
 109                     ∃∃b,V,T1,T2. T1 Ⓡ↦[q] T2 & {b}@V.T1 = F & {b}@V.T2 = G.
 110 #p #F #G * -p -F -G
 111 [ #V #T #q #H destruct
 112 | #b #p #T1 #T2 #_ #q #H destruct
 113 | #b #p #V1 #V2 #T #_ #q #H destruct
 114 | #b #p #V #T1 #T2 #HT12 #q #H destruct /2 width=7/
 115 ]
 116 qed-.
 117
 118
 119
 120 (*
 121 lemma pl_st_lift: ∀p. sliftable (pl_st p).
 122 #p #h #F1 #F2 #H elim H -p -F1 -F2 normalize /2 width=1/
 123 [ #V #T #d <sdsubst_slift_le //
 124 | #b #p #V1 #V2 #T #_ #IHV12 #d
 125 qed.
 126
 127 lemma pl_st_inv_lift: ∀p. deliftable_sn (pl_st p).
 128 #p #h #G1 #G2 #H elim H -p -G1 -G2
 129 [ #W #U #d #F1 #H
 130   elim (lift_inv_appl … H) -H #V #F #H0 #HF #H destruct
 131   elim (lift_inv_abst … HF) -HF #T #H0 #H destruct /3 width=3/
 132 | #p #U1 #U2 #_ #IHU12 #d #F1 #H
 133   elim (lift_inv_abst … H) -H #T1 #HTU1 #H
 134   elim (IHU12 … HTU1) -U1 #T2 #HT12 #HTU2 destruct
 135   @(ex2_intro … (𝛌.T2)) // /2 width=1/
 136 | #p #W1 #W2 #U1 #_ #IHW12 #d #F1 #H
 137   elim (lift_inv_appl … H) -H #V1 #T #HVW1 #H1 #H2
 138   elim (IHW12 … HVW1) -W1 #V2 #HV12 #HVW2 destruct
 139   @(ex2_intro … (@V2.T)) // /2 width=1/
 140 | #p #W1 #U1 #U2 #_ #IHU12 #d #F1 #H
 141   elim (lift_inv_appl … H) -H #V #T1 #H1 #HTU1 #H2
 142   elim (IHU12 … HTU1) -U1 #T2 #HT12 #HTU2 destruct
 143   @(ex2_intro … (@V.T2)) // /2 width=1/
 144 ]
 145 qed-.
 146
 147 lemma pl_st_dsubst: ∀p. sdsubstable_dx (pl_st p).
 148 #p #W1 #F1 #F2 #H elim H -p -F1 -F2 normalize /2 width=1/
 149 #W2 #T #d >dsubst_dsubst_ge //
 150 qed.
 151 *)
 152
 153 lemma pl_st_inv_empty: ∀p,G1,G2. G1 Ⓡ↦[p] G2 → ∀F1. {⊥}⇕F1 = G1 → ⊥.
 154 #p #F1 #F2 #H elim H -p -F1 -F2
 155 [ #V #T #F1 #H
 156   elim (mk_boolean_inv_appl … H) -H #b0 #W #U #H destruct
 157 | #b #p #T1 #T2 #_ #IHT12 #F1 #H
 158   elim (mk_boolean_inv_abst … H) -H /2 width=2/
 159 | #b #p #V1 #V2 #T #_ #IHV12 #F1 #H
 160   elim (mk_boolean_inv_appl … H) -H /2 width=2/
 161 | #b #p #V #T1 #T2 #_ #IHT12 #F1 #H
 162   elim (mk_boolean_inv_appl … H) -H /2 width=2/
 163 ]
 164 qed-.
 165
 166 theorem pl_st_mono: ∀p. singlevalued … (pl_st p).
 167 #p #F #G1 #H elim H -p -F -G1
 168 [ #V #T #G2 #H elim (pl_st_inv_nil … H ?) -H //
 169   #W #U #H #HG2 destruct //
 170 | #b #p #T1 #T2 #_ #IHT12 #G2 #H elim (pl_st_inv_rc … H ??) -H [3: // |2: skip ] (**) (* simplify line *)
 171   #b0 #U1 #U2 #HU12 #H #HG2 destruct /3 width=1/
 172 | #b #p #V1 #V2 #T #_ #IHV12 #G2 #H elim (pl_st_inv_sn … H ??) -H [3: // |2: skip ] (**) (* simplify line *)
 173   #b0 #W1 #W2 #U #HW12 #H #HG2 destruct /3 width=1/
 174 | #b #p #V #T1 #T2 #_ #IHT12 #G2 #H elim (pl_st_inv_dx … H ??) -H [3: // |2: skip ] (**) (* simplify line *)
 175   #b0 #W #U1 #U2 #HU12 #H #HG2 destruct /3 width=1/
 176 ]
 177 qed-.
 178
 179 theorem pl_st_inv_is_standard: ∀p1,F1,F. F1 Ⓡ↦[p1] F →
 180                                ∀p2,F2. F Ⓡ↦[p2] F2 → p1 ≤ p2.
 181 #p1 #F1 #F #H elim H -p1 -F1 -F //
 182 [ #b #p #T1 #T #_ #IHT1 #p2 #F2 #H elim (pl_st_inv_abst … H ???) -H [3: // |2,4: skip ] (**) (* simplify line *)
 183   #q #T2 #HT2 #H1 #H2 destruct /3 width=2/
 184 | #b #p #V1 #V #T #_ #IHV1 #p2 #F2 #H elim (pl_st_inv_appl … H ????) -H [7: // |2,3,4: skip ] * (**) (* simplify line *)
 185   [ #U #H destruct
 186   | #q #V2 #H1 #HV2 #H2 destruct /3 width=2/
 187   | #q #U #_ #H elim (pl_st_inv_empty … H ??) [ // | skip ] (**) (* simplify line *)
 188   ]
 189 | #b #p #V #T1 #T #HT1 #IHT1 #p2 #F2 #H elim (pl_st_inv_appl … H ????) -H [7: // |2,3,4: skip ] * (**) (* simplify line *)
 190   [ #U #_ #H1 #H2 #_ -b -V -F2 -IHT1
 191     elim (pl_st_fwd_abst … HT1 … H2) // -H1 * #q #H
 192     elim (pl_st_inv_rc … HT1 … H) -HT1 -H #b #U1 #U2 #_ #_ #H -b -q -T1 -U1 destruct
 193   | #q #V2 #H1 #_ #_ -b -F2 -T1 -T -V -V2 destruct //
 194   | #q #T2 #H1 #HT2 #H2 -b -F2 -T1 -V /3 width=2/
 195   ]
 196 ]
 197 qed-.