matita/matita/contribs/lambda-delta/Basic-2/grammar/leq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic-2/grammar/lenv_length.ma".
  16
  17 (* LOCAL ENVIRONMENT EQUALITY ***********************************************)
  18
  19 inductive leq: lenv → nat → nat → lenv → Prop ≝
  20 | leq_sort: ∀d,e. leq (⋆) d e (⋆)
  21 | leq_OO:   ∀L1,L2. leq L1 0 0 L2
  22 | leq_eq:   ∀L1,L2,I,V,e. leq L1 0 e L2 → leq (L1. 𝕓{I} V) 0 (e + 1) (L2.𝕓{I} V)
  23 | leq_skip: ∀L1,L2,I1,I2,V1,V2,d,e.
  24             leq L1 d e L2 → leq (L1. 𝕓{I1} V1) (d + 1) e (L2. 𝕓{I2} V2)
  25 .
  26
  27 interpretation "local environment equality" 'Eq L1 d e L2 = (leq L1 d e L2).
  28
  29 (* Basic properties *********************************************************)
  30
  31 lemma leq_refl: ∀d,e,L. L [d, e] ≈ L.
  32 #d elim d -d
  33 [ #e elim e -e // #e #IHe #L elim L -L /2/
  34 | #d #IHd #e #L elim L -L /2/
  35 ]
  36 qed.
  37
  38 lemma leq_sym: ∀L1,L2,d,e. L1 [d, e] ≈ L2 → L2 [d, e] ≈ L1.
  39 #L1 #L2 #d #e #H elim H -H L1 L2 d e /2/
  40 qed.
  41
  42 lemma leq_skip_lt: ∀L1,L2,d,e. L1 [d - 1, e] ≈ L2 → 0 < d →
  43                    ∀I1,I2,V1,V2. L1. 𝕓{I1} V1 [d, e] ≈ L2. 𝕓{I2} V2.
  44
  45 #L1 #L2 #d #e #HL12 #Hd >(plus_minus_m_m d 1) /2/
  46 qed.
  47
  48 (* Basic inversion lemmas ***************************************************)