matita/matita/contribs/lambda-delta/Basic-2/reduction/tpr_tpr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic-2/reduction/tpr_tps.ma".
  16
  17 (* CONTEXT-FREE PARALLEL REDUCTION ON TERMS *********************************)
  18
  19 (* Confluence lemmas ********************************************************)
  20
  21 fact tpr_conf_atom_atom: ∀I. ∃∃X. 𝕒{I} ⇒ X & 𝕒{I} ⇒ X.
  22 /2/ qed.
  23
  24 fact tpr_conf_flat_flat:
  25    ∀I,V0,V1,T0,T1,V2,T2. (
  26       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
  27       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  28       ∃∃X. X1 ⇒ X & X2 ⇒ X
  29    ) →
  30    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
  31    ∃∃T0. 𝕗{I} V1. T1 ⇒ T0 & 𝕗{I} V2. T2 ⇒ T0.
  32 #I #V0 #V1 #T0 #T1 #V2 #T2 #IH #HV01 #HV02 #HT01 #HT02
  33 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
  34 elim (IH … HT01 … HT02) -HT01 HT02 /3 width=5/
  35 qed.
  36
  37 fact tpr_conf_flat_beta:
  38    ∀V0,V1,T1,V2,W0,U0,T2. (
  39       ∀X0:term. #[X0] < #[V0] + (#[W0] + #[U0] + 1) + 1 →
  40       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  41       ∃∃X. X1 ⇒ X & X2 ⇒ X
  42    ) →
  43    V0 ⇒ V1 → V0 ⇒ V2 →
  44    U0 ⇒ T2 → 𝕔{Abst} W0. U0 ⇒ T1 →
  45    ∃∃X. 𝕔{Appl} V1. T1 ⇒ X & 𝕔{Abbr} V2. T2 ⇒ X.
  46 #V0 #V1 #T1 #V2 #W0 #U0 #T2 #IH #HV01 #HV02 #HT02 #H
  47 elim (tpr_inv_abst1 … H) -H #W1 #U1 #HW01 #HU01 #H destruct -T1;
  48 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
  49 elim (IH … HT02 … HU01) -HT02 HU01 IH /3 width=5/
  50 qed.
  51
  52 (* basic-1: was:
  53             pr0_cong_upsilon_refl pr0_cong_upsilon_zeta
  54             pr0_cong_upsilon_cong pr0_cong_upsilon_delta
  55 *)
  56 fact tpr_conf_flat_theta:
  57    ∀V0,V1,T1,V2,V,W0,W2,U0,U2. (
  58       ∀X0:term. #[X0] < #[V0] + (#[W0] + #[U0] + 1) + 1 →
  59       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  60       ∃∃X. X1 ⇒ X & X2 ⇒ X
  61    ) →
  62    V0 ⇒ V1 → V0 ⇒ V2 → ↑[O,1] V2 ≡ V →
  63    W0 ⇒ W2 → U0 ⇒ U2 →  𝕔{Abbr} W0. U0 ⇒ T1 →
  64    ∃∃X. 𝕔{Appl} V1. T1 ⇒ X & 𝕔{Abbr} W2. 𝕔{Appl} V. U2 ⇒ X.
  65 #V0 #V1 #T1 #V2 #V #W0 #W2 #U0 #U2 #IH #HV01 #HV02 #HV2 #HW02 #HU02 #H
  66 elim (IH … HV01 … HV02) -HV01 HV02 // #VV #HVV1 #HVV2
  67 elim (lift_total VV 0 1) #VVV #HVV
  68 lapply (tpr_lift … HVV2 … HV2 … HVV) #HVVV
  69 elim (tpr_inv_abbr1 … H) -H *
  70 (* case 1: delta *)
  71 [ -HV2 HVV2 #WW2 #UU2 #UU #HWW2 #HUU02 #HUU2 #H destruct -T1;
  72   elim (IH … HW02 … HWW2) -HW02 HWW2 // #W #HW02 #HWW2
  73   elim (IH … HU02 … HUU02) -HU02 HUU02 IH // #U #HU2 #HUUU2
  74   elim (tpr_tps_bind … HWW2 HUUU2 … HUU2) -HUU2 HUUU2 #UUU #HUUU2 #HUUU1
  75   @ex2_1_intro
  76   [2: @tpr_theta [6: @HVV |7: @HWW2 |8: @HUUU2 |1,2,3,4: skip | // ]
  77   |1:skip
  78   |3: @tpr_delta [3: @tpr_flat |1: skip ] /2 width=5/
  79   ] (**) (* /5 width=14/ is too slow *)
  80 (* case 3: zeta *)
  81 | -HW02 HVV HVVV #UU1 #HUU10 #HUUT1
  82   elim (tpr_inv_lift … HU02 … HUU10) -HU02 #UU #HUU2 #HUU1
  83   lapply (tw_lift … HUU10) -HUU10 #HUU10
  84   elim (IH … HUUT1 … HUU1) -HUUT1 HUU1 IH // -HUU10 #U #HU2 #HUUU2
  85   @ex2_1_intro
  86   [2: @tpr_flat
  87   |1: skip
  88   |3: @tpr_zeta [2: @lift_flat |1: skip |3: @tpr_flat ]
  89   ] /2 width=5/ (**) (* /5 width=5/ is too slow *)
  90 ]
  91 qed.
  92
  93 fact tpr_conf_flat_cast:
  94    ∀X2,V0,V1,T0,T1. (
  95       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
  96       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  97       ∃∃X. X1 ⇒ X & X2 ⇒ X
  98    ) →
  99    V0 ⇒ V1 → T0 ⇒ T1 → T0 ⇒ X2 →
 100    ∃∃X. 𝕔{Cast} V1. T1 ⇒ X & X2 ⇒ X.
 101 #X2 #V0 #V1 #T0 #T1 #IH #_ #HT01 #HT02
 102 elim (IH … HT01 … HT02) -HT01 HT02 IH /3/
 103 qed.
 104
 105 fact tpr_conf_beta_beta:
 106    ∀W0:term. ∀V0,V1,T0,T1,V2,T2. (
 107       ∀X0:term. #[X0] < #[V0] + (#[W0] + #[T0] + 1) + 1 →
 108       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 109       ∃∃X. X1 ⇒ X & X2 ⇒ X
 110    ) →
 111    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
 112    ∃∃X. 𝕔{Abbr} V1. T1 ⇒X & 𝕔{Abbr} V2. T2 ⇒ X.
 113 #W0 #V0 #V1 #T0 #T1 #V2 #T2 #IH #HV01 #HV02 #HT01 #HT02
 114 elim (IH … HV01 … HV02) -HV01 HV02 //
 115 elim (IH … HT01 … HT02) -HT01 HT02 IH /3 width=5/
 116 qed.
 117
 118 (* Basic-1: was: pr0_cong_delta pr0_delta_delta *)
 119 fact tpr_conf_delta_delta:
 120    ∀I1,V0,V1,T0,T1,TT1,V2,T2,TT2. (
 121       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
 122       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 123       ∃∃X. X1 ⇒ X & X2 ⇒ X
 124    ) →
 125    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
 126    ⋆. 𝕓{I1} V1 ⊢ T1 [O, 1] ≫ TT1 →
 127    ⋆. 𝕓{I1} V2 ⊢ T2 [O, 1] ≫ TT2 →
 128    ∃∃X. 𝕓{I1} V1. TT1 ⇒ X & 𝕓{I1} V2. TT2 ⇒ X.
 129 #I1 #V0 #V1 #T0 #T1 #TT1 #V2 #T2 #TT2 #IH #HV01 #HV02 #HT01 #HT02 #HTT1 #HTT2
 130 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
 131 elim (IH … HT01 … HT02) -HT01 HT02 IH // #T #HT1 #HT2
 132 elim (tpr_tps_bind … HV1 HT1 … HTT1) -HT1 HTT1 #U1 #TTU1 #HTU1
 133 elim (tpr_tps_bind … HV2 HT2 … HTT2) -HT2 HTT2 #U2 #TTU2 #HTU2
 134 elim (tps_conf_eq … HTU1 … HTU2) -HTU1 HTU2 #U #HU1 #HU2
 135 @ex2_1_intro [2,3: @tpr_delta |1: skip ] /width=10/ (**) (* /3 width=10/ is too slow *)
 136 qed.
 137
 138 fact tpr_conf_delta_zeta:
 139    ∀X2,V0,V1,T0,T1,TT1,T2. (
 140       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
 141       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 142       ∃∃X. X1 ⇒ X & X2 ⇒ X
 143    ) →
 144    V0 ⇒ V1 → T0 ⇒ T1 → ⋆. 𝕓{Abbr} V1 ⊢ T1 [O,1] ≫ TT1 →
 145    T2 ⇒ X2 → ↑[O, 1] T2 ≡ T0 →
 146    ∃∃X. 𝕓{Abbr} V1. TT1 ⇒ X & X2 ⇒ X.
 147 #X2 #V0 #V1 #T0 #T1 #TT1 #T2 #IH #_ #HT01 #HTT1 #HTX2 #HTT20
 148 elim (tpr_inv_lift … HT01 … HTT20) -HT01 #TT2 #HTT21 #HTT2
 149 lapply (tps_inv_lift1_eq … HTT1 … HTT21) -HTT1 #HTT1 destruct -T1;
 150 lapply (tw_lift … HTT20) -HTT20 #HTT20
 151 elim (IH … HTX2 … HTT2) -HTX2 HTT2 IH /3/
 152 qed.
 153
 154 (* Basic-1: was: pr0_upsilon_upsilon *)
 155 fact tpr_conf_theta_theta:
 156    ∀VV1,V0,V1,W0,W1,T0,T1,V2,VV2,W2,T2. (
 157       ∀X0:term. #[X0] < #[V0] + (#[W0] + #[T0] + 1) + 1 →
 158       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 159       ∃∃X. X1 ⇒ X & X2 ⇒ X
 160    ) →
 161    V0 ⇒ V1 → V0 ⇒ V2 → W0 ⇒ W1 → W0 ⇒ W2 → T0 ⇒ T1 → T0 ⇒ T2 →
 162    ↑[O, 1] V1 ≡ VV1 → ↑[O, 1] V2 ≡ VV2 →
 163    ∃∃X. 𝕔{Abbr} W1. 𝕔{Appl} VV1. T1 ⇒ X & 𝕔{Abbr} W2. 𝕔{Appl} VV2. T2 ⇒ X.
 164 #VV1 #V0 #V1 #W0 #W1 #T0 #T1 #V2 #VV2 #W2 #T2 #IH #HV01 #HV02 #HW01 #HW02 #HT01 #HT02 #HVV1 #HVV2
 165 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
 166 elim (IH … HW01 … HW02) -HW01 HW02 // #W #HW1 #HW2
 167 elim (IH … HT01 … HT02) -HT01 HT02 IH // #T #HT1 #HT2
 168 elim (lift_total V 0 1) #VV #HVV
 169 lapply (tpr_lift … HV1 … HVV1 … HVV) -HV1 HVV1 #HVV1
 170 lapply (tpr_lift … HV2 … HVV2 … HVV) -HV2 HVV2 HVV #HVV2
 171 @ex2_1_intro [2,3: @tpr_bind |1:skip ] /2 width=5/ (**) (* /4 width=5/ is too slow *)
 172 qed.
 173
 174 fact tpr_conf_zeta_zeta:
 175    ∀V0:term. ∀X2,TT0,T0,T1,T2. (
 176       ∀X0:term. #[X0] < #[V0] + #[TT0] + 1 →
 177       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 178       ∃∃X. X1 ⇒ X & X2 ⇒ X
 179    ) →
 180    T0 ⇒ T1 → T2 ⇒ X2 →
 181    ↑[O, 1] T0 ≡ TT0 → ↑[O, 1] T2 ≡ TT0 →
 182    ∃∃X. T1 ⇒ X & X2 ⇒ X.
 183 #V0 #X2 #TT0 #T0 #T1 #T2 #IH #HT01 #HTX2 #HTT0 #HTT20
 184 lapply (lift_inj … HTT0 … HTT20) -HTT0 #H destruct -T0;
 185 lapply (tw_lift … HTT20) -HTT20 #HTT20
 186 elim (IH … HT01 … HTX2) -HT01 HTX2 IH /2/
 187 qed.
 188
 189 fact tpr_conf_tau_tau:
 190    ∀V0,T0:term. ∀X2,T1. (
 191       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
 192       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 193       ∃∃X. X1 ⇒ X & X2 ⇒ X
 194    ) →
 195    T0 ⇒ T1 → T0 ⇒ X2 →
 196    ∃∃X. T1 ⇒ X & X2 ⇒ X.
 197 #V0 #T0 #X2 #T1 #IH #HT01 #HT02
 198 elim (IH … HT01 … HT02) -HT01 HT02 IH /2/
 199 qed.
 200
 201 (* Confluence ***************************************************************)
 202
 203 fact tpr_conf_aux:
 204    ∀Y0:term. (
 205       ∀X0:term. #[X0] < #[Y0] →
 206       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 207       ∃∃X. X1 ⇒ X & X2 ⇒ X
 208          ) →
 209    ∀X0,X1,X2. X0 ⇒ X1 → X0 ⇒ X2 → X0 = Y0 →
 210    ∃∃X. X1 ⇒ X & X2 ⇒ X.
 211 #Y0 #IH #X0 #X1 #X2 * -X0 X1
 212 [ #I1 #H1 #H2 destruct -Y0;
 213   lapply (tpr_inv_atom1 … H1) -H1
 214 (* case 1: atom, atom *)
 215   #H1 destruct -X2 //
 216 | #I #V0 #V1 #T0 #T1 #HV01 #HT01 #H1 #H2 destruct -Y0;
 217   elim (tpr_inv_flat1 … H1) -H1 *
 218 (* case 2: flat, flat *)
 219   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 220     /3 width=7 by tpr_conf_flat_flat/ (**) (* /3 width=7/ is too slow *)
 221 (* case 3: flat, beta *)
 222   | #V2 #W #U0 #T2 #HV02 #HT02 #H1 #H2 #H3 destruct -T0 X2 I
 223     /3 width=8 by tpr_conf_flat_beta/ (**) (* /3 width=8/ is too slow *)
 224 (* case 4: flat, theta *)
 225   | #V2 #V #W0 #W2 #U0 #U2 #HV02 #HW02 #HT02 #HV2 #H1 #H2 #H3 destruct -T0 X2 I
 226     /3 width=11 by tpr_conf_flat_theta/ (**) (* /3 width=11/ is too slow *)
 227 (* case 5: flat, tau *)
 228   | #HT02 #H destruct -I
 229     /3 width=6 by tpr_conf_flat_cast/ (**) (* /3 width=6/ is too slow *)
 230   ]
 231 | #V0 #V1 #W0 #T0 #T1 #HV01 #HT01 #H1 #H2 destruct -Y0;
 232   elim (tpr_inv_appl1 … H1) -H1 *
 233 (* case 6: beta, flat (repeated) *)
 234   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 235     @ex2_1_comm /3 width=8 by tpr_conf_flat_beta/
 236 (* case 7: beta, beta *)
 237   | #V2 #WW0 #TT0 #T2 #HV02 #HT02 #H1 #H2 destruct -W0 T0 X2
 238     /3 width=8 by tpr_conf_beta_beta/ (**) (* /3 width=8/ is too slow *)
 239 (* case 8, beta, theta (excluded) *)
 240   | #V2 #VV2 #WW0 #W2 #TT0 #T2 #_ #_ #_ #_ #H destruct
 241   ]
 242 | #I1 #V0 #V1 #T0 #T1 #TT1 #HV01 #HT01 #HTT1 #H1 #H2 destruct -Y0;
 243   elim (tpr_inv_bind1 … H1) -H1 *
 244 (* case 9: delta, delta *)
 245   [ #V2 #T2 #TT2 #HV02 #HT02 #HTT2 #H destruct -X2
 246     /3 width=11 by tpr_conf_delta_delta/ (**) (* /3 width=11/ is too slow *)
 247 (* case 10: delta, zata *)
 248   | #T2 #HT20 #HTX2 #H destruct -I1;
 249     /3 width=10 by tpr_conf_delta_zeta/ (**) (* /3 width=10/ is too slow *)
 250   ]
 251 | #VV1 #V0 #V1 #W0 #W1 #T0 #T1 #HV01 #HVV1 #HW01 #HT01 #H1 #H2 destruct -Y0;
 252   elim (tpr_inv_appl1 … H1) -H1 *
 253 (* case 11: theta, flat (repeated) *)
 254   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 255     @ex2_1_comm /3 width=11 by tpr_conf_flat_theta/
 256 (* case 12: theta, beta (repeated) *)
 257   | #V2 #WW0 #TT0 #T2 #_ #_ #H destruct
 258 (* case 13: theta, theta *)
 259   | #V2 #VV2 #WW0 #W2 #TT0 #T2 #V02 #HW02 #HT02 #HVV2 #H1 #H2 destruct -W0 T0 X2
 260     /3 width=14 by tpr_conf_theta_theta/ (**) (* /3 width=14/ is too slow *)
 261   ]
 262 | #V0 #TT0 #T0 #T1 #HTT0 #HT01 #H1 #H2 destruct -Y0;
 263   elim (tpr_inv_abbr1 … H1) -H1 *
 264 (* case 14: zeta, delta (repeated) *)
 265   [ #V2 #T2 #TT2 #HV02 #HT02 #HTT2 #H destruct -X2
 266     @ex2_1_comm /3 width=10 by tpr_conf_delta_zeta/
 267 (* case 15: zeta, zeta *)
 268   | #T2 #HTT20 #HTX2
 269     /3 width=9 by tpr_conf_zeta_zeta/ (**) (* /3 width=9/ is too slow *)
 270   ]
 271 | #V0 #T0 #T1 #HT01 #H1 #H2 destruct -Y0;
 272   elim (tpr_inv_cast1 … H1) -H1
 273 (* case 16: tau, flat (repeated) *)
 274   [ * #V2 #T2 #HV02 #HT02 #H destruct -X2
 275     @ex2_1_comm /3 width=6 by tpr_conf_flat_cast/
 276 (* case 17: tau, tau *)
 277   | #HT02
 278     /2 by tpr_conf_tau_tau/
 279   ]
 280 ]
 281 qed.
 282
 283 (* Basic-1: was: pr0_confluence *)
 284 theorem tpr_conf: ∀T0:term. ∀T1,T2. T0 ⇒ T1 → T0 ⇒ T2 →
 285                   ∃∃T. T1 ⇒ T & T2 ⇒ T.
 286 #T @(tw_wf_ind … T) -T /3 width=6 by tpr_conf_aux/
 287 qed.