matita/matita/contribs/lambda/st_computation.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "labelled_sequential_computation.ma".
  16
  17 (* KASHIMA'S "ST" COMPUTATION ***********************************************)
  18
  19 (* Note: this is the "standard" computation of:
  20          R. Kashima: "A proof of the Standization Theorem in λ-Calculus". Typescript note, (2000).
  21 *)
  22 inductive st: relation term ≝
  23 | st_vref: ∀s,M,i. is_head s → M ↦*[s] #i → st M (#i)
  24 | st_abst: ∀s,M,A1,A2. is_head s → M ↦*[s] 𝛌.A1 → st A1 A2 → st M (𝛌.A2)
  25 | st_appl: ∀s,M,B1,B2,A1,A2. is_head s → M ↦*[s] @B1.A1 → st B1 B2 → st A1 A2 → st M (@B2.A2)
  26 .
  27
  28 interpretation "'st' computation"
  29     'Std M N = (st M N).
  30
  31 notation "hvbox( M ⓢ⤇* break term 46 N )"
  32    non associative with precedence 45
  33    for @{ 'Std $M $N }.
  34
  35 lemma st_inv_lref: ∀M,N. M ⓢ⤇* N → ∀j. #j = N →
  36                    ∃∃s. is_head s & M ↦*[s] #j.
  37 #M #N * -M -N
  38 [ /2 width=3/
  39 | #s #M #A1 #A2 #_ #_ #_ #j #H destruct
  40 | #s #M #B1 #B2 #A1 #A2 #_ #_ #_ #_ #j #H destruct
  41 ]
  42 qed-.
  43
  44 lemma st_inv_abst: ∀M,N. M ⓢ⤇* N → ∀C2. 𝛌.C2 = N →
  45                    ∃∃s,C1. is_head s & M ↦*[s] 𝛌.C1 & C1 ⓢ⤇* C2.
  46 #M #N * -M -N
  47 [ #s #M #i #_ #_ #C2 #H destruct
  48 | #s #M #A1 #A2 #Hs #HM #A12 #C2 #H destruct /2 width=5/
  49 | #s #M #B1 #B2 #A1 #A2 #_ #_ #_ #_ #C2 #H destruct
  50 ]
  51 qed-.
  52
  53 lemma st_inv_appl: ∀M,N. M ⓢ⤇* N → ∀D2,C2. @D2.C2 = N →
  54                    ∃∃s,D1,C1. is_head s & M ↦*[s] @D1.C1 & D1 ⓢ⤇* D2 & C1 ⓢ⤇* C2.
  55 #M #N * -M -N
  56 [ #s #M #i #_ #_ #D2 #C2 #H destruct
  57 | #s #M #A1 #A2 #_ #_ #_ #D2 #C2 #H destruct
  58 | #s #M #B1 #B2 #A1 #A2 #Hs #HM #HB12 #HA12 #D2 #C2 #H destruct /2 width=7/
  59 ]
  60 qed-.
  61
  62 lemma st_refl: reflexive … st.
  63 #M elim M -M /2 width=3/ /2 width=5/ /2 width=7/
  64 qed.
  65
  66 lemma st_step_sn: ∀N1,N2. N1 ⓢ⤇* N2 → ∀s,M. is_head s → M ↦*[s] N1 → M ⓢ⤇* N2.
  67 #N1 #N2 #H elim H -N1 -N2
  68 [ #r #N #i #Hr #HN #s #M #Hs #HMN
  69   lapply (lsreds_trans … HMN … HN) -N /3 width=3/
  70 | #r #N #C1 #C2 #Hr #HN #_ #IHC12 #s #M #Hs #HMN
  71   lapply (lsreds_trans … HMN … HN) -N /3 width=7/
  72 | #r #N #D1 #D2 #C1 #C2 #Hr #HN #_ #_ #IHD12 #IHC12 #s #M #Hs #HMN
  73   lapply (lsreds_trans … HMN … HN) -N /3 width=9/
  74 ]
  75 qed-.
  76
  77 lemma st_step_rc: ∀s,M1,M2. is_head s → M1 ↦*[s] M2 → M1 ⓢ⤇* M2.
  78 /3 width=5 by st_step_sn/
  79 qed.
  80
  81 lemma st_lift: liftable st.
  82 #h #M1 #M2 #H elim H -M1 -M2
  83 [ /3 width=3/
  84 | #s #M #A1 #A2 #Hs #HM #_ #IHA12 #d
  85   @(st_abst … Hs) [2: @(lsreds_lift … HM) | skip ] -M // (**) (* auto fails here *)
  86 | #s #M #B1 #B2 #A1 #A2 #Hs #HM #_ #_ #IHB12 #IHA12 #d
  87   @(st_appl … Hs) [3: @(lsreds_lift … HM) |1,2: skip ] -M // (**) (* auto fails here *)
  88 ]
  89 qed.
  90
  91 lemma st_inv_lift: deliftable_sn st.
  92 #h #N1 #N2 #H elim H -N1 -N2
  93 [ #s #N1 #i #Hs #HN1 #d #M1 #HMN1
  94   elim (lsreds_inv_lift … HN1 … HMN1) -N1 /3 width=3/
  95 | #s #N1 #C1 #C2 #Hs  #HN1 #_ #IHC12 #d #M1 #HMN1
  96   elim (lsreds_inv_lift … HN1 … HMN1) -N1 #M2 #HM12 #HM2
  97   elim (lift_inv_abst … HM2) -HM2 #A1 #HAC1 #HM2 destruct
  98   elim (IHC12 ???) -IHC12 [4: // |2,3: skip ] #A2 #HA12 #HAC2 destruct (**) (* simplify line *)
  99   @(ex2_intro … (𝛌.A2)) // /2 width=5/
 100 | #s #N1 #D1 #D2 #C1 #C2 #Hs #HN1 #_ #_ #IHD12 #IHC12 #d #M1 #HMN1
 101   elim (lsreds_inv_lift … HN1 … HMN1) -N1 #M2 #HM12 #HM2
 102   elim (lift_inv_appl … HM2) -HM2 #B1 #A1 #HBD1 #HAC1 #HM2 destruct
 103   elim (IHD12 ???) -IHD12 [4: // |2,3: skip ] #B2 #HB12 #HBD2 destruct (**) (* simplify line *)
 104   elim (IHC12 ???) -IHC12 [4: // |2,3: skip ] #A2 #HA12 #HAC2 destruct (**) (* simplify line *)
 105   @(ex2_intro … (@B2.A2)) // /2 width=7/
 106 ]
 107 qed-.
 108
 109 lemma st_dsubst: dsubstable st.
 110 #N1 #N2 #HN12 #M1 #M2 #H elim H -M1 -M2
 111 [ #s #M #i #Hs #HM #d elim (lt_or_eq_or_gt i d) #Hid
 112   [ lapply (lsreds_dsubst … N1 … HM d) -HM
 113     >(dsubst_vref_lt … Hid) >(dsubst_vref_lt … Hid) /2 width=3/
 114   | destruct >dsubst_vref_eq
 115     @(st_step_sn (↑[0,i]N1) … s) /2 width=1/
 116   | lapply (lsreds_dsubst … N1 … HM d) -HM
 117     >(dsubst_vref_gt … Hid) >(dsubst_vref_gt … Hid) /2 width=3/
 118   ]
 119 | #s #M #A1 #A2 #Hs #HM #_ #IHA12 #d
 120   lapply (lsreds_dsubst … N1 … HM d) -HM /2 width=5/ (**) (* auto needs some help here *)
 121 | #s #M #B1 #B2 #A1 #A2 #Hs #HM #_ #_ #IHB12 #IHA12 #d
 122   lapply (lsreds_dsubst … N1 … HM d) -HM /2 width=7/ (**) (* auto needs some help here *)
 123 ]
 124 qed.
 125
 126 lemma st_inv_lsreds_is_le: ∀M,N. M ⓢ⤇* N →
 127                            ∃∃r. M ↦*[r] N & is_le r.
 128 #M #N #H elim H -M -N
 129 [ #s #M #i #Hs #HM
 130   lapply (is_head_is_le … Hs) -Hs /2 width=3/
 131 | #s #M #A1 #A2 #Hs #HM #_ * #r #HA12 #Hr
 132   lapply (lsreds_trans … HM (sn:::r) (𝛌.A2) ?) /2 width=1/ -A1 #HM
 133   @(ex2_intro … HM) -M -A2 /3 width=1/
 134 | #s #M #B1 #B2 #A1 #A2 #Hs #HM #_ #_ * #rb #HB12 #Hrb * #ra #HA12 #Hra
 135   lapply (lsreds_trans … HM (dx:::ra) (@B1.A2) ?) /2 width=1/ -A1 #HM
 136   lapply (lsreds_trans … HM (sn:::rb) (@B2.A2) ?) /2 width=1/ -B1 #HM
 137   @(ex2_intro … HM) -M -B2 -A2 >associative_append /3 width=1/
 138 ]
 139 qed-.
 140
 141 lemma st_step_dx: ∀p,M,M2. M ↦[p] M2 → ∀M1. M1 ⓢ⤇* M → M1 ⓢ⤇* M2.
 142 #p #M #M2 #H elim H -p -M -M2
 143 [ #B #A #M1 #H
 144   elim (st_inv_appl … H ???) -H [4: // |2,3: skip ] #s #B1 #M #Hs #HM1 #HB1 #H (**) (* simplify line *)
 145   elim (st_inv_abst … H ??) -H [3: // |2: skip ] #r #A1 #Hr #HM #HA1 (**) (* simplify line *)
 146   lapply (lsreds_trans … HM1 … (dx:::r) (@B1.𝛌.A1) ?) /2 width=1/ -M #HM1
 147   lapply (lsreds_step_dx … HM1 (◊) ([↙B1]A1) ?) -HM1 // #HM1
 148   @(st_step_sn … HM1) /2 width=1/ /4 width=1/
 149 | #p #A #A2 #_ #IHA2 #M1 #H
 150   elim (st_inv_abst … H ??) -H [3: // |2: skip ] /3 width=5/ (**) (* simplify line *)
 151 | #p #B #B2 #A #_ #IHB2 #M1 #H
 152   elim (st_inv_appl … H ???) -H [4: // |2,3: skip ] /3 width=7/ (**) (* simplify line *)
 153 | #p #B #A #A2 #_ #IHA2 #M1 #H
 154   elim (st_inv_appl … H ???) -H [4: // |2,3: skip ] /3 width=7/ (**) (* simplify line *)
 155 ]
 156 qed-.
 157
 158 (* Note: we use "lapply (rewrite_r ?? is_head … Hq)" (procedural)
 159          in place of "cut (is_head (q::r)) [ >Hq ]"  (declarative)
 160 *)
 161 lemma st_lsred_swap: ∀p. in_head p → ∀N1,N2. N1 ↦[p] N2 → ∀M1. M1 ⓢ⤇* N1 →
 162                      ∃∃q,M2. in_head q & M1 ↦[q] M2 & M2 ⓢ⤇* N2.
 163 #p #H @(in_head_ind … H) -p
 164 [ #N1 #N2 #H1 #M1 #H2
 165   elim (lsred_inv_nil … H1 ?) -H1 // #D #C #HN1 #HN2
 166   elim (st_inv_appl … H2 … HN1) -N1 #s1 #D1 #N #Hs1 #HM1 #HD1 #H
 167   elim (st_inv_abst … H ??) -H [3: // |2: skip ] #s2 #C1 #Hs2 #HN #HC1 (**) (* simplify line *)
 168   lapply (lsreds_trans … HM1 … (dx:::s2) (@D1.𝛌.C1) ?) /2 width=1/ -N #HM1
 169   lapply (lsreds_step_dx … HM1 (◊) ([↙D1]C1) ?) -HM1 // #HM1
 170   elim (lsreds_inv_pos … HM1 ?) -HM1
 171   [2: >length_append normalize in ⊢ (??(??%)); // ]
 172   #q #r #M #Hq #HM1 #HM
 173   lapply (rewrite_r ?? is_head … Hq) -Hq /4 width=1/ -s1 -s2 * #Hq #Hr
 174   @(ex3_2_intro … HM1) -M1 // -q
 175   @(st_step_sn … HM) /2 width=1/
 176 | #p #_ #IHp #N1 #N2 #H1 #M1 #H2
 177   elim (lsred_inv_dx … H1 ??) -H1 [3: // |2: skip ] #D #C1 #C2 #HC12 #HN1 #HN2 (**) (* simplify line *)
 178   elim (st_inv_appl … H2 … HN1) -N1 #s #B #A1 #Hs #HM1 #HBD #HAC1
 179   elim (IHp … HC12 … HAC1) -p -C1 #p #C1 #Hp #HAC1 #HC12
 180   lapply (lsreds_step_dx … HM1 (dx::p) (@B.C1) ?) -HM1 /2 width=1/ -A1 #HM1
 181   elim (lsreds_inv_pos … HM1 ?) -HM1
 182   [2: >length_append normalize in ⊢ (??(??%)); // ]
 183   #q #r #M #Hq #HM1 #HM
 184   lapply (rewrite_r ?? is_head … Hq) -Hq /4 width=1/ -p -s * #Hq #Hr
 185   @(ex3_2_intro … HM1) -M1 // -q /2 width=7/
 186 ]
 187 qed-.
 188
 189 lemma st_lsreds: ∀s,M1,M2. M1 ↦*[s] M2 → M1 ⓢ⤇* M2.
 190 #s #M1 #M2 #H @(lstar_ind_r ????????? H) -s -M2 // /2 width=4 by st_step_dx/
 191 qed.
 192
 193 theorem st_trans: transitive … st.
 194 #M1 #M #M2 #HM1 #HM2
 195 elim (st_inv_lsreds_is_le … HM1) -HM1 #s1 #HM1 #_
 196 elim (st_inv_lsreds_is_le … HM2) -HM2 #s2 #HM2 #_
 197 lapply (lsreds_trans … HM1 … HM2) -M /2 width=2/
 198 qed-.
 199
 200 theorem lsreds_standard: ∀s,M,N. M ↦*[s] N → ∃∃r. M ↦*[r] N & is_le r.
 201 #s #M #N #H
 202 @st_inv_lsreds_is_le /2 width=2/
 203 qed-.
 204
 205 theorem lsreds_lhap1_swap: ∀s,M1,N1. M1 ↦*[s] N1 →
 206                            ∀p,N2. in_head p → N1 ↦[p] N2 →
 207                            ∃∃q,r,M2. in_head q & M1 ↦[q] M2 & M2 ↦*[r] N2 &
 208                                      is_le (q::r).
 209 #s #M1 #N1 #HMN1 #p #N2 #Hp #HN12
 210 lapply (st_lsreds … HMN1) -s #HMN1
 211 elim (st_lsred_swap … Hp … HN12 … HMN1) -p -N1 #q #M2 #Hq #HM12 #HMN2
 212 elim (st_inv_lsreds_is_le … HMN2) -HMN2 /3 width=8/
 213 qed-.