matita/matita/contribs/lambda-delta/Basic-2/substitution/drop_drop.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic-2/substitution/lift_lift.ma".
  16 include "Basic-2/substitution/drop.ma".
  17
  18 (* DROPPING *****************************************************************)
  19
  20 (* Main properties **********************************************************)
  21
  22 (* Basic-1: was: drop_mono *)
  23 theorem drop_mono: ∀d,e,L,L1. ↓[d, e] L ≡ L1 →
  24                    ∀L2. ↓[d, e] L ≡ L2 → L1 = L2.
  25 #d #e #L #L1 #H elim H -H d e L L1
  26 [ #d #e #L2 #H
  27   >(drop_inv_sort1 … H) -H L2 //
  28 | #K1 #K2 #I #V #HK12 #_ #L2 #HL12
  29    <(drop_inv_refl … HK12) -HK12 K2
  30    <(drop_inv_refl … HL12) -HL12 L2 //
  31 | #L #K #I #V #e #_ #IHLK #L2 #H
  32   lapply (drop_inv_drop1 … H ?) -H /2/
  33 | #L #K1 #I #T #V1 #d #e #_ #HVT1 #IHLK1 #X #H
  34   elim (drop_inv_skip1 … H ?) -H // <minus_plus_m_m #K2 #V2 #HLK2 #HVT2 #H destruct -X
  35   >(lift_inj … HVT1 … HVT2) -HVT1 HVT2
  36   >(IHLK1 … HLK2) -IHLK1 HLK2 //
  37 ]
  38 qed.
  39
  40 (* Basic-1: was: drop_conf_ge *)
  41 theorem drop_conf_ge: ∀d1,e1,L,L1. ↓[d1, e1] L ≡ L1 →
  42                       ∀e2,L2. ↓[0, e2] L ≡ L2 → d1 + e1 ≤ e2 →
  43                       ↓[0, e2 - e1] L1 ≡ L2.
  44 #d1 #e1 #L #L1 #H elim H -H d1 e1 L L1
  45 [ #d #e #e2 #L2 #H
  46   >(drop_inv_sort1 … H) -H L2 //
  47 | #K1 #K2 #I #V #HK12 #_ #e2 #L2 #H #_ <minus_n_O
  48    <(drop_inv_refl … HK12) -HK12 K2 //
  49 | #L #K #I #V #e #_ #IHLK #e2 #L2 #H #He2
  50   lapply (drop_inv_drop1 … H ?) -H /2/ #HL2
  51   <minus_plus_comm /3/
  52 | #L #K #I #V1 #V2 #d #e #_ #_ #IHLK #e2 #L2 #H #Hdee2
  53   lapply (transitive_le 1 … Hdee2) // #He2
  54   lapply (drop_inv_drop1 … H ?) -H // -He2 #HL2
  55   lapply (transitive_le (1 + e) … Hdee2) // #Hee2
  56   @drop_drop_lt >minus_minus_comm /3/ (**) (* explicit constructor *)
  57 ]
  58 qed.
  59
  60 (* Basic-1: was: drop_conf_lt *)
  61 theorem drop_conf_lt: ∀d1,e1,L,L1. ↓[d1, e1] L ≡ L1 →
  62                       ∀e2,K2,I,V2. ↓[0, e2] L ≡ K2. 𝕓{I} V2 →
  63                       e2 < d1 → let d ≝ d1 - e2 - 1 in
  64                       ∃∃K1,V1. ↓[0, e2] L1 ≡ K1. 𝕓{I} V1 &
  65                                ↓[d, e1] K2 ≡ K1 & ↑[d, e1] V1 ≡ V2.
  66 #d1 #e1 #L #L1 #H elim H -H d1 e1 L L1
  67 [ #d #e #e2 #K2 #I #V2 #H
  68   lapply (drop_inv_sort1 … H) -H #H destruct
  69 | #L1 #L2 #I #V #_ #_ #e2 #K2 #J #V2 #_ #H
  70   elim (lt_zero_false … H)
  71 | #L1 #L2 #I #V #e #_ #_ #e2 #K2 #J #V2 #_ #H
  72   elim (lt_zero_false … H)
  73 | #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #IHL12 #e2 #K2 #J #V #H #He2d
  74   elim (drop_inv_O1 … H) -H *
  75   [ -IHL12 He2d #H1 #H2 destruct -e2 K2 J V /2 width=5/
  76   | -HL12 -HV12 #He #HLK
  77     elim (IHL12 … HLK ?) -IHL12 HLK [ <minus_minus /3 width=5/ | /2/ ] (**) (* a bit slow *)
  78   ]
  79 ]
  80 qed.
  81
  82 (* Basic-1: was: drop_trans_le *)
  83 theorem drop_trans_le: ∀d1,e1,L1,L. ↓[d1, e1] L1 ≡ L →
  84                        ∀e2,L2. ↓[0, e2] L ≡ L2 → e2 ≤ d1 →
  85                        ∃∃L0. ↓[0, e2] L1 ≡ L0 & ↓[d1 - e2, e1] L0 ≡ L2.
  86 #d1 #e1 #L1 #L #H elim H -H d1 e1 L1 L
  87 [ #d #e #e2 #L2 #H
  88   >(drop_inv_sort1 … H) -H L2 /2/
  89 | #K1 #K2 #I #V #HK12 #_ #e2 #L2 #HL2 #H
  90   >(drop_inv_refl … HK12) -HK12 K1;
  91   lapply (le_O_to_eq_O … H) -H #H destruct -e2 /2/
  92 | #L1 #L2 #I #V #e #_ #IHL12 #e2 #L #HL2 #H
  93   lapply (le_O_to_eq_O … H) -H #H destruct -e2;
  94   elim (IHL12 … HL2 ?) -IHL12 HL2 // #L0 #H #HL0
  95   lapply (drop_inv_refl … H) -H #H destruct -L1 /3 width=5/
  96 | #L1 #L2 #I #V1 #V2 #d #e #HL12 #HV12 #IHL12 #e2 #L #H #He2d
  97   elim (drop_inv_O1 … H) -H *
  98   [ -He2d IHL12 #H1 #H2 destruct -e2 L /3 width=5/
  99   | -HL12 HV12 #He2 #HL2
 100     elim (IHL12 … HL2 ?) -IHL12 HL2 L2
 101     [ >minus_le_minus_minus_comm // /3/ | /2/ ]
 102   ]
 103 ]
 104 qed.
 105
 106 (* Basic-1: was: drop_trans_ge *)
 107 theorem drop_trans_ge: ∀d1,e1,L1,L. ↓[d1, e1] L1 ≡ L →
 108                        ∀e2,L2. ↓[0, e2] L ≡ L2 → d1 ≤ e2 → ↓[0, e1 + e2] L1 ≡ L2.
 109 #d1 #e1 #L1 #L #H elim H -H d1 e1 L1 L
 110 [ #d #e #e2 #L2 #H
 111   >(drop_inv_sort1 … H) -H L2 //
 112 | #K1 #K2 #I #V #HK12 #_ #e2 #L2 #H #_ normalize
 113   >(drop_inv_refl … HK12) -HK12 K1 //
 114 | /3/
 115 | #L1 #L2 #I #V1 #V2 #d #e #H_ #_ #IHL12 #e2 #L #H #Hde2
 116   lapply (lt_to_le_to_lt 0 … Hde2) // #He2
 117   lapply (lt_to_le_to_lt … (e + e2) He2 ?) // #Hee2
 118   lapply (drop_inv_drop1 … H ?) -H // #HL2
 119   @drop_drop_lt // >le_plus_minus // @IHL12 /2/ (**) (* explicit constructor *)
 120 ]
 121 qed.
 122
 123 theorem drop_trans_ge_comm: ∀d1,e1,e2,L1,L2,L.
 124                             ↓[d1, e1] L1 ≡ L → ↓[0, e2] L ≡ L2 → d1 ≤ e2 →
 125                             ↓[0, e2 + e1] L1 ≡ L2.
 126 #e1 #e1 #e2 >commutative_plus /2 width=5/
 127 qed.
 128
 129 (* Basic-1: was: drop_conf_rev *)
 130 axiom drop_div: ∀e1,L1,L. ↓[0, e1] L1 ≡ L → ∀e2,L2. ↓[0, e2] L2 ≡ L →
 131                 ∃∃L0. ↓[0, e1] L0 ≡ L2 & ↓[e1, e2] L0 ≡ L1.