matita/matita/contribs/lambda/preamble.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basics/star.ma".
  16 include "basics/lists/list.ma".
  17 include "arithmetics/nat.ma".
  18
  19 include "xoa_notation.ma".
  20 include "xoa.ma".
  21
  22 (* Note: For some reason this cannot be in the standard library *)
  23 interpretation "logical false" 'false = False.
  24
  25 notation "⊥"
  26   non associative with precedence 90
  27   for @{'false}.
  28
  29 lemma lt_refl_false: ∀n. n < n → ⊥.
  30 #n #H elim (lt_to_not_eq … H) -H /2 width=1/
  31 qed-.
  32
  33 lemma lt_zero_false: ∀n. n < 0 → ⊥.
  34 #n #H elim (lt_to_not_le … H) -H /2 width=1/
  35 qed-.
  36
  37 lemma plus_lt_false: ∀m,n. m + n < m → ⊥.
  38 #m #n #H elim (lt_to_not_le … H) -H /2 width=1/
  39 qed-.
  40
  41 lemma lt_or_eq_or_gt: ∀m,n. ∨∨ m < n | n = m | n < m.
  42 #m #n elim (lt_or_ge m n) /2 width=1/
  43 #H elim H -m /2 width=1/
  44 #m #Hm * #H /2 width=1/ /3 width=1/
  45 qed-.
  46
  47 (* trichotomy operator *)
  48
  49 (* Note: this is "if eqb n1 n2 then a2 else if leb n1 n2 then a1 else a3" *)
  50 let rec tri (A:Type[0]) n1 n2 a1 a2 a3 on n1 : A ≝
  51   match n1 with
  52   [ O    ⇒ match n2 with [ O ⇒ a2 | S n2 ⇒ a1 ]
  53   | S n1 ⇒ match n2 with [ O ⇒ a3 | S n2 ⇒ tri A n1 n2 a1 a2 a3 ]
  54   ].
  55
  56 lemma tri_lt: ∀A,a1,a2,a3,n2,n1. n1 < n2 → tri A n1 n2 a1 a2 a3 = a1.
  57 #A #a1 #a2 #a3 #n2 elim n2 -n2
  58 [ #n1 #H elim (lt_zero_false … H)
  59 | #n2 #IH #n1 elim n1 -n1 // /3 width=1/
  60 ]
  61 qed.
  62
  63 lemma tri_eq: ∀A,a1,a2,a3,n. tri A n n a1 a2 a3 = a2.
  64 #A #a1 #a2 #a3 #n elim n -n normalize //
  65 qed.
  66
  67 lemma tri_gt: ∀A,a1,a2,a3,n1,n2. n2 < n1 → tri A n1 n2 a1 a2 a3 = a3.
  68 #A #a1 #a2 #a3 #n1 elim n1 -n1
  69 [ #n2 #H elim (lt_zero_false … H)
  70 | #n1 #IH #n2 elim n2 -n2 // /3 width=1/
  71 ]
  72 qed.