matita/matita/contribs/lambda-delta/Basic-2/substitution/drop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic-2/grammar/leq.ma".
  16 include "Basic-2/substitution/lift.ma".
  17
  18 (* DROPPING *****************************************************************)
  19
  20 (* Basic-1: includes: drop_skip_bind *)
  21 inductive drop: lenv → nat → nat → lenv → Prop ≝
  22 | drop_sort: ∀d,e. drop (⋆) d e (⋆)
  23 | drop_comp: ∀L1,L2,I,V. drop L1 0 0 L2 → drop (L1. 𝕓{I} V) 0 0 (L2. 𝕓{I} V)
  24 | drop_drop: ∀L1,L2,I,V,e. drop L1 0 e L2 → drop (L1. 𝕓{I} V) 0 (e + 1) L2
  25 | drop_skip: ∀L1,L2,I,V1,V2,d,e.
  26              drop L1 d e L2 → ↑[d,e] V2 ≡ V1 →
  27              drop (L1. 𝕓{I} V1) (d + 1) e (L2. 𝕓{I} V2)
  28 .
  29
  30 interpretation "dropping" 'RDrop L1 d e L2 = (drop L1 d e L2).
  31
  32 (* Basic inversion lemmas ***************************************************)
  33
  34 fact drop_inv_refl_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → d = 0 → e = 0 → L1 = L2.
  35 #d #e #L1 #L2 #H elim H -H d e L1 L2
  36 [ //
  37 | #L1 #L2 #I #V #_ #IHL12 #H1 #H2
  38   >(IHL12 H1 H2) -IHL12 H1 H2 L1 //
  39 | #L1 #L2 #I #V #e #_ #_ #_ #H
  40   elim (plus_S_eq_O_false … H)
  41 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #_ #H
  42   elim (plus_S_eq_O_false … H)
  43 ]
  44 qed.
  45
  46 (* Basic-1: was: drop_gen_refl *)
  47 lemma drop_inv_refl: ∀L1,L2. ↓[0, 0] L1 ≡ L2 → L1 = L2.
  48 /2 width=5/ qed.
  49
  50 fact drop_inv_sort1_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → L1 = ⋆ →
  51                          L2 = ⋆.
  52 #d #e #L1 #L2 * -d e L1 L2
  53 [ //
  54 | #L1 #L2 #I #V #_ #H destruct
  55 | #L1 #L2 #I #V #e #_ #H destruct
  56 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
  57 ]
  58 qed.
  59
  60 (* Basic-1: was: drop_gen_sort *)
  61 lemma drop_inv_sort1: ∀d,e,L2. ↓[d, e] ⋆ ≡ L2 → L2 = ⋆.
  62 /2 width=5/ qed.
  63
  64 fact drop_inv_O1_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → d = 0 →
  65                       ∀K,I,V. L1 = K. 𝕓{I} V →
  66                       (e = 0 ∧ L2 = K. 𝕓{I} V) ∨
  67                       (0 < e ∧ ↓[d, e - 1] K ≡ L2).
  68 #d #e #L1 #L2 * -d e L1 L2
  69 [ #d #e #_ #K #I #V #H destruct
  70 | #L1 #L2 #I #V #HL12 #H #K #J #W #HX destruct -L1 I V
  71   >(drop_inv_refl … HL12) -HL12 K /3/
  72 | #L1 #L2 #I #V #e #HL12 #_ #K #J #W #H destruct -L1 I V /3/
  73 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H elim (plus_S_eq_O_false … H)
  74 ]
  75 qed.
  76
  77 lemma drop_inv_O1: ∀e,K,I,V,L2. ↓[0, e] K. 𝕓{I} V ≡ L2 →
  78                    (e = 0 ∧ L2 = K. 𝕓{I} V) ∨
  79                    (0 < e ∧ ↓[0, e - 1] K ≡ L2).
  80 /2/ qed.
  81
  82 (* Basic-1: was: drop_gen_drop *)
  83 lemma drop_inv_drop1: ∀e,K,I,V,L2.
  84                       ↓[0, e] K. 𝕓{I} V ≡ L2 → 0 < e → ↓[0, e - 1] K ≡ L2.
  85 #e #K #I #V #L2 #H #He
  86 elim (drop_inv_O1 … H) -H * // #H destruct -e;
  87 elim (lt_refl_false … He)
  88 qed.
  89
  90 fact drop_inv_skip1_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → 0 < d →
  91                          ∀I,K1,V1. L1 = K1. 𝕓{I} V1 →
  92                          ∃∃K2,V2. ↓[d - 1, e] K1 ≡ K2 &
  93                                   ↑[d - 1, e] V2 ≡ V1 &
  94                                   L2 = K2. 𝕓{I} V2.
  95 #d #e #L1 #L2 * -d e L1 L2
  96 [ #d #e #_ #I #K #V #H destruct
  97 | #L1 #L2 #I #V #_ #H elim (lt_refl_false … H)
  98 | #L1 #L2 #I #V #e #_ #H elim (lt_refl_false … H)
  99 | #X #L2 #Y #Z #V2 #d #e #HL12 #HV12 #_ #I #L1 #V1 #H destruct -X Y Z
 100   /2 width=5/
 101 ]
 102 qed.
 103
 104 (* Basic-1: was: drop_gen_skip_l *)
 105 lemma drop_inv_skip1: ∀d,e,I,K1,V1,L2. ↓[d, e] K1. 𝕓{I} V1 ≡ L2 → 0 < d →
 106                       ∃∃K2,V2. ↓[d - 1, e] K1 ≡ K2 &
 107                                ↑[d - 1, e] V2 ≡ V1 &
 108                                L2 = K2. 𝕓{I} V2.
 109 /2/ qed.
 110
 111 fact drop_inv_skip2_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → 0 < d →
 112                          ∀I,K2,V2. L2 = K2. 𝕓{I} V2 →
 113                          ∃∃K1,V1. ↓[d - 1, e] K1 ≡ K2 &
 114                                   ↑[d - 1, e] V2 ≡ V1 &
 115                                   L1 = K1. 𝕓{I} V1.
 116 #d #e #L1 #L2 * -d e L1 L2
 117 [ #d #e #_ #I #K #V #H destruct
 118 | #L1 #L2 #I #V #_ #H elim (lt_refl_false … H)
 119 | #L1 #L2 #I #V #e #_ #H elim (lt_refl_false … H)
 120 | #L1 #X #Y #V1 #Z #d #e #HL12 #HV12 #_ #I #L2 #V2 #H destruct -X Y Z
 121   /2 width=5/
 122 ]
 123 qed.
 124
 125 (* Basic-1: was: drop_gen_skip_r *)
 126 lemma drop_inv_skip2: ∀d,e,I,L1,K2,V2. ↓[d, e] L1 ≡ K2. 𝕓{I} V2 → 0 < d →
 127                       ∃∃K1,V1. ↓[d - 1, e] K1 ≡ K2 & ↑[d - 1, e] V2 ≡ V1 &
 128                                L1 = K1. 𝕓{I} V1.
 129 /2/ qed.
 130
 131 (* Basic properties *********************************************************)
 132
 133 (* Basic-1: was by definition: drop_refl *)
 134 lemma drop_refl: ∀L. ↓[0, 0] L ≡ L.
 135 #L elim L -L /2/
 136 qed.
 137
 138 lemma drop_drop_lt: ∀L1,L2,I,V,e.
 139                     ↓[0, e - 1] L1 ≡ L2 → 0 < e → ↓[0, e] L1. 𝕓{I} V ≡ L2.
 140 #L1 #L2 #I #V #e #HL12 #He >(plus_minus_m_m e 1) /2/
 141 qed.
 142
 143 lemma drop_leq_drop1: ∀L1,L2,d,e. L1 [d, e] ≈ L2 →
 144                       ∀I,K1,V,i. ↓[0, i] L1 ≡ K1. 𝕓{I} V →
 145                       d ≤ i → i < d + e →
 146                       ∃∃K2. K1 [0, d + e - i - 1] ≈ K2 &
 147                             ↓[0, i] L2 ≡ K2. 𝕓{I} V.
 148 #L1 #L2 #d #e #H elim H -H L1 L2 d e
 149 [ #d #e #I #K1 #V #i #H
 150   lapply (drop_inv_sort1 … H) -H #H destruct
 151 | #L1 #L2 #I #K1 #V #i #_ #_ #H
 152   elim (lt_zero_false … H)
 153 | #L1 #L2 #I #V #e #HL12 #IHL12 #J #K1 #W #i #H #_ #Hie
 154   elim (drop_inv_O1 … H) -H * #Hi #HLK1
 155   [ -IHL12 Hie; destruct -i K1 J W;
 156     <minus_n_O <minus_plus_m_m /2/
 157   | -HL12;
 158     elim (IHL12 … HLK1 ? ?) -IHL12 HLK1 // [2: /2/ ] -Hie >arith_g1 // /3/
 159   ]
 160 | #L1 #L2 #I1 #I2 #V1 #V2 #d #e #_ #IHL12 #I #K1 #V #i #H #Hdi >plus_plus_comm_23 #Hide
 161   lapply (plus_S_le_to_pos … Hdi) #Hi
 162   lapply (drop_inv_drop1 … H ?) -H // #HLK1
 163   elim (IHL12 … HLK1 ? ?) -IHL12 HLK1 [2: /2/ |3: /2/ ] -Hdi Hide >arith_g1 // /3/
 164 ]
 165 qed.
 166
 167 (* Basic forvard lemmas *****************************************************)
 168
 169 (* Basic-1: was: drop_S *)
 170 lemma drop_fwd_drop2: ∀L1,I2,K2,V2,e. ↓[O, e] L1 ≡ K2. 𝕓{I2} V2 →
 171                       ↓[O, e + 1] L1 ≡ K2.
 172 #L1 elim L1 -L1
 173 [ #I2 #K2 #V2 #e #H lapply (drop_inv_sort1 … H) -H #H destruct
 174 | #K1 #I1 #V1 #IHL1 #I2 #K2 #V2 #e #H
 175   elim (drop_inv_O1 … H) -H * #He #H
 176   [ -IHL1; destruct -e K2 I2 V2 /2/
 177   | @drop_drop >(plus_minus_m_m e 1) /2/
 178   ]
 179 ]
 180 qed.
 181
 182 lemma drop_fwd_drop2_length: ∀L1,I2,K2,V2,e.
 183                              ↓[0, e] L1 ≡ K2. 𝕓{I2} V2 → e < |L1|.
 184 #L1 elim L1 -L1
 185 [ #I2 #K2 #V2 #e #H lapply (drop_inv_sort1 … H) -H #H destruct
 186 | #K1 #I1 #V1 #IHL1 #I2 #K2 #V2 #e #H
 187   elim (drop_inv_O1 … H) -H * #He #H
 188   [ -IHL1; destruct -e K2 I2 V2 //
 189   | lapply (IHL1 … H) -IHL1 H #HeK1 whd in ⊢ (? ? %) /2/
 190   ]
 191 ]
 192 qed.
 193
 194 lemma drop_fwd_O1_length: ∀L1,L2,e. ↓[0, e] L1 ≡ L2 → |L2| = |L1| - e.
 195 #L1 elim L1 -L1
 196 [ #L2 #e #H >(drop_inv_sort1 … H) -H //
 197 | #K1 #I1 #V1 #IHL1 #L2 #e #H
 198   elim (drop_inv_O1 … H) -H * #He #H
 199   [ -IHL1; destruct -e L2 //
 200   | lapply (IHL1 … H) -IHL1 H #H >H -H; normalize
 201     >minus_le_minus_minus_comm //
 202   ]
 203 ]
 204 qed.
 205
 206 (* Basic-1: removed theorems 49:
 207             drop_skip_flat
 208             cimp_flat_sx cimp_flat_dx cimp_bind cimp_getl_conf
 209             drop_clear drop_clear_O drop_clear_S
 210             clear_gen_sort clear_gen_bind clear_gen_flat clear_gen_flat_r
 211             clear_gen_all clear_clear clear_mono clear_trans clear_ctail clear_cle
 212             getl_ctail_clen getl_gen_tail clear_getl_trans getl_clear_trans
 213             getl_clear_bind getl_clear_conf getl_dec getl_drop getl_drop_conf_lt
 214             getl_drop_conf_ge getl_conf_ge_drop getl_drop_conf_rev
 215             drop_getl_trans_lt drop_getl_trans_le drop_getl_trans_ge
 216             getl_drop_trans getl_flt getl_gen_all getl_gen_sort getl_gen_O
 217             getl_gen_S getl_gen_2 getl_gen_flat getl_gen_bind getl_conf_le
 218             getl_trans getl_refl getl_head getl_flat getl_ctail getl_mono
 219 *)