matita/matita/contribs/lambda-delta/Basic-2/reduction/tpr_tpr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic-2/substitution/tps_tps.ma".
  16 include "Basic-2/reduction/tpr_lift.ma".
  17 include "Basic-2/reduction/tpr_tps.ma".
  18
  19 (* CONTEXT-FREE PARALLEL REDUCTION ON TERMS *********************************)
  20
  21 (* Confluence lemmas ********************************************************)
  22
  23 fact tpr_conf_atom_atom: ∀I. ∃∃X. 𝕒{I} ⇒ X & 𝕒{I} ⇒ X.
  24 /2/ qed.
  25
  26 fact tpr_conf_flat_flat:
  27    ∀I,V0,V1,T0,T1,V2,T2. (
  28       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
  29       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  30       ∃∃X. X1 ⇒ X & X2 ⇒ X
  31    ) →
  32    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
  33    ∃∃T0. 𝕗{I} V1. T1 ⇒ T0 & 𝕗{I} V2. T2 ⇒ T0.
  34 #I #V0 #V1 #T0 #T1 #V2 #T2 #IH #HV01 #HV02 #HT01 #HT02
  35 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
  36 elim (IH … HT01 … HT02) -HT01 HT02 /3 width=5/
  37 qed.
  38
  39 fact tpr_conf_flat_beta:
  40    ∀V0,V1,T1,V2,W0,U0,T2. (
  41       ∀X0:term. #[X0] < #[V0] + (#[W0] + #[U0] + 1) + 1 →
  42       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  43       ∃∃X. X1 ⇒ X & X2 ⇒ X
  44    ) →
  45    V0 ⇒ V1 → V0 ⇒ V2 →
  46    U0 ⇒ T2 → 𝕔{Abst} W0. U0 ⇒ T1 →
  47    ∃∃X. 𝕔{Appl} V1. T1 ⇒ X & 𝕔{Abbr} V2. T2 ⇒ X.
  48 #V0 #V1 #T1 #V2 #W0 #U0 #T2 #IH #HV01 #HV02 #HT02 #H
  49 elim (tpr_inv_abst1 … H) -H #W1 #U1 #HW01 #HU01 #H destruct -T1;
  50 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
  51 elim (IH … HT02 … HU01) -HT02 HU01 IH /3 width=5/
  52 qed.
  53
  54 fact tpr_conf_flat_theta:
  55    ∀V0,V1,T1,V2,V,W0,W2,U0,U2. (
  56       ∀X0:term. #[X0] < #[V0] + (#[W0] + #[U0] + 1) + 1 →
  57       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  58       ∃∃X. X1 ⇒ X & X2 ⇒ X
  59    ) →
  60    V0 ⇒ V1 → V0 ⇒ V2 → ↑[O,1] V2 ≡ V →
  61    W0 ⇒ W2 → U0 ⇒ U2 →  𝕔{Abbr} W0. U0 ⇒ T1 →
  62    ∃∃X. 𝕔{Appl} V1. T1 ⇒ X & 𝕔{Abbr} W2. 𝕔{Appl} V. U2 ⇒ X.
  63 #V0 #V1 #T1 #V2 #V #W0 #W2 #U0 #U2 #IH #HV01 #HV02 #HV2 #HW02 #HU02 #H
  64 elim (IH … HV01 … HV02) -HV01 HV02 // #VV #HVV1 #HVV2
  65 elim (lift_total VV 0 1) #VVV #HVV
  66 lapply (tpr_lift … HVV2 … HV2 … HVV) #HVVV
  67 elim (tpr_inv_abbr1 … H) -H *
  68 (* case 1: delta *)
  69 [ -HV2 HVV2 #WW2 #UU2 #UU #HWW2 #HUU02 #HUU2 #H destruct -T1;
  70   elim (IH … HW02 … HWW2) -HW02 HWW2 // #W #HW02 #HWW2
  71   elim (IH … HU02 … HUU02) -HU02 HUU02 IH // #U #HU2 #HUUU2
  72   elim (tpr_tps_bind … HWW2 HUUU2 … HUU2) -HUU2 HUUU2 #UUU #HUUU2 #HUUU1
  73   @ex2_1_intro
  74   [2: @tpr_theta [6: @HVV |7: @HWW2 |8: @HUUU2 |1,2,3,4: skip | // ]
  75   |1:skip
  76   |3: @tpr_delta [3: @tpr_flat |1: skip ] /2 width=5/
  77   ] (**) (* /5 width=14/ is too slow *)
  78 (* case 3: zeta *)
  79 | -HW02 HVV HVVV #UU1 #HUU10 #HUUT1
  80   elim (tpr_inv_lift … HU02 … HUU10) -HU02 #UU #HUU2 #HUU1
  81   lapply (tw_lift … HUU10) -HUU10 #HUU10
  82   elim (IH … HUUT1 … HUU1) -HUUT1 HUU1 IH // -HUU10 #U #HU2 #HUUU2
  83   @ex2_1_intro
  84   [2: @tpr_flat
  85   |1: skip
  86   |3: @tpr_zeta [2: @lift_flat |1: skip |3: @tpr_flat ]
  87   ] /2 width=5/ (**) (* /5 width=5/ is too slow *)
  88 ]
  89 qed.
  90
  91 fact tpr_conf_flat_cast:
  92    ∀X2,V0,V1,T0,T1. (
  93       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
  94       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  95       ∃∃X. X1 ⇒ X & X2 ⇒ X
  96    ) →
  97    V0 ⇒ V1 → T0 ⇒ T1 → T0 ⇒ X2 →
  98    ∃∃X. 𝕔{Cast} V1. T1 ⇒ X & X2 ⇒ X.
  99 #X2 #V0 #V1 #T0 #T1 #IH #_ #HT01 #HT02
 100 elim (IH … HT01 … HT02) -HT01 HT02 IH /3/
 101 qed.
 102
 103 fact tpr_conf_beta_beta:
 104    ∀W0:term. ∀V0,V1,T0,T1,V2,T2. (
 105       ∀X0:term. #[X0] < #[V0] + (#[W0] + #[T0] + 1) + 1 →
 106       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 107       ∃∃X. X1 ⇒ X & X2 ⇒ X
 108    ) →
 109    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
 110    ∃∃X. 𝕔{Abbr} V1. T1 ⇒X & 𝕔{Abbr} V2. T2 ⇒ X.
 111 #W0 #V0 #V1 #T0 #T1 #V2 #T2 #IH #HV01 #HV02 #HT01 #HT02
 112 elim (IH … HV01 … HV02) -HV01 HV02 //
 113 elim (IH … HT01 … HT02) -HT01 HT02 IH /3 width=5/
 114 qed.
 115
 116 fact tpr_conf_delta_delta:
 117    ∀I1,V0,V1,T0,T1,TT1,V2,T2,TT2. (
 118       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
 119       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 120       ∃∃X. X1 ⇒ X & X2 ⇒ X
 121    ) →
 122    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
 123    ⋆. 𝕓{I1} V1 ⊢ T1 [O, 1] ≫ TT1 →
 124    ⋆. 𝕓{I1} V2 ⊢ T2 [O, 1] ≫ TT2 →
 125    ∃∃X. 𝕓{I1} V1. TT1 ⇒ X & 𝕓{I1} V2. TT2 ⇒ X.
 126 #I1 #V0 #V1 #T0 #T1 #TT1 #V2 #T2 #TT2 #IH #HV01 #HV02 #HT01 #HT02 #HTT1 #HTT2
 127 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
 128 elim (IH … HT01 … HT02) -HT01 HT02 IH // #T #HT1 #HT2
 129 elim (tpr_tps_bind … HV1 HT1 … HTT1) -HT1 HTT1 #U1 #TTU1 #HTU1
 130 elim (tpr_tps_bind … HV2 HT2 … HTT2) -HT2 HTT2 #U2 #TTU2 #HTU2
 131 elim (tps_conf … HTU1 … HTU2) -HTU1 HTU2 #U #HU1 #HU2
 132 @ex2_1_intro [2,3: @tpr_delta |1: skip ] /width=10/ (**) (* /3 width=10/ is too slow *)
 133 qed.
 134
 135 fact tpr_conf_delta_zeta:
 136    ∀X2,V0,V1,T0,T1,TT1,T2. (
 137       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
 138       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 139       ∃∃X. X1 ⇒ X & X2 ⇒ X
 140    ) →
 141    V0 ⇒ V1 → T0 ⇒ T1 → ⋆. 𝕓{Abbr} V1 ⊢ T1 [O,1] ≫ TT1 →
 142    T2 ⇒ X2 → ↑[O, 1] T2 ≡ T0 →
 143    ∃∃X. 𝕓{Abbr} V1. TT1 ⇒ X & X2 ⇒ X.
 144 #X2 #V0 #V1 #T0 #T1 #TT1 #T2 #IH #_ #HT01 #HTT1 #HTX2 #HTT20
 145 elim (tpr_inv_lift … HT01 … HTT20) -HT01 #TT2 #HTT21 #HTT2
 146 lapply (tps_inv_lift1_eq … HTT1 … HTT21) -HTT1 #HTT1 destruct -T1;
 147 lapply (tw_lift … HTT20) -HTT20 #HTT20
 148 elim (IH … HTX2 … HTT2) -HTX2 HTT2 IH /3/
 149 qed.
 150
 151 fact tpr_conf_theta_theta:
 152    ∀VV1,V0,V1,W0,W1,T0,T1,V2,VV2,W2,T2. (
 153       ∀X0:term. #[X0] < #[V0] + (#[W0] + #[T0] + 1) + 1 →
 154       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 155       ∃∃X. X1 ⇒ X & X2 ⇒ X
 156    ) →
 157    V0 ⇒ V1 → V0 ⇒ V2 → W0 ⇒ W1 → W0 ⇒ W2 → T0 ⇒ T1 → T0 ⇒ T2 →
 158    ↑[O, 1] V1 ≡ VV1 → ↑[O, 1] V2 ≡ VV2 →
 159    ∃∃X. 𝕔{Abbr} W1. 𝕔{Appl} VV1. T1 ⇒ X & 𝕔{Abbr} W2. 𝕔{Appl} VV2. T2 ⇒ X.
 160 #VV1 #V0 #V1 #W0 #W1 #T0 #T1 #V2 #VV2 #W2 #T2 #IH #HV01 #HV02 #HW01 #HW02 #HT01 #HT02 #HVV1 #HVV2
 161 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
 162 elim (IH … HW01 … HW02) -HW01 HW02 // #W #HW1 #HW2
 163 elim (IH … HT01 … HT02) -HT01 HT02 IH // #T #HT1 #HT2
 164 elim (lift_total V 0 1) #VV #HVV
 165 lapply (tpr_lift … HV1 … HVV1 … HVV) -HV1 HVV1 #HVV1
 166 lapply (tpr_lift … HV2 … HVV2 … HVV) -HV2 HVV2 HVV #HVV2
 167 @ex2_1_intro [2,3: @tpr_bind |1:skip ] /2 width=5/ (**) (* /4 width=5/ is too slow *)
 168 qed.
 169
 170 fact tpr_conf_zeta_zeta:
 171    ∀V0:term. ∀X2,TT0,T0,T1,T2. (
 172       ∀X0:term. #[X0] < #[V0] + #[TT0] + 1 →
 173       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 174       ∃∃X. X1 ⇒ X & X2 ⇒ X
 175    ) →
 176    T0 ⇒ T1 → T2 ⇒ X2 →
 177    ↑[O, 1] T0 ≡ TT0 → ↑[O, 1] T2 ≡ TT0 →
 178    ∃∃X. T1 ⇒ X & X2 ⇒ X.
 179 #V0 #X2 #TT0 #T0 #T1 #T2 #IH #HT01 #HTX2 #HTT0 #HTT20
 180 lapply (lift_inj … HTT0 … HTT20) -HTT0 #H destruct -T0;
 181 lapply (tw_lift … HTT20) -HTT20 #HTT20
 182 elim (IH … HT01 … HTX2) -HT01 HTX2 IH /2/
 183 qed.
 184
 185 fact tpr_conf_tau_tau:
 186    ∀V0,T0:term. ∀X2,T1. (
 187       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
 188       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 189       ∃∃X. X1 ⇒ X & X2 ⇒ X
 190    ) →
 191    T0 ⇒ T1 → T0 ⇒ X2 →
 192    ∃∃X. T1 ⇒ X & X2 ⇒ X.
 193 #V0 #T0 #X2 #T1 #IH #HT01 #HT02
 194 elim (IH … HT01 … HT02) -HT01 HT02 IH /2/
 195 qed.
 196
 197 (* Confluence ***************************************************************)
 198
 199 fact tpr_conf_aux:
 200    ∀Y0:term. (
 201       ∀X0:term. #[X0] < #[Y0] →
 202       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 203       ∃∃X. X1 ⇒ X & X2 ⇒ X
 204          ) →
 205    ∀X0,X1,X2. X0 ⇒ X1 → X0 ⇒ X2 → X0 = Y0 →
 206    ∃∃X. X1 ⇒ X & X2 ⇒ X.
 207 #Y0 #IH #X0 #X1 #X2 * -X0 X1
 208 [ #I1 #H1 #H2 destruct -Y0;
 209   lapply (tpr_inv_atom1 … H1) -H1
 210 (* case 1: atom, atom *)
 211   #H1 destruct -X2 //
 212 | #I #V0 #V1 #T0 #T1 #HV01 #HT01 #H1 #H2 destruct -Y0;
 213   elim (tpr_inv_flat1 … H1) -H1 *
 214 (* case 2: flat, flat *)
 215   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 216     /3 width=7 by tpr_conf_flat_flat/ (**) (* /3 width=7/ is too slow *)
 217 (* case 3: flat, beta *)
 218   | #V2 #W #U0 #T2 #HV02 #HT02 #H1 #H2 #H3 destruct -T0 X2 I
 219     /3 width=8 by tpr_conf_flat_beta/ (**) (* /3 width=8/ is too slow *)
 220 (* case 4: flat, theta *)
 221   | #V2 #V #W0 #W2 #U0 #U2 #HV02 #HW02 #HT02 #HV2 #H1 #H2 #H3 destruct -T0 X2 I
 222     /3 width=11 by tpr_conf_flat_theta/ (**) (* /3 width=11/ is too slow *)
 223 (* case 5: flat, tau *)
 224   | #HT02 #H destruct -I
 225     /3 width=6 by tpr_conf_flat_cast/ (**) (* /3 width=6/ is too slow *)
 226   ]
 227 | #V0 #V1 #W0 #T0 #T1 #HV01 #HT01 #H1 #H2 destruct -Y0;
 228   elim (tpr_inv_appl1 … H1) -H1 *
 229 (* case 6: beta, flat (repeated) *)
 230   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 231     @ex2_1_comm /3 width=8 by tpr_conf_flat_beta/
 232 (* case 7: beta, beta *)
 233   | #V2 #WW0 #TT0 #T2 #HV02 #HT02 #H1 #H2 destruct -W0 T0 X2
 234     /3 width=8 by tpr_conf_beta_beta/ (**) (* /3 width=8/ is too slow *)
 235 (* case 8, beta, theta (excluded) *)
 236   | #V2 #VV2 #WW0 #W2 #TT0 #T2 #_ #_ #_ #_ #H destruct
 237   ]
 238 | #I1 #V0 #V1 #T0 #T1 #TT1 #HV01 #HT01 #HTT1 #H1 #H2 destruct -Y0;
 239   elim (tpr_inv_bind1 … H1) -H1 *
 240 (* case 9: delta, delta *)
 241   [ #V2 #T2 #TT2 #HV02 #HT02 #HTT2 #H destruct -X2
 242     /3 width=11 by tpr_conf_delta_delta/ (**) (* /3 width=11/ is too slow *)
 243 (* case 10: delta, zata *)
 244   | #T2 #HT20 #HTX2 #H destruct -I1;
 245     /3 width=10 by tpr_conf_delta_zeta/ (**) (* /3 width=10/ is too slow *)
 246   ]
 247 | #VV1 #V0 #V1 #W0 #W1 #T0 #T1 #HV01 #HVV1 #HW01 #HT01 #H1 #H2 destruct -Y0;
 248   elim (tpr_inv_appl1 … H1) -H1 *
 249 (* case 11: theta, flat (repeated) *)
 250   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 251     @ex2_1_comm /3 width=11 by tpr_conf_flat_theta/
 252 (* case 12: theta, beta (repeated) *)
 253   | #V2 #WW0 #TT0 #T2 #_ #_ #H destruct
 254 (* case 13: theta, theta *)
 255   | #V2 #VV2 #WW0 #W2 #TT0 #T2 #V02 #HW02 #HT02 #HVV2 #H1 #H2 destruct -W0 T0 X2
 256     /3 width=14 by tpr_conf_theta_theta/ (**) (* /3 width=14/ is too slow *)
 257   ]
 258 | #V0 #TT0 #T0 #T1 #HTT0 #HT01 #H1 #H2 destruct -Y0;
 259   elim (tpr_inv_abbr1 … H1) -H1 *
 260 (* case 14: zeta, delta (repeated) *)
 261   [ #V2 #T2 #TT2 #HV02 #HT02 #HTT2 #H destruct -X2
 262     @ex2_1_comm /3 width=10 by tpr_conf_delta_zeta/
 263 (* case 15: zeta, zeta *)
 264   | #T2 #HTT20 #HTX2
 265     /3 width=9 by tpr_conf_zeta_zeta/ (**) (* /3 width=9/ is too slow *)
 266   ]
 267 | #V0 #T0 #T1 #HT01 #H1 #H2 destruct -Y0;
 268   elim (tpr_inv_cast1 … H1) -H1
 269 (* case 16: tau, flat (repeated) *)
 270   [ * #V2 #T2 #HV02 #HT02 #H destruct -X2
 271     @ex2_1_comm /3 width=6 by tpr_conf_flat_cast/
 272 (* case 17: tau, tau *)
 273   | #HT02
 274     /2 by tpr_conf_tau_tau/
 275   ]
 276 ]
 277 qed.
 278
 279 theorem tpr_conf: ∀T0:term. ∀T1,T2. T0 ⇒ T1 → T0 ⇒ T2 →
 280                   ∃∃T. T1 ⇒ T & T2 ⇒ T.
 281 #T @(tw_wf_ind … T) -T /3 width=6 by tpr_conf_aux/
 282 qed.