matita/matita/contribs/lambda-delta/Basic-2/substitution/drop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic-2/substitution/leq.ma".
  16 include "Basic-2/substitution/lift.ma".
  17
  18 (* DROPPING *****************************************************************)
  19
  20 inductive drop: lenv → nat → nat → lenv → Prop ≝
  21 | drop_sort: ∀d,e. drop (⋆) d e (⋆)
  22 | drop_comp: ∀L1,L2,I,V. drop L1 0 0 L2 → drop (L1. 𝕓{I} V) 0 0 (L2. 𝕓{I} V)
  23 | drop_drop: ∀L1,L2,I,V,e. drop L1 0 e L2 → drop (L1. 𝕓{I} V) 0 (e + 1) L2
  24 | drop_skip: ∀L1,L2,I,V1,V2,d,e.
  25              drop L1 d e L2 → ↑[d,e] V2 ≡ V1 →
  26              drop (L1. 𝕓{I} V1) (d + 1) e (L2. 𝕓{I} V2)
  27 .
  28
  29 interpretation "dropping" 'RDrop L1 d e L2 = (drop L1 d e L2).
  30
  31 (* Basic inversion lemmas ***************************************************)
  32
  33 lemma drop_inv_refl_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → d = 0 → e = 0 → L1 = L2.
  34 #d #e #L1 #L2 #H elim H -H d e L1 L2
  35 [ //
  36 | #L1 #L2 #I #V #_ #IHL12 #H1 #H2
  37   >(IHL12 H1 H2) -IHL12 H1 H2 L1 //
  38 | #L1 #L2 #I #V #e #_ #_ #_ #H
  39   elim (plus_S_eq_O_false … H)
  40 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #_ #H
  41   elim (plus_S_eq_O_false … H)
  42 ]
  43 qed.
  44
  45 lemma drop_inv_refl: ∀L1,L2. ↓[0, 0] L1 ≡ L2 → L1 = L2.
  46 /2 width=5/ qed.
  47
  48 lemma drop_inv_sort1_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → L1 = ⋆ →
  49                           L2 = ⋆.
  50 #d #e #L1 #L2 * -d e L1 L2
  51 [ //
  52 | #L1 #L2 #I #V #_ #H destruct
  53 | #L1 #L2 #I #V #e #_ #H destruct
  54 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H destruct
  55 ]
  56 qed.
  57
  58 lemma drop_inv_sort1: ∀d,e,L2. ↓[d, e] ⋆ ≡ L2 → L2 = ⋆.
  59 /2 width=5/ qed.
  60
  61 lemma drop_inv_O1_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → d = 0 →
  62                        ∀K,I,V. L1 = K. 𝕓{I} V →
  63                        (e = 0 ∧ L2 = K. 𝕓{I} V) ∨
  64                        (0 < e ∧ ↓[d, e - 1] K ≡ L2).
  65 #d #e #L1 #L2 * -d e L1 L2
  66 [ #d #e #_ #K #I #V #H destruct
  67 | #L1 #L2 #I #V #HL12 #H #K #J #W #HX destruct -L1 I V
  68   >(drop_inv_refl … HL12) -HL12 K /3/
  69 | #L1 #L2 #I #V #e #HL12 #_ #K #J #W #H destruct -L1 I V /3/
  70 | #L1 #L2 #I #V1 #V2 #d #e #_ #_ #H elim (plus_S_eq_O_false … H)
  71 ]
  72 qed.
  73
  74 lemma drop_inv_O1: ∀e,K,I,V,L2. ↓[0, e] K. 𝕓{I} V ≡ L2 →
  75                    (e = 0 ∧ L2 = K. 𝕓{I} V) ∨
  76                    (0 < e ∧ ↓[0, e - 1] K ≡ L2).
  77 /2/ qed.
  78
  79 lemma drop_inv_drop1: ∀e,K,I,V,L2.
  80                       ↓[0, e] K. 𝕓{I} V ≡ L2 → 0 < e → ↓[0, e - 1] K ≡ L2.
  81 #e #K #I #V #L2 #H #He
  82 elim (drop_inv_O1 … H) -H * // #H destruct -e;
  83 elim (lt_refl_false … He)
  84 qed.
  85
  86 lemma drop_inv_skip1_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → 0 < d →
  87                           ∀I,K1,V1. L1 = K1. 𝕓{I} V1 →
  88                           ∃∃K2,V2. ↓[d - 1, e] K1 ≡ K2 &
  89                                    ↑[d - 1, e] V2 ≡ V1 &
  90                                    L2 = K2. 𝕓{I} V2.
  91 #d #e #L1 #L2 * -d e L1 L2
  92 [ #d #e #_ #I #K #V #H destruct
  93 | #L1 #L2 #I #V #_ #H elim (lt_refl_false … H)
  94 | #L1 #L2 #I #V #e #_ #H elim (lt_refl_false … H)
  95 | #X #L2 #Y #Z #V2 #d #e #HL12 #HV12 #_ #I #L1 #V1 #H destruct -X Y Z
  96   /2 width=5/
  97 ]
  98 qed.
  99
 100 lemma drop_inv_skip1: ∀d,e,I,K1,V1,L2. ↓[d, e] K1. 𝕓{I} V1 ≡ L2 → 0 < d →
 101                       ∃∃K2,V2. ↓[d - 1, e] K1 ≡ K2 &
 102                                ↑[d - 1, e] V2 ≡ V1 &
 103                                L2 = K2. 𝕓{I} V2.
 104 /2/ qed.
 105
 106 lemma drop_inv_skip2_aux: ∀d,e,L1,L2. ↓[d, e] L1 ≡ L2 → 0 < d →
 107                           ∀I,K2,V2. L2 = K2. 𝕓{I} V2 →
 108                           ∃∃K1,V1. ↓[d - 1, e] K1 ≡ K2 &
 109                                    ↑[d - 1, e] V2 ≡ V1 &
 110                                    L1 = K1. 𝕓{I} V1.
 111 #d #e #L1 #L2 * -d e L1 L2
 112 [ #d #e #_ #I #K #V #H destruct
 113 | #L1 #L2 #I #V #_ #H elim (lt_refl_false … H)
 114 | #L1 #L2 #I #V #e #_ #H elim (lt_refl_false … H)
 115 | #L1 #X #Y #V1 #Z #d #e #HL12 #HV12 #_ #I #L2 #V2 #H destruct -X Y Z
 116   /2 width=5/
 117 ]
 118 qed.
 119
 120 lemma drop_inv_skip2: ∀d,e,I,L1,K2,V2. ↓[d, e] L1 ≡ K2. 𝕓{I} V2 → 0 < d →
 121                       ∃∃K1,V1. ↓[d - 1, e] K1 ≡ K2 & ↑[d - 1, e] V2 ≡ V1 &
 122                                L1 = K1. 𝕓{I} V1.
 123 /2/ qed.
 124
 125 (* Basic properties *********************************************************)
 126
 127 lemma drop_refl: ∀L. ↓[0, 0] L ≡ L.
 128 #L elim L -L /2/
 129 qed.
 130
 131 lemma drop_drop_lt: ∀L1,L2,I,V,e.
 132                     ↓[0, e - 1] L1 ≡ L2 → 0 < e → ↓[0, e] L1. 𝕓{I} V ≡ L2.
 133 #L1 #L2 #I #V #e #HL12 #He >(plus_minus_m_m e 1) /2/
 134 qed.
 135
 136 lemma drop_leq_drop1: ∀L1,L2,d,e. L1 [d, e] ≈ L2 →
 137                       ∀I,K1,V,i. ↓[0, i] L1 ≡ K1. 𝕓{I} V →
 138                       d ≤ i → i < d + e →
 139                       ∃∃K2. K1 [0, d + e - i - 1] ≈ K2 &
 140                             ↓[0, i] L2 ≡ K2. 𝕓{I} V.
 141 #L1 #L2 #d #e #H elim H -H L1 L2 d e
 142 [ #d #e #I #K1 #V #i #H
 143   lapply (drop_inv_sort1 … H) -H #H destruct
 144 | #L1 #L2 #I #K1 #V #i #_ #_ #H
 145   elim (lt_zero_false … H)
 146 | #L1 #L2 #I #V #e #HL12 #IHL12 #J #K1 #W #i #H #_ #Hie
 147   elim (drop_inv_O1 … H) -H * #Hi #HLK1
 148   [ -IHL12 Hie; destruct -i K1 J W;
 149     <minus_n_O <minus_plus_m_m /2/
 150   | -HL12;
 151     elim (IHL12 … HLK1 ? ?) -IHL12 HLK1 // [2: /2/ ] -Hie >arith_g1 // /3/
 152   ]
 153 | #L1 #L2 #I1 #I2 #V1 #V2 #d #e #_ #IHL12 #I #K1 #V #i #H #Hdi >plus_plus_comm_23 #Hide
 154   lapply (plus_S_le_to_pos … Hdi) #Hi
 155   lapply (drop_inv_drop1 … H ?) -H // #HLK1
 156   elim (IHL12 … HLK1 ? ?) -IHL12 HLK1 [2: /2/ |3: /2/ ] -Hdi Hide >arith_g1 // /3/
 157 ]
 158 qed.
 159
 160 (* Basic forvard lemmas *****************************************************)
 161
 162 lemma drop_fwd_drop2: ∀L1,I2,K2,V2,e. ↓[O, e] L1 ≡ K2. 𝕓{I2} V2 →
 163                       ↓[O, e + 1] L1 ≡ K2.
 164 #L1 elim L1 -L1
 165 [ #I2 #K2 #V2 #e #H lapply (drop_inv_sort1 … H) -H #H destruct
 166 | #K1 #I1 #V1 #IHL1 #I2 #K2 #V2 #e #H
 167   elim (drop_inv_O1 … H) -H * #He #H
 168   [ -IHL1; destruct -e K2 I2 V2 /2/
 169   | @drop_drop >(plus_minus_m_m e 1) /2/
 170   ]
 171 ]
 172 qed.
 173
 174 lemma drop_fwd_drop2_length: ∀L1,I2,K2,V2,e.
 175                              ↓[0, e] L1 ≡ K2. 𝕓{I2} V2 → e < |L1|.
 176 #L1 elim L1 -L1
 177 [ #I2 #K2 #V2 #e #H lapply (drop_inv_sort1 … H) -H #H destruct
 178 | #K1 #I1 #V1 #IHL1 #I2 #K2 #V2 #e #H
 179   elim (drop_inv_O1 … H) -H * #He #H
 180   [ -IHL1; destruct -e K2 I2 V2 //
 181   | lapply (IHL1 … H) -IHL1 H #HeK1 whd in ⊢ (? ? %) /2/
 182   ]
 183 ]
 184 qed.
 185
 186 lemma drop_fwd_O1_length: ∀L1,L2,e. ↓[0, e] L1 ≡ L2 → |L2| = |L1| - e.
 187 #L1 elim L1 -L1
 188 [ #L2 #e #H >(drop_inv_sort1 … H) -H //
 189 | #K1 #I1 #V1 #IHL1 #L2 #e #H
 190   elim (drop_inv_O1 … H) -H * #He #H
 191   [ -IHL1; destruct -e L2 //
 192   | lapply (IHL1 … H) -IHL1 H #H >H -H; normalize
 193     >minus_le_minus_minus_comm //
 194   ]
 195 ]
 196 qed.