matita/matita/contribs/lambda-delta/Basic-2/substitution/leq.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic-2/grammar/lenv_length.ma".
  16
  17 (* LOCAL ENVIRONMENT EQUALITY ***********************************************)
  18
  19 inductive leq: lenv → nat → nat → lenv → Prop ≝
  20 | leq_sort: ∀d,e. leq (⋆) d e (⋆)
  21 | leq_comp: ∀L1,L2,I1,I2,V1,V2.
  22             leq L1 0 0 L2 → leq (L1. 𝕓{I1} V1) 0 0 (L2. 𝕓{I2} V2)
  23 | leq_eq:   ∀L1,L2,I,V,e. leq L1 0 e L2 → leq (L1. 𝕓{I} V) 0 (e + 1) (L2.𝕓{I} V)
  24 | leq_skip: ∀L1,L2,I1,I2,V1,V2,d,e.
  25             leq L1 d e L2 → leq (L1. 𝕓{I1} V1) (d + 1) e (L2. 𝕓{I2} V2)
  26 .
  27
  28 interpretation "local environment equality" 'Eq L1 d e L2 = (leq L1 d e L2).
  29
  30 (* Basic properties *********************************************************)
  31
  32 lemma leq_refl: ∀d,e,L. L [d, e] ≈ L.
  33 #d elim d -d
  34 [ #e elim e -e [ #L elim L -L /2/ | #e #IHe #L elim L -L /2/ ]
  35 | #d #IHd #e #L elim L -L /2/
  36 ]
  37 qed.
  38
  39 lemma leq_sym: ∀L1,L2,d,e. L1 [d, e] ≈ L2 → L2 [d, e] ≈ L1.
  40 #L1 #L2 #d #e #H elim H -H L1 L2 d e /2/
  41 qed.
  42
  43 lemma leq_skip_lt: ∀L1,L2,d,e. L1 [d - 1, e] ≈ L2 → 0 < d →
  44                    ∀I1,I2,V1,V2. L1. 𝕓{I1} V1 [d, e] ≈ L2. 𝕓{I2} V2.
  45
  46 #L1 #L2 #d #e #HL12 #Hd >(plus_minus_m_m d 1) /2/
  47 qed.
  48
  49 lemma leq_fwd_length: ∀L1,L2,d,e. L1 [d, e] ≈ L2 → |L1| = |L2|.
  50 #L1 #L2 #d #e #H elim H -H L1 L2 d e; normalize //
  51 qed.
  52
  53 (* Basic inversion lemmas ***************************************************)
  54
  55 lemma leq_inv_sort1_aux: ∀L1,L2,d,e. L1 [d, e] ≈ L2 → L1 = ⋆ → L2 = ⋆.
  56 #L1 #L2 #d #e #H elim H -H L1 L2 d e
  57 [ //
  58 | #L1 #L2 #I1 #I2 #V1 #V2 #_ #_ #H destruct
  59 | #L1 #L2 #I #V #e #_ #_ #H destruct
  60 | #L1 #L2 #I1 #I2 #V1 #V2 #d #e #_ #_ #H destruct
  61 qed.
  62
  63 lemma leq_inv_sort1: ∀L2,d,e. ⋆ [d, e] ≈ L2 → L2 = ⋆.
  64 /2 width=5/ qed.
  65
  66 lemma leq_inv_sort2: ∀L1,d,e. L1 [d, e] ≈ ⋆ → L1 = ⋆.
  67 /3/ qed.