matita/matita/contribs/lambda/preamble.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "basics/star.ma".
  16 include "basics/lists/lstar.ma".
  17 include "arithmetics/exp.ma".
  18
  19 include "xoa_notation.ma".
  20 include "xoa.ma".
  21
  22 (* logic *)
  23
  24 (* Note: For some reason this cannot be in the standard library *)
  25 interpretation "logical false" 'false = False.
  26
  27 notation "⊥"
  28   non associative with precedence 90
  29   for @{'false}.
  30
  31 (* relations *)
  32
  33 definition confluent1: ∀A. relation A → predicate A ≝ λA,R,a0.
  34                        ∀a1. R a0 a1 → ∀a2. R a0 a2 →
  35                        ∃∃a. R a1 a & R a2 a.
  36
  37 (* Note: confluent1 would be redundant if \Pi-reduction where enabled *)
  38 definition confluent: ∀A. predicate (relation A) ≝ λA,R.
  39                       ∀a0. confluent1 … R a0.
  40
  41 (* arithmetics *)
  42
  43 lemma lt_refl_false: ∀n. n < n → ⊥.
  44 #n #H elim (lt_to_not_eq … H) -H /2 width=1/
  45 qed-.
  46
  47 lemma lt_zero_false: ∀n. n < 0 → ⊥.
  48 #n #H elim (lt_to_not_le … H) -H /2 width=1/
  49 qed-.
  50
  51 lemma plus_lt_false: ∀m,n. m + n < m → ⊥.
  52 #m #n #H elim (lt_to_not_le … H) -H /2 width=1/
  53 qed-.
  54
  55 lemma lt_or_eq_or_gt: ∀m,n. ∨∨ m < n | n = m | n < m.
  56 #m #n elim (lt_or_ge m n) /2 width=1/
  57 #H elim H -m /2 width=1/
  58 #m #Hm * #H /2 width=1/ /3 width=1/
  59 qed-.
  60
  61 (* trichotomy operator *)
  62
  63 (* Note: this is "if eqb n1 n2 then a2 else if leb n1 n2 then a1 else a3" *)
  64 let rec tri (A:Type[0]) n1 n2 a1 a2 a3 on n1 : A ≝
  65   match n1 with
  66   [ O    ⇒ match n2 with [ O ⇒ a2 | S n2 ⇒ a1 ]
  67   | S n1 ⇒ match n2 with [ O ⇒ a3 | S n2 ⇒ tri A n1 n2 a1 a2 a3 ]
  68   ].
  69
  70 lemma tri_lt: ∀A,a1,a2,a3,n2,n1. n1 < n2 → tri A n1 n2 a1 a2 a3 = a1.
  71 #A #a1 #a2 #a3 #n2 elim n2 -n2
  72 [ #n1 #H elim (lt_zero_false … H)
  73 | #n2 #IH #n1 elim n1 -n1 // /3 width=1/
  74 ]
  75 qed.
  76
  77 lemma tri_eq: ∀A,a1,a2,a3,n. tri A n n a1 a2 a3 = a2.
  78 #A #a1 #a2 #a3 #n elim n -n normalize //
  79 qed.
  80
  81 lemma tri_gt: ∀A,a1,a2,a3,n1,n2. n2 < n1 → tri A n1 n2 a1 a2 a3 = a3.
  82 #A #a1 #a2 #a3 #n1 elim n1 -n1
  83 [ #n2 #H elim (lt_zero_false … H)
  84 | #n1 #IH #n2 elim n2 -n2 // /3 width=1/
  85 ]
  86 qed.
  87
  88 (* lists *)
  89
  90 (* Note: notation for nil not involving brackets *)
  91 notation > "◊"
  92   non associative with precedence 90
  93   for @{'nil}.
  94
  95 definition map_cons: ∀A. A → list (list A) → list (list A) ≝ λA,a.
  96                      map … (cons … a).
  97
  98 interpretation "map_cons" 'ho_cons a l = (map_cons ? a l).
  99
 100 notation "hvbox(a ::: break l)"
 101   right associative with precedence 47
 102   for @{'ho_cons $a $l}.
 103
 104 (* lstar *)
 105
 106 (* Note: this cannot be in lib because of the missing xoa quantifier *)
 107 lemma lstar_inv_pos: ∀A,B,R,l,b1,b2. lstar A B R l b1 b2 → 0 < |l| →
 108                      ∃∃a,ll,b. a::ll = l & R a b1 b & lstar A B R ll b b2.
 109 #A #B #R #l #b1 #b2 #H @(lstar_ind_l ????????? H) -b1
 110 [ #H elim (lt_refl_false … H)
 111 | #a #ll #b1 #b #Hb1 #Hb2 #_ #_ /2 width=6/ (**) (* auto fail if we do not remove the inductive premise *)
 112 ]
 113 qed-.