matita/matita/contribs/lambda-delta/Basic-2/reduction/tpr_tpr.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic-2/substitution/tps_tps.ma".
  16 include "Basic-2/reduction/tpr_lift.ma".
  17 include "Basic-2/reduction/tpr_tps.ma".
  18
  19 (* CONTEXT-FREE PARALLEL REDUCTION ON TERMS *********************************)
  20
  21 (* Confluence lemmas ********************************************************)
  22
  23 fact tpr_conf_sort_sort: ∀k. ∃∃X. ⋆k ⇒ X & ⋆k ⇒ X.
  24 /2/ qed.
  25
  26 fact tpr_conf_lref_lref: ∀i. ∃∃X. #i ⇒ X & #i ⇒ X.
  27 /2/ qed.
  28
  29 fact tpr_conf_flat_flat:
  30    ∀I,V0,V1,T0,T1,V2,T2. (
  31       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
  32       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  33       ∃∃X. X1 ⇒ X & X2 ⇒ X
  34    ) →
  35    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
  36    ∃∃T0. 𝕗{I} V1. T1 ⇒ T0 & 𝕗{I} V2. T2 ⇒ T0.
  37 #I #V0 #V1 #T0 #T1 #V2 #T2 #IH #HV01 #HV02 #HT01 #HT02
  38 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
  39 elim (IH … HT01 … HT02) -HT01 HT02 /3 width=5/
  40 qed.
  41
  42 fact tpr_conf_flat_beta:
  43    ∀V0,V1,T1,V2,W0,U0,T2. (
  44       ∀X0:term. #[X0] < #[V0] + (#[W0] + #[U0] + 1) + 1 →
  45       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  46       ∃∃X. X1 ⇒ X & X2 ⇒ X
  47    ) →
  48    V0 ⇒ V1 → V0 ⇒ V2 →
  49    U0 ⇒ T2 → 𝕓{Abst} W0. U0 ⇒ T1 →
  50    ∃∃X. 𝕗{Appl} V1. T1 ⇒ X & 𝕓{Abbr} V2. T2 ⇒ X.
  51 #V0 #V1 #T1 #V2 #W0 #U0 #T2 #IH #HV01 #HV02 #HT02 #H
  52 elim (tpr_inv_abst1 … H) -H #W1 #U1 #HW01 #HU01 #H destruct -T1;
  53 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
  54 elim (IH … HT02 … HU01) -HT02 HU01 IH /3 width=5/
  55 qed.
  56
  57 fact tpr_conf_flat_theta:
  58    ∀V0,V1,T1,V2,V,W0,W2,U0,U2. (
  59       ∀X0:term. #[X0] < #[V0] + (#[W0] + #[U0] + 1) + 1 →
  60       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  61       ∃∃X. X1 ⇒ X & X2 ⇒ X
  62    ) →
  63    V0 ⇒ V1 → V0 ⇒ V2 → ↑[O,1] V2 ≡ V →
  64    W0 ⇒ W2 → U0 ⇒ U2 →  𝕓{Abbr} W0. U0 ⇒ T1 →
  65    ∃∃X. 𝕗{Appl} V1. T1 ⇒ X & 𝕓{Abbr} W2. 𝕗{Appl} V. U2 ⇒ X.
  66 #V0 #V1 #T1 #V2 #V #W0 #W2 #U0 #U2 #IH #HV01 #HV02 #HV2 #HW02 #HU02 #H
  67 elim (IH … HV01 … HV02) -HV01 HV02 // #VV #HVV1 #HVV2
  68 elim (lift_total VV 0 1) #VVV #HVV
  69 lapply (tpr_lift … HVV2 … HV2 … HVV) #HVVV
  70 elim (tpr_inv_abbr1 … H) -H *
  71 (* case 1: delta *)
  72 [ -HV2 HVV2 #WW2 #UU2 #UU #HWW2 #HUU02 #HUU2 #H destruct -T1;
  73   elim (IH … HW02 … HWW2) -HW02 HWW2 // #W #HW02 #HWW2
  74   elim (IH … HU02 … HUU02) -HU02 HUU02 IH // #U #HU2 #HUUU2
  75   elim (tpr_tps_bind … HWW2 HUUU2 … HUU2) -HUU2 HUUU2 #UUU #HUUU2 #HUUU1
  76   @ex2_1_intro
  77   [2: @tpr_theta [6: @HVV |7: @HWW2 |8: @HUUU2 |1,2,3,4: skip | // ]
  78   |1:skip
  79   |3: @tpr_delta [3: @tpr_flat |1: skip ] /2 width=5/
  80   ] (**) (* /5 width=14/ is too slow *)
  81 (* case 3: zeta *)
  82 | -HW02 HVV HVVV #UU1 #HUU10 #HUUT1
  83   elim (tpr_inv_lift … HU02 … HUU10) -HU02 #UU #HUU2 #HUU1
  84   lapply (tw_lift … HUU10) -HUU10 #HUU10
  85   elim (IH … HUUT1 … HUU1) -HUUT1 HUU1 IH // -HUU10 #U #HU2 #HUUU2
  86   @ex2_1_intro
  87   [2: @tpr_flat
  88   |1: skip
  89   |3: @tpr_zeta [2: @lift_flat |1: skip |3: @tpr_flat ]
  90   ] /2 width=5/ (**) (* /5 width=5/ is too slow *)
  91 ]
  92 qed.
  93
  94 fact tpr_conf_flat_cast:
  95    ∀X2,V0,V1,T0,T1. (
  96       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
  97       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
  98       ∃∃X. X1 ⇒ X & X2 ⇒ X
  99    ) →
 100    V0 ⇒ V1 → T0 ⇒ T1 → T0 ⇒ X2 →
 101    ∃∃X. 𝕗{Cast} V1. T1 ⇒ X & X2 ⇒ X.
 102 #X2 #V0 #V1 #T0 #T1 #IH #_ #HT01 #HT02
 103 elim (IH … HT01 … HT02) -HT01 HT02 IH /3/
 104 qed.
 105
 106 fact tpr_conf_beta_beta:
 107    ∀W0:term. ∀V0,V1,T0,T1,V2,T2. (
 108       ∀X0:term. #[X0] < #[V0] + (#[W0] + #[T0] + 1) + 1 →
 109       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 110       ∃∃X. X1 ⇒ X & X2 ⇒ X
 111    ) →
 112    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
 113    ∃∃X. 𝕓{Abbr} V1. T1 ⇒X & 𝕓{Abbr} V2. T2 ⇒ X.
 114 #W0 #V0 #V1 #T0 #T1 #V2 #T2 #IH #HV01 #HV02 #HT01 #HT02
 115 elim (IH … HV01 … HV02) -HV01 HV02 //
 116 elim (IH … HT01 … HT02) -HT01 HT02 IH /3 width=5/
 117 qed.
 118
 119 fact tpr_conf_delta_delta:
 120    ∀I1,V0,V1,T0,T1,TT1,V2,T2,TT2. (
 121       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
 122       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 123       ∃∃X. X1 ⇒ X & X2 ⇒ X
 124    ) →
 125    V0 ⇒ V1 → V0 ⇒ V2 → T0 ⇒ T1 → T0 ⇒ T2 →
 126    ⋆. 𝕓{I1} V1 ⊢ T1 [O, 1] ≫ TT1 →
 127    ⋆. 𝕓{I1} V2 ⊢ T2 [O, 1] ≫ TT2 →
 128    ∃∃X. 𝕓{I1} V1. TT1 ⇒ X & 𝕓{I1} V2. TT2 ⇒ X.
 129 #I1 #V0 #V1 #T0 #T1 #TT1 #V2 #T2 #TT2 #IH #HV01 #HV02 #HT01 #HT02 #HTT1 #HTT2
 130 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
 131 elim (IH … HT01 … HT02) -HT01 HT02 IH // #T #HT1 #HT2
 132 elim (tpr_tps_bind … HV1 HT1 … HTT1) -HT1 HTT1 #U1 #TTU1 #HTU1
 133 elim (tpr_tps_bind … HV2 HT2 … HTT2) -HT2 HTT2 #U2 #TTU2 #HTU2
 134 elim (tps_conf … HTU1 … HTU2) -HTU1 HTU2 #U #HU1 #HU2
 135 @ex2_1_intro [2,3: @tpr_delta |1: skip ] /width=10/ (**) (* /3 width=10/ is too slow *)
 136 qed.
 137
 138 fact tpr_conf_delta_zeta:
 139    ∀X2,V0,V1,T0,T1,TT1,T2. (
 140       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
 141       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 142       ∃∃X. X1 ⇒ X & X2 ⇒ X
 143    ) →
 144    V0 ⇒ V1 → T0 ⇒ T1 → ⋆. 𝕓{Abbr} V1 ⊢ T1 [O,1] ≫ TT1 →
 145    T2 ⇒ X2 → ↑[O, 1] T2 ≡ T0 →
 146    ∃∃X. 𝕓{Abbr} V1. TT1 ⇒ X & X2 ⇒ X.
 147 #X2 #V0 #V1 #T0 #T1 #TT1 #T2 #IH #_ #HT01 #HTT1 #HTX2 #HTT20
 148 elim (tpr_inv_lift … HT01 … HTT20) -HT01 #TT2 #HTT21 #HTT2
 149 lapply (tps_inv_lift1_eq … HTT1 … HTT21) -HTT1 #HTT1 destruct -T1;
 150 lapply (tw_lift … HTT20) -HTT20 #HTT20
 151 elim (IH … HTX2 … HTT2) -HTX2 HTT2 IH /3/
 152 qed.
 153
 154 fact tpr_conf_theta_theta:
 155    ∀VV1,V0,V1,W0,W1,T0,T1,V2,VV2,W2,T2. (
 156       ∀X0:term. #[X0] < #[V0] + (#[W0] + #[T0] + 1) + 1 →
 157       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 158       ∃∃X. X1 ⇒ X & X2 ⇒ X
 159    ) →
 160    V0 ⇒ V1 → V0 ⇒ V2 → W0 ⇒ W1 → W0 ⇒ W2 → T0 ⇒ T1 → T0 ⇒ T2 →
 161    ↑[O, 1] V1 ≡ VV1 → ↑[O, 1] V2 ≡ VV2 →
 162    ∃∃X. 𝕓{Abbr} W1. 𝕗{Appl} VV1. T1 ⇒ X & 𝕓{Abbr} W2. 𝕗{Appl} VV2. T2 ⇒ X.
 163 #VV1 #V0 #V1 #W0 #W1 #T0 #T1 #V2 #VV2 #W2 #T2 #IH #HV01 #HV02 #HW01 #HW02 #HT01 #HT02 #HVV1 #HVV2
 164 elim (IH … HV01 … HV02) -HV01 HV02 // #V #HV1 #HV2
 165 elim (IH … HW01 … HW02) -HW01 HW02 // #W #HW1 #HW2
 166 elim (IH … HT01 … HT02) -HT01 HT02 IH // #T #HT1 #HT2
 167 elim (lift_total V 0 1) #VV #HVV
 168 lapply (tpr_lift … HV1 … HVV1 … HVV) -HV1 HVV1 #HVV1
 169 lapply (tpr_lift … HV2 … HVV2 … HVV) -HV2 HVV2 HVV #HVV2
 170 @ex2_1_intro [2,3: @tpr_bind |1:skip ] /2 width=5/ (**) (* /4 width=5/ is too slow *)
 171 qed.
 172
 173 fact tpr_conf_zeta_zeta:
 174    ∀V0:term. ∀X2,TT0,T0,T1,T2. (
 175       ∀X0:term. #[X0] < #[V0] + #[TT0] + 1 →
 176       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 177       ∃∃X. X1 ⇒ X & X2 ⇒ X
 178    ) →
 179    T0 ⇒ T1 → T2 ⇒ X2 →
 180    ↑[O, 1] T0 ≡ TT0 → ↑[O, 1] T2 ≡ TT0 →
 181    ∃∃X. T1 ⇒ X & X2 ⇒ X.
 182 #V0 #X2 #TT0 #T0 #T1 #T2 #IH #HT01 #HTX2 #HTT0 #HTT20
 183 lapply (lift_inj … HTT0 … HTT20) -HTT0 #H destruct -T0;
 184 lapply (tw_lift … HTT20) -HTT20 #HTT20
 185 elim (IH … HT01 … HTX2) -HT01 HTX2 IH /2/
 186 qed.
 187
 188 fact tpr_conf_tau_tau:
 189    ∀V0,T0:term. ∀X2,T1. (
 190       ∀X0:term. #[X0] < #[V0] + #[T0] + 1 →
 191       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 192       ∃∃X. X1 ⇒ X & X2 ⇒ X
 193    ) →
 194    T0 ⇒ T1 → T0 ⇒ X2 →
 195    ∃∃X. T1 ⇒ X & X2 ⇒ X.
 196 #V0 #T0 #X2 #T1 #IH #HT01 #HT02
 197 elim (IH … HT01 … HT02) -HT01 HT02 IH /2/
 198 qed.
 199
 200 (* Confluence ***************************************************************)
 201
 202 fact tpr_conf_aux:
 203    ∀Y0:term. (
 204       ∀X0:term. #[X0] < #[Y0] →
 205       ∀X1,X2. X0 ⇒ X1 → X0 ⇒ X2 →
 206       ∃∃X. X1 ⇒ X & X2 ⇒ X
 207          ) →
 208    ∀X0,X1,X2. X0 ⇒ X1 → X0 ⇒ X2 → X0 = Y0 →
 209    ∃∃X. X1 ⇒ X & X2 ⇒ X.
 210 #Y0 #IH #X0 #X1 #X2 * -X0 X1
 211 [ #k1 #H1 #H2 destruct -Y0;
 212   lapply (tpr_inv_sort1 … H1) -H1
 213 (* case 1: sort, sort *)
 214   #H1 destruct -X2 //
 215 | #i1 #H1 #H2 destruct -Y0;
 216   lapply (tpr_inv_lref1 … H1) -H1
 217 (* case 2: lref, lref *)
 218   #H1 destruct -X2 //
 219 | #I #V0 #V1 #T0 #T1 #HV01 #HT01 #H1 #H2 destruct -Y0;
 220   elim (tpr_inv_flat1 … H1) -H1 *
 221 (* case 3: flat, flat *)
 222   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 223     /3 width=7 by tpr_conf_flat_flat/ (**) (* /3 width=7/ is too slow *)
 224 (* case 4: flat, beta *)
 225   | #V2 #W #U0 #T2 #HV02 #HT02 #H1 #H2 #H3 destruct -T0 X2 I
 226     /3 width=8 by tpr_conf_flat_beta/ (**) (* /3 width=8/ is too slow *)
 227 (* case 5: flat, theta *)
 228   | #V2 #V #W0 #W2 #U0 #U2 #HV02 #HW02 #HT02 #HV2 #H1 #H2 #H3 destruct -T0 X2 I
 229     /3 width=11 by tpr_conf_flat_theta/ (**) (* /3 width=11/ is too slow *)
 230 (* case 6: flat, tau *)
 231   | #HT02 #H destruct -I
 232     /3 width=6 by tpr_conf_flat_cast/ (**) (* /3 width=6/ is too slow *)
 233   ]
 234 | #V0 #V1 #W0 #T0 #T1 #HV01 #HT01 #H1 #H2 destruct -Y0;
 235   elim (tpr_inv_appl1 … H1) -H1 *
 236 (* case 7: beta, flat (repeated) *)
 237   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 238     @ex2_1_comm /3 width=8 by tpr_conf_flat_beta/
 239 (* case 8: beta, beta *)
 240   | #V2 #WW0 #TT0 #T2 #HV02 #HT02 #H1 #H2 destruct -W0 T0 X2
 241     /3 width=8 by tpr_conf_beta_beta/ (**) (* /3 width=8/ is too slow *)
 242 (* case 9, beta, theta (excluded) *)
 243   | #V2 #VV2 #WW0 #W2 #TT0 #T2 #_ #_ #_ #_ #H destruct
 244   ]
 245 | #I1 #V0 #V1 #T0 #T1 #TT1 #HV01 #HT01 #HTT1 #H1 #H2 destruct -Y0;
 246   elim (tpr_inv_bind1 … H1) -H1 *
 247 (* case 10: delta, delta *)
 248   [ #V2 #T2 #TT2 #HV02 #HT02 #HTT2 #H destruct -X2
 249     /3 width=11 by tpr_conf_delta_delta/ (**) (* /3 width=11/ is too slow *)
 250 (* case 11: delta, zata *)
 251   | #T2 #HT20 #HTX2 #H destruct -I1;
 252     /3 width=10 by tpr_conf_delta_zeta/ (**) (* /3 width=10/ is too slow *)
 253   ]
 254 | #VV1 #V0 #V1 #W0 #W1 #T0 #T1 #HV01 #HVV1 #HW01 #HT01 #H1 #H2 destruct -Y0;
 255   elim (tpr_inv_appl1 … H1) -H1 *
 256 (* case 12: theta, flat (repeated) *)
 257   [ #V2 #T2 #HV02 #HT02 #H destruct -X2
 258     @ex2_1_comm /3 width=11 by tpr_conf_flat_theta/
 259 (* case 13: theta, beta (repeated) *)
 260   | #V2 #WW0 #TT0 #T2 #_ #_ #H destruct
 261 (* case 14: theta, theta *)
 262   | #V2 #VV2 #WW0 #W2 #TT0 #T2 #V02 #HW02 #HT02 #HVV2 #H1 #H2 destruct -W0 T0 X2
 263     /3 width=14 by tpr_conf_theta_theta/ (**) (* /3 width=14/ is too slow *)
 264   ]
 265 | #V0 #TT0 #T0 #T1 #HTT0 #HT01 #H1 #H2 destruct -Y0;
 266   elim (tpr_inv_abbr1 … H1) -H1 *
 267 (* case 15: zeta, delta (repeated) *)
 268   [ #V2 #T2 #TT2 #HV02 #HT02 #HTT2 #H destruct -X2
 269     @ex2_1_comm /3 width=10 by tpr_conf_delta_zeta/
 270 (* case 16: zeta, zeta *)
 271   | #T2 #HTT20 #HTX2
 272     /3 width=9 by tpr_conf_zeta_zeta/ (**) (* /3 width=9/ is too slow *)
 273   ]
 274 | #V0 #T0 #T1 #HT01 #H1 #H2 destruct -Y0;
 275   elim (tpr_inv_cast1 … H1) -H1
 276 (* case 17: tau, flat (repeated) *)
 277   [ * #V2 #T2 #HV02 #HT02 #H destruct -X2
 278     @ex2_1_comm /3 width=6 by tpr_conf_flat_cast/
 279 (* case 18: tau, tau *)
 280   | #HT02
 281     /2 by tpr_conf_tau_tau/
 282   ]
 283 ]
 284 qed.
 285
 286 theorem tpr_conf: ∀T0:term. ∀T1,T2. T0 ⇒ T1 → T0 ⇒ T2 →
 287                   ∃∃T. T1 ⇒ T & T2 ⇒ T.
 288 #T @(tw_wf_ind … T) -T /3 width=6 by tpr_conf_aux/
 289 qed.