matita/matita/contribs/lambda-delta/Basic-2/substitution/drop.ma

   1 (*
   2     ||M||  This file is part of HELM, an Hypertextual, Electronic
   3     ||A||  Library of Mathematics, developed at the Computer Science
   4     ||T||  Department of the University of Bologna, Italy.
   5     ||I||
   6     ||T||
   7     ||A||  This file is distributed under the terms of the
   8     \   /  GNU General Public License Version 2
   9      \ /
  10       V_______________________________________________________________ *)
  11
  12 include "lambda-delta/substitution/leq.ma".
  13 include "lambda-delta/substitution/lift.ma".
  14
  15 (* DROPPING *****************************************************************)
  16
  17 inductive drop: lenv → nat → nat → lenv → Prop ≝
  18 | drop_sort: ∀d,e. drop (⋆) d e (⋆)
  19 | drop_comp: ∀L1,L2,I,V. drop L1 0 0 L2 → drop (L1. 𝕓{I} V) 0 0 (L2. 𝕓{I} V)
  20 | drop_drop: ∀L1,L2,I,V,e. drop L1 0 e L2 → drop (L1. 𝕓{I} V) 0 (e + 1) L2
  21 | drop_skip: ∀L1,L2,I,V1,V2,d,e.
  22              drop L1 d e L2 → ↑[d,e] V2 ≡ V1 →
  23              drop (L1. 𝕓{I} V1) (d + 1) e (L2. 𝕓{I} V2)
  24 .
  25
  26 interpretation "dropping" 'RDrop L1 d e L2 = (drop L1 d e L2).
  27
  28 (* Basic inversion lemmas ***************************************************)
  29
  30 lemma drop_inv_refl_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → d = 0 → e = 0 → L1 = L2.
  31 #d #e #L1 #L2 #H elim H -H d e L1 L2
  32 [ //
  33 | #L1 #L2 #I #V #_ #IHL12 #H1 #H2
  34   >(IHL12 H1 H2) -IHL12 H1 H2 L1 //
  35 | #L1 #L2 #I #V #e #_ #_ #_ #H
  36   elim (plus_S_eq_O_false … H)
  37 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #_ #H
  38   elim (plus_S_eq_O_false … H)
  39 ]
  40 qed.
  41
  42 lemma drop_inv_refl: ∀L1,L2. ↓[0, 0] L1 ≡ L2 → L1 = L2.
  43 /2 width=5/ qed.
  44
  45 lemma drop_inv_sort1_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → L1 = ⋆ →
  46                           L2 = ⋆.
  47 #d #e #L1 #L2 * -d e L1 L2
  48 [ //
  49 | #L1 #L2 #I #V #_ #H destruct
  50 | #L1 #L2 #I #V #e #_ #H destruct
  51 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
  52 ]
  53 qed.
  54
  55 lemma drop_inv_sort1: ∀d,e,L2. ↓[d, e] ⋆ ≡ L2 → L2 = ⋆.
  56 /2 width=5/ qed.
  57
  58 lemma drop_inv_O1_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → d = 0 →
  59                        ∀K,I,V. L1 = K. 𝕓{I} V →
  60                        (e = 0 ∧ L2 = K. 𝕓{I} V) ∨
  61                        (0 < e ∧ ↓[d, e - 1] K ≡ L2).
  62 #d #e #L1 #L2 * -d e L1 L2
  63 [ #d #e #_ #K #I #V #H destruct
  64 | #L1 #L2 #I #V #HL12 #H #K #J #W #HX destruct -L1 I V
  65   >(drop_inv_refl … HL12) -HL12 K /3/
  66 | #L1 #L2 #I #V #e #HL12 #_ #K #J #W #H destruct -L1 I V /3/
  67 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H elim (plus_S_eq_O_false … H)
  68 ]
  69 qed.
  70
  71 lemma drop_inv_O1: ∀e,K,I,V,L2. ↓[0, e] K. 𝕓{I} V ≡ L2 →
  72                    (e = 0 ∧ L2 = K. 𝕓{I} V) ∨
  73                    (0 < e ∧ ↓[0, e - 1] K ≡ L2).
  74 /2/ qed.
  75
  76 lemma drop_inv_drop1: ∀e,K,I,V,L2.
  77                       ↓[0, e] K. 𝕓{I} V ≡ L2 → 0 < e → ↓[0, e - 1] K ≡ L2.
  78 #e #K #I #V #L2 #H #He
  79 elim (drop_inv_O1 … H) -H * // #H destruct -e;
  80 elim (lt_refl_false … He)
  81 qed.
  82
  83 lemma drop_inv_skip1_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → 0 < d →
  84                           ∀I,K1,V1. L1 = K1. 𝕓{I} V1 →
  85                           ∃∃K2,V2. ↓[d - 1, e] K1 ≡ K2 &
  86                                    ↑[d - 1, e] V2 ≡ V1 &
  87                                    L2 = K2. 𝕓{I} V2.
  88 #d #e #L1 #L2 * -d e L1 L2
  89 [ #d #e #_ #I #K #V #H destruct
  90 | #L1 #L2 #I #V #_ #H elim (lt_refl_false … H)
  91 | #L1 #L2 #I #V #e #_ #H elim (lt_refl_false … H)
  92 | #X #L2 #Y #Z #V2 #d #e #HL12 #HV12 #_ #I #L1 #V1 #H destruct -X Y Z
  93   /2 width=5/
  94 ]
  95 qed.
  96
  97 lemma drop_inv_skip1: ∀d,e,I,K1,V1,L2. ↓[d, e] K1. 𝕓{I} V1 ≡ L2 → 0 < d →
  98                       ∃∃K2,V2. ↓[d - 1, e] K1 ≡ K2 &
  99                                ↑[d - 1, e] V2 ≡ V1 &
 100                                L2 = K2. 𝕓{I} V2.
 101 /2/ qed.
 102
 103 lemma drop_inv_skip2_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → 0 < d →
 104                           ∀I,K2,V2. L2 = K2. 𝕓{I} V2 →
 105                           ∃∃K1,V1. ↓[d - 1, e] K1 ≡ K2 &
 106                                    ↑[d - 1, e] V2 ≡ V1 &
 107                                    L1 = K1. 𝕓{I} V1.
 108 #d #e #L1 #L2 * -d e L1 L2
 109 [ #d #e #_ #I #K #V #H destruct
 110 | #L1 #L2 #I #V #_ #H elim (lt_refl_false … H)
 111 | #L1 #L2 #I #V #e #_ #H elim (lt_refl_false … H)
 112 | #L1 #X #Y #V1 #Z #d #e #HL12 #HV12 #_ #I #L2 #V2 #H destruct -X Y Z
 113   /2 width=5/
 114 ]
 115 qed.
 116
 117 lemma drop_inv_skip2: ∀d,e,I,L1,K2,V2. ↓[d, e] L1 ≡ K2. 𝕓{I} V2 → 0 < d →
 118                       ∃∃K1,V1. ↓[d - 1, e] K1 ≡ K2 & ↑[d - 1, e] V2 ≡ V1 &
 119                                L1 = K1. 𝕓{I} V1.
 120 /2/ qed.
 121
 122 (* Basic properties *********************************************************)
 123
 124 lemma drop_refl: ∀L. ↓[0, 0] L ≡ L.
 125 #L elim L -L /2/
 126 qed.
 127
 128 lemma drop_drop_lt: ∀L1,L2,I,V,e.
 129                     ↓[0, e - 1] L1 ≡ L2 → 0 < e → ↓[0, e] L1. 𝕓{I} V ≡ L2.
 130 #L1 #L2 #I #V #e #HL12 #He >(plus_minus_m_m e 1) /2/
 131 qed.
 132
 133 lemma drop_leq_drop1: ∀L1,L2,d,e. L1 [d, e] ≈ L2 →
 134                       ∀I,K1,V,i. ↓[0, i] L1 ≡ K1. 𝕓{I} V →
 135                       d ≤ i → i < d + e →
 136                       ∃∃K2. K1 [0, d + e - i - 1] ≈ K2 &
 137                             ↓[0, i] L2 ≡ K2. 𝕓{I} V.
 138 #L1 #L2 #d #e #H elim H -H L1 L2 d e
 139 [ #d #e #I #K1 #V #i #H
 140   lapply (drop_inv_sort1 … H) -H #H destruct
 141 | #L1 #L2 #I1 #I2 #V1 #V2 #_ #_ #I #K1 #V #i #_ #_ #H
 142   elim (lt_zero_false … H)
 143 | #L1 #L2 #I #V #e #HL12 #IHL12 #J #K1 #W #i #H #_ #Hie
 144   elim (drop_inv_O1 … H) -H * #Hi #HLK1
 145   [ -IHL12 Hie; destruct -i K1 J W;
 146     <minus_n_O <minus_plus_m_m /2/
 147   | -HL12;
 148     elim (IHL12 … HLK1 ? ?) -IHL12 HLK1 // [2: /2/ ] -Hie >arith_g1 // /3/
 149   ]
 150 | #L1 #L2 #I1 #I2 #V1 #V2 #d #e #_ #IHL12 #I #K1 #V #i #H #Hdi >plus_plus_comm_23 #Hide
 151   lapply (plus_S_le_to_pos … Hdi) #Hi
 152   lapply (drop_inv_drop1 … H ?) -H // #HLK1
 153   elim (IHL12 … HLK1 ? ?) -IHL12 HLK1 [2: /2/ |3: /2/ ] -Hdi Hide >arith_g1 // /3/
 154 ]
 155 qed.
 156
 157 (* Basic forvard lemmas *****************************************************)
 158
 159 lemma drop_fwd_drop2: ∀L1,I2,K2,V2,e. ↓[O, e] L1 ≡ K2. 𝕓{I2} V2 →
 160                       ↓[O, e + 1] L1 ≡ K2.
 161 #L1 elim L1 -L1
 162 [ #I2 #K2 #V2 #e #H lapply (drop_inv_sort1 … H) -H #H destruct
 163 | #K1 #I1 #V1 #IHL1 #I2 #K2 #V2 #e #H
 164   elim (drop_inv_O1 … H) -H * #He #H
 165   [ -IHL1; destruct -e K2 I2 V2 /2/
 166   | @drop_drop >(plus_minus_m_m e 1) /2/
 167   ]
 168 ]
 169 qed.
 170
 171 lemma drop_fwd_drop2_length: ∀L1,I2,K2,V2,e.
 172                              ↓[0, e] L1 ≡ K2. 𝕓{I2} V2 → e < |L1|.
 173 #L1 elim L1 -L1
 174 [ #I2 #K2 #V2 #e #H lapply (drop_inv_sort1 … H) -H #H destruct
 175 | #K1 #I1 #V1 #IHL1 #I2 #K2 #V2 #e #H
 176   elim (drop_inv_O1 … H) -H * #He #H
 177   [ -IHL1; destruct -e K2 I2 V2 //
 178   | lapply (IHL1 … H) -IHL1 H #HeK1 whd in ⊢ (? ? %) /2/
 179   ]
 180 ]
 181 qed.
 182
 183 lemma drop_fwd_O1_length: ∀L1,L2,e. ↓[0, e] L1 ≡ L2 → |L2| = |L1| - e.
 184 #L1 elim L1 -L1
 185 [ #L2 #e #H >(drop_inv_sort1 … H) -H //
 186 | #K1 #I1 #V1 #IHL1 #L2 #e #H
 187   elim (drop_inv_O1 … H) -H * #He #H
 188   [ -IHL1; destruct -e L2 //
 189   | lapply (IHL1 … H) -IHL1 H #H >H -H; normalize
 190     >minus_le_minus_minus_comm //
 191   ]
 192 ]
 193 qed.