matita/matita/contribs/lambda-delta/Basic-2/substitution/lift.ma

   1 (**************************************************************************)
   2 (*       ___                                                              *)
   3 (*      ||M||                                                             *)
   4 (*      ||A||       A project by Andrea Asperti                           *)
   5 (*      ||T||                                                             *)
   6 (*      ||I||       Developers:                                           *)
   7 (*      ||T||         The HELM team.                                      *)
   8 (*      ||A||         http://helm.cs.unibo.it                             *)
   9 (*      \   /                                                             *)
  10 (*       \ /        This file is distributed under the terms of the       *)
  11 (*        v         GNU General Public License Version 2                  *)
  12 (*                                                                        *)
  13 (**************************************************************************)
  14
  15 include "Basic-2/grammar/term_weight.ma".
  16
  17 (* RELOCATION ***************************************************************)
  18
  19 inductive lift: term → nat → nat → term → Prop ≝
  20 | lift_sort   : ∀k,d,e. lift (⋆k) d e (⋆k)
  21 | lift_lref_lt: ∀i,d,e. i < d → lift (#i) d e (#i)
  22 | lift_lref_ge: ∀i,d,e. d ≤ i → lift (#i) d e (#(i + e))
  23 | lift_bind   : ∀I,V1,V2,T1,T2,d,e.
  24                 lift V1 d e V2 → lift T1 (d + 1) e T2 →
  25                 lift (𝕓{I} V1. T1) d e (𝕓{I} V2. T2)
  26 | lift_flat   : ∀I,V1,V2,T1,T2,d,e.
  27                 lift V1 d e V2 → lift T1 d e T2 →
  28                 lift (𝕗{I} V1. T1) d e (𝕗{I} V2. T2)
  29 .
  30
  31 interpretation "relocation" 'RLift T1 d e T2 = (lift T1 d e T2).
  32
  33 (* Basic properties *********************************************************)
  34
  35 lemma lift_lref_ge_minus: ∀d,e,i. d + e ≤ i → ↑[d, e] #(i - e) ≡ #i.
  36 #d #e #i #H >(plus_minus_m_m i e) in ⊢ (? ? ? ? %) /3/
  37 qed.
  38
  39 lemma lift_refl: ∀T,d. ↑[d, 0] T ≡ T.
  40 #T elim T -T
  41 [ * #i // #d elim (lt_or_ge i d) /2/
  42 | * /2/
  43 ]
  44 qed.
  45
  46 lemma lift_total: ∀T1,d,e. ∃T2. ↑[d,e] T1 ≡ T2.
  47 #T1 elim T1 -T1
  48 [ * #i /2/ #d #e elim (lt_or_ge i d) /3/
  49 | * #I #V1 #T1 #IHV1 #IHT1 #d #e
  50   elim (IHV1 d e) -IHV1 #V2 #HV12
  51   [ elim (IHT1 (d+1) e) -IHT1 /3/
  52   | elim (IHT1 d e) -IHT1 /3/
  53   ]
  54 ]
  55 qed.
  56
  57 lemma lift_split: ∀d1,e2,T1,T2. ↑[d1, e2] T1 ≡ T2 → ∀d2,e1.
  58                                 d1 ≤ d2 → d2 ≤ d1 + e1 → e1 ≤ e2 →
  59                                 ∃∃T. ↑[d1, e1] T1 ≡ T & ↑[d2, e2 - e1] T ≡ T2.
  60 #d1 #e2 #T1 #T2 #H elim H -H d1 e2 T1 T2
  61 [ /3/
  62 | #i #d1 #e2 #Hid1 #d2 #e1 #Hd12 #_ #_
  63   lapply (lt_to_le_to_lt … Hid1 Hd12) -Hd12 #Hid2 /4/
  64 | #i #d1 #e2 #Hid1 #d2 #e1 #_ #Hd21 #He12
  65   lapply (transitive_le …(i+e1) Hd21 ?) /2/ -Hd21 #Hd21
  66   <(arith_d1 i e2 e1) // /3/
  67 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
  68   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
  69   elim (IHT (d2+1) … ? ? He12) /3 width = 5/
  70 | #I #V1 #V2 #T1 #T2 #d1 #e2 #_ #_ #IHV #IHT #d2 #e1 #Hd12 #Hd21 #He12
  71   elim (IHV … Hd12 Hd21 He12) -IHV #V0 #HV0a #HV0b
  72   elim (IHT d2 … ? ? He12) /3 width = 5/
  73 ]
  74 qed.
  75
  76 (* Basic forward lemmas *****************************************************)
  77
  78 lemma tw_lift: ∀d,e,T1,T2. ↑[d, e] T1 ≡ T2 → #[T1] = #[T2].
  79 #d #e #T1 #T2 #H elim H -d e T1 T2; normalize //
  80 qed.
  81
  82 (* Basic inversion lemmas ***************************************************)
  83
  84 fact lift_inv_refl_aux: ∀d,e,T1,T2. ↑[d, e] T1 ≡ T2 → e = 0 → T1 = T2.
  85 #d #e #T1 #T2 #H elim H -H d e T1 T2 /3/
  86 qed.
  87
  88 lemma lift_inv_refl: ∀d,T1,T2. ↑[d, 0] T1 ≡ T2 → T1 = T2.
  89 /2/ qed.
  90
  91 fact lift_inv_sort1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀k. T1 = ⋆k → T2 = ⋆k.
  92 #d #e #T1 #T2 * -d e T1 T2 //
  93 [ #i #d #e #_ #k #H destruct
  94 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  95 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
  96 ]
  97 qed.
  98
  99 lemma lift_inv_sort1: ∀d,e,T2,k. ↑[d,e] ⋆k ≡ T2 → T2 = ⋆k.
 100 /2 width=5/ qed.
 101
 102 fact lift_inv_lref1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀i. T1 = #i →
 103                          (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
 104 #d #e #T1 #T2 * -d e T1 T2
 105 [ #k #d #e #i #H destruct
 106 | #j #d #e #Hj #i #Hi destruct /3/
 107 | #j #d #e #Hj #i #Hi destruct /3/
 108 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 109 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 110 ]
 111 qed.
 112
 113 lemma lift_inv_lref1: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 →
 114                       (i < d ∧ T2 = #i) ∨ (d ≤ i ∧ T2 = #(i + e)).
 115 /2/ qed.
 116
 117 lemma lift_inv_lref1_lt: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 → i < d → T2 = #i.
 118 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
 119 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 120 elim (lt_refl_false … Hdd)
 121 qed.
 122
 123 lemma lift_inv_lref1_ge: ∀d,e,T2,i. ↑[d,e] #i ≡ T2 → d ≤ i → T2 = #(i + e).
 124 #d #e #T2 #i #H elim (lift_inv_lref1 … H) -H * //
 125 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 126 elim (lt_refl_false … Hdd)
 127 qed.
 128
 129 fact lift_inv_bind1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 130                          ∀I,V1,U1. T1 = 𝕓{I} V1.U1 →
 131                          ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 132                                   T2 = 𝕓{I} V2. U2.
 133 #d #e #T1 #T2 * -d e T1 T2
 134 [ #k #d #e #I #V1 #U1 #H destruct
 135 | #i #d #e #_ #I #V1 #U1 #H destruct
 136 | #i #d #e #_ #I #V1 #U1 #H destruct
 137 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct /2 width=5/
 138 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct
 139 ]
 140 qed.
 141
 142 lemma lift_inv_bind1: ∀d,e,T2,I,V1,U1. ↑[d,e] 𝕓{I} V1. U1 ≡ T2 →
 143                       ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 144                                T2 = 𝕓{I} V2. U2.
 145 /2/ qed.
 146
 147 fact lift_inv_flat1_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 148                          ∀I,V1,U1. T1 = 𝕗{I} V1.U1 →
 149                          ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 150                                   T2 = 𝕗{I} V2. U2.
 151 #d #e #T1 #T2 * -d e T1 T2
 152 [ #k #d #e #I #V1 #U1 #H destruct
 153 | #i #d #e #_ #I #V1 #U1 #H destruct
 154 | #i #d #e #_ #I #V1 #U1 #H destruct
 155 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct
 156 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V1 #U1 #H destruct /2 width=5/
 157 ]
 158 qed.
 159
 160 lemma lift_inv_flat1: ∀d,e,T2,I,V1,U1. ↑[d,e] 𝕗{I} V1. U1 ≡ T2 →
 161                       ∃∃V2,U2. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 162                                T2 = 𝕗{I} V2. U2.
 163 /2/ qed.
 164
 165 fact lift_inv_sort2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀k. T2 = ⋆k → T1 = ⋆k.
 166 #d #e #T1 #T2 * -d e T1 T2 //
 167 [ #i #d #e #_ #k #H destruct
 168 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 169 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #k #H destruct
 170 ]
 171 qed.
 172
 173 lemma lift_inv_sort2: ∀d,e,T1,k. ↑[d,e] T1 ≡ ⋆k → T1 = ⋆k.
 174 /2 width=5/ qed.
 175
 176 fact lift_inv_lref2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 → ∀i. T2 = #i →
 177                          (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 178 #d #e #T1 #T2 * -d e T1 T2
 179 [ #k #d #e #i #H destruct
 180 | #j #d #e #Hj #i #Hi destruct /3/
 181 | #j #d #e #Hj #i #Hi destruct <minus_plus_m_m /4/
 182 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 183 | #I #V1 #V2 #T1 #T2 #d #e #_ #_ #i #H destruct
 184 ]
 185 qed.
 186
 187 lemma lift_inv_lref2: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i →
 188                       (i < d ∧ T1 = #i) ∨ (d + e ≤ i ∧ T1 = #(i - e)).
 189 /2/ qed.
 190
 191 lemma lift_inv_lref2_lt: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i → i < d → T1 = #i.
 192 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 193 #Hdi #_ #Hid lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 194 elim (plus_lt_false … Hdd)
 195 qed.
 196
 197 lemma lift_inv_lref2_ge: ∀d,e,T1,i. ↑[d,e] T1 ≡ #i → d + e ≤ i → T1 = #(i - e).
 198 #d #e #T1 #i #H elim (lift_inv_lref2 … H) -H * //
 199 #Hid #_ #Hdi lapply (le_to_lt_to_lt … Hdi Hid) -Hdi Hid #Hdd
 200 elim (plus_lt_false … Hdd)
 201 qed.
 202
 203 fact lift_inv_bind2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 204                          ∀I,V2,U2. T2 = 𝕓{I} V2.U2 →
 205                          ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 206                                   T1 = 𝕓{I} V1. U1.
 207 #d #e #T1 #T2 * -d e T1 T2
 208 [ #k #d #e #I #V2 #U2 #H destruct
 209 | #i #d #e #_ #I #V2 #U2 #H destruct
 210 | #i #d #e #_ #I #V2 #U2 #H destruct
 211 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct /2 width=5/
 212 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct
 213 ]
 214 qed.
 215
 216 lemma lift_inv_bind2: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  𝕓{I} V2. U2 →
 217                       ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d+1,e] U1 ≡ U2 &
 218                                T1 = 𝕓{I} V1. U1.
 219 /2/ qed.
 220
 221 fact lift_inv_flat2_aux: ∀d,e,T1,T2. ↑[d,e] T1 ≡ T2 →
 222                          ∀I,V2,U2. T2 = 𝕗{I} V2.U2 →
 223                          ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 224                                   T1 = 𝕗{I} V1. U1.
 225 #d #e #T1 #T2 * -d e T1 T2
 226 [ #k #d #e #I #V2 #U2 #H destruct
 227 | #i #d #e #_ #I #V2 #U2 #H destruct
 228 | #i #d #e #_ #I #V2 #U2 #H destruct
 229 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct
 230 | #J #W1 #W2 #T1 #T2 #d #e #HW #HT #I #V2 #U2 #H destruct /2 width = 5/
 231 ]
 232 qed.
 233
 234 lemma lift_inv_flat2: ∀d,e,T1,I,V2,U2. ↑[d,e] T1 ≡  𝕗{I} V2. U2 →
 235                       ∃∃V1,U1. ↑[d,e] V1 ≡ V2 & ↑[d,e] U1 ≡ U2 &
 236                                T1 = 𝕗{I} V1. U1.
 237 /2/ qed.