matita/matita/contribs/lambda-delta/Basic-2/reduction/tpr_tpr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic-2/reduction/tpr_tps.ma".
  16
  17 (* CONTEXT-FREE PARALLEL REDUCTION ON TERMS *********************************)
  18
  19 (* Confluence lemmas ********************************************************)
  20
  21 fact tpr_conf_atom_atom: ∀I. ∃∃X. 𝕒{I} ⇒ X & 𝕒{I} ⇒ X.
  22 /2/ qed.
  23
  24 fact tpr_conf_flat_flat:
  25    ∀I,V0,V1,T0,T1,V2,T2. (
  26       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
  27       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  28       ∃∃X. X1 ⇒ X & X2 ⇒ X
  29    ) →
  30    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
  31    ∃∃T0. 𝕗{I} V1. T1 ⇒ T0 & 𝕗{I} V2. T2 ⇒ T0.
  32 #I #V0 #V1 #T0 #T1 #V2 #T2 #IH #HV01 #HV02 #HT01 #HT02
  33 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
  34 elim (IH … HT01 … HT02) -HT01 HT02 /3 width=5/
  35 qed.
  36
  37 fact tpr_conf_flat_beta:
  38    ∀V0,V1,T1,V2,W0,U0,T2. (
  39       ∀X0:term. #[X0] < #[V0] + (#[W0] + #[U0] + 1) + 1 →
  40       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  41       ∃∃X. X1 ⇒ X & X2 ⇒ X
  42    ) →
  43    V0 ⇒ V1 → V0 ⇒ V2 →
  44    U0 ⇒ T2 → 𝕔{Abst} W0. U0 ⇒ T1 →
  45    ∃∃X. 𝕔{Appl} V1. T1 ⇒ X & 𝕔{Abbr} V2. T2 ⇒ X.
  46 #V0 #V1 #T1 #V2 #W0 #U0 #T2 #IH #HV01 #HV02 #HT02 #H
  47 elim (tpr_inv_abst1 … H) -H #W1 #U1 #HW01 #HU01 #H destruct -T1;
  48 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
  49 elim (IH … HT02 … HU01) -HT02 HU01 IH /3 width=5/
  50 qed.
  51
  52 fact tpr_conf_flat_theta:
  53    ∀V0,V1,T1,V2,V,W0,W2,U0,U2. (
  54       ∀X0:term. #[X0] < #[V0] + (#[W0] + #[U0] + 1) + 1 →
  55       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  56       ∃∃X. X1 ⇒ X & X2 ⇒ X
  57    ) →
  58    V0 ⇒ V1 → V0 ⇒ V2 → ↑[O,1] V2 ≡ V →
  59    W0 ⇒ W2 → U0 ⇒ U2 →  𝕔{Abbr} W0. U0 ⇒ T1 →
  60    ∃∃X. 𝕔{Appl} V1. T1 ⇒ X & 𝕔{Abbr} W2. 𝕔{Appl} V. U2 ⇒ X.
  61 #V0 #V1 #T1 #V2 #V #W0 #W2 #U0 #U2 #IH #HV01 #HV02 #HV2 #HW02 #HU02 #H
  62 elim (IH … HV01 … HV02) -HV01 HV02 // #VV #HVV1 #HVV2
  63 elim (lift_total VV 0 1) #VVV #HVV
  64 lapply (tpr_lift … HVV2 … HV2 … HVV) #HVVV
  65 elim (tpr_inv_abbr1 … H) -H *
  66 (* case 1: delta *)
  67 [ -HV2 HVV2 #WW2 #UU2 #UU #HWW2 #HUU02 #HUU2 #H destruct -T1;
  68   elim (IH … HW02 … HWW2) -HW02 HWW2 // #W #HW02 #HWW2
  69   elim (IH … HU02 … HUU02) -HU02 HUU02 IH // #U #HU2 #HUUU2
  70   elim (tpr_tps_bind … HWW2 HUUU2 … HUU2) -HUU2 HUUU2 #UUU #HUUU2 #HUUU1
  71   @ex2_1_intro
  72   [2: @tpr_theta [6: @HVV |7: @HWW2 |8: @HUUU2 |1,2,3,4: skip | // ]
  73   |1:skip
  74   |3: @tpr_delta [3: @tpr_flat |1: skip ] /2 width=5/
  75   ] (**) (* /5 width=14/ is too slow *)
  76 (* case 3: zeta *)
  77 | -HW02 HVV HVVV #UU1 #HUU10 #HUUT1
  78   elim (tpr_inv_lift … HU02 … HUU10) -HU02 #UU #HUU2 #HUU1
  79   lapply (tw_lift … HUU10) -HUU10 #HUU10
  80   elim (IH … HUUT1 … HUU1) -HUUT1 HUU1 IH // -HUU10 #U #HU2 #HUUU2
  81   @ex2_1_intro
  82   [2: @tpr_flat
  83   |1: skip
  84   |3: @tpr_zeta [2: @lift_flat |1: skip |3: @tpr_flat ]
  85   ] /2 width=5/ (**) (* /5 width=5/ is too slow *)
  86 ]
  87 qed.
  88
  89 fact tpr_conf_flat_cast:
  90    ∀X2,V0,V1,T0,T1. (
  91       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
  92       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  93       ∃∃X. X1 ⇒ X & X2 ⇒ X
  94    ) →
  95    V0 ⇒ V1 → T0 ⇒ T1 → T0 ⇒ X2 →
  96    ∃∃X. 𝕔{Cast} V1. T1 ⇒ X & X2 ⇒ X.
  97 #X2 #V0 #V1 #T0 #T1 #IH #_ #HT01 #HT02
  98 elim (IH … HT01 … HT02) -HT01 HT02 IH /3/
  99 qed.
 100
 101 fact tpr_conf_beta_beta:
 102    ∀W0:term. ∀V0,V1,T0,T1,V2,T2. (
 103       ∀X0:term. #[X0] < #[V0] + (#[W0] + #[T0] + 1) + 1 →
 104       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 105       ∃∃X. X1 ⇒ X & X2 ⇒ X
 106    ) →
 107    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
 108    ∃∃X. 𝕔{Abbr} V1. T1 ⇒X & 𝕔{Abbr} V2. T2 ⇒ X.
 109 #W0 #V0 #V1 #T0 #T1 #V2 #T2 #IH #HV01 #HV02 #HT01 #HT02
 110 elim (IH … HV01 … HV02) -HV01 HV02 //
 111 elim (IH … HT01 … HT02) -HT01 HT02 IH /3 width=5/
 112 qed.
 113
 114 fact tpr_conf_delta_delta:
 115    ∀I1,V0,V1,T0,T1,TT1,V2,T2,TT2. (
 116       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
 117       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 118       ∃∃X. X1 ⇒ X & X2 ⇒ X
 119    ) →
 120    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
 121    ⋆. 𝕓{I1} V1 ⊢ T1 [O, 1] ≫ TT1 →
 122    ⋆. 𝕓{I1} V2 ⊢ T2 [O, 1] ≫ TT2 →
 123    ∃∃X. 𝕓{I1} V1. TT1 ⇒ X & 𝕓{I1} V2. TT2 ⇒ X.
 124 #I1 #V0 #V1 #T0 #T1 #TT1 #V2 #T2 #TT2 #IH #HV01 #HV02 #HT01 #HT02 #HTT1 #HTT2
 125 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
 126 elim (IH … HT01 … HT02) -HT01 HT02 IH // #T #HT1 #HT2
 127 elim (tpr_tps_bind … HV1 HT1 … HTT1) -HT1 HTT1 #U1 #TTU1 #HTU1
 128 elim (tpr_tps_bind … HV2 HT2 … HTT2) -HT2 HTT2 #U2 #TTU2 #HTU2
 129 elim (tps_conf_eq … HTU1 … HTU2) -HTU1 HTU2 #U #HU1 #HU2
 130 @ex2_1_intro [2,3: @tpr_delta |1: skip ] /width=10/ (**) (* /3 width=10/ is too slow *)
 131 qed.
 132
 133 fact tpr_conf_delta_zeta:
 134    ∀X2,V0,V1,T0,T1,TT1,T2. (
 135       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
 136       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 137       ∃∃X. X1 ⇒ X & X2 ⇒ X
 138    ) →
 139    V0 ⇒ V1 → T0 ⇒ T1 → ⋆. 𝕓{Abbr} V1 ⊢ T1 [O,1] ≫ TT1 →
 140    T2 ⇒ X2 → ↑[O, 1] T2 ≡ T0 →
 141    ∃∃X. 𝕓{Abbr} V1. TT1 ⇒ X & X2 ⇒ X.
 142 #X2 #V0 #V1 #T0 #T1 #TT1 #T2 #IH #_ #HT01 #HTT1 #HTX2 #HTT20
 143 elim (tpr_inv_lift … HT01 … HTT20) -HT01 #TT2 #HTT21 #HTT2
 144 lapply (tps_inv_lift1_eq … HTT1 … HTT21) -HTT1 #HTT1 destruct -T1;
 145 lapply (tw_lift … HTT20) -HTT20 #HTT20
 146 elim (IH … HTX2 … HTT2) -HTX2 HTT2 IH /3/
 147 qed.
 148
 149 fact tpr_conf_theta_theta:
 150    ∀VV1,V0,V1,W0,W1,T0,T1,V2,VV2,W2,T2. (
 151       ∀X0:term. #[X0] < #[V0] + (#[W0] + #[T0] + 1) + 1 →
 152       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 153       ∃∃X. X1 ⇒ X & X2 ⇒ X
 154    ) →
 155    V0 ⇒ V1 → V0 ⇒ V2 → W0 ⇒ W1 → W0 ⇒ W2 → T0 ⇒ T1 → T0 ⇒ T2 →
 156    ↑[O, 1] V1 ≡ VV1 → ↑[O, 1] V2 ≡ VV2 →
 157    ∃∃X. 𝕔{Abbr} W1. 𝕔{Appl} VV1. T1 ⇒ X & 𝕔{Abbr} W2. 𝕔{Appl} VV2. T2 ⇒ X.
 158 #VV1 #V0 #V1 #W0 #W1 #T0 #T1 #V2 #VV2 #W2 #T2 #IH #HV01 #HV02 #HW01 #HW02 #HT01 #HT02 #HVV1 #HVV2
 159 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
 160 elim (IH … HW01 … HW02) -HW01 HW02 // #W #HW1 #HW2
 161 elim (IH … HT01 … HT02) -HT01 HT02 IH // #T #HT1 #HT2
 162 elim (lift_total V 0 1) #VV #HVV
 163 lapply (tpr_lift … HV1 … HVV1 … HVV) -HV1 HVV1 #HVV1
 164 lapply (tpr_lift … HV2 … HVV2 … HVV) -HV2 HVV2 HVV #HVV2
 165 @ex2_1_intro [2,3: @tpr_bind |1:skip ] /2 width=5/ (**) (* /4 width=5/ is too slow *)
 166 qed.
 167
 168 fact tpr_conf_zeta_zeta:
 169    ∀V0:term. ∀X2,TT0,T0,T1,T2. (
 170       ∀X0:term. #[X0] < #[V0] + #[TT0] + 1 →
 171       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 172       ∃∃X. X1 ⇒ X & X2 ⇒ X
 173    ) →
 174    T0 ⇒ T1 → T2 ⇒ X2 →
 175    ↑[O, 1] T0 ≡ TT0 → ↑[O, 1] T2 ≡ TT0 →
 176    ∃∃X. T1 ⇒ X & X2 ⇒ X.
 177 #V0 #X2 #TT0 #T0 #T1 #T2 #IH #HT01 #HTX2 #HTT0 #HTT20
 178 lapply (lift_inj … HTT0 … HTT20) -HTT0 #H destruct -T0;
 179 lapply (tw_lift … HTT20) -HTT20 #HTT20
 180 elim (IH … HT01 … HTX2) -HT01 HTX2 IH /2/
 181 qed.
 182
 183 fact tpr_conf_tau_tau:
 184    ∀V0,T0:term. ∀X2,T1. (
 185       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
 186       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 187       ∃∃X. X1 ⇒ X & X2 ⇒ X
 188    ) →
 189    T0 ⇒ T1 → T0 ⇒ X2 →
 190    ∃∃X. T1 ⇒ X & X2 ⇒ X.
 191 #V0 #T0 #X2 #T1 #IH #HT01 #HT02
 192 elim (IH … HT01 … HT02) -HT01 HT02 IH /2/
 193 qed.
 194
 195 (* Confluence ***************************************************************)
 196
 197 fact tpr_conf_aux:
 198    ∀Y0:term. (
 199       ∀X0:term. #[X0] < #[Y0] →
 200       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 201       ∃∃X. X1 ⇒ X & X2 ⇒ X
 202          ) →
 203    ∀X0,X1,X2. X0 ⇒ X1 → X0 ⇒ X2 → X0 = Y0 →
 204    ∃∃X. X1 ⇒ X & X2 ⇒ X.
 205 #Y0 #IH #X0 #X1 #X2 * -X0 X1
 206 [ #I1 #H1 #H2 destruct -Y0;
 207   lapply (tpr_inv_atom1 … H1) -H1
 208 (* case 1: atom, atom *)
 209   #H1 destruct -X2 //
 210 | #I #V0 #V1 #T0 #T1 #HV01 #HT01 #H1 #H2 destruct -Y0;
 211   elim (tpr_inv_flat1 … H1) -H1 *
 212 (* case 2: flat, flat *)
 213   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 214     /3 width=7 by tpr_conf_flat_flat/ (**) (* /3 width=7/ is too slow *)
 215 (* case 3: flat, beta *)
 216   | #V2 #W #U0 #T2 #HV02 #HT02 #H1 #H2 #H3 destruct -T0 X2 I
 217     /3 width=8 by tpr_conf_flat_beta/ (**) (* /3 width=8/ is too slow *)
 218 (* case 4: flat, theta *)
 219   | #V2 #V #W0 #W2 #U0 #U2 #HV02 #HW02 #HT02 #HV2 #H1 #H2 #H3 destruct -T0 X2 I
 220     /3 width=11 by tpr_conf_flat_theta/ (**) (* /3 width=11/ is too slow *)
 221 (* case 5: flat, tau *)
 222   | #HT02 #H destruct -I
 223     /3 width=6 by tpr_conf_flat_cast/ (**) (* /3 width=6/ is too slow *)
 224   ]
 225 | #V0 #V1 #W0 #T0 #T1 #HV01 #HT01 #H1 #H2 destruct -Y0;
 226   elim (tpr_inv_appl1 … H1) -H1 *
 227 (* case 6: beta, flat (repeated) *)
 228   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 229     @ex2_1_comm /3 width=8 by tpr_conf_flat_beta/
 230 (* case 7: beta, beta *)
 231   | #V2 #WW0 #TT0 #T2 #HV02 #HT02 #H1 #H2 destruct -W0 T0 X2
 232     /3 width=8 by tpr_conf_beta_beta/ (**) (* /3 width=8/ is too slow *)
 233 (* case 8, beta, theta (excluded) *)
 234   | #V2 #VV2 #WW0 #W2 #TT0 #T2 #_ #_ #_ #_ #H destruct
 235   ]
 236 | #I1 #V0 #V1 #T0 #T1 #TT1 #HV01 #HT01 #HTT1 #H1 #H2 destruct -Y0;
 237   elim (tpr_inv_bind1 … H1) -H1 *
 238 (* case 9: delta, delta *)
 239   [ #V2 #T2 #TT2 #HV02 #HT02 #HTT2 #H destruct -X2
 240     /3 width=11 by tpr_conf_delta_delta/ (**) (* /3 width=11/ is too slow *)
 241 (* case 10: delta, zata *)
 242   | #T2 #HT20 #HTX2 #H destruct -I1;
 243     /3 width=10 by tpr_conf_delta_zeta/ (**) (* /3 width=10/ is too slow *)
 244   ]
 245 | #VV1 #V0 #V1 #W0 #W1 #T0 #T1 #HV01 #HVV1 #HW01 #HT01 #H1 #H2 destruct -Y0;
 246   elim (tpr_inv_appl1 … H1) -H1 *
 247 (* case 11: theta, flat (repeated) *)
 248   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 249     @ex2_1_comm /3 width=11 by tpr_conf_flat_theta/
 250 (* case 12: theta, beta (repeated) *)
 251   | #V2 #WW0 #TT0 #T2 #_ #_ #H destruct
 252 (* case 13: theta, theta *)
 253   | #V2 #VV2 #WW0 #W2 #TT0 #T2 #V02 #HW02 #HT02 #HVV2 #H1 #H2 destruct -W0 T0 X2
 254     /3 width=14 by tpr_conf_theta_theta/ (**) (* /3 width=14/ is too slow *)
 255   ]
 256 | #V0 #TT0 #T0 #T1 #HTT0 #HT01 #H1 #H2 destruct -Y0;
 257   elim (tpr_inv_abbr1 … H1) -H1 *
 258 (* case 14: zeta, delta (repeated) *)
 259   [ #V2 #T2 #TT2 #HV02 #HT02 #HTT2 #H destruct -X2
 260     @ex2_1_comm /3 width=10 by tpr_conf_delta_zeta/
 261 (* case 15: zeta, zeta *)
 262   | #T2 #HTT20 #HTX2
 263     /3 width=9 by tpr_conf_zeta_zeta/ (**) (* /3 width=9/ is too slow *)
 264   ]
 265 | #V0 #T0 #T1 #HT01 #H1 #H2 destruct -Y0;
 266   elim (tpr_inv_cast1 … H1) -H1
 267 (* case 16: tau, flat (repeated) *)
 268   [ * #V2 #T2 #HV02 #HT02 #H destruct -X2
 269     @ex2_1_comm /3 width=6 by tpr_conf_flat_cast/
 270 (* case 17: tau, tau *)
 271   | #HT02
 272     /2 by tpr_conf_tau_tau/
 273   ]
 274 ]
 275 qed.
 276
 277 theorem tpr_conf: ∀T0:term. ∀T1,T2. T0 ⇒ T1 → T0 ⇒ T2 →
 278                   ∃∃T. T1 ⇒ T & T2 ⇒ T.
 279 #T @(tw_wf_ind … T) -T /3 width=6 by tpr_conf_aux/
 280 qed.