matita/matita/contribs/lambda-delta/Basic-2/reduction/tpr_tpr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic-2/substitution/tps_tps.ma".
  16 include "Basic-2/reduction/tpr_lift.ma".
  17 include "Basic-2/reduction/tpr_tps.ma".
  18
  19 (* CONTEXT-FREE PARALLEL REDUCTION ON TERMS *********************************)
  20
  21 (* Confluence lemmas ********************************************************)
  22
  23 lemma tpr_conf_sort_sort: ∀k. ∃∃X. ⋆k ⇒ X & ⋆k ⇒ X.
  24 /2/ qed.
  25
  26 lemma tpr_conf_lref_lref: ∀i. ∃∃X. #i ⇒ X & #i ⇒ X.
  27 /2/ qed.
  28
  29 lemma tpr_conf_bind_bind:
  30    ∀I,V0,V1,T0,T1,V2,T2. (
  31       ∀X0:term. #X0 < #V0 + #T0 + 1 →
  32       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  33       ∃∃X. X1 ⇒ X & X2 ⇒ X
  34    ) →
  35    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
  36    ∃∃X. 𝕓{I} V1. T1 ⇒ X & 𝕓{I} V2. T2 ⇒ X.
  37 #I #V0 #V1 #T0 #T1 #V2 #T2 #IH #HV01 #HV02 #HT01 #HT02
  38 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
  39 elim (IH … HT01 … HT02) -HT01 HT02 IH /3 width=5/
  40 qed.
  41
  42 lemma tpr_conf_bind_delta:
  43    ∀V0,V1,T0,T1,V2,T2,T. (
  44       ∀X0:term. #X0 < #V0 + #T0 + 1 →
  45       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  46       ∃∃X. X1 ⇒ X & X2 ⇒ X
  47    ) →
  48    V0 ⇒ V1 → V0 ⇒ V2 →
  49    T0 ⇒ T1 → T0 ⇒ T2 → ⋆. 𝕓{Abbr} V2 ⊢ T2 [O,1] ≫ T →
  50    ∃∃X. 𝕓{Abbr} V1. T1 ⇒ X & 𝕓{Abbr} V2. T ⇒ X.
  51 #V0 #V1 #T0 #T1 #V2 #T2 #T #IH #HV01 #HV02 #HT01 #HT02 #HT2
  52 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
  53 elim (IH … HT01 … HT02) -HT01 HT02 IH // -V0 T0 #T0 #HT10 #HT20
  54 elim (tpr_tps_bind … HV2 HT20 … HT2) -HT20 HT2 /3 width=5/
  55 qed.
  56
  57 lemma tpr_conf_bind_zeta:
  58    ∀X2,V0,V1,T0,T1,T. (
  59       ∀X0:term. #X0 < #V0 + #T0 +1 →
  60       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  61       ∃∃X. X1 ⇒ X & X2 ⇒ X
  62    ) →
  63    V0 ⇒ V1 → T0 ⇒ T1 → T ⇒ X2 → ↑[O, 1] T ≡ T0 →
  64    ∃∃X. 𝕓{Abbr} V1. T1 ⇒ X & X2 ⇒ X.
  65 #X2 #V0 #V1 #T0 #T1 #T #IH #HV01 #HT01 #HTX2 #HT0
  66 elim (tpr_inv_lift … HT01 … HT0) -HT01 #U #HUT1 #HTU
  67 lapply (tw_lift … HT0) -HT0 #HT0
  68 elim (IH … HTX2 … HTU) -HTX2 HTU IH /3/
  69 qed.
  70
  71 lemma tpr_conf_flat_flat:
  72    ∀I,V0,V1,T0,T1,V2,T2. (
  73       ∀X0:term. #X0 < #V0 + #T0 + 1 →
  74       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  75       ∃∃X. X1 ⇒ X & X2 ⇒ X
  76    ) →
  77    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
  78    ∃∃T0. 𝕗{I} V1. T1 ⇒ T0 & 𝕗{I} V2. T2 ⇒ T0.
  79 #I #V0 #V1 #T0 #T1 #V2 #T2 #IH #HV01 #HV02 #HT01 #HT02
  80 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
  81 elim (IH … HT01 … HT02) -HT01 HT02 /3 width=5/
  82 qed.
  83
  84 lemma tpr_conf_flat_beta:
  85    ∀V0,V1,T1,V2,W0,U0,T2. (
  86       ∀X0:term. #X0 < #V0 + (#W0 + #U0 + 1) + 1 →
  87       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  88       ∃∃X. X1 ⇒ X & X2 ⇒ X
  89    ) →
  90    V0 ⇒ V1 → V0 ⇒ V2 →
  91    U0 ⇒ T2 → 𝕓{Abst} W0. U0 ⇒ T1 →
  92    ∃∃X. 𝕗{Appl} V1. T1 ⇒ X & 𝕓{Abbr} V2. T2 ⇒ X.
  93 #V0 #V1 #T1 #V2 #W0 #U0 #T2 #IH #HV01 #HV02 #HT02 #H
  94 elim (tpr_inv_abst1 … H) -H #W1 #U1 #HW01 #HU01 #H destruct -T1;
  95 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
  96 elim (IH … HT02 … HU01) -HT02 HU01 IH /3 width=5/
  97 qed.
  98
  99 lemma tpr_conf_flat_theta:
 100    ∀V0,V1,T1,V2,V,W0,W2,U0,U2. (
 101       ∀X0:term. #X0 < #V0 + (#W0 + #U0 + 1) + 1 →
 102       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 103       ∃∃X. X1 ⇒ X & X2 ⇒ X
 104    ) →
 105    V0 ⇒ V1 → V0 ⇒ V2 → ↑[O,1] V2 ≡ V →
 106    W0 ⇒ W2 → U0 ⇒ U2 →  𝕓{Abbr} W0. U0 ⇒ T1 →
 107    ∃∃X. 𝕗{Appl} V1. T1 ⇒ X & 𝕓{Abbr} W2. 𝕗{Appl} V. U2 ⇒ X.
 108 #V0 #V1 #T1 #V2 #V #W0 #W2 #U0 #U2 #IH #HV01 #HV02 #HV2 #HW02 #HU02 #H
 109 elim (IH … HV01 … HV02) -HV01 HV02 // #VV #HVV1 #HVV2
 110 elim (lift_total VV 0 1) #VVV #HVV
 111 lapply (tpr_lift … HVV2 … HV2 … HVV) #HVVV
 112 elim (tpr_inv_abbr1 … H) -H *
 113 (* case 1: bind *)
 114 [ -HV2 HVV2 #WW #UU #HWW0 #HUU0 #H destruct -T1;
 115   elim (IH … HW02 … HWW0) -HW02 HWW0 // #W #HW2 #HWW
 116   elim (IH … HU02 … HUU0) -HU02 HUU0 IH // #U #HU2 #HUU
 117   @ex2_1_intro [2: @tpr_theta |1:skip |3: @tpr_bind ] /2 width=7/ (**) (* /4 width=7/ is too slow *)
 118 (* case 2: delta *)
 119 | -HV2 HVV2 #WW2 #UU2 #UU #HWW2 #HUU02 #HUU2 #H destruct -T1;
 120   elim (IH … HW02 … HWW2) -HW02 HWW2 // #W #HW02 #HWW2
 121   elim (IH … HU02 … HUU02) -HU02 HUU02 IH // #U #HU2 #HUUU2
 122   elim (tpr_tps_bind … HWW2 HUUU2 … HUU2) -HUU2 HUUU2 #UUU #HUUU2 #HUUU1
 123   @ex2_1_intro
 124   [2: @tpr_theta [6: @HVV |7: @HWW2 |8: @HUUU2 |1,2,3,4: skip | // ]
 125   |1:skip
 126   |3: @tpr_delta [3: @tpr_flat |1: skip ] /2 width=5/
 127   ] (**) (* /5 width=14/ is too slow *)
 128 (* case 3: zeta *)
 129 | -HW02 HVV HVVV #UU1 #HUU10 #HUUT1
 130   elim (tpr_inv_lift … HU02 … HUU10) -HU02 #UU #HUU2 #HUU1
 131   lapply (tw_lift … HUU10) -HUU10 #HUU10
 132   elim (IH … HUUT1 … HUU1) -HUUT1 HUU1 IH // -HUU10 #U #HU2 #HUUU2
 133   @ex2_1_intro
 134   [2: @tpr_flat
 135   |1: skip
 136   |3: @tpr_zeta [2: @lift_flat |1: skip |3: @tpr_flat ]
 137   ] /2 width=5/ (**) (* /5 width=5/ is too slow *)
 138 ]
 139 qed.
 140
 141 lemma tpr_conf_flat_cast:
 142    ∀X2,V0,V1,T0,T1. (
 143       ∀X0:term. #X0 < #V0 + # T0 + 1 →
 144       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 145       ∃∃X. X1 ⇒ X & X2 ⇒ X
 146    ) →
 147    V0 ⇒ V1 → T0 ⇒ T1 → T0 ⇒ X2 →
 148    ∃∃X. 𝕗{Cast} V1. T1 ⇒ X & X2 ⇒ X.
 149 #X2 #V0 #V1 #T0 #T1 #IH #_ #HT01 #HT02
 150 elim (IH … HT01 … HT02) -HT01 HT02 IH /3/
 151 qed.
 152
 153 lemma tpr_conf_beta_beta:
 154    ∀W0:term. ∀V0,V1,T0,T1,V2,T2. (
 155       ∀X0:term. #X0 < #V0 + (#W0 + #T0 + 1) + 1 →
 156       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 157       ∃∃X. X1 ⇒ X & X2 ⇒ X
 158    ) →
 159    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
 160    ∃∃X. 𝕓{Abbr} V1. T1 ⇒X & 𝕓{Abbr} V2. T2 ⇒ X.
 161 #W0 #V0 #V1 #T0 #T1 #V2 #T2 #IH #HV01 #HV02 #HT01 #HT02
 162 elim (IH … HV01 … HV02) -HV01 HV02 //
 163 elim (IH … HT01 … HT02) -HT01 HT02 IH /3 width=5/
 164 qed.
 165
 166 lemma tpr_conf_delta_delta:
 167    ∀V0,V1,T0,T1,TT1,V2,T2,TT2. (
 168       ∀X0:term. #X0 < #V0 +#T0 + 1→
 169       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 170       ∃∃X. X1 ⇒ X & X2 ⇒ X
 171    ) →
 172    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
 173    ⋆. 𝕓{Abbr} V1 ⊢ T1 [O, 1] ≫ TT1 →
 174    ⋆. 𝕓{Abbr} V2 ⊢ T2 [O, 1] ≫ TT2 →
 175    ∃∃X. 𝕓{Abbr} V1. TT1 ⇒ X & 𝕓{Abbr} V2. TT2 ⇒ X.
 176 #V0 #V1 #T0 #T1 #TT1 #V2 #T2 #TT2 #IH #HV01 #HV02 #HT01 #HT02 #HTT1 #HTT2
 177 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
 178 elim (IH … HT01 … HT02) -HT01 HT02 IH // #T #HT1 #HT2
 179 elim (tpr_tps_bind … HV1 HT1 … HTT1) -HT1 HTT1 #U1 #TTU1 #HTU1
 180 elim (tpr_tps_bind … HV2 HT2 … HTT2) -HT2 HTT2 #U2 #TTU2 #HTU2
 181 elim (tps_conf … HTU1 … HTU2) -HTU1 HTU2 #U #HU1 #HU2
 182 @ex2_1_intro [2,3: @tpr_delta |1: skip ] /width=10/ (**) (* /3 width=10/ is too slow *)
 183 qed.
 184
 185 lemma tpr_conf_delta_zeta:
 186    ∀X2,V0,V1,T0,T1,TT1,T2. (
 187       ∀X0:term. #X0 < #V0 +#T0 + 1→
 188       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 189       ∃∃X. X1 ⇒ X & X2 ⇒ X
 190    ) →
 191    V0 ⇒ V1 → T0 ⇒ T1 → ⋆. 𝕓{Abbr} V1 ⊢ T1 [O,1] ≫ TT1 →
 192    T2 ⇒ X2 → ↑[O, 1] T2 ≡ T0 →
 193    ∃∃X. 𝕓{Abbr} V1. TT1 ⇒ X & X2 ⇒ X.
 194 #X2 #V0 #V1 #T0 #T1 #TT1 #T2 #IH #_ #HT01 #HTT1 #HTX2 #HTT20
 195 elim (tpr_inv_lift … HT01 … HTT20) -HT01 #TT2 #HTT21 #HTT2
 196 lapply (tps_inv_lift1_eq … HTT1 … HTT21) -HTT1 #HTT1 destruct -T1;
 197 lapply (tw_lift … HTT20) -HTT20 #HTT20
 198 elim (IH … HTX2 … HTT2) -HTX2 HTT2 IH /3/
 199 qed.
 200
 201 lemma tpr_conf_theta_theta:
 202    ∀VV1,V0,V1,W0,W1,T0,T1,V2,VV2,W2,T2. (
 203       ∀X0:term. #X0 < #V0 + (#W0 + #T0 + 1) + 1 →
 204       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 205       ∃∃X. X1 ⇒ X & X2 ⇒ X
 206    ) →
 207    V0 ⇒ V1 → V0 ⇒ V2 → W0 ⇒ W1 → W0 ⇒ W2 → T0 ⇒ T1 → T0 ⇒ T2 →
 208    ↑[O, 1] V1 ≡ VV1 → ↑[O, 1] V2 ≡ VV2 →
 209    ∃∃X. 𝕓{Abbr} W1. 𝕗{Appl} VV1. T1 ⇒ X & 𝕓{Abbr} W2. 𝕗{Appl} VV2. T2 ⇒ X.
 210 #VV1 #V0 #V1 #W0 #W1 #T0 #T1 #V2 #VV2 #W2 #T2 #IH #HV01 #HV02 #HW01 #HW02 #HT01 #HT02 #HVV1 #HVV2
 211 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
 212 elim (IH … HW01 … HW02) -HW01 HW02 // #W #HW1 #HW2
 213 elim (IH … HT01 … HT02) -HT01 HT02 IH // #T #HT1 #HT2
 214 elim (lift_total V 0 1) #VV #HVV
 215 lapply (tpr_lift … HV1 … HVV1 … HVV) -HV1 HVV1 #HVV1
 216 lapply (tpr_lift … HV2 … HVV2 … HVV) -HV2 HVV2 HVV #HVV2
 217 @ex2_1_intro [2,3: @tpr_bind |1:skip ] /2 width=5/ (**) (* /4 width=5/ is too slow *)
 218 qed.
 219
 220 lemma tpr_conf_zeta_zeta:
 221    ∀V0:term. ∀X2,TT0,T0,T1,T2. (
 222       ∀X0:term. #X0 < #V0 + #TT0 + 1 →
 223       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 224       ∃∃X. X1 ⇒ X & X2 ⇒ X
 225    ) →
 226    T0 ⇒ T1 → T2 ⇒ X2 →
 227    ↑[O, 1] T0 ≡ TT0 → ↑[O, 1] T2 ≡ TT0 →
 228    ∃∃X. T1 ⇒ X & X2 ⇒ X.
 229 #V0 #X2 #TT0 #T0 #T1 #T2 #IH #HT01 #HTX2 #HTT0 #HTT20
 230 lapply (lift_inj … HTT0 … HTT20) -HTT0 #H destruct -T0;
 231 lapply (tw_lift … HTT20) -HTT20 #HTT20
 232 elim (IH … HT01 … HTX2) -HT01 HTX2 IH /2/
 233 qed.
 234
 235 lemma tpr_conf_tau_tau:
 236    ∀V0,T0:term. ∀X2,T1. (
 237       ∀X0:term. #X0 < #V0 + #T0 + 1 →
 238       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 239       ∃∃X. X1 ⇒ X & X2 ⇒ X
 240    ) →
 241    T0 ⇒ T1 → T0 ⇒ X2 →
 242    ∃∃X. T1 ⇒ X & X2 ⇒ X.
 243 #V0 #T0 #X2 #T1 #IH #HT01 #HT02
 244 elim (IH … HT01 … HT02) -HT01 HT02 IH /2/
 245 qed.
 246
 247 (* Confluence ***************************************************************)
 248
 249 lemma tpr_conf_aux:
 250    ∀Y0:term. (
 251       ∀X0:term. #X0 < #Y0 → ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 252       ∃∃X. X1 ⇒ X & X2 ⇒ X
 253          ) →
 254    ∀X0,X1,X2. X0 ⇒ X1 → X0 ⇒ X2 → X0 = Y0 →
 255    ∃∃X. X1 ⇒ X & X2 ⇒ X.
 256 #Y0 #IH #X0 #X1 #X2 * -X0 X1
 257 [ #k1 #H1 #H2 destruct -Y0;
 258   lapply (tpr_inv_sort1 … H1) -H1
 259 (* case 1: sort, sort *)
 260   #H1 destruct -X2 //
 261 | #i1 #H1 #H2 destruct -Y0;
 262   lapply (tpr_inv_lref1 … H1) -H1
 263 (* case 2: lref, lref *)
 264   #H1 destruct -X2 //
 265 | #I #V0 #V1 #T0 #T1 #HV01 #HT01 #H1 #H2 destruct -Y0;
 266   elim (tpr_inv_bind1 … H1) -H1 *
 267 (* case 3: bind, bind *)
 268   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 269     /3 width=7 by tpr_conf_bind_bind/ (**) (* /3 width=7/ is too slow *)
 270 (* case 4: bind, delta *)
 271   | #V2 #T2 #T #HV02 #HT02 #HT2 #H1 #H2 destruct -X2 I
 272     /3 width=9 by tpr_conf_bind_delta/ (**) (* /3 width=9/ is too slow *)
 273 (* case 5: bind, zeta *)
 274   | #T #HT0 #HTX2 #H destruct -I
 275     /3 width=8 by tpr_conf_bind_zeta/ (**) (* /3 width=8/ is too slow *)
 276   ]
 277 | #I #V0 #V1 #T0 #T1 #HV01 #HT01 #H1 #H2 destruct -Y0;
 278   elim (tpr_inv_flat1 … H1) -H1 *
 279 (* case 6: flat, flat *)
 280   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 281     /3 width=7 by tpr_conf_flat_flat/ (**) (* /3 width=7/ is too slow *)
 282 (* case 7: flat, beta *)
 283   | #V2 #W #U0 #T2 #HV02 #HT02 #H1 #H2 #H3 destruct -T0 X2 I
 284     /3 width=8 by tpr_conf_flat_beta/ (**) (* /3 width=8/ is too slow *)
 285 (* case 8: flat, theta *)
 286   | #V2 #V #W0 #W2 #U0 #U2 #HV02 #HW02 #HT02 #HV2 #H1 #H2 #H3 destruct -T0 X2 I
 287     /3 width=11 by tpr_conf_flat_theta/ (**) (* /3 width=11/ is too slow *)
 288 (* case 9: flat, tau *)
 289   | #HT02 #H destruct -I
 290     /3 width=6 by tpr_conf_flat_cast/ (**) (* /3 width=6/ is too slow *)
 291   ]
 292 | #V0 #V1 #W0 #T0 #T1 #HV01 #HT01 #H1 #H2 destruct -Y0;
 293   elim (tpr_inv_appl1 … H1) -H1 *
 294 (* case 10: beta, flat (repeated) *)
 295   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 296     @ex2_1_comm /3 width=8 by tpr_conf_flat_beta/
 297 (* case 11: beta, beta *)
 298   | #V2 #WW0 #TT0 #T2 #HV02 #HT02 #H1 #H2 destruct -W0 T0 X2
 299     /3 width=8 by tpr_conf_beta_beta/ (**) (* /3 width=8/ is too slow *)
 300 (* case 12, beta, theta (excluded) *)
 301   | #V2 #VV2 #WW0 #W2 #TT0 #T2 #_ #_ #_ #_ #H destruct
 302   ]
 303 | #V0 #V1 #T0 #T1 #TT1 #HV01 #HT01 #HTT1 #H1 #H2 destruct -Y0;
 304   elim (tpr_inv_abbr1 … H1) -H1 *
 305 (* case 13: delta, bind (repeated) *)
 306   [ #V2 #T2 #HV02 #T02 #H destruct -X2
 307     @ex2_1_comm /3 width=9 by tpr_conf_bind_delta/
 308 (* case 14: delta, delta *)
 309   | #V2 #T2 #TT2 #HV02 #HT02 #HTT2 #H destruct -X2
 310     /3 width=11 by tpr_conf_delta_delta/ (**) (* /3 width=11/ is too slow *)
 311 (* case 15: delta, zata *)
 312   | #T2 #HT20 #HTX2
 313     /3 width=10 by tpr_conf_delta_zeta/ (**) (* /3 width=10/ is too slow *)
 314   ]
 315 | #VV1 #V0 #V1 #W0 #W1 #T0 #T1 #HV01 #HVV1 #HW01 #HT01 #H1 #H2 destruct -Y0;
 316   elim (tpr_inv_appl1 … H1) -H1 *
 317 (* case 16: theta, flat (repeated) *)
 318   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 319     @ex2_1_comm /3 width=11 by tpr_conf_flat_theta/
 320 (* case 17: theta, beta (repeated) *)
 321   | #V2 #WW0 #TT0 #T2 #_ #_ #H destruct
 322 (* case 18: theta, theta *)
 323   | #V2 #VV2 #WW0 #W2 #TT0 #T2 #V02 #HW02 #HT02 #HVV2 #H1 #H2 destruct -W0 T0 X2
 324     /3 width=14 by tpr_conf_theta_theta/  (**) (* /3 width=14/ is too slow *)
 325   ]
 326 | #V0 #TT0 #T0 #T1 #HTT0 #HT01 #H1 #H2 destruct -Y0;
 327   elim (tpr_inv_abbr1 … H1) -H1 *
 328 (* case 19: zeta, bind (repeated) *)
 329   [ #V2 #T2 #HV02 #T02 #H destruct -X2
 330     @ex2_1_comm /3 width=8 by tpr_conf_bind_zeta/
 331 (* case 20: zeta, delta (repeated) *)
 332   | #V2 #T2 #TT2 #HV02 #HT02 #HTT2 #H destruct -X2
 333     @ex2_1_comm /3 width=10 by tpr_conf_delta_zeta/
 334 (* case 21: zeta, zeta *)
 335   | #T2 #HTT20 #HTX2
 336     /3 width=9 by tpr_conf_zeta_zeta/ (**) (* /3 width=9/ is too slow *)
 337   ]
 338 | #V0 #T0 #T1 #HT01 #H1 #H2 destruct -Y0;
 339   elim (tpr_inv_cast1 … H1) -H1
 340 (* case 22: tau, flat (repeated) *)
 341   [ * #V2 #T2 #HV02 #HT02 #H destruct -X2
 342     @ex2_1_comm /3 width=6 by tpr_conf_flat_cast/
 343 (* case 23: tau, tau *)
 344   | #HT02
 345     /2 by tpr_conf_tau_tau/
 346   ]
 347 ]
 348 qed.
 349
 350 theorem tpr_conf: ∀T0:term. ∀T1,T2. T0 ⇒ T1 → T0 ⇒ T2 →
 351                   ∃∃T. T1 ⇒ T & T2 ⇒ T.
 352 #T @(tw_wf_ind … T) -T /3 width=6 by tpr_conf_aux/
 353 qed.